helm/ocaml/getter/http_getter_common.ml

   1 (*
   2  * Copyright (C) 2003-2004:
   3  *    Stefano Zacchiroli <zack@cs.unibo.it>
   4  *    for the HELM Team http://helm.cs.unibo.it/
   5  *
   6  *  This file is part of HELM, an Hypertextual, Electronic
   7  *  Library of Mathematics, developed at the Computer Science
   8  *  Department, University of Bologna, Italy.
   9  *
  10  *  HELM is free software; you can redistribute it and/or
  11  *  modify it under the terms of the GNU General Public License
  12  *  as published by the Free Software Foundation; either version 2
  13  *  of the License, or (at your option) any later version.
  14  *
  15  *  HELM is distributed in the hope that it will be useful,
  16  *  but WITHOUT ANY WARRANTY; without even the implied warranty of
  17  *  MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the
  18  *  GNU General Public License for more details.
  19  *
  20  *  You should have received a copy of the GNU General Public License
  21  *  along with HELM; if not, write to the Free Software
  22  *  Foundation, Inc., 59 Temple Place - Suite 330, Boston,
  23  *  MA  02111-1307, USA.
  24  *
  25  *  For details, see the HELM World-Wide-Web page,
  26  *  http://helm.cs.unibo.it/
  27  *)
  28
  29 open Http_getter_types;;
  30 open Printf;;
  31
  32 let string_of_ls_flag = function No -> "NO" | Yes -> "YES" | Ann -> "ANN"
  33 let string_of_encoding = function
  34   | `Normal -> "Normal"
  35   | `Gzipped -> "GZipped"
  36
  37 let is_cic_obj_uri uri = Pcre.pmatch ~pat:"^cic:" uri
  38 let is_theory_uri uri = Pcre.pmatch ~pat:"^theory:" uri
  39 let is_cic_uri uri = is_cic_obj_uri uri || is_theory_uri uri
  40 let is_nuprl_uri uri = Pcre.pmatch ~pat:"^nuprl:" uri
  41 let is_rdf_uri uri = Pcre.pmatch ~pat:"^helm:rdf(.*):(.*)//(.*)" uri
  42 let is_xsl_uri uri = Pcre.pmatch ~pat:"^\\w+\\.xsl" uri
  43
  44 let rec uri_of_string = function
  45   | uri when is_rdf_uri uri ->
  46       (match Pcre.split ~pat:"//" uri with
  47       | [ prefix; uri ] ->
  48           let rest =
  49             match uri_of_string uri with
  50             | Cic_uri xmluri -> xmluri
  51             | _ -> raise (Invalid_URI uri)
  52           in
  53           Rdf_uri (prefix, rest)
  54       | _ -> raise (Invalid_URI uri))
  55   | uri when is_cic_uri uri -> Cic_uri (Cic (Pcre.replace ~pat:"^cic:" uri))
  56   | uri when is_nuprl_uri uri -> Nuprl_uri (Pcre.replace ~pat:"^nuprl:" uri)
  57   | uri when is_theory_uri uri ->
  58       Cic_uri (Theory (Pcre.replace ~pat:"^theory:" uri))
  59   | uri -> raise (Invalid_URI uri)
  60
  61 let patch_xsl ?(via_http = true) () =
  62   fun line ->
  63     let mk_patch_fun tag line =
  64       Pcre.replace
  65         ~pat:(sprintf "%s\\s+href=\"" tag)
  66         ~templ:(sprintf "%s href=\"%s/getxslt?uri="
  67           tag (Lazy.force Http_getter_env.my_own_url))
  68         line
  69     in
  70     let (patch_import, patch_include) =
  71       (mk_patch_fun "xsl:import", mk_patch_fun "xsl:include")
  72     in
  73     patch_include (patch_import line)
  74
  75 let patch_entity ?(via_http = true) () =
  76   if via_http then
  77     fun line ->
  78       Pcre.replace
  79         ~pat:(sprintf "ENTITY (.*) SYSTEM\\s+\"(%s/)?"
  80           (Lazy.force Http_getter_env.dtd_base_url))
  81         ~templ:(sprintf "ENTITY $1 SYSTEM \"%s/getdtd?uri="
  82           (Lazy.force Http_getter_env.my_own_url))
  83         line
  84   else
  85     fun line ->
  86       Pcre.replace
  87         ~pat:(sprintf "ENTITY (.*) SYSTEM\\s+\"(%s/)?"
  88           (Lazy.force Http_getter_env.dtd_base_url))
  89         ~templ:(sprintf "ENTITY $1 SYSTEM \"file://%s/"
  90           (Lazy.force Http_getter_env.dtd_dir))
  91         line
  92
  93 let patch_doctype ?(via_http = true) () =
  94   if via_http then
  95     fun line ->
  96       Pcre.replace
  97         ~pat:(sprintf "DOCTYPE (.*) SYSTEM\\s+\"%s/"
  98           (Lazy.force Http_getter_env.dtd_base_url))
  99         ~templ:(sprintf "DOCTYPE $1 SYSTEM \"%s/getdtd?uri="
 100           (Lazy.force Http_getter_env.my_own_url))
 101         line
 102   else
 103     fun line ->
 104       Pcre.replace
 105         ~pat:(sprintf "DOCTYPE (.*) SYSTEM\\s+\"%s/"
 106           (Lazy.force Http_getter_env.dtd_base_url))
 107         ~templ:(sprintf "DOCTYPE $1 SYSTEM \"file://%s/"
 108           (Lazy.force Http_getter_env.dtd_dir))
 109         line
 110
 111 let patch_dtd = patch_entity
 112
 113 let patch_xml ?via_http () line =
 114   patch_doctype ?via_http () (patch_entity ?via_http () line)
 115
 116 let return_file
 117   ~fname ?contype ?contenc
 118   ?(patch_fun = fun x -> x) ?(gunzip = false) ?(via_http = true) outchan
 119   =
 120   let headers =
 121     match (contype, contenc) with
 122     | (Some t, Some e) -> ["Content-Encoding", e; "Content-Type", t]
 123     | (Some t, None) -> ["Content-Type" , t]
 124     | (None, Some e) -> ["Content-Encoding", e]
 125     | (None, None) -> []
 126   in
 127   if via_http then begin
 128     Http_daemon.send_basic_headers ~code:200 outchan;
 129     Http_daemon.send_headers headers outchan;
 130     Http_daemon.send_CRLF outchan
 131   end;
 132   if gunzip then begin  (* gunzip needed, uncompress file, apply patch_fun to
 133                         it, compress the result and sent it to client *)
 134     let (tmp1, tmp2) =
 135       (Http_getter_misc.tempfile (), Http_getter_misc.tempfile ())
 136     in
 137     try
 138       Http_getter_misc.gunzip ~keep:true ~output:tmp1 fname;(* gunzip to tmp1 *)
 139       let new_file = open_out tmp2 in
 140       Http_getter_misc.iter_file  (* tmp2 = patch(tmp1) *)
 141         (fun line ->
 142           output_string new_file (patch_fun line ^ "\n");
 143           flush outchan)
 144         tmp1;
 145       close_out new_file;
 146       Http_getter_misc.gzip ~output:tmp1 tmp2;  (* tmp1 = gzip(tmp2); rm tmp2 *)
 147       Http_getter_misc.iter_file  (* send tmp1 to client as is*)
 148         (fun line -> output_string outchan (line ^ "\n"); flush outchan)
 149         tmp1;
 150       Sys.remove tmp1       (* rm tmp1 *)
 151     with e ->
 152       Sys.remove tmp1;
 153       raise e
 154   end else begin (* no need to gunzip, apply patch_fun directly to file *)
 155     Http_getter_misc.iter_file
 156       (fun line -> output_string outchan (patch_fun line ^ "\n"); flush outchan)
 157       fname;
 158   end
 159 ;;
 160