helm/ocaml/mathql_generator/mQueryLevels2.ml

   1 (* Copyright (C) 2000, HELM Team.
   2  *
   3  * This file is part of HELM, an Hypertextual, Electronic
   4  * Library of Mathematics, developed at the Computer Science
   5  * Department, University of Bologna, Italy.
   6  *
   7  * HELM is free software; you can redistribute it and/or
   8  * modify it under the terms of the GNU General Public License
   9  * as published by the Free Software Foundation; either version 2
  10  * of the License, or (at your option) any later version.
  11  *
  12  * HELM is distributed in the hope that it will be useful,
  13  * but WITHOUT ANY WARRANTY; without even the implied warranty of
  14  * MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the
  15  * GNU General Public License for more details.
  16  *
  17  * You should have received a copy of the GNU General Public License
  18  * along with HELM; if not, write to the Free Software
  19  * Foundation, Inc., 59 Temple Place - Suite 330, Boston,
  20  * MA  02111-1307, USA.
  21  *
  22  * For details, see the HELM World-Wide-Web page,
  23  * http://cs.unibo.it/helm/.
  24  *)
  25
  26 (******************************************************************************)
  27 (*                                                                            *)
  28 (*                               PROJECT HELM                                 *)
  29 (*                                                                            *)
  30 (*                Claudio Sacerdoti Coen <sacerdot@cs.unibo.it>               *)
  31 (*                                 02/12/2002                                 *)
  32 (*                                                                            *)
  33 (*                            Missing description                             *)
  34 (*                                                                            *)
  35 (******************************************************************************)
  36
  37 type classification =
  38    Backbone of int
  39  | Branch of int
  40  | InConclusion
  41  | InHypothesis
  42 ;;
  43
  44 let soften_classification =
  45  function
  46     Backbone _ -> InConclusion
  47   | Branch _ -> InHypothesis
  48   | k -> k
  49 ;;
  50
  51 let (!!) =
  52  function
  53     Backbone n ->
  54      "http://www.cs.unibo.it/helm/schemas/schema-helm#MainConclusion", Some n
  55   | Branch n ->
  56      "http://www.cs.unibo.it/helm/schemas/schema-helm#MainHypothesis", Some n
  57   | InConclusion ->
  58      "http://www.cs.unibo.it/helm/schemas/schema-helm#InConclusion", None
  59   | InHypothesis ->
  60      "http://www.cs.unibo.it/helm/schemas/schema-helm#InHypothesis", None
  61 ;;
  62
  63 let (@@) (l1,l2,l3) (l1',l2',l3') =
  64  let merge l1 l2 =
  65   List.fold_left (fun i t -> if List.mem t l2 then i else t::i) l2 l1
  66  in
  67   merge l1 l1', merge l2 l2', merge l3 l3'
  68 ;;
  69
  70 let get_constraints term =
  71  let module U = UriManager in
  72  let module C = Cic in
  73   let rec process_type_aux kind =
  74    function
  75       C.Var (uri,expl_named_subst) ->
  76        let kind',depth = !!kind in
  77         ([UriManager.string_of_uri uri,kind',depth],[],[]) @@
  78           (process_type_aux_expl_named_subst kind expl_named_subst)
  79     | C.Rel _ ->
  80        let kind',depth = !!kind in
  81         (match depth with
  82             None -> [],[],[]
  83           | Some d -> [],[kind',Some d],[])
  84     | C.Sort s ->
  85        (match kind with
  86            Backbone _
  87          | Branch _ ->
  88             let s' =
  89              match s with
  90                 Cic.Prop -> "Prop"
  91               | Cic.Set -> "Set"
  92               | Cic.Type -> "Type"
  93             in
  94              let kind',depth = !!kind in
  95               (match depth with
  96                   None -> assert false
  97                 | Some d -> [],[],[kind',Some d,s'])
  98          | _ -> [],[],[])
  99     | C.Meta _
 100     | C.Implicit -> assert false
 101     | C.Cast (te,_) ->
 102        (* type ignored *)
 103        process_type_aux kind te
 104     | C.Prod (_,sou,ta) ->
 105        let (source_kind,target_kind) =
 106         match kind with
 107            Backbone n -> (Branch 0, Backbone (n+1))
 108          | Branch n -> (InHypothesis, Branch (n+1))
 109          | k -> (k,k)
 110        in
 111         process_type_aux source_kind sou @@
 112         process_type_aux target_kind ta
 113     | C.Lambda (_,sou,ta) ->
 114         let kind' = soften_classification kind in
 115          process_type_aux kind' sou @@
 116          process_type_aux kind' ta
 117     | C.LetIn (_,te,ta)->
 118        let kind' = soften_classification kind in
 119         process_type_aux kind' te @@
 120         process_type_aux kind ta
 121     | C.Appl (he::tl) ->
 122        let kind' = soften_classification kind in
 123         process_type_aux kind he @@
 124         List.fold_left (fun i t -> i @@ process_type_aux kind' t) ([],[],[]) tl
 125     | C.Appl _ -> assert false
 126     | C.Const (uri,_) ->
 127        let kind',depth = !!kind in
 128         [UriManager.string_of_uri uri,kind',depth],[],[]
 129     | C.MutInd (uri,typeno,expl_named_subst) ->
 130        let kind',depth = !!kind in
 131        ([U.string_of_uri uri ^ "#xpointer(1/" ^ string_of_int (typeno + 1) ^
 132           ")", kind', depth],[],[]) @@
 133          (process_type_aux_expl_named_subst kind expl_named_subst)
 134     | C.MutConstruct (uri,typeno,consno,expl_named_subst) ->
 135        let kind',depth = !!kind in
 136         ([U.string_of_uri uri ^ "#xpointer(1/" ^ string_of_int (typeno + 1) ^
 137           "/" ^ string_of_int consno ^ ")",kind',depth],[],[]) @@
 138           (process_type_aux_expl_named_subst kind expl_named_subst)
 139     | C.MutCase (_,_,_,term,patterns) ->
 140        (* outtype ignored *)
 141        let kind' = soften_classification kind in
 142         process_type_aux kind' term @@
 143         List.fold_left (fun i t -> i @@ process_type_aux kind' t)
 144          ([],[],[]) patterns
 145     | C.Fix (_,funs) ->
 146        let kind' = soften_classification kind in
 147         List.fold_left
 148          (fun i (_,_,bo,ty) ->
 149            i @@
 150             process_type_aux kind' bo @@
 151             process_type_aux kind' ty
 152          ) ([],[],[]) funs
 153     | C.CoFix (_,funs) ->
 154        let kind' = soften_classification kind in
 155         List.fold_left
 156          (fun i (_,bo,ty) ->
 157            i @@
 158             process_type_aux kind' bo @@
 159             process_type_aux kind' ty
 160          ) ([],[],[]) funs
 161  and process_type_aux_expl_named_subst kind =
 162   List.fold_left
 163    (fun i (_,t) -> i @@ (process_type_aux (soften_classification kind) t))
 164    ([],[],[])
 165 in
 166  let obj_constraints,rel_constraints,sort_constraints =
 167   process_type_aux (Backbone 0) (CicMiniReduction.letin_nf term)
 168  in
 169   (obj_constraints,rel_constraints,sort_constraints)
 170 ;;
 171
 172 (*CSC: Debugging only *)
 173 let get_constraints term =
 174  let res = get_constraints term in
 175  let (objs,rels,sorts) = res in
 176   prerr_endline "Constraints on objs:" ;
 177   List.iter
 178    (function (s1,s2,n) ->
 179      prerr_endline
 180       (s1 ^ " " ^ s2 ^ " " ^
 181         match n with None -> "NULL" | Some n -> string_of_int n)
 182    ) objs ;
 183   prerr_endline "Constraints on Rels:" ;
 184   List.iter
 185    (function (s,n) ->
 186      prerr_endline
 187       (s ^ " " ^ (match n with Some n' -> string_of_int n' | None -> "NULL"))
 188    ) rels ;
 189   prerr_endline "Constraints on Sorts:" ;
 190   List.iter
 191    (function (s1,n,s2) ->
 192      prerr_endline
 193       (s1 ^ " " ^ (match n with Some n' -> string_of_int n' | None -> "NULL") ^
 194         " " ^ s2)
 195    ) sorts ;
 196   res
 197 ;;