helm/ocaml/registry/helm_registry.ml

   1 (* Copyright (C) 2004-2005, HELM Team.
   2  *
   3  * This file is part of HELM, an Hypertextual, Electronic
   4  * Library of Mathematics, developed at the Computer Science
   5  * Department, University of Bologna, Italy.
   6  *
   7  * HELM is free software; you can redistribute it and/or
   8  * modify it under the terms of the GNU General Public License
   9  * as published by the Free Software Foundation; either version 2
  10  * of the License, or (at your option) any later version.
  11  *
  12  * HELM is distributed in the hope that it will be useful,
  13  * but WITHOUT ANY WARRANTY; without even the implied warranty of
  14  * MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the
  15  * GNU General Public License for more details.
  16  *
  17  * You should have received a copy of the GNU General Public License
  18  * along with HELM; if not, write to the Free Software
  19  * Foundation, Inc., 59 Temple Place - Suite 330, Boston,
  20  * MA  02111-1307, USA.
  21  *
  22  * For details, see the HELM World-Wide-Web page,
  23  * http://helm.cs.unibo.it/
  24  *)
  25
  26 open Printf
  27
  28 let debug = false
  29 let debug_print s =
  30   if debug then prerr_endline ("Helm_registry debugging: " ^ (Lazy.force s))
  31
  32   (** <helpers> *)
  33
  34 let list_uniq l =
  35   let rec aux last_element = function
  36     | [] -> []
  37     | hd :: tl ->
  38         (match last_element with
  39         | Some elt when elt = hd -> aux last_element tl
  40         | _ -> hd :: aux (Some hd) tl)
  41   in
  42   aux None l
  43
  44 let starts_with prefix =
  45 (*
  46   let rex = Str.regexp (Str.quote prefix) in
  47   fun s -> Str.string_match rex s 0
  48 *)
  49   let prefix_len = String.length prefix in
  50   fun s ->
  51     try
  52       String.sub s 0 prefix_len = prefix
  53     with Invalid_argument _ -> false
  54
  55 let hashtbl_keys tbl = Hashtbl.fold (fun k _ acc -> k :: acc) tbl []
  56 let hashtbl_pairs tbl = Hashtbl.fold (fun k v acc -> (k,v) :: acc) tbl []
  57
  58   (** </helpers> *)
  59
  60 exception Malformed_key of string
  61 exception Key_not_found of string
  62 exception Cyclic_definition of string
  63 exception Type_error of string (* expected type, value, msg *)
  64 exception Parse_error of string * int * int * string  (* file, line, col, msg *)
  65
  66   (* root XML tag: used by save_to, ignored by load_from *)
  67 let root_tag = "helm_registry"
  68
  69 let magic_size = 127
  70
  71 let backup_registry registry = Hashtbl.copy registry
  72 let restore_registry backup registry =
  73   Hashtbl.clear registry;
  74   Hashtbl.iter (fun key value -> Hashtbl.add registry key value) backup
  75
  76   (* as \\w but:
  77    * - no sequences of '_' longer than 1 are permitted
  78    *)
  79 let valid_step_rex_raw = "[a-zA-Z0-9]+\\(_[a-z0A-Z-9]+\\)*"
  80 let valid_key_rex_raw =
  81   sprintf "%s\\(\\.%s\\)*" valid_step_rex_raw valid_step_rex_raw
  82 let valid_key_rex = Str.regexp ("^" ^ valid_key_rex_raw ^ "$")
  83 let interpolated_key_rex = Str.regexp ("\\$(" ^ valid_key_rex_raw ^ ")")
  84 let dot_rex = Str.regexp "\\."
  85 let spaces_rex = Str.regexp "[ \t\n\r]+"
  86 let heading_spaces_rex = Str.regexp "^[ \t\n\r]+"
  87 let margin_blanks_rex =
  88   Str.regexp "^\\([ \t\n\r]*\\)\\([^ \t\n\r]*\\)\\([ \t\n\r]*\\)$"
  89
  90 let strip_blanks s = Str.global_replace margin_blanks_rex "\\2" s
  91
  92 let split s =
  93   (* trailing blanks are removed per default by split *)
  94   Str.split spaces_rex (Str.global_replace heading_spaces_rex "" s)
  95 let merge l = String.concat " " l
  96
  97 let handle_type_error f x =
  98   try f x with exn -> raise (Type_error (Printexc.to_string exn))
  99
 100   (** marshallers/unmarshallers *)
 101 let string x = x
 102 let int = handle_type_error int_of_string
 103 let float = handle_type_error float_of_string
 104 let bool = handle_type_error bool_of_string
 105 let of_string x = x
 106 let of_int = handle_type_error string_of_int
 107 let of_float = handle_type_error string_of_float
 108 let of_bool = handle_type_error string_of_bool
 109
 110   (* escapes for xml configuration file *)
 111 let (escape, unescape) =
 112   let (in_enc, out_enc) = (`Enc_utf8, `Enc_utf8) in
 113   (Netencoding.Html.encode ~in_enc ~out_enc (),
 114    Netencoding.Html.decode ~in_enc ~out_enc ~entity_base:`Xml ())
 115
 116 let key_is_valid key =
 117   if not (Str.string_match valid_key_rex key 0) then
 118     raise (Malformed_key key)
 119
 120 let set' ?(replace=true) registry ~key ~value =
 121   debug_print (lazy (sprintf "Setting %s = %s" key value));
 122   key_is_valid key;
 123   if replace then
 124     Hashtbl.replace registry key value
 125   else
 126     Hashtbl.add registry key value
 127
 128 let unset registry = Hashtbl.remove registry
 129
 130 let env_var_of_key = Str.global_replace dot_rex "__"
 131
 132 let singleton = function
 133   | [] ->
 134       raise (Type_error ("empty list value found where singleton was expected"))
 135   | hd :: _ -> hd
 136
 137 let get registry key =
 138   let rec aux stack key =
 139     key_is_valid key;
 140     if List.mem key stack then begin
 141       let msg = (String.concat " -> " (List.rev stack)) ^ " -> " ^ key in
 142       raise (Cyclic_definition msg)
 143     end;
 144       (* internal value *)
 145     let registry_values = List.rev (Hashtbl.find_all registry key) in
 146     let env_value = (* environment value *)
 147       try
 148         Some (Sys.getenv (env_var_of_key key))
 149       with Not_found -> None
 150     in
 151     let values = (* resulting value *)
 152       match registry_values, env_value with
 153       | _, Some env -> [env]
 154       | [], None -> raise (Key_not_found key)
 155       | values, None -> values
 156     in
 157     List.map (interpolate (key :: stack)) values
 158   and interpolate stack value =
 159     Str.global_substitute interpolated_key_rex
 160       (fun s ->
 161         let matched = Str.matched_string s in
 162           (* "$(var)" -> "var" *)
 163         let key = String.sub matched 2 (String.length matched - 3) in
 164         singleton (aux stack key))
 165       value
 166   in
 167   List.map strip_blanks (aux [] key)
 168
 169 let set = set'
 170
 171 let has registry key = Hashtbl.mem registry key
 172
 173 let get_typed registry unmarshaller key =
 174   let value = singleton (get registry key) in
 175   unmarshaller value
 176
 177 let set_typed registry marshaller ~key ~value =
 178   set registry ~key ~value:(marshaller value)
 179
 180 let get_opt registry unmarshaller key =
 181   try
 182     Some (unmarshaller (singleton (get registry key)))
 183   with Key_not_found _ -> None
 184
 185 let get_opt_default registry unmarshaller ~default key =
 186   match get_opt registry unmarshaller key with
 187   | None -> default
 188   | Some v -> v
 189
 190 let set_opt registry marshaller ~key ~value =
 191   match value with
 192   | None -> unset registry key
 193   | Some value -> set registry ~key ~value:(marshaller value)
 194
 195 let get_list registry unmarshaller key =
 196   try
 197     List.map unmarshaller (get registry key)
 198   with Key_not_found _ -> []
 199
 200 let get_pair registry fst_unmarshaller snd_unmarshaller key =
 201   let v = singleton (get registry key) in
 202   match Str.split spaces_rex v with
 203   | [fst; snd] -> fst_unmarshaller fst, snd_unmarshaller snd
 204   | _ -> raise (Type_error "not a pair")
 205
 206 let set_list registry marshaller ~key ~value =
 207   List.iter
 208     (fun v -> set ~replace:false registry ~key ~value:(marshaller v))
 209     value
 210
 211 type xml_tree =
 212   | Cdata of string
 213   | Element of string * (string * string) list * xml_tree list
 214
 215 let dot_RE = Str.regexp "\\."
 216
 217 let xml_tree_of_registry registry =
 218   let has_child name elements =
 219     List.exists
 220       (function
 221         | Element (_, ["name", name'], _) when name = name' -> true
 222         | _ -> false)
 223       elements
 224   in
 225   let rec get_child name = function
 226     | [] -> assert false
 227     | (Element (_, ["name", name'], _) as child) :: tl when name = name' ->
 228         child, tl
 229     | hd :: tl ->
 230         let child, rest = get_child name tl in
 231         child, hd :: rest
 232   in
 233   let rec add_key path value tree =
 234     match path, tree with
 235     | [key], Element (name, attrs, children) ->
 236         Element (name, attrs,
 237           Element ("key", ["name", key],
 238             [Cdata (strip_blanks value)]) :: children)
 239     | dir :: path, Element (name, attrs, children) ->
 240         if has_child dir children then
 241           let child, rest = get_child dir children in
 242           Element (name, attrs, add_key path value child :: rest)
 243         else
 244           Element (name, attrs,
 245             ((add_key path value (Element ("section", ["name", dir], [])))
 246               :: children))
 247     | _ -> assert false
 248   in
 249   Hashtbl.fold
 250     (fun k v tree -> add_key ((Str.split dot_RE k)) v tree)
 251     registry
 252     (Element (root_tag, [], []))
 253
 254 let rec stream_of_xml_tree = function
 255   | Cdata s -> Xml.xml_cdata s
 256   | Element (name, attrs, children) ->
 257       Xml.xml_nempty name
 258         (List.map (fun (n, v) -> (None, n, v)) attrs)
 259         (stream_of_xml_trees children)
 260 and stream_of_xml_trees = function
 261   | [] -> [< >]
 262   | hd :: tl -> [< stream_of_xml_tree hd; stream_of_xml_trees tl >]
 263
 264 let save_to registry fname =
 265   let token_stream = stream_of_xml_tree (xml_tree_of_registry registry) in
 266   let oc = open_out fname in
 267   Xml.pp_to_outchan token_stream oc;
 268   close_out oc
 269
 270 let rec load_from_absolute ?path registry fname =
 271   let _path = ref (match path with None -> [] | Some p -> p)in
 272     (* <section> elements entered so far *)
 273   let in_key = ref false in (* have we entered a <key> element? *)
 274   let cdata = ref "" in     (* collected cdata (inside <key> *)
 275   let push_path name = _path := name :: !_path in
 276   let pop_path () = _path := List.tl !_path in
 277   let start_element tag attrs =
 278     match tag, attrs with
 279     | "section", ["name", name] -> push_path name
 280     | "key", ["name", name] -> in_key := true; push_path name
 281     | "helm_registry", _ -> ()
 282     | "include", ["href", fname] ->
 283         debug_print (lazy ("including file " ^ fname));
 284         load_from_absolute ~path:!_path registry fname
 285     | tag, _ ->
 286         raise (Parse_error (fname, ~-1, ~-1,
 287           (sprintf "unexpected element <%s> or wrong attribute set" tag)))
 288   in
 289   let end_element tag =
 290     match tag with
 291     | "section" -> pop_path ()
 292     | "key" ->
 293         let key = String.concat "." (List.rev !_path) in
 294         set registry ~key ~value:!cdata;
 295         cdata := "";
 296         in_key := false;
 297         pop_path ()
 298     | "include" | "helm_registry" -> ()
 299     | _ -> assert false
 300   in
 301   let character_data text =
 302     if !in_key then cdata := !cdata ^ text
 303   in
 304   let callbacks = {
 305     XmlPushParser.default_callbacks with
 306       XmlPushParser.start_element = Some start_element;
 307       XmlPushParser.end_element = Some end_element;
 308       XmlPushParser.character_data = Some character_data;
 309   } in
 310   let xml_parser = XmlPushParser.create_parser callbacks in
 311   let backup = backup_registry registry in
 312 (*   if path = None then Hashtbl.clear registry; *)
 313   try
 314     XmlPushParser.parse xml_parser (`File fname)
 315   with exn ->
 316     restore_registry backup registry;
 317     raise exn
 318
 319 let load_from registry ?path fname =
 320   if Filename.is_relative fname then begin
 321     let no_file_found = ref true in
 322     let path =
 323       match path with
 324       | Some path -> path (* path given as argument *)
 325       | None -> [ Sys.getcwd () ] (* no path given, try with cwd *)
 326     in
 327     List.iter
 328       (fun dir ->
 329         let conffile = dir ^ "/" ^ fname in
 330         if Sys.file_exists conffile then begin
 331           no_file_found := false;
 332           load_from_absolute registry conffile
 333         end)
 334        path;
 335     if !no_file_found then
 336       failwith (sprintf
 337         "Helm_registry.init: no configuration file named %s in [ %s ]"
 338         fname (String.concat "; " path))
 339   end else
 340     load_from_absolute registry fname
 341
 342 let fold registry ?prefix ?(interpolate = true) f init =
 343   let value_of k v =
 344     if interpolate then singleton (get registry k) else strip_blanks v
 345   in
 346   match prefix with
 347   | None -> Hashtbl.fold (fun k v acc -> f acc k (value_of k v)) registry init
 348   | Some s ->
 349       let key_matches = starts_with (s ^ ".") in
 350       let rec fold_filter acc = function
 351         | [] -> acc
 352         | (k,v) :: tl when key_matches k ->
 353             fold_filter (f acc k (value_of k v)) tl
 354         | _ :: tl -> fold_filter acc tl
 355       in
 356       fold_filter init (hashtbl_pairs registry)
 357
 358 let iter registry ?prefix ?interpolate f =
 359   fold registry ?prefix ?interpolate (fun _ k v -> f k v) ()
 360 let to_list registry ?prefix ?interpolate () =
 361   fold registry ?prefix ?interpolate (fun acc k v -> (k, v) :: acc) []
 362
 363 let ls registry prefix =
 364   let prefix = prefix ^ "." in
 365   let prefix_len = String.length prefix in
 366   let key_matches = starts_with prefix in
 367   let matching_keys = (* collect matching keys' _postfixes_ *)
 368     fold registry
 369       (fun acc key _ ->
 370         if key_matches key then
 371           String.sub key prefix_len (String.length key - prefix_len) :: acc
 372         else
 373           acc)
 374       []
 375   in
 376   let (sections, keys) =
 377     List.fold_left
 378       (fun (sections, keys) postfix ->
 379         match Str.split dot_rex postfix with
 380         | [key] -> (sections, key :: keys)
 381         | hd_key :: _ ->  (* length > 1 => nested section found *)
 382             (hd_key :: sections, keys)
 383         | _ -> assert false)
 384       ([], []) matching_keys
 385   in
 386   (list_uniq (List.sort Pervasives.compare sections), keys)
 387
 388 (** {2 API implementation}
 389  * functional methods above are wrapped so that they work on a default
 390  * (imperative) registry*)
 391
 392 let default_registry = Hashtbl.create magic_size
 393
 394 let get key = singleton (get default_registry key)
 395 let set = set default_registry
 396 let has = has default_registry
 397 let fold ?prefix ?interpolate f init =
 398   fold default_registry ?prefix ?interpolate f init
 399 let iter = iter default_registry
 400 let to_list = to_list default_registry
 401 let ls = ls default_registry
 402 let get_typed unmarshaller = get_typed default_registry unmarshaller
 403 let get_opt unmarshaller = get_opt default_registry unmarshaller
 404 let get_opt_default unmarshaller = get_opt_default default_registry unmarshaller
 405 let get_list unmarshaller = get_list default_registry unmarshaller
 406 let get_pair unmarshaller = get_pair default_registry unmarshaller
 407 let set_typed marshaller = set_typed default_registry marshaller
 408 let set_opt unmarshaller = set_opt default_registry unmarshaller
 409 let set_list marshaller = set_list default_registry marshaller
 410 let unset = unset default_registry
 411 let save_to = save_to default_registry
 412 let load_from = load_from default_registry
 413 let clear () = Hashtbl.clear default_registry
 414
 415 let get_string = get_typed string
 416 let get_int = get_typed int
 417 let get_float = get_typed float
 418 let get_bool = get_typed bool
 419 let set_string = set_typed of_string
 420 let set_int = set_typed of_int
 421 let set_float = set_typed of_float
 422 let set_bool = set_typed of_bool
 423