helm/ocaml/tactics/primitiveTactics.ml

   1 (* Copyright (C) 2002, HELM Team.
   2  *
   3  * This file is part of HELM, an Hypertextual, Electronic
   4  * Library of Mathematics, developed at the Computer Science
   5  * Department, University of Bologna, Italy.
   6  *
   7  * HELM is free software; you can redistribute it and/or
   8  * modify it under the terms of the GNU General Public License
   9  * as published by the Free Software Foundation; either version 2
  10  * of the License, or (at your option) any later version.
  11  *
  12  * HELM is distributed in the hope that it will be useful,
  13  * but WITHOUT ANY WARRANTY; without even the implied warranty of
  14  * MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the
  15  * GNU General Public License for more details.
  16  *
  17  * You should have received a copy of the GNU General Public License
  18  * along with HELM; if not, write to the Free Software
  19  * Foundation, Inc., 59 Temple Place - Suite 330, Boston,
  20  * MA  02111-1307, USA.
  21  *
  22  * For details, see the HELM World-Wide-Web page,
  23  * http://cs.unibo.it/helm/.
  24  *)
  25
  26 open ProofEngineHelpers
  27 open ProofEngineTypes
  28
  29 exception NotAnInductiveTypeToEliminate
  30 exception NotTheRightEliminatorShape
  31 exception NoHypothesesFound
  32 exception WrongUriToVariable of string
  33
  34 (* lambda_abstract newmeta ty *)
  35 (* returns a triple [bo],[context],[ty'] where              *)
  36 (* [ty] = Pi/LetIn [context].[ty'] ([context] is a vector!) *)
  37 (* and [bo] = Lambda/LetIn [context].(Meta [newmeta])       *)
  38 (* So, lambda_abstract is the core of the implementation of *)
  39 (* the Intros tactic.                                       *)
  40 let lambda_abstract metasenv context newmeta ty mk_fresh_name =
  41  let module C = Cic in
  42   let rec collect_context context =
  43    function
  44       C.Cast (te,_)   -> collect_context context te
  45     | C.Prod (n,s,t)  ->
  46        let n' = mk_fresh_name metasenv context n ~typ:s in
  47         let (context',ty,bo) =
  48          collect_context ((Some (n',(C.Decl s)))::context) t
  49         in
  50          (context',ty,C.Lambda(n',s,bo))
  51     | C.LetIn (n,s,t) ->
  52        let (context',ty,bo) =
  53         collect_context ((Some (n,(C.Def (s,None))))::context) t
  54        in
  55         (context',ty,C.LetIn(n,s,bo))
  56     | _ as t ->
  57       let irl =
  58         CicMkImplicit.identity_relocation_list_for_metavariable context
  59       in
  60        context, t, (C.Meta (newmeta,irl))
  61   in
  62    collect_context context ty
  63
  64 let eta_expand metasenv context t arg =
  65  let module T = CicTypeChecker in
  66  let module S = CicSubstitution in
  67  let module C = Cic in
  68   let rec aux n =
  69    function
  70       t' when t' = S.lift n arg -> C.Rel (1 + n)
  71     | C.Rel m  -> if m <= n then C.Rel m else C.Rel (m+1)
  72     | C.Var (uri,exp_named_subst) ->
  73        let exp_named_subst' = aux_exp_named_subst n exp_named_subst in
  74         C.Var (uri,exp_named_subst')
  75     | C.Meta _
  76     | C.Sort _
  77     | C.Implicit _ as t -> t
  78     | C.Cast (te,ty) -> C.Cast (aux n te, aux n ty)
  79     | C.Prod (nn,s,t) -> C.Prod (nn, aux n s, aux (n+1) t)
  80     | C.Lambda (nn,s,t) -> C.Lambda (nn, aux n s, aux (n+1) t)
  81     | C.LetIn (nn,s,t) -> C.LetIn (nn, aux n s, aux (n+1) t)
  82     | C.Appl l -> C.Appl (List.map (aux n) l)
  83     | C.Const (uri,exp_named_subst) ->
  84        let exp_named_subst' = aux_exp_named_subst n exp_named_subst in
  85         C.Const (uri,exp_named_subst')
  86     | C.MutInd (uri,i,exp_named_subst) ->
  87        let exp_named_subst' = aux_exp_named_subst n exp_named_subst in
  88         C.MutInd (uri,i,exp_named_subst')
  89     | C.MutConstruct (uri,i,j,exp_named_subst) ->
  90        let exp_named_subst' = aux_exp_named_subst n exp_named_subst in
  91         C.MutConstruct (uri,i,j,exp_named_subst')
  92     | C.MutCase (sp,i,outt,t,pl) ->
  93        C.MutCase (sp,i,aux n outt, aux n t,
  94         List.map (aux n) pl)
  95     | C.Fix (i,fl) ->
  96        let tylen = List.length fl in
  97         let substitutedfl =
  98          List.map
  99           (fun (name,i,ty,bo) -> (name, i, aux n ty, aux (n+tylen) bo))
 100            fl
 101         in
 102          C.Fix (i, substitutedfl)
 103     | C.CoFix (i,fl) ->
 104        let tylen = List.length fl in
 105         let substitutedfl =
 106          List.map
 107           (fun (name,ty,bo) -> (name, aux n ty, aux (n+tylen) bo))
 108            fl
 109         in
 110          C.CoFix (i, substitutedfl)
 111   and aux_exp_named_subst n =
 112    List.map (function uri,t -> uri,aux n t)
 113   in
 114    let argty =
 115     T.type_of_aux' metasenv context arg
 116    in
 117     let fresh_name =
 118      FreshNamesGenerator.mk_fresh_name
 119       metasenv context (Cic.Name "Heta") ~typ:argty
 120     in
 121      (C.Appl [C.Lambda (fresh_name,argty,aux 0 t) ; arg])
 122
 123 (*CSC: ma serve solamente la prima delle new_uninst e l'unione delle due!!! *)
 124 let classify_metas newmeta in_subst_domain subst_in metasenv =
 125  List.fold_right
 126   (fun (i,canonical_context,ty) (old_uninst,new_uninst) ->
 127     if in_subst_domain i then
 128      old_uninst,new_uninst
 129     else
 130      let ty' = subst_in canonical_context ty in
 131       let canonical_context' =
 132        List.fold_right
 133         (fun entry canonical_context' ->
 134           let entry' =
 135            match entry with
 136               Some (n,Cic.Decl s) ->
 137                Some (n,Cic.Decl (subst_in canonical_context' s))
 138             | Some (n,Cic.Def (s,None)) ->
 139                Some (n,Cic.Def ((subst_in canonical_context' s),None))
 140             | None -> None
 141             | Some (_,Cic.Def (_,Some _)) -> assert false
 142           in
 143            entry'::canonical_context'
 144         ) canonical_context []
 145      in
 146       if i < newmeta then
 147        ((i,canonical_context',ty')::old_uninst),new_uninst
 148       else
 149        old_uninst,((i,canonical_context',ty')::new_uninst)
 150   ) metasenv ([],[])
 151
 152 (* Auxiliary function for apply: given a type (a backbone), it returns its   *)
 153 (* head, a META environment in which there is new a META for each hypothesis,*)
 154 (* a list of arguments for the new applications and the indexes of the first *)
 155 (* and last new METAs introduced. The nth argument in the list of arguments  *)
 156 (* is just the nth new META.                                                 *)
 157 let new_metasenv_for_apply newmeta proof context ty =
 158  let module C = Cic in
 159  let module S = CicSubstitution in
 160   let rec aux newmeta =
 161    function
 162       C.Cast (he,_) -> aux newmeta he
 163       (* If the expected type is a Type, then also Set is OK ==>
 164       *  we accept any term of type Type *)
 165       (*CSC: BUG HERE: in this way it is possible for the term of
 166       * type Type to be different from a Sort!!! *)
 167     | C.Prod (name,(C.Sort C.Type as s),t) ->
 168        let irl =
 169          CicMkImplicit.identity_relocation_list_for_metavariable context
 170        in
 171         let newargument = C.Meta (newmeta+1,irl) in
 172          let (res,newmetasenv,arguments,lastmeta) =
 173           aux (newmeta + 2) (S.subst newargument t)
 174          in
 175           res,
 176            (newmeta,[],s)::(newmeta+1,context,C.Meta (newmeta,[]))::newmetasenv,
 177            newargument::arguments,lastmeta
 178     | C.Prod (name,s,t) ->
 179        let irl =
 180          CicMkImplicit.identity_relocation_list_for_metavariable context
 181        in
 182         let newargument = C.Meta (newmeta,irl) in
 183          let (res,newmetasenv,arguments,lastmeta) =
 184           aux (newmeta + 1) (S.subst newargument t)
 185          in
 186           res,(newmeta,context,s)::newmetasenv,newargument::arguments,lastmeta
 187     | t -> t,[],[],newmeta
 188   in
 189    (* WARNING: here we are using the invariant that above the most *)
 190    (* recente new_meta() there are no used metas.                  *)
 191    let (res,newmetasenv,arguments,lastmeta) = aux newmeta ty in
 192     res,newmetasenv,arguments,lastmeta
 193
 194 (* Useful only inside apply_tac *)
 195 let
 196  generalize_exp_named_subst_with_fresh_metas context newmeta uri exp_named_subst
 197 =
 198  let module C = Cic in
 199   let params =
 200    match CicEnvironment.get_obj uri with
 201       C.Constant (_,_,_,params)
 202     | C.CurrentProof (_,_,_,_,params)
 203     | C.Variable (_,_,_,params)
 204     | C.InductiveDefinition (_,params,_) -> params
 205   in
 206    let exp_named_subst_diff,new_fresh_meta,newmetasenvfragment,exp_named_subst'=
 207     let next_fresh_meta = ref newmeta in
 208     let newmetasenvfragment = ref [] in
 209     let exp_named_subst_diff = ref [] in
 210      let rec aux =
 211       function
 212          [],[] -> []
 213        | uri::tl,[] ->
 214           let ty =
 215            match CicEnvironment.get_obj uri with
 216               C.Variable (_,_,ty,_) ->
 217                CicSubstitution.subst_vars !exp_named_subst_diff ty
 218             | _ -> raise (WrongUriToVariable (UriManager.string_of_uri uri))
 219           in
 220            (match ty with
 221                C.Sort C.Type as s ->
 222                 let irl =
 223                   CicMkImplicit.identity_relocation_list_for_metavariable context
 224                 in
 225                  let fresh_meta = !next_fresh_meta in
 226                  let fresh_meta' = fresh_meta + 1 in
 227                   next_fresh_meta := !next_fresh_meta + 2 ;
 228                   let subst_item = uri,C.Meta (fresh_meta',irl) in
 229                    newmetasenvfragment :=
 230                     (fresh_meta,[],C.Sort C.Type) ::
 231                      (fresh_meta',[],C.Meta (fresh_meta,[])) :: !newmetasenvfragment ;
 232                    exp_named_subst_diff := !exp_named_subst_diff @ [subst_item] ;
 233                    subst_item::(aux (tl,[]))
 234              | _ ->
 235               let irl =
 236                 CicMkImplicit.identity_relocation_list_for_metavariable context
 237               in
 238               let subst_item = uri,C.Meta (!next_fresh_meta,irl) in
 239                newmetasenvfragment :=
 240                 (!next_fresh_meta,context,ty)::!newmetasenvfragment ;
 241                exp_named_subst_diff := !exp_named_subst_diff @ [subst_item] ;
 242                incr next_fresh_meta ;
 243                subst_item::(aux (tl,[])))
 244        | uri::tl1,((uri',_) as s)::tl2 ->
 245           assert (UriManager.eq uri uri') ;
 246           s::(aux (tl1,tl2))
 247        | [],_ -> assert false
 248      in
 249       let exp_named_subst' = aux (params,exp_named_subst) in
 250        !exp_named_subst_diff,!next_fresh_meta,
 251         List.rev !newmetasenvfragment, exp_named_subst'
 252    in
 253     new_fresh_meta,newmetasenvfragment,exp_named_subst',exp_named_subst_diff
 254 ;;
 255
 256 let apply_tac ~term ~status:(proof, goal) =
 257   (* Assumption: The term "term" must be closed in the current context *)
 258  let module T = CicTypeChecker in
 259  let module R = CicReduction in
 260  let module C = Cic in
 261   let (_,metasenv,_,_) = proof in
 262   let metano,context,ty = CicUtil.lookup_meta goal metasenv in
 263   let newmeta = new_meta_of_proof ~proof in
 264    let exp_named_subst_diff,newmeta',newmetasenvfragment,term' =
 265     match term with
 266        C.Var (uri,exp_named_subst) ->
 267         let newmeta',newmetasenvfragment,exp_named_subst',exp_named_subst_diff =
 268          generalize_exp_named_subst_with_fresh_metas context newmeta uri
 269           exp_named_subst
 270         in
 271          exp_named_subst_diff,newmeta',newmetasenvfragment,
 272           C.Var (uri,exp_named_subst')
 273      | C.Const (uri,exp_named_subst) ->
 274         let newmeta',newmetasenvfragment,exp_named_subst',exp_named_subst_diff =
 275          generalize_exp_named_subst_with_fresh_metas context newmeta uri
 276           exp_named_subst
 277         in
 278          exp_named_subst_diff,newmeta',newmetasenvfragment,
 279           C.Const (uri,exp_named_subst')
 280      | C.MutInd (uri,tyno,exp_named_subst) ->
 281         let newmeta',newmetasenvfragment,exp_named_subst',exp_named_subst_diff =
 282          generalize_exp_named_subst_with_fresh_metas context newmeta uri
 283           exp_named_subst
 284         in
 285          exp_named_subst_diff,newmeta',newmetasenvfragment,
 286           C.MutInd (uri,tyno,exp_named_subst')
 287      | C.MutConstruct (uri,tyno,consno,exp_named_subst) ->
 288         let newmeta',newmetasenvfragment,exp_named_subst',exp_named_subst_diff =
 289          generalize_exp_named_subst_with_fresh_metas context newmeta uri
 290           exp_named_subst
 291         in
 292          exp_named_subst_diff,newmeta',newmetasenvfragment,
 293           C.MutConstruct (uri,tyno,consno,exp_named_subst')
 294      | _ -> [],newmeta,[],term
 295    in
 296    let metasenv' = metasenv@newmetasenvfragment in
 297    let termty =
 298     CicSubstitution.subst_vars exp_named_subst_diff
 299      (CicTypeChecker.type_of_aux' metasenv' context term)
 300    in
 301     (* newmeta is the lowest index of the new metas introduced *)
 302     let (consthead,newmetas,arguments,_) =
 303      new_metasenv_for_apply newmeta' proof context termty
 304     in
 305      let newmetasenv = metasenv'@newmetas in
 306       let subst,newmetasenv' =
 307         CicUnification.fo_unif newmetasenv context consthead ty
 308       in
 309        let in_subst_domain i = List.exists (function (j,_) -> i=j) subst in
 310        let apply_subst = CicMetaSubst.apply_subst subst in
 311         let old_uninstantiatedmetas,new_uninstantiatedmetas =
 312          (* subst_in doesn't need the context. Hence the underscore. *)
 313          let subst_in _ = CicMetaSubst.apply_subst subst in
 314           classify_metas newmeta in_subst_domain subst_in newmetasenv'
 315         in
 316          let bo' =
 317           apply_subst
 318            (if List.length newmetas = 0 then
 319              term'
 320             else
 321              Cic.Appl (term'::arguments)
 322            )
 323          in
 324           let newmetasenv'' = new_uninstantiatedmetas@old_uninstantiatedmetas in
 325           let (newproof, newmetasenv''') =
 326            let subst_in = CicMetaSubst.apply_subst ((metano,bo')::subst) in
 327             subst_meta_and_metasenv_in_proof
 328               proof metano subst_in newmetasenv''
 329           in
 330            (newproof, List.map (function (i,_,_) -> i) new_uninstantiatedmetas)
 331
 332   (* TODO per implementare i tatticali e' necessario che tutte le tattiche
 333   sollevino _solamente_ Fail *)
 334 let apply_tac ~term ~status =
 335   try
 336     apply_tac ~term ~status
 337       (* TODO cacciare anche altre eccezioni? *)
 338   with CicUnification.UnificationFailure _ as e ->
 339     raise (Fail (Printexc.to_string e))
 340
 341 let intros_tac
 342  ?(mk_fresh_name_callback = FreshNamesGenerator.mk_fresh_name) ()
 343  ~status:(proof, goal)
 344 =
 345  let module C = Cic in
 346  let module R = CicReduction in
 347   let (_,metasenv,_,_) = proof in
 348   let metano,context,ty = CicUtil.lookup_meta goal metasenv in
 349    let newmeta = new_meta_of_proof ~proof in
 350     let (context',ty',bo') =
 351      lambda_abstract metasenv context newmeta ty mk_fresh_name_callback
 352     in
 353      let (newproof, _) =
 354        subst_meta_in_proof proof metano bo' [newmeta,context',ty']
 355      in
 356       (newproof, [newmeta])
 357
 358 let cut_tac
 359  ?(mk_fresh_name_callback = FreshNamesGenerator.mk_fresh_name)
 360  term ~status:(proof, goal)
 361 =
 362  let module C = Cic in
 363   let curi,metasenv,pbo,pty = proof in
 364   let metano,context,ty = CicUtil.lookup_meta goal metasenv in
 365    let newmeta1 = new_meta_of_proof ~proof in
 366    let newmeta2 = newmeta1 + 1 in
 367    let fresh_name =
 368     mk_fresh_name_callback metasenv context (Cic.Name "Hcut") ~typ:term in
 369    let context_for_newmeta1 =
 370     (Some (fresh_name,C.Decl term))::context in
 371    let irl1 =
 372     CicMkImplicit.identity_relocation_list_for_metavariable
 373      context_for_newmeta1
 374    in
 375    let irl2 =
 376      CicMkImplicit.identity_relocation_list_for_metavariable context
 377    in
 378     let newmeta1ty = CicSubstitution.lift 1 ty in
 379     let bo' =
 380      C.Appl
 381       [C.Lambda (fresh_name,term,C.Meta (newmeta1,irl1)) ;
 382        C.Meta (newmeta2,irl2)]
 383     in
 384      let (newproof, _) =
 385       subst_meta_in_proof proof metano bo'
 386        [newmeta2,context,term; newmeta1,context_for_newmeta1,newmeta1ty];
 387      in
 388       (newproof, [newmeta1 ; newmeta2])
 389
 390 let letin_tac
 391  ?(mk_fresh_name_callback = FreshNamesGenerator.mk_fresh_name)
 392  term ~status:(proof, goal)
 393 =
 394  let module C = Cic in
 395   let curi,metasenv,pbo,pty = proof in
 396   let metano,context,ty = CicUtil.lookup_meta goal metasenv in
 397    let _ = CicTypeChecker.type_of_aux' metasenv context term in
 398     let newmeta = new_meta_of_proof ~proof in
 399     let fresh_name =
 400      mk_fresh_name_callback metasenv context (Cic.Name "Hletin") ~typ:term in
 401     let context_for_newmeta =
 402      (Some (fresh_name,C.Def (term,None)))::context in
 403     let irl =
 404      CicMkImplicit.identity_relocation_list_for_metavariable
 405       context_for_newmeta
 406     in
 407      let newmetaty = CicSubstitution.lift 1 ty in
 408      let bo' = C.LetIn (fresh_name,term,C.Meta (newmeta,irl)) in
 409       let (newproof, _) =
 410         subst_meta_in_proof
 411           proof metano bo'[newmeta,context_for_newmeta,newmetaty]
 412       in
 413        (newproof, [newmeta])
 414
 415   (** functional part of the "exact" tactic *)
 416 let exact_tac ~term ~status:(proof, goal) =
 417  (* Assumption: the term bo must be closed in the current context *)
 418  let (_,metasenv,_,_) = proof in
 419  let metano,context,ty = CicUtil.lookup_meta goal metasenv in
 420  let module T = CicTypeChecker in
 421  let module R = CicReduction in
 422  if R.are_convertible context (T.type_of_aux' metasenv context term) ty then
 423   begin
 424    let (newproof, metasenv') =
 425      subst_meta_in_proof proof metano term [] in
 426    (newproof, [])
 427   end
 428  else
 429   raise (Fail "The type of the provided term is not the one expected.")
 430
 431
 432 (* not really "primitive" tactics .... *)
 433
 434 let elim_tac ~term ~status:(proof, goal) =
 435  let module T = CicTypeChecker in
 436  let module U = UriManager in
 437  let module R = CicReduction in
 438  let module C = Cic in
 439   let (curi,metasenv,_,_) = proof in
 440   let metano,context,ty = CicUtil.lookup_meta goal metasenv in
 441    let termty = T.type_of_aux' metasenv context term in
 442    let uri,exp_named_subst,typeno,args =
 443     match termty with
 444        C.MutInd (uri,typeno,exp_named_subst) -> (uri,exp_named_subst,typeno,[])
 445      | C.Appl ((C.MutInd (uri,typeno,exp_named_subst))::args) ->
 446          (uri,exp_named_subst,typeno,args)
 447      | _ -> raise NotAnInductiveTypeToEliminate
 448    in
 449     let eliminator_uri =
 450      let buri = U.buri_of_uri uri in
 451      let name =
 452       match CicEnvironment.get_obj uri with
 453          C.InductiveDefinition (tys,_,_) ->
 454           let (name,_,_,_) = List.nth tys typeno in
 455            name
 456        | _ -> assert false
 457      in
 458      let ext =
 459       match T.type_of_aux' metasenv context ty with
 460          C.Sort C.Prop -> "_ind"
 461        | C.Sort C.Set  -> "_rec"
 462        | C.Sort C.CProp -> "_rec"
 463        | C.Sort C.Type -> "_rect"
 464        | _ -> assert false
 465      in
 466       U.uri_of_string (buri ^ "/" ^ name ^ ext ^ ".con")
 467     in
 468      let eliminator_ref = C.Const (eliminator_uri,exp_named_subst) in
 469       let ety = T.type_of_aux' metasenv context eliminator_ref in
 470       let newmeta = new_meta_of_proof ~proof in
 471        let (econclusion,newmetas,arguments,lastmeta) =
 472          new_metasenv_for_apply newmeta proof context ety
 473        in
 474         (* Here we assume that we have only one inductive hypothesis to *)
 475         (* eliminate and that it is the last hypothesis of the theorem. *)
 476         (* A better approach would be fingering the hypotheses in some  *)
 477         (* way.                                                         *)
 478         let meta_of_corpse =
 479          let (_,canonical_context,_) =
 480            CicUtil.lookup_meta (lastmeta - 1) newmetas
 481          in
 482           let irl =
 483            CicMkImplicit.identity_relocation_list_for_metavariable
 484             canonical_context
 485           in
 486            Cic.Meta (lastmeta - 1, irl)
 487         in
 488         let newmetasenv = newmetas @ metasenv in
 489         let subst1,newmetasenv' =
 490          CicUnification.fo_unif newmetasenv context term meta_of_corpse
 491         in
 492          let ueconclusion = CicMetaSubst.apply_subst subst1 econclusion in
 493           (* The conclusion of our elimination principle is *)
 494           (*  (?i farg1 ... fargn)                         *)
 495           (* The conclusion of our goal is ty. So, we can   *)
 496           (* eta-expand ty w.r.t. farg1 .... fargn to get   *)
 497           (* a new ty equal to (P farg1 ... fargn). Now     *)
 498           (* ?i can be instantiated with P and we are ready *)
 499           (* to refine the term.                            *)
 500           let emeta, fargs =
 501            match ueconclusion with
 502               C.Appl ((C.Meta (emeta,_))::fargs) -> emeta,fargs
 503             | C.Meta (emeta,_) -> emeta,[]
 504             | _ -> raise NotTheRightEliminatorShape
 505           in
 506            let ty' = CicMetaSubst.apply_subst subst1 ty in
 507            let eta_expanded_ty =
 508 (*CSC: newmetasenv' era metasenv ??????????? *)
 509             List.fold_left (eta_expand newmetasenv' context) ty' fargs
 510            in
 511             let subst2,newmetasenv'' =
 512 (*CSC: passo newmetasenv', ma alcune variabili sono gia' state sostituite
 513 da subst1!!!! Dovrei rimuoverle o sono innocue?*)
 514              CicUnification.fo_unif
 515               newmetasenv' context ueconclusion eta_expanded_ty
 516             in
 517              let in_subst_domain i =
 518               let eq_to_i = function (j,_) -> i=j in
 519                List.exists eq_to_i subst1 ||
 520                List.exists eq_to_i subst2
 521              in
 522               (* When unwinding the META that corresponds to the elimination *)
 523               (* predicate (which is emeta), we must also perform one-step   *)
 524               (* beta-reduction. apply_subst doesn't need the context. Hence *)
 525               (* the underscore.                                             *)
 526               let apply_subst _ t =
 527                let t' = CicMetaSubst.apply_subst subst1 t in
 528                 CicMetaSubst.apply_subst_reducing
 529                  (Some (emeta,List.length fargs)) subst2 t'
 530               in
 531                 let old_uninstantiatedmetas,new_uninstantiatedmetas =
 532                  classify_metas newmeta in_subst_domain apply_subst
 533                   newmetasenv''
 534                 in
 535                  let arguments' = List.map (apply_subst context) arguments in
 536                   let bo' = Cic.Appl (eliminator_ref::arguments') in
 537                    let newmetasenv''' =
 538                     new_uninstantiatedmetas@old_uninstantiatedmetas
 539                    in
 540                     let (newproof, newmetasenv'''') =
 541                      (* When unwinding the META that corresponds to the *)
 542                      (* elimination predicate (which is emeta), we must *)
 543                      (* also perform one-step beta-reduction.           *)
 544                      (* The only difference w.r.t. apply_subst is that  *)
 545                      (* we also substitute metano with bo'.             *)
 546                      (*CSC: Nota: sostituire nuovamente subst1 e' superfluo, *)
 547                      (*CSC: no?                                              *)
 548                      let apply_subst' t =
 549                       let t' = CicMetaSubst.apply_subst subst1 t in
 550                        CicMetaSubst.apply_subst_reducing
 551                         (Some (emeta,List.length fargs))
 552                         ((metano,bo')::subst2) t'
 553                      in
 554                       subst_meta_and_metasenv_in_proof
 555                         proof metano apply_subst' newmetasenv'''
 556                     in
 557                      (newproof,
 558                       List.map (function (i,_,_) -> i) new_uninstantiatedmetas)
 559 ;;
 560
 561 (* The simplification is performed only on the conclusion *)
 562 let elim_intros_simpl_tac ~term =
 563  Tacticals.then_ ~start:(elim_tac ~term)
 564   ~continuation:
 565    (Tacticals.thens
 566      ~start:(intros_tac ())
 567      ~continuations:
 568        [ReductionTactics.simpl_tac ~also_in_hypotheses:false ~terms:None])
 569 ;;
 570
 571 exception NotConvertible
 572
 573 (*CSC: Bug (or feature?). [with_what] is parsed in the context of the goal,  *)
 574 (*CSC: while [what] can have a richer context (because of binders)           *)
 575 (*CSC: So it is _NOT_ possible to use those binders in the [with_what] term. *)
 576 (*CSC: Is that evident? Is that right? Or should it be changed?              *)
 577 let change_tac ~what ~with_what ~status:(proof, goal) =
 578  let curi,metasenv,pbo,pty = proof in
 579  let metano,context,ty = CicUtil.lookup_meta goal metasenv in
 580   (* are_convertible works only on well-typed terms *)
 581   ignore (CicTypeChecker.type_of_aux' metasenv context with_what) ;
 582   if CicReduction.are_convertible context what with_what then
 583    begin
 584     let replace =
 585      ProofEngineReduction.replace
 586       ~equality:(==) ~what:[what] ~with_what:[with_what]
 587     in
 588     let ty' = replace ty in
 589     let context' =
 590      List.map
 591       (function
 592           Some (name,Cic.Def (t,None)) -> Some (name,Cic.Def ((replace t),None))
 593         | Some (name,Cic.Decl t) -> Some (name,Cic.Decl (replace t))
 594         | None -> None
 595         | Some (_,Cic.Def (_,Some _)) -> assert false
 596       ) context
 597     in
 598      let metasenv' =
 599       List.map
 600        (function
 601            (n,_,_) when n = metano -> (metano,context',ty')
 602          | _ as t -> t
 603        ) metasenv
 604      in
 605       (curi,metasenv',pbo,pty), [metano]
 606    end
 607   else
 608    raise (ProofEngineTypes.Fail "Not convertible")