helm/ocaml/registry/helm_registry.ml

   1 (* Copyright (C) 2004-2005, HELM Team.
   2  *
   3  * This file is part of HELM, an Hypertextual, Electronic
   4  * Library of Mathematics, developed at the Computer Science
   5  * Department, University of Bologna, Italy.
   6  *
   7  * HELM is free software; you can redistribute it and/or
   8  * modify it under the terms of the GNU General Public License
   9  * as published by the Free Software Foundation; either version 2
  10  * of the License, or (at your option) any later version.
  11  *
  12  * HELM is distributed in the hope that it will be useful,
  13  * but WITHOUT ANY WARRANTY; without even the implied warranty of
  14  * MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the
  15  * GNU General Public License for more details.
  16  *
  17  * You should have received a copy of the GNU General Public License
  18  * along with HELM; if not, write to the Free Software
  19  * Foundation, Inc., 59 Temple Place - Suite 330, Boston,
  20  * MA  02111-1307, USA.
  21  *
  22  * For details, see the HELM World-Wide-Web page,
  23  * http://helm.cs.unibo.it/
  24  *)
  25
  26 (* $Id$ *)
  27
  28 open Printf
  29
  30 let debug = false
  31 let debug_print s =
  32   if debug then prerr_endline ("Helm_registry debugging: " ^ (Lazy.force s))
  33
  34   (** <helpers> *)
  35
  36 let list_uniq l =
  37   let rec aux last_element = function
  38     | [] -> []
  39     | hd :: tl ->
  40         (match last_element with
  41         | Some elt when elt = hd -> aux last_element tl
  42         | _ -> hd :: aux (Some hd) tl)
  43   in
  44   aux None l
  45
  46 let starts_with prefix =
  47 (*
  48   let rex = Str.regexp (Str.quote prefix) in
  49   fun s -> Str.string_match rex s 0
  50 *)
  51   let prefix_len = String.length prefix in
  52   fun s ->
  53     try
  54       String.sub s 0 prefix_len = prefix
  55     with Invalid_argument _ -> false
  56
  57 let hashtbl_keys tbl = Hashtbl.fold (fun k _ acc -> k :: acc) tbl []
  58 let hashtbl_pairs tbl = Hashtbl.fold (fun k v acc -> (k,v) :: acc) tbl []
  59
  60   (** </helpers> *)
  61
  62 exception Malformed_key of string
  63 exception Key_not_found of string
  64 exception Cyclic_definition of string
  65 exception Type_error of string (* expected type, value, msg *)
  66 exception Parse_error of string * int * int * string  (* file, line, col, msg *)
  67
  68   (* root XML tag: used by save_to, ignored by load_from *)
  69 let root_tag = "helm_registry"
  70
  71 let magic_size = 127
  72
  73 let backup_registry registry = Hashtbl.copy registry
  74 let restore_registry backup registry =
  75   Hashtbl.clear registry;
  76   Hashtbl.iter (fun key value -> Hashtbl.add registry key value) backup
  77
  78   (* as \\w but:
  79    * - no sequences of '_' longer than 1 are permitted
  80    *)
  81 let valid_step_rex_raw = "[a-zA-Z0-9]+\\(_[a-z0A-Z-9]+\\)*"
  82 let valid_key_rex_raw =
  83   sprintf "%s\\(\\.%s\\)*" valid_step_rex_raw valid_step_rex_raw
  84 let valid_key_rex = Str.regexp ("^" ^ valid_key_rex_raw ^ "$")
  85 let interpolated_key_rex = Str.regexp ("\\$(" ^ valid_key_rex_raw ^ ")")
  86 let dot_rex = Str.regexp "\\."
  87 let spaces_rex = Str.regexp "[ \t\n\r]+"
  88 let heading_spaces_rex = Str.regexp "^[ \t\n\r]+"
  89 let margin_blanks_rex =
  90   Str.regexp "^\\([ \t\n\r]*\\)\\([^ \t\n\r]*\\)\\([ \t\n\r]*\\)$"
  91
  92 let strip_blanks s = Str.global_replace margin_blanks_rex "\\2" s
  93
  94 let split s =
  95   (* trailing blanks are removed per default by split *)
  96   Str.split spaces_rex (Str.global_replace heading_spaces_rex "" s)
  97 let merge l = String.concat " " l
  98
  99 let handle_type_error f x =
 100   try f x with exn -> raise (Type_error (Printexc.to_string exn))
 101
 102   (** marshallers/unmarshallers *)
 103 let string x = x
 104 let int = handle_type_error int_of_string
 105 let float = handle_type_error float_of_string
 106 let bool = handle_type_error bool_of_string
 107 let of_string x = x
 108 let of_int = handle_type_error string_of_int
 109 let of_float = handle_type_error string_of_float
 110 let of_bool = handle_type_error string_of_bool
 111
 112   (* escapes for xml configuration file *)
 113 let (escape, unescape) =
 114   let (in_enc, out_enc) = (`Enc_utf8, `Enc_utf8) in
 115   (Netencoding.Html.encode ~in_enc ~out_enc (),
 116    Netencoding.Html.decode ~in_enc ~out_enc ~entity_base:`Xml ())
 117
 118 let key_is_valid key =
 119   if not (Str.string_match valid_key_rex key 0) then
 120     raise (Malformed_key key)
 121
 122 let set' ?(replace=false) registry ~key ~value =
 123   debug_print (lazy(sprintf "Setting (replace: %b) %s = %s" replace key value));
 124   key_is_valid key;
 125   let add_fun = if replace then Hashtbl.replace else Hashtbl.add in
 126   add_fun registry key value
 127
 128 let unset registry = Hashtbl.remove registry
 129
 130 let env_var_of_key = Str.global_replace dot_rex "__"
 131
 132 let singleton = function
 133   | [] ->
 134       raise (Type_error ("empty list value found where singleton was expected"))
 135   | hd :: _ -> hd
 136
 137 let get registry key =
 138   let rec aux stack key =
 139     key_is_valid key;
 140     if List.mem key stack then begin
 141       let msg = (String.concat " -> " (List.rev stack)) ^ " -> " ^ key in
 142       raise (Cyclic_definition msg)
 143     end;
 144       (* internal value *)
 145     let registry_values = List.rev (Hashtbl.find_all registry key) in
 146     let env_value = (* environment value *)
 147       try
 148         Some (Sys.getenv (env_var_of_key key))
 149       with Not_found -> None
 150     in
 151     let values = (* resulting value *)
 152       match registry_values, env_value with
 153       | _, Some env -> [env]
 154       | [], None -> raise (Key_not_found key)
 155       | values, None -> values
 156     in
 157     List.map (interpolate (key :: stack)) values
 158   and interpolate stack value =
 159     Str.global_substitute interpolated_key_rex
 160       (fun s ->
 161         let matched = Str.matched_string s in
 162           (* "$(var)" -> "var" *)
 163         let key = String.sub matched 2 (String.length matched - 3) in
 164         singleton (aux stack key))
 165       value
 166   in
 167   List.map strip_blanks (aux [] key)
 168
 169 let has registry key = Hashtbl.mem registry key
 170
 171 let get_typed registry unmarshaller key =
 172   let value = singleton (get registry key) in
 173   unmarshaller value
 174
 175 let set_typed registry marshaller ~key ~value =
 176   set' ~replace:true registry ~key ~value:(marshaller value)
 177
 178 let get_opt registry unmarshaller key =
 179   try
 180     Some (unmarshaller (singleton (get registry key)))
 181   with Key_not_found _ -> None
 182
 183 let get_opt_default registry unmarshaller ~default key =
 184   match get_opt registry unmarshaller key with
 185   | None -> default
 186   | Some v -> v
 187
 188 let set_opt registry marshaller ~key ~value =
 189   match value with
 190   | None -> unset registry key
 191   | Some value -> set' ~replace:true registry ~key ~value:(marshaller value)
 192
 193 let get_list registry unmarshaller key =
 194   try
 195     List.map unmarshaller (get registry key)
 196   with Key_not_found _ -> []
 197
 198 let get_pair registry fst_unmarshaller snd_unmarshaller key =
 199   let v = singleton (get registry key) in
 200   match Str.split spaces_rex v with
 201   | [fst; snd] -> fst_unmarshaller fst, snd_unmarshaller snd
 202   | _ -> raise (Type_error "not a pair")
 203
 204 let set_list registry marshaller ~key ~value =
 205   Hashtbl.remove registry key;
 206   List.iter
 207     (fun v -> set' ~replace:false registry ~key ~value:(marshaller v))
 208     value
 209
 210 type xml_tree =
 211   | Cdata of string
 212   | Element of string * (string * string) list * xml_tree list
 213
 214 let dot_RE = Str.regexp "\\."
 215
 216 let xml_tree_of_registry registry =
 217   let has_child name elements =
 218     List.exists
 219       (function
 220         | Element (_, ["name", name'], _) when name = name' -> true
 221         | _ -> false)
 222       elements
 223   in
 224   let rec get_child name = function
 225     | [] -> assert false
 226     | (Element (_, ["name", name'], _) as child) :: tl when name = name' ->
 227         child, tl
 228     | hd :: tl ->
 229         let child, rest = get_child name tl in
 230         child, hd :: rest
 231   in
 232   let rec add_key path value tree =
 233     match path, tree with
 234     | [key], Element (name, attrs, children) ->
 235         Element (name, attrs,
 236           Element ("key", ["name", key],
 237             [Cdata (strip_blanks value)]) :: children)
 238     | dir :: path, Element (name, attrs, children) ->
 239         if has_child dir children then
 240           let child, rest = get_child dir children in
 241           Element (name, attrs, add_key path value child :: rest)
 242         else
 243           Element (name, attrs,
 244             ((add_key path value (Element ("section", ["name", dir], [])))
 245               :: children))
 246     | _ -> assert false
 247   in
 248   Hashtbl.fold
 249     (fun k v tree -> add_key ((Str.split dot_RE k)) v tree)
 250     registry
 251     (Element (root_tag, [], []))
 252
 253 let rec stream_of_xml_tree = function
 254   | Cdata s -> Xml.xml_cdata s
 255   | Element (name, attrs, children) ->
 256       Xml.xml_nempty name
 257         (List.map (fun (n, v) -> (None, n, v)) attrs)
 258         (stream_of_xml_trees children)
 259 and stream_of_xml_trees = function
 260   | [] -> [< >]
 261   | hd :: tl -> [< stream_of_xml_tree hd; stream_of_xml_trees tl >]
 262
 263 let save_to registry fname =
 264   let token_stream = stream_of_xml_tree (xml_tree_of_registry registry) in
 265   let oc = open_out fname in
 266   Xml.pp_to_outchan token_stream oc;
 267   close_out oc
 268
 269 let rec load_from_absolute ?path registry fname =
 270   let _path = ref (match path with None -> [] | Some p -> p)in
 271     (* <section> elements entered so far *)
 272   let in_key = ref false in (* have we entered a <key> element? *)
 273   let cdata = ref "" in     (* collected cdata (inside <key> *)
 274   let push_path name = _path := name :: !_path in
 275   let pop_path () = _path := List.tl !_path in
 276   let start_element tag attrs =
 277     match tag, attrs with
 278     | "section", ["name", name] -> push_path name
 279     | "key", ["name", name] -> in_key := true; push_path name
 280     | "helm_registry", _ -> ()
 281     | "include", ["href", fname] ->
 282         debug_print (lazy ("including file " ^ fname));
 283         load_from_absolute ~path:!_path registry fname
 284     | tag, _ ->
 285         raise (Parse_error (fname, ~-1, ~-1,
 286           (sprintf "unexpected element <%s> or wrong attribute set" tag)))
 287   in
 288   let end_element tag =
 289     match tag with
 290     | "section" -> pop_path ()
 291     | "key" ->
 292         let key = String.concat "." (List.rev !_path) in
 293         set' registry ~key ~value:!cdata;
 294         cdata := "";
 295         in_key := false;
 296         pop_path ()
 297     | "include" | "helm_registry" -> ()
 298     | _ -> assert false
 299   in
 300   let character_data text =
 301     if !in_key then cdata := !cdata ^ text
 302   in
 303   let callbacks = {
 304     XmlPushParser.default_callbacks with
 305       XmlPushParser.start_element = Some start_element;
 306       XmlPushParser.end_element = Some end_element;
 307       XmlPushParser.character_data = Some character_data;
 308   } in
 309   let xml_parser = XmlPushParser.create_parser callbacks in
 310   let backup = backup_registry registry in
 311 (*   if path = None then Hashtbl.clear registry; *)
 312   try
 313     XmlPushParser.parse xml_parser (`File fname)
 314   with exn ->
 315     restore_registry backup registry;
 316     raise exn
 317
 318 let load_from registry ?path fname =
 319   if Filename.is_relative fname then begin
 320     let no_file_found = ref true in
 321     let path =
 322       match path with
 323       | Some path -> path (* path given as argument *)
 324       | None -> [ Sys.getcwd () ] (* no path given, try with cwd *)
 325     in
 326     List.iter
 327       (fun dir ->
 328         let conffile = dir ^ "/" ^ fname in
 329         if Sys.file_exists conffile then begin
 330           no_file_found := false;
 331           load_from_absolute registry conffile
 332         end)
 333        path;
 334     if !no_file_found then
 335       failwith (sprintf
 336         "Helm_registry.init: no configuration file named %s in [ %s ]"
 337         fname (String.concat "; " path))
 338   end else
 339     load_from_absolute registry fname
 340
 341 let fold registry ?prefix ?(interpolate = true) f init =
 342   let value_of k v =
 343     if interpolate then singleton (get registry k) else strip_blanks v
 344   in
 345   match prefix with
 346   | None -> Hashtbl.fold (fun k v acc -> f acc k (value_of k v)) registry init
 347   | Some s ->
 348       let key_matches = starts_with (s ^ ".") in
 349       let rec fold_filter acc = function
 350         | [] -> acc
 351         | (k,v) :: tl when key_matches k ->
 352             fold_filter (f acc k (value_of k v)) tl
 353         | _ :: tl -> fold_filter acc tl
 354       in
 355       fold_filter init (hashtbl_pairs registry)
 356
 357 let iter registry ?prefix ?interpolate f =
 358   fold registry ?prefix ?interpolate (fun _ k v -> f k v) ()
 359 let to_list registry ?prefix ?interpolate () =
 360   fold registry ?prefix ?interpolate (fun acc k v -> (k, v) :: acc) []
 361
 362 let ls registry prefix =
 363   let prefix = prefix ^ "." in
 364   let prefix_len = String.length prefix in
 365   let key_matches = starts_with prefix in
 366   let matching_keys = (* collect matching keys' _postfixes_ *)
 367     fold registry
 368       (fun acc key _ ->
 369         if key_matches key then
 370           String.sub key prefix_len (String.length key - prefix_len) :: acc
 371         else
 372           acc)
 373       []
 374   in
 375   let (sections, keys) =
 376     List.fold_left
 377       (fun (sections, keys) postfix ->
 378         match Str.split dot_rex postfix with
 379         | [key] -> (sections, key :: keys)
 380         | hd_key :: _ ->  (* length > 1 => nested section found *)
 381             (hd_key :: sections, keys)
 382         | _ -> assert false)
 383       ([], []) matching_keys
 384   in
 385   (list_uniq (List.sort Pervasives.compare sections), keys)
 386
 387 (** {2 API implementation}
 388  * functional methods above are wrapped so that they work on a default
 389  * (imperative) registry*)
 390
 391 let default_registry = Hashtbl.create magic_size
 392
 393 let get key = singleton (get default_registry key)
 394 let set = set' ~replace:true default_registry
 395 let has = has default_registry
 396 let fold ?prefix ?interpolate f init =
 397   fold default_registry ?prefix ?interpolate f init
 398 let iter = iter default_registry
 399 let to_list = to_list default_registry
 400 let ls = ls default_registry
 401 let get_typed unmarshaller = get_typed default_registry unmarshaller
 402 let get_opt unmarshaller = get_opt default_registry unmarshaller
 403 let get_opt_default unmarshaller = get_opt_default default_registry unmarshaller
 404 let get_list unmarshaller = get_list default_registry unmarshaller
 405 let get_pair unmarshaller = get_pair default_registry unmarshaller
 406 let set_typed marshaller = set_typed default_registry marshaller
 407 let set_opt unmarshaller = set_opt default_registry unmarshaller
 408 let set_list marshaller = set_list default_registry marshaller
 409 let unset = unset default_registry
 410 let save_to = save_to default_registry
 411 let load_from = load_from default_registry
 412 let clear () = Hashtbl.clear default_registry
 413
 414 let get_string = get_typed string
 415 let get_int = get_typed int
 416 let get_float = get_typed float
 417 let get_bool = get_typed bool
 418 let set_string = set_typed of_string
 419 let set_int = set_typed of_int
 420 let set_float = set_typed of_float
 421 let set_bool = set_typed of_bool
 422