helm/ocaml/registry/helm_registry.ml

   1 (* Copyright (C) 2004-2005, HELM Team.
   2  *
   3  * This file is part of HELM, an Hypertextual, Electronic
   4  * Library of Mathematics, developed at the Computer Science
   5  * Department, University of Bologna, Italy.
   6  *
   7  * HELM is free software; you can redistribute it and/or
   8  * modify it under the terms of the GNU General Public License
   9  * as published by the Free Software Foundation; either version 2
  10  * of the License, or (at your option) any later version.
  11  *
  12  * HELM is distributed in the hope that it will be useful,
  13  * but WITHOUT ANY WARRANTY; without even the implied warranty of
  14  * MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the
  15  * GNU General Public License for more details.
  16  *
  17  * You should have received a copy of the GNU General Public License
  18  * along with HELM; if not, write to the Free Software
  19  * Foundation, Inc., 59 Temple Place - Suite 330, Boston,
  20  * MA  02111-1307, USA.
  21  *
  22  * For details, see the HELM World-Wide-Web page,
  23  * http://helm.cs.unibo.it/
  24  *)
  25
  26 open Printf
  27
  28 let debug = false
  29 let debug_print s =
  30   if debug then prerr_endline ("Helm_registry debugging: " ^ (Lazy.force s))
  31
  32   (** <helpers> *)
  33
  34 let list_uniq l =
  35   let rec aux last_element = function
  36     | [] -> []
  37     | hd :: tl ->
  38         (match last_element with
  39         | Some elt when elt = hd -> aux last_element tl
  40         | _ -> hd :: aux (Some hd) tl)
  41   in
  42   aux None l
  43
  44 let starts_with prefix =
  45 (*
  46   let rex = Str.regexp (Str.quote prefix) in
  47   fun s -> Str.string_match rex s 0
  48 *)
  49   let prefix_len = String.length prefix in
  50   fun s ->
  51     try
  52       String.sub s 0 prefix_len = prefix
  53     with Invalid_argument _ -> false
  54
  55 let hashtbl_keys tbl = Hashtbl.fold (fun k _ acc -> k :: acc) tbl []
  56 let hashtbl_pairs tbl = Hashtbl.fold (fun k v acc -> (k,v) :: acc) tbl []
  57
  58   (** </helpers> *)
  59
  60 exception Malformed_key of string
  61 exception Key_not_found of string
  62 exception Cyclic_definition of string
  63 exception Type_error of string (* expected type, value, msg *)
  64 exception Parse_error of string * int * int * string  (* file, line, col, msg *)
  65
  66   (* root XML tag: used by save_to, ignored by load_from *)
  67 let root_tag = "helm_registry"
  68
  69 let magic_size = 127
  70
  71 let backup_registry registry = Hashtbl.copy registry
  72 let restore_registry backup registry =
  73   Hashtbl.clear registry;
  74   Hashtbl.iter (fun key value -> Hashtbl.add registry key value) backup
  75
  76   (* as \\w but:
  77    * - no sequences of '_' longer than 1 are permitted
  78    *)
  79 let valid_step_rex_raw = "[a-zA-Z0-9]+\\(_[a-z0A-Z-9]+\\)*"
  80 let valid_key_rex_raw =
  81   sprintf "%s\\(\\.%s\\)*" valid_step_rex_raw valid_step_rex_raw
  82 let valid_key_rex = Str.regexp ("^" ^ valid_key_rex_raw ^ "$")
  83 let interpolated_key_rex = Str.regexp ("\\$(" ^ valid_key_rex_raw ^ ")")
  84 let dot_rex = Str.regexp "\\."
  85 let spaces_rex = Str.regexp "[ \t\n\r]+"
  86 let heading_spaces_rex = Str.regexp "^[ \t\n\r]+"
  87 let margin_blanks_rex =
  88   Str.regexp "^\\([ \t\n\r]*\\)\\([^ \t\n\r]*\\)\\([ \t\n\r]*\\)$"
  89
  90 let strip_blanks s = Str.global_replace margin_blanks_rex "\\2" s
  91
  92 let split s =
  93   (* trailing blanks are removed per default by split *)
  94   Str.split spaces_rex (Str.global_replace heading_spaces_rex "" s)
  95 let merge l = String.concat " " l
  96
  97 let handle_type_error f x =
  98   try f x with exn -> raise (Type_error (Printexc.to_string exn))
  99
 100   (** marshallers/unmarshallers *)
 101 let string x = x
 102 let int = handle_type_error int_of_string
 103 let float = handle_type_error float_of_string
 104 let bool = handle_type_error bool_of_string
 105 let of_string x = x
 106 let of_int = handle_type_error string_of_int
 107 let of_float = handle_type_error string_of_float
 108 let of_bool = handle_type_error string_of_bool
 109
 110   (* escapes for xml configuration file *)
 111 let (escape, unescape) =
 112   let (in_enc, out_enc) = (`Enc_utf8, `Enc_utf8) in
 113   (Netencoding.Html.encode ~in_enc ~out_enc (),
 114    Netencoding.Html.decode ~in_enc ~out_enc ~entity_base:`Xml ())
 115
 116 let key_is_valid key =
 117   if not (Str.string_match valid_key_rex key 0) then
 118     raise (Malformed_key key)
 119
 120 let set' ?(replace=false) registry ~key ~value =
 121   debug_print (lazy(sprintf "Setting (replace: %b) %s = %s" replace key value));
 122   key_is_valid key;
 123   let add_fun = if replace then Hashtbl.replace else Hashtbl.add in
 124   add_fun registry key value
 125
 126 let unset registry = Hashtbl.remove registry
 127
 128 let env_var_of_key = Str.global_replace dot_rex "__"
 129
 130 let singleton = function
 131   | [] ->
 132       raise (Type_error ("empty list value found where singleton was expected"))
 133   | hd :: _ -> hd
 134
 135 let get registry key =
 136   let rec aux stack key =
 137     key_is_valid key;
 138     if List.mem key stack then begin
 139       let msg = (String.concat " -> " (List.rev stack)) ^ " -> " ^ key in
 140       raise (Cyclic_definition msg)
 141     end;
 142       (* internal value *)
 143     let registry_values = List.rev (Hashtbl.find_all registry key) in
 144     let env_value = (* environment value *)
 145       try
 146         Some (Sys.getenv (env_var_of_key key))
 147       with Not_found -> None
 148     in
 149     let values = (* resulting value *)
 150       match registry_values, env_value with
 151       | _, Some env -> [env]
 152       | [], None -> raise (Key_not_found key)
 153       | values, None -> values
 154     in
 155     List.map (interpolate (key :: stack)) values
 156   and interpolate stack value =
 157     Str.global_substitute interpolated_key_rex
 158       (fun s ->
 159         let matched = Str.matched_string s in
 160           (* "$(var)" -> "var" *)
 161         let key = String.sub matched 2 (String.length matched - 3) in
 162         singleton (aux stack key))
 163       value
 164   in
 165   List.map strip_blanks (aux [] key)
 166
 167 let has registry key = Hashtbl.mem registry key
 168
 169 let get_typed registry unmarshaller key =
 170   let value = singleton (get registry key) in
 171   unmarshaller value
 172
 173 let set_typed registry marshaller ~key ~value =
 174   set' ~replace:true registry ~key ~value:(marshaller value)
 175
 176 let get_opt registry unmarshaller key =
 177   try
 178     Some (unmarshaller (singleton (get registry key)))
 179   with Key_not_found _ -> None
 180
 181 let get_opt_default registry unmarshaller ~default key =
 182   match get_opt registry unmarshaller key with
 183   | None -> default
 184   | Some v -> v
 185
 186 let set_opt registry marshaller ~key ~value =
 187   match value with
 188   | None -> unset registry key
 189   | Some value -> set' ~replace:true registry ~key ~value:(marshaller value)
 190
 191 let get_list registry unmarshaller key =
 192   try
 193     List.map unmarshaller (get registry key)
 194   with Key_not_found _ -> []
 195
 196 let get_pair registry fst_unmarshaller snd_unmarshaller key =
 197   let v = singleton (get registry key) in
 198   match Str.split spaces_rex v with
 199   | [fst; snd] -> fst_unmarshaller fst, snd_unmarshaller snd
 200   | _ -> raise (Type_error "not a pair")
 201
 202 let set_list registry marshaller ~key ~value =
 203   Hashtbl.remove registry key;
 204   List.iter
 205     (fun v -> set' ~replace:false registry ~key ~value:(marshaller v))
 206     value
 207
 208 type xml_tree =
 209   | Cdata of string
 210   | Element of string * (string * string) list * xml_tree list
 211
 212 let dot_RE = Str.regexp "\\."
 213
 214 let xml_tree_of_registry registry =
 215   let has_child name elements =
 216     List.exists
 217       (function
 218         | Element (_, ["name", name'], _) when name = name' -> true
 219         | _ -> false)
 220       elements
 221   in
 222   let rec get_child name = function
 223     | [] -> assert false
 224     | (Element (_, ["name", name'], _) as child) :: tl when name = name' ->
 225         child, tl
 226     | hd :: tl ->
 227         let child, rest = get_child name tl in
 228         child, hd :: rest
 229   in
 230   let rec add_key path value tree =
 231     match path, tree with
 232     | [key], Element (name, attrs, children) ->
 233         Element (name, attrs,
 234           Element ("key", ["name", key],
 235             [Cdata (strip_blanks value)]) :: children)
 236     | dir :: path, Element (name, attrs, children) ->
 237         if has_child dir children then
 238           let child, rest = get_child dir children in
 239           Element (name, attrs, add_key path value child :: rest)
 240         else
 241           Element (name, attrs,
 242             ((add_key path value (Element ("section", ["name", dir], [])))
 243               :: children))
 244     | _ -> assert false
 245   in
 246   Hashtbl.fold
 247     (fun k v tree -> add_key ((Str.split dot_RE k)) v tree)
 248     registry
 249     (Element (root_tag, [], []))
 250
 251 let rec stream_of_xml_tree = function
 252   | Cdata s -> Xml.xml_cdata s
 253   | Element (name, attrs, children) ->
 254       Xml.xml_nempty name
 255         (List.map (fun (n, v) -> (None, n, v)) attrs)
 256         (stream_of_xml_trees children)
 257 and stream_of_xml_trees = function
 258   | [] -> [< >]
 259   | hd :: tl -> [< stream_of_xml_tree hd; stream_of_xml_trees tl >]
 260
 261 let save_to registry fname =
 262   let token_stream = stream_of_xml_tree (xml_tree_of_registry registry) in
 263   let oc = open_out fname in
 264   Xml.pp_to_outchan token_stream oc;
 265   close_out oc
 266
 267 let rec load_from_absolute ?path registry fname =
 268   let _path = ref (match path with None -> [] | Some p -> p)in
 269     (* <section> elements entered so far *)
 270   let in_key = ref false in (* have we entered a <key> element? *)
 271   let cdata = ref "" in     (* collected cdata (inside <key> *)
 272   let push_path name = _path := name :: !_path in
 273   let pop_path () = _path := List.tl !_path in
 274   let start_element tag attrs =
 275     match tag, attrs with
 276     | "section", ["name", name] -> push_path name
 277     | "key", ["name", name] -> in_key := true; push_path name
 278     | "helm_registry", _ -> ()
 279     | "include", ["href", fname] ->
 280         debug_print (lazy ("including file " ^ fname));
 281         load_from_absolute ~path:!_path registry fname
 282     | tag, _ ->
 283         raise (Parse_error (fname, ~-1, ~-1,
 284           (sprintf "unexpected element <%s> or wrong attribute set" tag)))
 285   in
 286   let end_element tag =
 287     match tag with
 288     | "section" -> pop_path ()
 289     | "key" ->
 290         let key = String.concat "." (List.rev !_path) in
 291         set' registry ~key ~value:!cdata;
 292         cdata := "";
 293         in_key := false;
 294         pop_path ()
 295     | "include" | "helm_registry" -> ()
 296     | _ -> assert false
 297   in
 298   let character_data text =
 299     if !in_key then cdata := !cdata ^ text
 300   in
 301   let callbacks = {
 302     XmlPushParser.default_callbacks with
 303       XmlPushParser.start_element = Some start_element;
 304       XmlPushParser.end_element = Some end_element;
 305       XmlPushParser.character_data = Some character_data;
 306   } in
 307   let xml_parser = XmlPushParser.create_parser callbacks in
 308   let backup = backup_registry registry in
 309 (*   if path = None then Hashtbl.clear registry; *)
 310   try
 311     XmlPushParser.parse xml_parser (`File fname)
 312   with exn ->
 313     restore_registry backup registry;
 314     raise exn
 315
 316 let load_from registry ?path fname =
 317   if Filename.is_relative fname then begin
 318     let no_file_found = ref true in
 319     let path =
 320       match path with
 321       | Some path -> path (* path given as argument *)
 322       | None -> [ Sys.getcwd () ] (* no path given, try with cwd *)
 323     in
 324     List.iter
 325       (fun dir ->
 326         let conffile = dir ^ "/" ^ fname in
 327         if Sys.file_exists conffile then begin
 328           no_file_found := false;
 329           load_from_absolute registry conffile
 330         end)
 331        path;
 332     if !no_file_found then
 333       failwith (sprintf
 334         "Helm_registry.init: no configuration file named %s in [ %s ]"
 335         fname (String.concat "; " path))
 336   end else
 337     load_from_absolute registry fname
 338
 339 let fold registry ?prefix ?(interpolate = true) f init =
 340   let value_of k v =
 341     if interpolate then singleton (get registry k) else strip_blanks v
 342   in
 343   match prefix with
 344   | None -> Hashtbl.fold (fun k v acc -> f acc k (value_of k v)) registry init
 345   | Some s ->
 346       let key_matches = starts_with (s ^ ".") in
 347       let rec fold_filter acc = function
 348         | [] -> acc
 349         | (k,v) :: tl when key_matches k ->
 350             fold_filter (f acc k (value_of k v)) tl
 351         | _ :: tl -> fold_filter acc tl
 352       in
 353       fold_filter init (hashtbl_pairs registry)
 354
 355 let iter registry ?prefix ?interpolate f =
 356   fold registry ?prefix ?interpolate (fun _ k v -> f k v) ()
 357 let to_list registry ?prefix ?interpolate () =
 358   fold registry ?prefix ?interpolate (fun acc k v -> (k, v) :: acc) []
 359
 360 let ls registry prefix =
 361   let prefix = prefix ^ "." in
 362   let prefix_len = String.length prefix in
 363   let key_matches = starts_with prefix in
 364   let matching_keys = (* collect matching keys' _postfixes_ *)
 365     fold registry
 366       (fun acc key _ ->
 367         if key_matches key then
 368           String.sub key prefix_len (String.length key - prefix_len) :: acc
 369         else
 370           acc)
 371       []
 372   in
 373   let (sections, keys) =
 374     List.fold_left
 375       (fun (sections, keys) postfix ->
 376         match Str.split dot_rex postfix with
 377         | [key] -> (sections, key :: keys)
 378         | hd_key :: _ ->  (* length > 1 => nested section found *)
 379             (hd_key :: sections, keys)
 380         | _ -> assert false)
 381       ([], []) matching_keys
 382   in
 383   (list_uniq (List.sort Pervasives.compare sections), keys)
 384
 385 (** {2 API implementation}
 386  * functional methods above are wrapped so that they work on a default
 387  * (imperative) registry*)
 388
 389 let default_registry = Hashtbl.create magic_size
 390
 391 let get key = singleton (get default_registry key)
 392 let set = set' ~replace:true default_registry
 393 let has = has default_registry
 394 let fold ?prefix ?interpolate f init =
 395   fold default_registry ?prefix ?interpolate f init
 396 let iter = iter default_registry
 397 let to_list = to_list default_registry
 398 let ls = ls default_registry
 399 let get_typed unmarshaller = get_typed default_registry unmarshaller
 400 let get_opt unmarshaller = get_opt default_registry unmarshaller
 401 let get_opt_default unmarshaller = get_opt_default default_registry unmarshaller
 402 let get_list unmarshaller = get_list default_registry unmarshaller
 403 let get_pair unmarshaller = get_pair default_registry unmarshaller
 404 let set_typed marshaller = set_typed default_registry marshaller
 405 let set_opt unmarshaller = set_opt default_registry unmarshaller
 406 let set_list marshaller = set_list default_registry marshaller
 407 let unset = unset default_registry
 408 let save_to = save_to default_registry
 409 let load_from = load_from default_registry
 410 let clear () = Hashtbl.clear default_registry
 411
 412 let get_string = get_typed string
 413 let get_int = get_typed int
 414 let get_float = get_typed float
 415 let get_bool = get_typed bool
 416 let set_string = set_typed of_string
 417 let set_int = set_typed of_int
 418 let set_float = set_typed of_float
 419 let set_bool = set_typed of_bool
 420