helm/ocaml/getter/http_getter.ml

   1 (* Copyright (C) 2005, HELM Team.
   2  *
   3  * This file is part of HELM, an Hypertextual, Electronic
   4  * Library of Mathematics, developed at the Computer Science
   5  * Department, University of Bologna, Italy.
   6  *
   7  * HELM is free software; you can redistribute it and/or
   8  * modify it under the terms of the GNU General Public License
   9  * as published by the Free Software Foundation; either version 2
  10  * of the License, or (at your option) any later version.
  11  *
  12  * HELM is distributed in the hope that it will be useful,
  13  * but WITHOUT ANY WARRANTY; without even the implied warranty of
  14  * MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the
  15  * GNU General Public License for more details.
  16  *
  17  * You should have received a copy of the GNU General Public License
  18  * along with HELM; if not, write to the Free Software
  19  * Foundation, Inc., 59 Temple Place - Suite 330, Boston,
  20  * MA  02111-1307, USA.
  21  *
  22  * For details, see the HELM World-Wide-Web page,
  23  * http://helm.cs.unibo.it/
  24  *)
  25
  26 open Printf
  27
  28 open Http_getter_common
  29 open Http_getter_misc
  30 open Http_getter_types
  31
  32 exception Not_implemented of string
  33 exception UnexpectedGetterOutput
  34
  35 type resolve_result =
  36   | Unknown
  37   | Exception of exn
  38   | Resolved of string
  39
  40 type logger_callback = HelmLogger.html_tag -> unit
  41
  42 let stdout_logger tag = print_string (HelmLogger.string_of_html_tag tag)
  43
  44 let not_implemented s = raise (Not_implemented ("Http_getter." ^ s))
  45
  46 let index_line_sep_RE     = Pcre.regexp "[ \t]+"
  47 let index_sep_RE          = Pcre.regexp "\r\n|\r|\n"
  48 let trailing_types_RE     = Pcre.regexp "\\.types$"
  49 let heading_cic_RE        = Pcre.regexp "^cic:"
  50 let heading_theory_RE     = Pcre.regexp "^theory:"
  51 let heading_nuprl_RE      = Pcre.regexp "^nuprl:"
  52 let types_RE              = Pcre.regexp "\\.types$"
  53 let types_ann_RE          = Pcre.regexp "\\.types\\.ann$"
  54 let body_RE               = Pcre.regexp "\\.body$"
  55 let body_ann_RE           = Pcre.regexp "\\.body\\.ann$"
  56 let proof_tree_RE         = Pcre.regexp "\\.proof_tree$"
  57 let proof_tree_ann_RE     = Pcre.regexp "\\.proof_tree\\.ann$"
  58 let theory_RE             = Pcre.regexp "\\.theory$"
  59 let basepart_RE           = Pcre.regexp
  60   "^([^.]*\\.[^.]*)((\\.body)|(\\.proof_tree)|(\\.types))?(\\.ann)?$"
  61 let slash_RE              = Pcre.regexp "/"
  62 let pipe_RE               = Pcre.regexp "\\|"
  63 let til_slash_RE          = Pcre.regexp "^.*/"
  64 let no_slashes_RE         = Pcre.regexp "^[^/]*$"
  65 let fix_regexp_RE         = Pcre.regexp ("^" ^ (Pcre.quote "(cic|theory)"))
  66 let showable_file_RE      =
  67   Pcre.regexp "(\\.con|\\.ind|\\.var|\\.body|\\.types|\\.proof_tree)$"
  68
  69 let xml_suffix = ".xml"
  70 let theory_suffix = ".theory"
  71
  72   (* global maps, shared by all threads *)
  73
  74 let ends_with_slash s =
  75   try
  76     s.[String.length s - 1] = '/'
  77   with Invalid_argument _ -> false
  78
  79   (* should we use a remote getter or not *)
  80 let remote () =
  81   try
  82     Helm_registry.get "getter.mode" = "remote"
  83   with Helm_registry.Key_not_found _ -> false
  84
  85 let getter_url () = Helm_registry.get "getter.url"
  86
  87 (* Remote interface: getter methods implemented using a remote getter *)
  88
  89   (* <TODO> *)
  90 let getxml_remote uri = not_implemented "getxml_remote"
  91 let getxslt_remote uri = not_implemented "getxslt_remote"
  92 let getdtd_remote uri = not_implemented "getdtd_remote"
  93 let clean_cache_remote () = not_implemented "clean_cache_remote"
  94 let list_servers_remote () = not_implemented "list_servers_remote"
  95 let add_server_remote ~logger ~position name =
  96   not_implemented "add_server_remote"
  97 let remove_server_remote ~logger position =
  98   not_implemented "remove_server_remote"
  99 let getalluris_remote () = not_implemented "getalluris_remote"
 100 let ls_remote lsuri = not_implemented "ls_remote"
 101 let exists_remote uri = not_implemented "exists_remote"
 102   (* </TODO> *)
 103
 104 let resolve_remote uri =
 105   (* deliver resolve request to http_getter *)
 106   let doc =
 107     Http_getter_wget.get (sprintf "%sresolve?uri=%s" (getter_url ()) uri)
 108   in
 109   let res = ref Unknown in
 110   let start_element tag attrs =
 111     match tag with
 112     | "url" ->
 113         (try
 114           res := Resolved (List.assoc "value" attrs)
 115         with Not_found -> ())
 116     | "unresolvable" -> res := Exception (Unresolvable_URI uri)
 117     | "not_found" -> res := Exception (Key_not_found uri)
 118     | _ -> ()
 119   in
 120   let callbacks = {
 121     XmlPushParser.default_callbacks with
 122       XmlPushParser.start_element = Some start_element
 123   } in
 124   let xml_parser = XmlPushParser.create_parser callbacks in
 125   XmlPushParser.parse xml_parser (`String doc);
 126   XmlPushParser.final xml_parser;
 127   match !res with
 128   | Unknown -> raise UnexpectedGetterOutput
 129   | Exception e -> raise e
 130   | Resolved url -> url
 131
 132 (* API *)
 133
 134 let help () = Http_getter_const.usage_string (Http_getter_env.env_to_string ())
 135
 136 let exists uri =
 137   prerr_endline ("Http_getter.exists " ^ uri);
 138   if remote () then
 139     exists_remote uri
 140   else
 141     Http_getter_storage.exists (uri ^ xml_suffix)
 142
 143 let resolve uri =
 144   if remote () then
 145     resolve_remote uri
 146   else
 147     try
 148       Http_getter_storage.resolve (uri ^ xml_suffix)
 149     with Http_getter_storage.Resource_not_found _ -> raise (Key_not_found uri)
 150
 151 let deref_index_theory uri =
 152   if is_theory_uri uri && Filename.basename uri = "index.theory" then
 153     strip_trailing_slash (Filename.dirname uri) ^ theory_suffix
 154   else
 155     uri
 156
 157 let getxml uri =
 158   if remote () then getxml_remote uri
 159   else begin
 160     try
 161       let uri = deref_index_theory uri in
 162       Http_getter_storage.filename (uri ^ xml_suffix)
 163     with Http_getter_storage.Resource_not_found _ -> raise (Key_not_found uri)
 164   end
 165
 166 let getxslt uri =
 167   if remote () then getxslt_remote uri
 168   else Http_getter_storage.filename ~find:true ("xslt:/" ^ uri)
 169
 170 let getdtd uri =
 171   if remote () then
 172     getdtd_remote uri
 173   else begin
 174     let fname = Lazy.force Http_getter_env.dtd_dir ^ "/" ^ uri in
 175     if not (Sys.file_exists fname) then raise (Dtd_not_found uri);
 176     fname
 177   end
 178
 179 let clean_cache () =
 180   if remote () then
 181     clean_cache_remote ()
 182   else
 183     Http_getter_storage.clean_cache ()
 184
 185 let (++) (oldann, oldtypes, oldbody, oldtree)
 186          (newann, newtypes, newbody, newtree) =
 187   ((if newann   > oldann    then newann   else oldann),
 188    (if newtypes > oldtypes  then newtypes else oldtypes),
 189    (if newbody  > oldbody   then newbody  else oldbody),
 190    (if newtree  > oldtree   then newtree  else oldtree))
 191
 192 let store_obj tbl o =
 193 (*   prerr_endline ("Http_getter.store_obj " ^ o); *)
 194   if Pcre.pmatch ~rex:showable_file_RE o then begin
 195     let basepart = Pcre.replace ~rex:basepart_RE ~templ:"$1" o in
 196     let no_flags = false, No, No, No in
 197     let oldflags =
 198       try
 199         Hashtbl.find tbl basepart
 200       with Not_found -> (* no ann, no types, no body, no proof tree *)
 201         no_flags
 202     in
 203     let newflags =
 204       match o with
 205       | s when Pcre.pmatch ~rex:types_RE s          -> (false, Yes, No, No)
 206       | s when Pcre.pmatch ~rex:types_ann_RE s      -> (true,  Ann, No, No)
 207       | s when Pcre.pmatch ~rex:body_RE s           -> (false, No, Yes, No)
 208       | s when Pcre.pmatch ~rex:body_ann_RE s       -> (true,  No, Ann, No)
 209       | s when Pcre.pmatch ~rex:proof_tree_RE s     -> (false, No, No, Yes)
 210       | s when Pcre.pmatch ~rex:proof_tree_ann_RE s -> (true,  No, No, Ann)
 211       | s -> no_flags
 212     in
 213     Hashtbl.replace tbl basepart (oldflags ++ newflags)
 214   end
 215
 216 let store_dir set_ref d =
 217   set_ref := StringSet.add (List.hd (Pcre.split ~rex:slash_RE d)) !set_ref
 218
 219 let collect_ls_items dirs_set objs_tbl =
 220   let items = ref [] in
 221   StringSet.iter (fun dir -> items := Ls_section dir :: !items) dirs_set;
 222   Http_getter_misc.hashtbl_sorted_iter
 223     (fun uri (annflag, typesflag, bodyflag, treeflag) ->
 224       items :=
 225         Ls_object {
 226           uri = uri; ann = annflag;
 227           types = typesflag; body = bodyflag; proof_tree = treeflag
 228         } :: !items)
 229     objs_tbl;
 230   List.rev !items
 231
 232 let contains_object = (<>) []
 233 (*   List.iter
 234     (function
 235       | Ls_section name -> prerr_endline (name ^ "/");
 236       | Ls_object obj -> prerr_endline obj.uri)
 237     l;
 238   prerr_endline (string_of_bool b);
 239   b *)
 240 (*   List.exists (function Ls_object _ -> true | _ -> false) *)
 241
 242   (** non regexp-aware version of ls *)
 243 let rec dumb_ls uri_prefix =
 244   prerr_endline ("Http_getter.dumb_ls " ^ uri_prefix);
 245   if is_cic_obj_uri uri_prefix then begin
 246     let dirs = ref StringSet.empty in
 247     let objs = Hashtbl.create 17 in
 248     List.iter
 249       (fun fname ->
 250         if ends_with_slash fname then
 251           store_dir dirs fname
 252         else
 253           try
 254             store_obj objs (strip_suffix ~suffix:xml_suffix fname)
 255           with Invalid_argument _ -> ())
 256       (Http_getter_storage.ls uri_prefix);
 257     collect_ls_items !dirs objs
 258   end else if is_theory_uri uri_prefix then begin
 259     let items = ref [] in
 260     let add_theory fname =
 261       items :=
 262         Ls_object {
 263           uri = fname; ann = false; types = No; body = No; proof_tree = No }
 264         :: !items
 265     in
 266     let cic_uri_prefix =
 267       Pcre.replace_first ~rex:heading_theory_RE ~templ:"cic:" uri_prefix
 268     in
 269     List.iter
 270       (fun fname ->
 271         if ends_with_slash fname then
 272           items := Ls_section (strip_trailing_slash fname) :: !items
 273         else
 274           try
 275             let fname = strip_suffix ~suffix:xml_suffix fname in
 276             let theory_name = strip_suffix ~suffix:theory_suffix fname in
 277             let sub_theory = normalize_dir cic_uri_prefix ^ theory_name ^ "/" in
 278             if is_empty_theory sub_theory then add_theory fname
 279           with Invalid_argument _ -> ())
 280       (Http_getter_storage.ls uri_prefix);
 281     (try
 282       if contains_object (dumb_ls cic_uri_prefix)
 283         && exists (strip_trailing_slash uri_prefix ^ theory_suffix)
 284       then
 285         add_theory "index.theory";
 286     with Unresolvable_URI _ -> ());
 287     !items
 288   end else
 289     raise (Invalid_URI uri_prefix)
 290
 291 and is_empty_theory uri_prefix =
 292   prerr_endline ("is_empty_theory " ^ uri_prefix);
 293   not (contains_object (dumb_ls uri_prefix))
 294
 295   (* handle simple regular expressions of the form "...(..|..|..)..." on cic
 296    * uris, not meant to be a real implementation of regexp. The only we use is
 297    * "(cic|theory):/..." *)
 298 let explode_ls_regexp regexp =
 299   try
 300     let len = String.length regexp in
 301     let lparen_idx = String.index regexp '(' in
 302     let rparen_idx = String.index_from regexp lparen_idx ')' in
 303     let choices_str = (* substring between parens, parens excluded *)
 304       String.sub regexp (lparen_idx + 1) (rparen_idx - lparen_idx - 1)
 305     in
 306     let choices = Pcre.split ~rex:pipe_RE choices_str in
 307     let prefix = String.sub regexp 0 lparen_idx in
 308     let suffix = String.sub regexp (rparen_idx + 1) (len - (rparen_idx + 1)) in
 309     List.map (fun choice -> prefix ^ choice ^ suffix) choices
 310   with Not_found -> [regexp]
 311
 312 let merge_results results =
 313   let rec aux objects_acc dirs_acc = function
 314     | [] -> dirs_acc @ objects_acc
 315     | Ls_object _ as obj :: tl -> aux (obj :: objects_acc) dirs_acc tl
 316     | Ls_section _ as dir :: tl ->
 317         if List.mem dir dirs_acc then (* filters out dir duplicates *)
 318           aux objects_acc dirs_acc tl
 319         else
 320           aux objects_acc (dir :: dirs_acc) tl
 321   in
 322   aux [] [] (List.concat results)
 323
 324 let ls regexp =
 325   if remote () then
 326     ls_remote regexp
 327   else
 328     let prefixes = explode_ls_regexp regexp in
 329     merge_results (List.map dumb_ls prefixes)
 330
 331 let getalluris () =
 332   let rec aux acc = function
 333     | [] -> acc
 334     | dir :: todo ->
 335         let acc', todo' =
 336           List.fold_left
 337             (fun (acc, subdirs) result ->
 338               match result with
 339               | Ls_object obj -> (dir ^ obj.uri) :: acc, subdirs
 340               | Ls_section sect -> acc, (dir ^ sect ^ "/") :: subdirs)
 341             (acc, todo)
 342             (dumb_ls dir)
 343         in
 344         aux acc' todo'
 345   in
 346   aux [] ["cic:/"] (* trailing slash required *)
 347
 348 (* Shorthands from now on *)
 349
 350 let getxml' uri = getxml (UriManager.string_of_uri uri)
 351 let resolve' uri = resolve (UriManager.string_of_uri uri)
 352 let exists' uri = exists (UriManager.string_of_uri uri)
 353
 354 let init () =
 355   Http_getter_logger.set_log_level
 356     (Helm_registry.get_opt_default Helm_registry.int ~default:1
 357       "getter.log_level");
 358   Http_getter_logger.set_log_file
 359     (Helm_registry.get_opt Helm_registry.string "getter.log_file")
 360