helm/ocaml/getter/http_getter_env.ml

   1 (*
   2  * Copyright (C) 2003-2004:
   3  *    Stefano Zacchiroli <zack@cs.unibo.it>
   4  *    for the HELM Team http://helm.cs.unibo.it/
   5  *
   6  *  This file is part of HELM, an Hypertextual, Electronic
   7  *  Library of Mathematics, developed at the Computer Science
   8  *  Department, University of Bologna, Italy.
   9  *
  10  *  HELM is free software; you can redistribute it and/or
  11  *  modify it under the terms of the GNU General Public License
  12  *  as published by the Free Software Foundation; either version 2
  13  *  of the License, or (at your option) any later version.
  14  *
  15  *  HELM is distributed in the hope that it will be useful,
  16  *  but WITHOUT ANY WARRANTY; without even the implied warranty of
  17  *  MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the
  18  *  GNU General Public License for more details.
  19  *
  20  *  You should have received a copy of the GNU General Public License
  21  *  along with HELM; if not, write to the Free Software
  22  *  Foundation, Inc., 59 Temple Place - Suite 330, Boston,
  23  *  MA  02111-1307, USA.
  24  *
  25  *  For details, see the HELM World-Wide-Web page,
  26  *  http://helm.cs.unibo.it/
  27  *)
  28
  29 (* $Id$ *)
  30
  31 open Printf
  32
  33 open Http_getter_types
  34 open Http_getter_misc
  35
  36 let version = Http_getter_const.version
  37
  38 let prefix_RE = Pcre.regexp "^\\s*([^\\s]+)\\s+([^\\s]+)\\s*(.*)$"
  39
  40 let cache_dir  = lazy (normalize_dir (Helm_registry.get "getter.cache_dir"))
  41 let dtd_dir = lazy (normalize_dir (Helm_registry.get "getter.dtd_dir"))
  42 let dtd_base_urls  = lazy (
  43   let rex = Pcre.regexp "/*$" in
  44   let raw_urls =
  45     match
  46       Helm_registry.get_list Helm_registry.string "getter.dtd_base_urls"
  47     with
  48     | [] -> ["http://helm.cs.unibo.it/dtd"; "http://mowgli.cs.unibo.it/dtd"]
  49     | urls -> urls
  50   in
  51   List.map (Pcre.replace ~rex) raw_urls)
  52 let port            = lazy (
  53   Helm_registry.get_opt_default Helm_registry.int ~default:58081 "getter.port")
  54
  55 let parse_prefix_attrs s =
  56   List.fold_right
  57     (fun s acc ->
  58       match s with
  59       | "ro" -> `Read_only :: acc
  60       | "legacy" -> `Legacy :: acc
  61       | s ->
  62           Http_getter_logger.log ("ignoring unknown attribute: " ^ s);
  63           acc)
  64     (Pcre.split s) []
  65
  66 let prefixes = lazy (
  67   let prefixes = Helm_registry.get_list Helm_registry.string "getter.prefix" in
  68   List.fold_left
  69     (fun acc prefix ->
  70       let subs = Pcre.extract ~rex:prefix_RE prefix in
  71       try
  72         (subs.(1), (subs.(2), parse_prefix_attrs subs.(3))) :: acc
  73       with Invalid_argument _ ->
  74         Http_getter_logger.log ("skipping invalid prefix: " ^ prefix);
  75         acc)
  76     [] prefixes)
  77
  78 let host = lazy (Http_getter_misc.backtick "hostname -f")
  79
  80 let my_own_url =
  81   lazy
  82     (let (host, port) = (Lazy.force host, Lazy.force port) in
  83     sprintf "http://%s%s" (* without trailing '/' *)
  84     host (if port = 80 then "" else (sprintf ":%d" port)))
  85
  86 let env_to_string () =
  87   let pp_attr = function `Read_only -> "ro" | `Legacy -> "legacy" in
  88   let pp_prefix (uri_prefix, (url_prefix, attrs)) =
  89     sprintf "    %s -> %s [%s]" uri_prefix url_prefix
  90       (String.concat "," (List.map pp_attr attrs)) in
  91   let pp_prefixes prefixes =
  92     match prefixes with
  93     | [] -> ""
  94     | l -> "\n" ^ String.concat "\n" (List.map pp_prefix l)
  95   in
  96   sprintf
  97 "HTTP Getter %s
  98
  99 prefixes:%s
 100 dtd_dir:\t%s
 101 host:\t\t%s
 102 port:\t\t%d
 103 my_own_url:\t%s
 104 dtd_base_urls:\t%s
 105 log_file:\t%s
 106 log_level:\t%d
 107 "
 108     version
 109     (pp_prefixes (Lazy.force prefixes))
 110     (Lazy.force dtd_dir) (Lazy.force host) (Lazy.force port)
 111     (Lazy.force my_own_url) (String.concat " " (Lazy.force dtd_base_urls))
 112     (match Http_getter_logger.get_log_file () with None -> "None" | Some f -> f)
 113     (Http_getter_logger.get_log_level ())
 114