helm/ocaml/getter/http_getter_cache.ml

   1 (*
   2  * Copyright (C) 2003-2004:
   3  *    Stefano Zacchiroli <zack@cs.unibo.it>
   4  *    for the HELM Team http://helm.cs.unibo.it/
   5  *
   6  *  This file is part of HELM, an Hypertextual, Electronic
   7  *  Library of Mathematics, developed at the Computer Science
   8  *  Department, University of Bologna, Italy.
   9  *
  10  *  HELM is free software; you can redistribute it and/or
  11  *  modify it under the terms of the GNU General Public License
  12  *  as published by the Free Software Foundation; either version 2
  13  *  of the License, or (at your option) any later version.
  14  *
  15  *  HELM is distributed in the hope that it will be useful,
  16  *  but WITHOUT ANY WARRANTY; without even the implied warranty of
  17  *  MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the
  18  *  GNU General Public License for more details.
  19  *
  20  *  You should have received a copy of the GNU General Public License
  21  *  along with HELM; if not, write to the Free Software
  22  *  Foundation, Inc., 59 Temple Place - Suite 330, Boston,
  23  *  MA  02111-1307, USA.
  24  *
  25  *  For details, see the HELM World-Wide-Web page,
  26  *  http://helm.cs.unibo.it/
  27  *)
  28
  29 (* TODO cache expires control!!! *)
  30 (* TODO uwobo loop:
  31     if two large proof (already in cache) are requested at the same time by two
  32     clients, uwobo (java implementation, not yet tested with the OCaml one)
  33     starts looping sending output to one of the client *)
  34
  35 open Http_getter_common
  36 open Http_getter_misc
  37 open Http_getter_types
  38 open Printf
  39
  40   (* expose ThreadSafe.threadSafe methods *)
  41 class threadSafe =
  42   object
  43     inherit ThreadSafe.threadSafe
  44     method virtual doCritical : 'a. 'a lazy_t -> 'a
  45     method virtual doReader : 'a. 'a lazy_t -> 'a
  46     method virtual doWriter : 'a. 'a lazy_t -> 'a
  47   end
  48
  49 let threadSafe = new threadSafe
  50
  51 let finally cleanup f =
  52   try
  53     let res = Lazy.force f in
  54     cleanup ();
  55     res
  56   with e ->
  57     cleanup ();
  58     raise (Http_getter_types.Cache_failure (Printexc.to_string e))
  59
  60 let resource_type_of_url = function
  61   | url when Pcre.pmatch ~pat:"\\.xml\\.gz$" url -> `Gzipped
  62   | url when Pcre.pmatch ~pat:"\\.xml$" url -> `Normal
  63   | url -> raise (Invalid_URL url)
  64
  65 let extension_of_resource_type = function
  66   | `Normal -> "xml"
  67   | `Gzipped -> "xml.gz"
  68
  69   (* basename = resource name without trailing ".gz", if any *)
  70 let is_in_cache basename =
  71   Sys.file_exists
  72     (match Lazy.force Http_getter_env.cache_mode with
  73     | `Normal -> basename
  74     | `Gzipped -> basename ^ ".gz")
  75
  76 let respond_xml
  77   ?(via_http = true) ?(enc = `Normal) ?(patch = true) ~url ~uri outchan
  78   =
  79   let resource_type = resource_type_of_url url in
  80   let extension = extension_of_resource_type resource_type in
  81   let downloadname =
  82     match uri_of_string uri with  (* parse uri *)
  83     | Cic_uri (Cic baseuri) | Cic_uri (Theory baseuri) ->
  84           (* assumption: baseuri starts with "/" *)
  85         sprintf "%s%s.%s" (Lazy.force Http_getter_env.cic_dir) baseuri extension
  86     | Nuprl_uri baseuri ->
  87           (* assumption: baseuri starts with "/" *)
  88         sprintf "%s%s.%s" (Lazy.force Http_getter_env.nuprl_dir) baseuri
  89           extension
  90     | Rdf_uri (prefix, ((Cic baseuri) as qbaseuri))
  91     | Rdf_uri (prefix, ((Theory baseuri) as qbaseuri)) ->
  92         let escaped_prefix =
  93           (Pcre.replace ~pat:"/" ~templ:"_"
  94             (Pcre.replace ~pat:"_" ~templ:"__"
  95               (prefix ^
  96               (match qbaseuri with
  97               | Cic _ -> "//cic:"
  98               | Theory _ -> "//theory:"))))
  99         in
 100         sprintf "%s/%s%s.%s"
 101           (Lazy.force Http_getter_env.rdf_dir) escaped_prefix baseuri extension
 102   in
 103   let patch_fun =
 104     if patch then Http_getter_common.patch_xml ~via_http () else (fun x -> x)
 105   in
 106   let basename = Pcre.replace ~pat:"\\.gz$" downloadname in
 107   let contype = "text/xml" in
 108     (* Fill cache if needed and return a short circuit file.
 109       Short circuit is needed in situations like:
 110         resource type = normal, cache type = gzipped, required encoding = normal
 111       we would like to avoid normal -> gzipped -> normal conversions. To avoid
 112       this tmp_short_circuit is used to remember the name of the intermediate
 113       file name *)
 114   let fill_cache () =
 115     threadSafe#doWriter (lazy(
 116       if not (is_in_cache basename) then begin  (* cache MISS *)
 117         Http_getter_logger.log ~level:2 "Cache MISS :-(";
 118         mkdir ~parents:true (Filename.dirname downloadname);
 119         match (resource_type, Lazy.force Http_getter_env.cache_mode) with
 120         | `Normal, `Normal | `Gzipped, `Gzipped ->
 121             wget ~output:downloadname url;
 122             None
 123         | `Normal, `Gzipped ->  (* resource normal, cache gzipped *)
 124             let tmp = tempfile () in
 125             let (res, cleanup) =
 126               if enc = `Normal then (* user wants normal: don't delete it! *)
 127                 (Some (tmp, enc), (fun () -> ()))
 128               else
 129                 (None, (fun () -> Sys.remove tmp))
 130             in
 131             finally cleanup (lazy (
 132               wget ~output:tmp url;
 133               gzip ~output:(basename ^ ".gz") ~keep:true tmp; (* fill cache *)
 134               res
 135             ));
 136         | `Gzipped, `Normal ->  (* resource gzipped, cache normal *)
 137             let tmp = tempfile () in
 138             let (res, cleanup) =
 139               if enc = `Gzipped then (* user wants .gz: don't delete it! *)
 140                 (Some (tmp, enc), (fun () -> ()))
 141               else
 142                 (None, (fun () -> Sys.remove tmp))
 143             in
 144             finally cleanup (lazy (
 145               wget ~output:tmp url;
 146               gunzip ~output:basename ~keep:true tmp; (* fill cache *)
 147               res
 148             ));
 149       end else begin
 150         Http_getter_logger.log ~level:2 "Cache HIT :-)";
 151         None
 152       end
 153     )) in
 154   let tmp_short_circuit = fill_cache () in
 155   threadSafe#doReader (lazy(
 156     assert (is_in_cache basename);
 157     match (enc, Lazy.force Http_getter_env.cache_mode) with
 158     | `Normal, `Normal | `Gzipped, `Gzipped ->
 159         (* resource in cache is already in the required format *)
 160         (match enc with
 161         | `Normal ->
 162             Http_getter_logger.log ~level:2
 163               "No format mangling required (encoding = normal)";
 164             return_file ~via_http ~fname:basename ~contype ~patch_fun outchan
 165         | `Gzipped ->
 166             Http_getter_logger.log ~level:2
 167               "No format mangling required (encoding = gzipped)";
 168             return_file
 169               ~via_http ~fname:(basename ^ ".gz") ~contype ~contenc:"x-gzip"
 170               ~patch_fun ~gunzip:true
 171               outchan)
 172     | `Normal, `Gzipped | `Gzipped, `Normal ->
 173         (match tmp_short_circuit with
 174         | None -> (* no short circuit possible, use cache *)
 175           Http_getter_logger.log ~level:2
 176             "No short circuit available, use cache";
 177           let tmp = tempfile () in
 178           finally (fun () -> Sys.remove tmp) (lazy (
 179             (match enc with
 180             | `Normal ->
 181               (* required format is normal, cached version is gzipped *)
 182               gunzip  (* gunzip to tmp *)
 183                 ~output:tmp ~keep:true (basename ^ ".gz");
 184               return_file ~via_http ~fname:tmp ~contype ~patch_fun outchan;
 185             | `Gzipped ->
 186               (* required format is gzipped, cached version is normal *)
 187               gzip ~output:tmp ~keep:true basename;  (* gzip to tmp *)
 188               return_file
 189                 ~via_http ~fname:tmp ~contype ~contenc:"x-gzip"
 190                 ~patch_fun ~gunzip:true
 191                 outchan)
 192           ))
 193         | Some (fname, `Normal) ->  (* short circuit available, use it! *)
 194             Http_getter_logger.log ~level:2
 195               "Using short circuit (encoding = normal)";
 196             finally (fun () -> Sys.remove fname) (lazy (
 197               return_file ~via_http ~fname ~contype ~patch_fun outchan
 198             ))
 199         | Some (fname, `Gzipped) -> (* short circuit available, use it! *)
 200             Http_getter_logger.log ~level:2
 201               "Using short circuit (encoding = gzipped)";
 202             finally (fun () -> Sys.remove fname) (lazy (
 203               return_file ~via_http ~fname ~contype ~contenc:"x-gzip" ~patch_fun
 204                 ~gunzip:true outchan
 205             )))
 206   ))
 207
 208   (* TODO enc is not yet supported *)
 209 let respond_xsl
 210   ?(via_http = true) ?(enc = `Normal) ?(patch = true) ~url outchan
 211   =
 212   let patch_fun =
 213     if patch then Http_getter_common.patch_xsl ~via_http () else (fun x -> x)
 214   in
 215   let fname = tempfile () in
 216   finally (fun () -> Sys.remove fname) (lazy (
 217     wget ~output:fname url;
 218     return_file ~via_http ~fname ~contype:"text/xml" ~patch_fun outchan
 219   ))
 220
 221   (* TODO enc is not yet supported *)
 222 let respond_dtd
 223   ?(via_http = true) ?(enc = `Normal) ?(patch = true) ~url outchan
 224   =
 225   let patch_fun =
 226     if patch then Http_getter_common.patch_dtd ~via_http () else (fun x -> x)
 227   in
 228   if Sys.file_exists url then
 229     (* TODO check this: old getter here used text/xml *)
 230     return_file ~via_http ~fname:url ~contype:"text/plain" ~patch_fun outchan
 231   else
 232     raise (Dtd_not_found url)
 233
 234 let clean () =
 235  let module E = Http_getter_env in
 236   List.iter
 237    (function dir -> ignore (Unix.system ("rm -rf " ^ dir ^ "/*")))
 238    [ Lazy.force E.cic_dir; Lazy.force E.nuprl_dir; Lazy.force E.rdf_dir ]
 239