helm/ocaml/getter/http_getter_misc.ml

   1 (*
   2  * Copyright (C) 2003-2004:
   3  *    Stefano Zacchiroli <zack@cs.unibo.it>
   4  *    for the HELM Team http://helm.cs.unibo.it/
   5  *
   6  *  This file is part of HELM, an Hypertextual, Electronic
   7  *  Library of Mathematics, developed at the Computer Science
   8  *  Department, University of Bologna, Italy.
   9  *
  10  *  HELM is free software; you can redistribute it and/or
  11  *  modify it under the terms of the GNU General Public License
  12  *  as published by the Free Software Foundation; either version 2
  13  *  of the License, or (at your option) any later version.
  14  *
  15  *  HELM is distributed in the hope that it will be useful,
  16  *  but WITHOUT ANY WARRANTY; without even the implied warranty of
  17  *  MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the
  18  *  GNU General Public License for more details.
  19  *
  20  *  You should have received a copy of the GNU General Public License
  21  *  along with HELM; if not, write to the Free Software
  22  *  Foundation, Inc., 59 Temple Place - Suite 330, Boston,
  23  *  MA  02111-1307, USA.
  24  *
  25  *  For details, see the HELM World-Wide-Web page,
  26  *  http://helm.cs.unibo.it/
  27  *)
  28
  29 open Printf
  30
  31 let trailing_dot_gz_RE = Pcre.regexp "\\.gz$"   (* for g{,un}zip *)
  32 let url_RE = Pcre.regexp "^([\\w.-]+)(:(\\d+))?(/.*)?$"
  33 let http_scheme_RE = Pcre.regexp ~flags:[`CASELESS] "^http://"
  34 let file_scheme_RE = Pcre.regexp ~flags:[`CASELESS] "^file://"
  35 let dir_sep_RE = Pcre.regexp "/"
  36 let heading_slash_RE = Pcre.regexp "^/"
  37
  38 let bufsiz = 16384  (* for file system I/O *)
  39 let tcp_bufsiz = 4096 (* for TCP I/O *)
  40
  41 let fold_file f init fname =
  42   let ic = open_in fname in
  43   let rec aux acc =
  44     let line = try Some (input_line ic) with End_of_file -> None in
  45     match line with
  46     | None -> acc
  47     | Some line -> aux (f line acc)
  48   in
  49   let res = try aux init with e -> close_in ic; raise e in
  50   close_in ic;
  51   res
  52
  53 let iter_file f = fold_file (fun line _ -> f line) ()
  54
  55 let hashtbl_sorted_fold f tbl init =
  56   let sorted_keys =
  57     List.sort compare (Hashtbl.fold (fun key _ keys -> key::keys) tbl [])
  58   in
  59   List.fold_left (fun acc k -> f k (Hashtbl.find tbl k) acc) init sorted_keys
  60
  61 let hashtbl_sorted_iter f tbl =
  62   let sorted_keys =
  63     List.sort compare (Hashtbl.fold (fun key _ keys -> key::keys) tbl [])
  64   in
  65   List.iter (fun k -> f k (Hashtbl.find tbl k)) sorted_keys
  66
  67 let cp src dst =
  68   let (ic, oc) = (open_in src, open_out dst) in
  69   let buf = String.create bufsiz in
  70   (try
  71     while true do
  72       let bytes = input ic buf 0 bufsiz in
  73       if bytes = 0 then raise End_of_file else output oc buf 0 bytes
  74     done
  75   with End_of_file -> ());
  76   close_in ic; close_out oc
  77
  78 let wget ?output url =
  79   Http_getter_logger.log
  80     (sprintf "wgetting %s (output: %s)" url
  81       (match output with None -> "default" | Some f -> f));
  82   match url with
  83   | url when Pcre.pmatch ~rex:file_scheme_RE url -> (* file:// *)
  84       (let src_fname = Pcre.replace ~rex:file_scheme_RE url in
  85       match output with
  86       | Some dst_fname -> cp src_fname dst_fname
  87       | None ->
  88           let dst_fname = Filename.basename src_fname in
  89           if src_fname <> dst_fname then
  90             cp src_fname dst_fname
  91           else  (* src and dst are the same: do nothing *)
  92             ())
  93   | url when Pcre.pmatch ~rex:http_scheme_RE url -> (* http:// *)
  94       (let oc =
  95         open_out (match output with Some f -> f | None -> Filename.basename url)
  96       in
  97       Http_client.http_get_iter (fun data -> output_string oc data) url;
  98       close_out oc)
  99   | scheme -> (* unsupported scheme *)
 100       failwith ("Http_getter_misc.wget: unsupported scheme: " ^ scheme)
 101
 102 let gzip ?(keep = false) ?output fname =
 103   let output = match output with None -> fname ^ ".gz" | Some fname -> fname in
 104   Http_getter_logger.log ~level:3
 105     (sprintf "gzipping %s (keep: %b, output: %s)" fname keep output);
 106   let (ic, oc) = (open_in fname, Gzip.open_out output) in
 107   let buf = String.create bufsiz in
 108   (try
 109     while true do
 110       let bytes = input ic buf 0 bufsiz in
 111       if bytes = 0 then raise End_of_file else Gzip.output oc buf 0 bytes
 112     done
 113   with End_of_file -> ());
 114   close_in ic; Gzip.close_out oc;
 115   if not keep then Sys.remove fname
 116 ;;
 117
 118 let gunzip ?(keep = false) ?output fname =
 119     (* assumption: given file name ends with ".gz" or output is set *)
 120   let output =
 121     match output with
 122     | None ->
 123         if (Pcre.pmatch ~rex:trailing_dot_gz_RE fname) then
 124           Pcre.replace ~rex:trailing_dot_gz_RE fname
 125         else
 126           failwith
 127             "Http_getter_misc.gunzip: unable to determine output file name"
 128     | Some fname -> fname
 129   in
 130   Http_getter_logger.log ~level:3
 131     (sprintf "gunzipping %s (keep: %b, output: %s)" fname keep output);
 132   (* Open the zipped file manually since Gzip.open_in may
 133    * leak the descriptor if it raises an exception *)
 134   let zic = open_in fname in
 135   begin
 136     try
 137       let ic = Gzip.open_in_chan zic in
 138       Http_getter_logger.log (sprintf "LUCA: OK" );
 139       let oc = open_out output in
 140       let buf = String.create bufsiz in
 141       (try
 142         while true do
 143           let bytes = Gzip.input ic buf 0 bufsiz in
 144           if bytes = 0 then raise End_of_file else Pervasives.output oc buf 0 bytes
 145         done
 146       with End_of_file -> ());
 147       close_out oc
 148     with
 149       e -> close_in zic ; raise e
 150   end ;
 151   close_in zic ;
 152   if not keep then Sys.remove fname
 153 ;;
 154
 155 let tempfile () = Filename.temp_file "http_getter_" ""
 156
 157 exception Mkdir_failure of string * string;;  (* dirname, failure reason *)
 158 let dir_perm = 0o755
 159
 160 let mkdir ?(parents = false) dirname =
 161   let mkdirhier () =
 162     let (pieces, hd) =
 163       let split = Pcre.split ~rex:dir_sep_RE dirname in
 164       if Pcre.pmatch ~rex:heading_slash_RE dirname then
 165         (List.tl split, "/")
 166       else
 167         (split, "")
 168     in
 169     ignore
 170       (List.fold_left
 171         (fun pre dir ->
 172           let next_dir =
 173             sprintf "%s%s%s" pre (match pre with "/" | "" -> "" | _ -> "/") dir
 174           in
 175           (try
 176             (match (Unix.stat next_dir).Unix.st_kind with
 177             | Unix.S_DIR -> ()  (* dir component already exists, go on! *)
 178             | _ ->  (* dir component already exists but isn't a dir, abort! *)
 179                 raise
 180                   (Mkdir_failure (dirname,
 181                     sprintf "'%s' already exists but is not a dir" next_dir)))
 182           with Unix.Unix_error (Unix.ENOENT, "stat", _) ->
 183             (* dir component doesn't exists, create it and go on! *)
 184             Unix.mkdir next_dir dir_perm);
 185           next_dir)
 186         hd pieces)
 187   in
 188   if parents then mkdirhier () else Unix.mkdir dirname dir_perm
 189
 190 let string_of_proc_status = function
 191   | Unix.WEXITED code -> sprintf "[Exited: %d]" code
 192   | Unix.WSIGNALED sg -> sprintf "[Killed: %d]" sg
 193   | Unix.WSTOPPED sg -> sprintf "[Stopped: %d]" sg
 194
 195 let http_get url =
 196   if Pcre.pmatch ~rex:file_scheme_RE url then begin
 197       (* file:// URL. Read data from file system *)
 198     let fname = Pcre.replace ~rex:file_scheme_RE url in
 199     try
 200       let size = (Unix.stat fname).Unix.st_size in
 201       let buf = String.create size in
 202       let ic = open_in fname in
 203       really_input ic buf 0 size ;
 204       close_in ic;
 205       Some buf
 206     with Unix.Unix_error (Unix.ENOENT, "stat", _) -> None
 207   end else  (* other URL, pass it to Http_client *)
 208     try
 209       Some (Http_client.http_get url)
 210     with e ->
 211       Http_getter_logger.log (sprintf
 212         "Warning: Http_client failed on url %s with exception: %s"
 213         url (Printexc.to_string e));
 214       None
 215
 216 let is_blank_line =
 217   let blank_line_RE = Pcre.regexp "(^#)|(^\\s*$)" in
 218   fun line ->
 219     Pcre.pmatch ~rex:blank_line_RE line
 220