helm/ocaml/registry/helm_registry.ml

   1 (* Copyright (C) 2004-2005, HELM Team.
   2  *
   3  * This file is part of HELM, an Hypertextual, Electronic
   4  * Library of Mathematics, developed at the Computer Science
   5  * Department, University of Bologna, Italy.
   6  *
   7  * HELM is free software; you can redistribute it and/or
   8  * modify it under the terms of the GNU General Public License
   9  * as published by the Free Software Foundation; either version 2
  10  * of the License, or (at your option) any later version.
  11  *
  12  * HELM is distributed in the hope that it will be useful,
  13  * but WITHOUT ANY WARRANTY; without even the implied warranty of
  14  * MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the
  15  * GNU General Public License for more details.
  16  *
  17  * You should have received a copy of the GNU General Public License
  18  * along with HELM; if not, write to the Free Software
  19  * Foundation, Inc., 59 Temple Place - Suite 330, Boston,
  20  * MA  02111-1307, USA.
  21  *
  22  * For details, see the HELM World-Wide-Web page,
  23  * http://helm.cs.unibo.it/
  24  *)
  25
  26 open Printf
  27
  28 let debug = false
  29 let debug_print s =
  30   if debug then prerr_endline ("Helm_registry debugging: " ^ (Lazy.force s))
  31
  32   (** <helpers> *)
  33
  34 let list_uniq l =
  35   let rec aux last_element = function
  36     | [] -> []
  37     | hd :: tl ->
  38         (match last_element with
  39         | Some elt when elt = hd -> aux last_element tl
  40         | _ -> hd :: aux (Some hd) tl)
  41   in
  42   aux None l
  43
  44 let starts_with prefix =
  45 (*
  46   let rex = Str.regexp (Str.quote prefix) in
  47   fun s -> Str.string_match rex s 0
  48 *)
  49   let prefix_len = String.length prefix in
  50   fun s ->
  51     try
  52       String.sub s 0 prefix_len = prefix
  53     with Invalid_argument _ -> false
  54
  55 let hashtbl_keys tbl = Hashtbl.fold (fun k _ acc -> k :: acc) tbl []
  56 let hashtbl_pairs tbl = Hashtbl.fold (fun k v acc -> (k,v) :: acc) tbl []
  57
  58   (** </helpers> *)
  59
  60 exception Malformed_key of string
  61 exception Key_not_found of string
  62 exception Cyclic_definition of string
  63 exception Type_error of string (* expected type, value, msg *)
  64 exception Parse_error of string * int * int * string  (* file, line, col, msg *)
  65
  66   (* root XML tag: used by save_to, ignored by load_from *)
  67 let root_tag = "helm_registry"
  68
  69 let magic_size = 127
  70
  71 let backup_registry registry = Hashtbl.copy registry
  72 let restore_registry backup registry =
  73   Hashtbl.clear registry;
  74   Hashtbl.iter (fun key value -> Hashtbl.add registry key value) backup
  75
  76   (* as \\w but:
  77    * - no sequences of '_' longer than 1 are permitted
  78    *)
  79 let valid_step_rex_raw = "[a-zA-Z0-9]+\\(_[a-z0A-Z-9]+\\)*"
  80 let valid_key_rex_raw =
  81   sprintf "%s\\(\\.%s\\)*" valid_step_rex_raw valid_step_rex_raw
  82 let valid_key_rex = Str.regexp ("^" ^ valid_key_rex_raw ^ "$")
  83 let interpolated_key_rex = Str.regexp ("\\$(" ^ valid_key_rex_raw ^ ")")
  84 let dot_rex = Str.regexp "\\."
  85 let spaces_rex = Str.regexp "[ \t\n\r]+"
  86 let heading_spaces_rex = Str.regexp "^[ \t\n\r]+"
  87 let margin_blanks_rex =
  88   Str.regexp "^\\([ \t\n\r]*\\)\\([^ \t\n\r]*\\)\\([ \t\n\r]*\\)$"
  89
  90 let strip_blanks s = Str.global_replace margin_blanks_rex "\\2" s
  91
  92 let split s =
  93   (* trailing blanks are removed per default by split *)
  94   Str.split spaces_rex (Str.global_replace heading_spaces_rex "" s)
  95 let merge l = String.concat " " l
  96
  97 let handle_type_error f x =
  98   try f x with exn -> raise (Type_error (Printexc.to_string exn))
  99
 100   (** marshallers/unmarshallers *)
 101 let string x = x
 102 let int = handle_type_error int_of_string
 103 let float = handle_type_error float_of_string
 104 let bool = handle_type_error bool_of_string
 105 let of_string x = x
 106 let of_int = handle_type_error string_of_int
 107 let of_float = handle_type_error string_of_float
 108 let of_bool = handle_type_error string_of_bool
 109
 110   (* escapes for xml configuration file *)
 111 let (escape, unescape) =
 112   let (in_enc, out_enc) = (`Enc_utf8, `Enc_utf8) in
 113   (Netencoding.Html.encode ~in_enc ~out_enc (),
 114    Netencoding.Html.decode ~in_enc ~out_enc ~entity_base:`Xml ())
 115
 116 let key_is_valid key =
 117   if not (Str.string_match valid_key_rex key 0) then
 118     raise (Malformed_key key)
 119
 120 let set' registry ~key ~value =
 121   debug_print (lazy (sprintf "Setting %s = %s" key value));
 122   key_is_valid key;
 123   Hashtbl.add registry key value
 124
 125 let unset registry = Hashtbl.remove registry
 126
 127 let env_var_of_key = Str.global_replace dot_rex "__"
 128
 129 let singleton = function
 130   | [] ->
 131       raise (Type_error ("empty list value found where singleton was expected"))
 132   | hd :: _ -> hd
 133
 134 let get registry key =
 135   let rec aux stack key =
 136     key_is_valid key;
 137     if List.mem key stack then begin
 138       let msg = (String.concat " -> " (List.rev stack)) ^ " -> " ^ key in
 139       raise (Cyclic_definition msg)
 140     end;
 141       (* internal value *)
 142     let registry_values = List.rev (Hashtbl.find_all registry key) in
 143     let env_value = (* environment value *)
 144       try
 145         Some (Sys.getenv (env_var_of_key key))
 146       with Not_found -> None
 147     in
 148     let values = (* resulting value *)
 149       match registry_values, env_value with
 150       | _, Some env -> [env]
 151       | [], None -> raise (Key_not_found key)
 152       | values, None -> values
 153     in
 154     List.map (interpolate (key :: stack)) values
 155   and interpolate stack value =
 156     Str.global_substitute interpolated_key_rex
 157       (fun s ->
 158         let matched = Str.matched_string s in
 159           (* "$(var)" -> "var" *)
 160         let key = String.sub matched 2 (String.length matched - 3) in
 161         singleton (aux stack key))
 162       value
 163   in
 164   List.map strip_blanks (aux [] key)
 165
 166 let set registry = set' registry
 167
 168 let has registry key = Hashtbl.mem registry key
 169
 170 let get_typed registry unmarshaller key =
 171   let value = singleton (get registry key) in
 172   unmarshaller value
 173
 174 let set_typed registry marshaller ~key ~value =
 175   set registry ~key ~value:(marshaller value)
 176
 177 let get_opt registry unmarshaller key =
 178   try
 179     Some (unmarshaller (singleton (get registry key)))
 180   with Key_not_found _ -> None
 181
 182 let get_opt_default registry unmarshaller ~default key =
 183   match get_opt registry unmarshaller key with
 184   | None -> default
 185   | Some v -> v
 186
 187 let set_opt registry marshaller ~key ~value =
 188   match value with
 189   | None -> unset registry key
 190   | Some value -> set registry ~key ~value:(marshaller value)
 191
 192 let get_list registry unmarshaller key =
 193   try
 194     List.map unmarshaller (get registry key)
 195   with Key_not_found _ -> []
 196
 197 let get_pair registry fst_unmarshaller snd_unmarshaller key =
 198   let v = singleton (get registry key) in
 199   match Str.split spaces_rex v with
 200   | [fst; snd] -> fst_unmarshaller fst, snd_unmarshaller snd
 201   | _ -> raise (Type_error "not a pair")
 202
 203 let set_list registry marshaller ~key ~value =
 204   List.iter (fun v -> set registry ~key ~value:(marshaller v)) value
 205
 206 type xml_tree =
 207   | Cdata of string
 208   | Element of string * (string * string) list * xml_tree list
 209
 210 let dot_RE = Str.regexp "\\."
 211
 212 let xml_tree_of_registry registry =
 213   let has_child name elements =
 214     List.exists
 215       (function
 216         | Element (_, ["name", name'], _) when name = name' -> true
 217         | _ -> false)
 218       elements
 219   in
 220   let rec get_child name = function
 221     | [] -> assert false
 222     | (Element (_, ["name", name'], _) as child) :: tl when name = name' ->
 223         child, tl
 224     | hd :: tl ->
 225         let child, rest = get_child name tl in
 226         child, hd :: rest
 227   in
 228   let rec add_key path value tree =
 229     match path, tree with
 230     | [key], Element (name, attrs, children) ->
 231         Element (name, attrs,
 232           Element ("key", ["name", key],
 233             [Cdata (strip_blanks value)]) :: children)
 234     | dir :: path, Element (name, attrs, children) ->
 235         if has_child dir children then
 236           let child, rest = get_child dir children in
 237           Element (name, attrs, add_key path value child :: rest)
 238         else
 239           Element (name, attrs,
 240             ((add_key path value (Element ("section", ["name", dir], [])))
 241               :: children))
 242     | _ -> assert false
 243   in
 244   Hashtbl.fold
 245     (fun k v tree -> add_key ((Str.split dot_RE k)) v tree)
 246     registry
 247     (Element (root_tag, [], []))
 248
 249 let rec stream_of_xml_tree = function
 250   | Cdata s -> Xml.xml_cdata s
 251   | Element (name, attrs, children) ->
 252       Xml.xml_nempty name
 253         (List.map (fun (n, v) -> (None, n, v)) attrs)
 254         (stream_of_xml_trees children)
 255 and stream_of_xml_trees = function
 256   | [] -> [< >]
 257   | hd :: tl -> [< stream_of_xml_tree hd; stream_of_xml_trees tl >]
 258
 259 let save_to registry fname =
 260   let token_stream = stream_of_xml_tree (xml_tree_of_registry registry) in
 261   let oc = open_out fname in
 262   Xml.pp_to_outchan token_stream oc;
 263   close_out oc
 264
 265 let rec load_from_absolute ?path registry fname =
 266   let _path = ref (match path with None -> [] | Some p -> p)in
 267     (* <section> elements entered so far *)
 268   let in_key = ref false in (* have we entered a <key> element? *)
 269   let cdata = ref "" in     (* collected cdata (inside <key> *)
 270   let push_path name = _path := name :: !_path in
 271   let pop_path () = _path := List.tl !_path in
 272   let start_element tag attrs =
 273     match tag, attrs with
 274     | "section", ["name", name] -> push_path name
 275     | "key", ["name", name] -> in_key := true; push_path name
 276     | "helm_registry", _ -> ()
 277     | "include", ["href", fname] ->
 278         debug_print (lazy ("including file " ^ fname));
 279         load_from_absolute ~path:!_path registry fname
 280     | tag, _ ->
 281         raise (Parse_error (fname, ~-1, ~-1,
 282           (sprintf "unexpected element <%s> or wrong attribute set" tag)))
 283   in
 284   let end_element tag =
 285     match tag with
 286     | "section" -> pop_path ()
 287     | "key" ->
 288         let key = String.concat "." (List.rev !_path) in
 289         set registry ~key ~value:!cdata;
 290         cdata := "";
 291         in_key := false;
 292         pop_path ()
 293     | "include" | "helm_registry" -> ()
 294     | _ -> assert false
 295   in
 296   let character_data text =
 297     if !in_key then cdata := !cdata ^ text
 298   in
 299   let callbacks = {
 300     XmlPushParser.default_callbacks with
 301       XmlPushParser.start_element = Some start_element;
 302       XmlPushParser.end_element = Some end_element;
 303       XmlPushParser.character_data = Some character_data;
 304   } in
 305   let xml_parser = XmlPushParser.create_parser callbacks in
 306   let backup = backup_registry registry in
 307   if path = None then Hashtbl.clear registry;
 308   try
 309     XmlPushParser.parse xml_parser (`File fname)
 310   with exn ->
 311     restore_registry backup registry;
 312     raise exn
 313
 314 let load_from registry ?path fname =
 315   if Filename.is_relative fname then begin
 316     let no_file_found = ref true in
 317     let path =
 318       match path with
 319       | Some path -> path (* path given as argument *)
 320       | None -> [ Sys.getcwd () ] (* no path given, try with cwd *)
 321     in
 322     List.iter
 323       (fun dir ->
 324         let conffile = dir ^ "/" ^ fname in
 325         if Sys.file_exists conffile then begin
 326           no_file_found := false;
 327           load_from_absolute registry conffile
 328         end)
 329        path;
 330     if !no_file_found then
 331       failwith (sprintf
 332         "Helm_registry.init: no configuration file named %s in [ %s ]"
 333         fname (String.concat "; " path))
 334   end else
 335     load_from_absolute registry fname
 336
 337 let fold registry ?prefix ?(interpolate = true) f init =
 338   let value_of k v =
 339     if interpolate then singleton (get registry k) else strip_blanks v
 340   in
 341   match prefix with
 342   | None -> Hashtbl.fold (fun k v acc -> f acc k (value_of k v)) registry init
 343   | Some s ->
 344       let key_matches = starts_with (s ^ ".") in
 345       let rec fold_filter acc = function
 346         | [] -> acc
 347         | (k,v) :: tl when key_matches k ->
 348             fold_filter (f acc k (value_of k v)) tl
 349         | _ :: tl -> fold_filter acc tl
 350       in
 351       fold_filter init (hashtbl_pairs registry)
 352
 353 let iter registry ?prefix ?interpolate f =
 354   fold registry ?prefix ?interpolate (fun _ k v -> f k v) ()
 355 let to_list registry ?prefix ?interpolate () =
 356   fold registry ?prefix ?interpolate (fun acc k v -> (k, v) :: acc) []
 357
 358 let ls registry prefix =
 359   let prefix = prefix ^ "." in
 360   let prefix_len = String.length prefix in
 361   let key_matches = starts_with prefix in
 362   let matching_keys = (* collect matching keys' _postfixes_ *)
 363     fold registry
 364       (fun acc key _ ->
 365         if key_matches key then
 366           String.sub key prefix_len (String.length key - prefix_len) :: acc
 367         else
 368           acc)
 369       []
 370   in
 371   let (sections, keys) =
 372     List.fold_left
 373       (fun (sections, keys) postfix ->
 374         match Str.split dot_rex postfix with
 375         | [key] -> (sections, key :: keys)
 376         | hd_key :: _ ->  (* length > 1 => nested section found *)
 377             (hd_key :: sections, keys)
 378         | _ -> assert false)
 379       ([], []) matching_keys
 380   in
 381   (list_uniq (List.sort Pervasives.compare sections), keys)
 382
 383 (** {2 API implementation}
 384  * functional methods above are wrapped so that they work on a default
 385  * (imperative) registry*)
 386
 387 let default_registry = Hashtbl.create magic_size
 388
 389 let get key = singleton (get default_registry key)
 390 let set = set default_registry
 391 let has = has default_registry
 392 let fold ?prefix ?interpolate f init =
 393   fold default_registry ?prefix ?interpolate f init
 394 let iter = iter default_registry
 395 let to_list = to_list default_registry
 396 let ls = ls default_registry
 397 let get_typed unmarshaller = get_typed default_registry unmarshaller
 398 let get_opt unmarshaller = get_opt default_registry unmarshaller
 399 let get_opt_default unmarshaller = get_opt_default default_registry unmarshaller
 400 let get_list unmarshaller = get_list default_registry unmarshaller
 401 let get_pair unmarshaller = get_pair default_registry unmarshaller
 402 let set_typed marshaller = set_typed default_registry marshaller
 403 let set_opt unmarshaller = set_opt default_registry unmarshaller
 404 let set_list marshaller = set_list default_registry marshaller
 405 let unset = unset default_registry
 406 let save_to = save_to default_registry
 407 let load_from = load_from default_registry
 408
 409 let get_string = get_typed string
 410 let get_int = get_typed int
 411 let get_float = get_typed float
 412 let get_bool = get_typed bool
 413 let set_string = set_typed of_string
 414 let set_int = set_typed of_int
 415 let set_float = set_typed of_float
 416 let set_bool = set_typed of_bool
 417