helm/ocaml/tactics/primitiveTactics.ml

   1 (* Copyright (C) 2002, HELM Team.
   2  *
   3  * This file is part of HELM, an Hypertextual, Electronic
   4  * Library of Mathematics, developed at the Computer Science
   5  * Department, University of Bologna, Italy.
   6  *
   7  * HELM is free software; you can redistribute it and/or
   8  * modify it under the terms of the GNU General Public License
   9  * as published by the Free Software Foundation; either version 2
  10  * of the License, or (at your option) any later version.
  11  *
  12  * HELM is distributed in the hope that it will be useful,
  13  * but WITHOUT ANY WARRANTY; without even the implied warranty of
  14  * MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the
  15  * GNU General Public License for more details.
  16  *
  17  * You should have received a copy of the GNU General Public License
  18  * along with HELM; if not, write to the Free Software
  19  * Foundation, Inc., 59 Temple Place - Suite 330, Boston,
  20  * MA  02111-1307, USA.
  21  *
  22  * For details, see the HELM World-Wide-Web page,
  23  * http://cs.unibo.it/helm/.
  24  *)
  25
  26 open ProofEngineHelpers
  27 open ProofEngineTypes
  28
  29 exception TheTypeOfTheCurrentGoalIsAMetaICannotChooseTheRightElimiantionPrinciple
  30 exception NotAnInductiveTypeToEliminate
  31 exception WrongUriToVariable of string
  32
  33 (* lambda_abstract newmeta ty *)
  34 (* returns a triple [bo],[context],[ty'] where              *)
  35 (* [ty] = Pi/LetIn [context].[ty'] ([context] is a vector!) *)
  36 (* and [bo] = Lambda/LetIn [context].(Meta [newmeta])       *)
  37 (* So, lambda_abstract is the core of the implementation of *)
  38 (* the Intros tactic.                                       *)
  39 (* howmany = -1 means Intros, howmany > 0 means Intros n    *)
  40 let lambda_abstract ?(howmany=(-1)) metasenv context newmeta ty mk_fresh_name =
  41  let module C = Cic in
  42   let rec collect_context context howmany ty =
  43    match howmany with
  44    | 0 ->
  45         let irl =
  46           CicMkImplicit.identity_relocation_list_for_metavariable context
  47         in
  48          context, ty, (C.Meta (newmeta,irl))
  49    | _ ->
  50       match ty with
  51         C.Cast (te,_)   -> collect_context context howmany te
  52       | C.Prod (n,s,t)  ->
  53          let n' = mk_fresh_name metasenv context n ~typ:s in
  54           let (context',ty,bo) =
  55            collect_context ((Some (n',(C.Decl s)))::context) (howmany - 1) t
  56           in
  57            (context',ty,C.Lambda(n',s,bo))
  58       | C.LetIn (n,s,t) ->
  59          let (context',ty,bo) =
  60           collect_context ((Some (n,(C.Def (s,None))))::context) (howmany - 1) t
  61          in
  62           (context',ty,C.LetIn(n,s,bo))
  63       | _ as t ->
  64         if howmany <= 0 then
  65          let irl =
  66           CicMkImplicit.identity_relocation_list_for_metavariable context
  67          in
  68           context, t, (C.Meta (newmeta,irl))
  69         else
  70          raise (Fail "intro(s): not enough products or let-ins")
  71   in
  72    collect_context context howmany ty
  73
  74 let eta_expand metasenv context t arg =
  75  let module T = CicTypeChecker in
  76  let module S = CicSubstitution in
  77  let module C = Cic in
  78   let rec aux n =
  79    function
  80       t' when t' = S.lift n arg -> C.Rel (1 + n)
  81     | C.Rel m  -> if m <= n then C.Rel m else C.Rel (m+1)
  82     | C.Var (uri,exp_named_subst) ->
  83        let exp_named_subst' = aux_exp_named_subst n exp_named_subst in
  84         C.Var (uri,exp_named_subst')
  85     | C.Meta (i,l) ->
  86        let l' =
  87         List.map (function None -> None | Some t -> Some (aux n t)) l
  88        in
  89         C.Meta (i, l')
  90     | C.Sort _
  91     | C.Implicit _ as t -> t
  92     | C.Cast (te,ty) -> C.Cast (aux n te, aux n ty)
  93     | C.Prod (nn,s,t) -> C.Prod (nn, aux n s, aux (n+1) t)
  94     | C.Lambda (nn,s,t) -> C.Lambda (nn, aux n s, aux (n+1) t)
  95     | C.LetIn (nn,s,t) -> C.LetIn (nn, aux n s, aux (n+1) t)
  96     | C.Appl l -> C.Appl (List.map (aux n) l)
  97     | C.Const (uri,exp_named_subst) ->
  98        let exp_named_subst' = aux_exp_named_subst n exp_named_subst in
  99         C.Const (uri,exp_named_subst')
 100     | C.MutInd (uri,i,exp_named_subst) ->
 101        let exp_named_subst' = aux_exp_named_subst n exp_named_subst in
 102         C.MutInd (uri,i,exp_named_subst')
 103     | C.MutConstruct (uri,i,j,exp_named_subst) ->
 104        let exp_named_subst' = aux_exp_named_subst n exp_named_subst in
 105         C.MutConstruct (uri,i,j,exp_named_subst')
 106     | C.MutCase (sp,i,outt,t,pl) ->
 107        C.MutCase (sp,i,aux n outt, aux n t,
 108         List.map (aux n) pl)
 109     | C.Fix (i,fl) ->
 110        let tylen = List.length fl in
 111         let substitutedfl =
 112          List.map
 113           (fun (name,i,ty,bo) -> (name, i, aux n ty, aux (n+tylen) bo))
 114            fl
 115         in
 116          C.Fix (i, substitutedfl)
 117     | C.CoFix (i,fl) ->
 118        let tylen = List.length fl in
 119         let substitutedfl =
 120          List.map
 121           (fun (name,ty,bo) -> (name, aux n ty, aux (n+tylen) bo))
 122            fl
 123         in
 124          C.CoFix (i, substitutedfl)
 125   and aux_exp_named_subst n =
 126    List.map (function uri,t -> uri,aux n t)
 127   in
 128    let argty,_ =
 129     T.type_of_aux' metasenv context arg CicUniv.empty_ugraph (* TASSI: FIXME *)
 130    in
 131     let fresh_name =
 132      FreshNamesGenerator.mk_fresh_name ~subst:[]
 133       metasenv context (Cic.Name "Heta") ~typ:argty
 134     in
 135      (C.Appl [C.Lambda (fresh_name,argty,aux 0 t) ; arg])
 136
 137 (*CSC: ma serve solamente la prima delle new_uninst e l'unione delle due!!! *)
 138 let classify_metas newmeta in_subst_domain subst_in metasenv =
 139  List.fold_right
 140   (fun (i,canonical_context,ty) (old_uninst,new_uninst) ->
 141     if in_subst_domain i then
 142      old_uninst,new_uninst
 143     else
 144      let ty' = subst_in canonical_context ty in
 145       let canonical_context' =
 146        List.fold_right
 147         (fun entry canonical_context' ->
 148           let entry' =
 149            match entry with
 150               Some (n,Cic.Decl s) ->
 151                Some (n,Cic.Decl (subst_in canonical_context' s))
 152             | Some (n,Cic.Def (s,None)) ->
 153                Some (n,Cic.Def ((subst_in canonical_context' s),None))
 154             | None -> None
 155             | Some (_,Cic.Def (_,Some _)) -> assert false
 156           in
 157            entry'::canonical_context'
 158         ) canonical_context []
 159      in
 160       if i < newmeta then
 161        ((i,canonical_context',ty')::old_uninst),new_uninst
 162       else
 163        old_uninst,((i,canonical_context',ty')::new_uninst)
 164   ) metasenv ([],[])
 165
 166 (* Useful only inside apply_tac *)
 167 let
 168  generalize_exp_named_subst_with_fresh_metas context newmeta uri exp_named_subst
 169 =
 170  let module C = Cic in
 171   let params =
 172     let o,_ = CicEnvironment.get_obj CicUniv.empty_ugraph uri in
 173     CicUtil.params_of_obj o
 174   in
 175    let exp_named_subst_diff,new_fresh_meta,newmetasenvfragment,exp_named_subst'=
 176     let next_fresh_meta = ref newmeta in
 177     let newmetasenvfragment = ref [] in
 178     let exp_named_subst_diff = ref [] in
 179      let rec aux =
 180       function
 181          [],[] -> []
 182        | uri::tl,[] ->
 183           let ty =
 184             let o,_ = CicEnvironment.get_obj CicUniv.empty_ugraph uri in
 185               match o with
 186                   C.Variable (_,_,ty,_,_) ->
 187                     CicSubstitution.subst_vars !exp_named_subst_diff ty
 188                 | _ -> raise (WrongUriToVariable (UriManager.string_of_uri uri))
 189           in
 190 (* CSC: patch to generate ?1 : ?2 : Type in place of ?1 : Type to simulate ?1 :< Type
 191            (match ty with
 192                C.Sort (C.Type _) as s -> (* TASSI: ?? *)
 193                  let fresh_meta = !next_fresh_meta in
 194                  let fresh_meta' = fresh_meta + 1 in
 195                   next_fresh_meta := !next_fresh_meta + 2 ;
 196                   let subst_item = uri,C.Meta (fresh_meta',[]) in
 197                    newmetasenvfragment :=
 198                     (fresh_meta,[],C.Sort (C.Type (CicUniv.fresh()))) ::
 199                      (* TASSI: ?? *)
 200                      (fresh_meta',[],C.Meta (fresh_meta,[])) :: !newmetasenvfragment ;
 201                    exp_named_subst_diff := !exp_named_subst_diff @ [subst_item] ;
 202                    subst_item::(aux (tl,[]))
 203              | _ ->
 204 *)
 205               let irl =
 206                 CicMkImplicit.identity_relocation_list_for_metavariable context
 207               in
 208               let subst_item = uri,C.Meta (!next_fresh_meta,irl) in
 209                newmetasenvfragment :=
 210                 (!next_fresh_meta,context,ty)::!newmetasenvfragment ;
 211                exp_named_subst_diff := !exp_named_subst_diff @ [subst_item] ;
 212                incr next_fresh_meta ;
 213                subst_item::(aux (tl,[]))(*)*)
 214        | uri::tl1,((uri',_) as s)::tl2 ->
 215           assert (UriManager.eq uri uri') ;
 216           s::(aux (tl1,tl2))
 217        | [],_ -> assert false
 218      in
 219       let exp_named_subst' = aux (params,exp_named_subst) in
 220        !exp_named_subst_diff,!next_fresh_meta,
 221         List.rev !newmetasenvfragment, exp_named_subst'
 222    in
 223     new_fresh_meta,newmetasenvfragment,exp_named_subst',exp_named_subst_diff
 224 ;;
 225
 226 let new_metasenv_and_unify_and_t newmeta' metasenv' context term' ty termty goal_arity =
 227   let (consthead,newmetasenv,arguments,_) =
 228    saturate_term newmeta' metasenv' context termty goal_arity in
 229   let subst,newmetasenv',_ =
 230    CicUnification.fo_unif newmetasenv context consthead ty CicUniv.empty_ugraph
 231   in
 232   let t =
 233     if List.length arguments = 0 then term' else Cic.Appl (term'::arguments)
 234   in
 235   subst,newmetasenv',t
 236
 237 let rec count_prods context ty =
 238  match CicReduction.whd context ty with
 239     Cic.Prod (n,s,t) -> 1 + count_prods (Some (n,Cic.Decl s)::context) t
 240   | _ -> 0
 241
 242 let apply_tac_verbose ~term (proof, goal) =
 243   (* Assumption: The term "term" must be closed in the current context *)
 244  let module T = CicTypeChecker in
 245  let module R = CicReduction in
 246  let module C = Cic in
 247   let (_,metasenv,_,_) = proof in
 248   let metano,context,ty = CicUtil.lookup_meta goal metasenv in
 249   let newmeta = new_meta_of_proof ~proof in
 250    let exp_named_subst_diff,newmeta',newmetasenvfragment,term' =
 251     match term with
 252        C.Var (uri,exp_named_subst) ->
 253         let newmeta',newmetasenvfragment,exp_named_subst',exp_named_subst_diff =
 254          generalize_exp_named_subst_with_fresh_metas context newmeta uri
 255           exp_named_subst
 256         in
 257          exp_named_subst_diff,newmeta',newmetasenvfragment,
 258           C.Var (uri,exp_named_subst')
 259      | C.Const (uri,exp_named_subst) ->
 260         let newmeta',newmetasenvfragment,exp_named_subst',exp_named_subst_diff =
 261          generalize_exp_named_subst_with_fresh_metas context newmeta uri
 262           exp_named_subst
 263         in
 264          exp_named_subst_diff,newmeta',newmetasenvfragment,
 265           C.Const (uri,exp_named_subst')
 266      | C.MutInd (uri,tyno,exp_named_subst) ->
 267         let newmeta',newmetasenvfragment,exp_named_subst',exp_named_subst_diff =
 268          generalize_exp_named_subst_with_fresh_metas context newmeta uri
 269           exp_named_subst
 270         in
 271          exp_named_subst_diff,newmeta',newmetasenvfragment,
 272           C.MutInd (uri,tyno,exp_named_subst')
 273      | C.MutConstruct (uri,tyno,consno,exp_named_subst) ->
 274         let newmeta',newmetasenvfragment,exp_named_subst',exp_named_subst_diff =
 275          generalize_exp_named_subst_with_fresh_metas context newmeta uri
 276           exp_named_subst
 277         in
 278          exp_named_subst_diff,newmeta',newmetasenvfragment,
 279           C.MutConstruct (uri,tyno,consno,exp_named_subst')
 280      | _ -> [],newmeta,[],term
 281    in
 282    let metasenv' = metasenv@newmetasenvfragment in
 283    let termty,_ =
 284      CicTypeChecker.type_of_aux' metasenv' context term' CicUniv.empty_ugraph in
 285    let termty =
 286      CicSubstitution.subst_vars exp_named_subst_diff termty in
 287    let goal_arity = count_prods context ty in
 288    let subst,newmetasenv',t =
 289     let rec add_one_argument n =
 290      try
 291       new_metasenv_and_unify_and_t newmeta' metasenv' context term' ty
 292         termty n
 293      with CicUnification.UnificationFailure _ when n > 0 ->
 294       add_one_argument (n - 1)
 295     in
 296      add_one_argument goal_arity
 297    in
 298    let in_subst_domain i = List.exists (function (j,_) -> i=j) subst in
 299    let apply_subst = CicMetaSubst.apply_subst subst in
 300    let old_uninstantiatedmetas,new_uninstantiatedmetas =
 301      (* subst_in doesn't need the context. Hence the underscore. *)
 302      let subst_in _ = CicMetaSubst.apply_subst subst in
 303      classify_metas newmeta in_subst_domain subst_in newmetasenv'
 304    in
 305    let bo' = apply_subst t in
 306    let newmetasenv'' = new_uninstantiatedmetas@old_uninstantiatedmetas in
 307 (*    prerr_endline ("me: " ^ CicMetaSubst.ppmetasenv newmetasenv'' subst); *)
 308    let subst_in =
 309      (* if we just apply the subtitution, the type is irrelevant:
 310               we may use Implicit, since it will be dropped *)
 311      CicMetaSubst.apply_subst ((metano,(context,bo',Cic.Implicit None))::subst)
 312    in
 313    let (newproof, newmetasenv''') =
 314      subst_meta_and_metasenv_in_proof proof metano subst_in newmetasenv''
 315    in
 316      (subst_in,
 317        (newproof,
 318           List.map (function (i,_,_) -> i) new_uninstantiatedmetas))
 319
 320 let apply_tac ~term status = snd (apply_tac_verbose ~term status)
 321
 322 let apply_tac_verbose ~term status =
 323   try
 324     apply_tac_verbose ~term status
 325       (* TODO cacciare anche altre eccezioni? *)
 326   with
 327   | CicUnification.UnificationFailure _ as e ->
 328       raise (Fail (Printexc.to_string e))
 329   | CicTypeChecker.TypeCheckerFailure _ as e ->
 330       raise (Fail (Printexc.to_string e))
 331
 332   (* TODO per implementare i tatticali e' necessario che tutte le tattiche
 333   sollevino _solamente_ Fail *)
 334 let apply_tac ~term =
 335  let apply_tac ~term status =
 336   try
 337     apply_tac ~term status
 338       (* TODO cacciare anche altre eccezioni? *)
 339   with
 340   | CicUnification.UnificationFailure _ as e ->
 341       raise (Fail (Printexc.to_string e))
 342   | CicTypeChecker.TypeCheckerFailure _ as e ->
 343       raise (Fail (Printexc.to_string e))
 344  in
 345   mk_tactic (apply_tac ~term)
 346
 347 let intros_tac ?howmany ?(mk_fresh_name_callback = FreshNamesGenerator.mk_fresh_name ~subst:[]) ()=
 348  let intros_tac
 349   ?(mk_fresh_name_callback = (FreshNamesGenerator.mk_fresh_name ~subst:[])) ()
 350   (proof, goal)
 351  =
 352   let module C = Cic in
 353   let module R = CicReduction in
 354    let (_,metasenv,_,_) = proof in
 355    let metano,context,ty = CicUtil.lookup_meta goal metasenv in
 356     let newmeta = new_meta_of_proof ~proof in
 357      let (context',ty',bo') =
 358       lambda_abstract ?howmany metasenv context newmeta ty mk_fresh_name_callback
 359      in
 360       let (newproof, _) =
 361         subst_meta_in_proof proof metano bo' [newmeta,context',ty']
 362       in
 363        (newproof, [newmeta])
 364  in
 365   mk_tactic (intros_tac ~mk_fresh_name_callback ())
 366
 367 let cut_tac ?(mk_fresh_name_callback = FreshNamesGenerator.mk_fresh_name ~subst:[]) term =
 368  let cut_tac
 369   ?(mk_fresh_name_callback = FreshNamesGenerator.mk_fresh_name ~subst:[])
 370   term (proof, goal)
 371  =
 372   let module C = Cic in
 373    let curi,metasenv,pbo,pty = proof in
 374    let metano,context,ty = CicUtil.lookup_meta goal metasenv in
 375     let newmeta1 = new_meta_of_proof ~proof in
 376     let newmeta2 = newmeta1 + 1 in
 377     let fresh_name =
 378      mk_fresh_name_callback metasenv context (Cic.Name "Hcut") ~typ:term in
 379     let context_for_newmeta1 =
 380      (Some (fresh_name,C.Decl term))::context in
 381     let irl1 =
 382      CicMkImplicit.identity_relocation_list_for_metavariable
 383       context_for_newmeta1
 384     in
 385     let irl2 =
 386       CicMkImplicit.identity_relocation_list_for_metavariable context
 387     in
 388      let newmeta1ty = CicSubstitution.lift 1 ty in
 389      let bo' =
 390       C.Appl
 391        [C.Lambda (fresh_name,term,C.Meta (newmeta1,irl1)) ;
 392         C.Meta (newmeta2,irl2)]
 393      in
 394       let (newproof, _) =
 395        subst_meta_in_proof proof metano bo'
 396         [newmeta2,context,term; newmeta1,context_for_newmeta1,newmeta1ty];
 397       in
 398        (newproof, [newmeta1 ; newmeta2])
 399  in
 400   mk_tactic (cut_tac ~mk_fresh_name_callback term)
 401
 402 let letin_tac ?(mk_fresh_name_callback=FreshNamesGenerator.mk_fresh_name ~subst:[]) term =
 403  let letin_tac
 404   ?(mk_fresh_name_callback = FreshNamesGenerator.mk_fresh_name ~subst:[])
 405   term (proof, goal)
 406  =
 407   let module C = Cic in
 408    let curi,metasenv,pbo,pty = proof in
 409    let metano,context,ty = CicUtil.lookup_meta goal metasenv in
 410     let _,_ = (* TASSI: FIXME *)
 411       CicTypeChecker.type_of_aux' metasenv context term CicUniv.empty_ugraph in
 412      let newmeta = new_meta_of_proof ~proof in
 413      let fresh_name =
 414       mk_fresh_name_callback metasenv context (Cic.Name "Hletin") ~typ:term in
 415      let context_for_newmeta =
 416       (Some (fresh_name,C.Def (term,None)))::context in
 417      let irl =
 418       CicMkImplicit.identity_relocation_list_for_metavariable
 419        context_for_newmeta
 420      in
 421       let newmetaty = CicSubstitution.lift 1 ty in
 422       let bo' = C.LetIn (fresh_name,term,C.Meta (newmeta,irl)) in
 423        let (newproof, _) =
 424          subst_meta_in_proof
 425            proof metano bo'[newmeta,context_for_newmeta,newmetaty]
 426        in
 427         (newproof, [newmeta])
 428  in
 429   mk_tactic (letin_tac ~mk_fresh_name_callback term)
 430
 431   (** functional part of the "exact" tactic *)
 432 let exact_tac ~term =
 433  let exact_tac ~term (proof, goal) =
 434   (* Assumption: the term bo must be closed in the current context *)
 435   let (_,metasenv,_,_) = proof in
 436   let metano,context,ty = CicUtil.lookup_meta goal metasenv in
 437   let module T = CicTypeChecker in
 438   let module R = CicReduction in
 439   let ty_term,u = T.type_of_aux' metasenv context term CicUniv.empty_ugraph in
 440   let b,_ = R.are_convertible context ty_term ty u in (* TASSI: FIXME *)
 441   if b then
 442    begin
 443     let (newproof, metasenv') =
 444       subst_meta_in_proof proof metano term [] in
 445     (newproof, [])
 446    end
 447   else
 448    raise (Fail "The type of the provided term is not the one expected.")
 449  in
 450   mk_tactic (exact_tac ~term)
 451
 452 (* not really "primitive" tactics .... *)
 453 let elim_tac ~term =
 454  let elim_tac ~term (proof, goal) =
 455   let module T = CicTypeChecker in
 456   let module U = UriManager in
 457   let module R = CicReduction in
 458   let module C = Cic in
 459    let (curi,metasenv,proofbo,proofty) = proof in
 460    let metano,context,ty = CicUtil.lookup_meta goal metasenv in
 461     let termty,_ = T.type_of_aux' metasenv context term CicUniv.empty_ugraph in
 462     let (termty,metasenv',arguments,fresh_meta) =
 463      ProofEngineHelpers.saturate_term
 464       (ProofEngineHelpers.new_meta_of_proof proof) metasenv context termty 0 in
 465     let term = if arguments = [] then term else Cic.Appl (term::arguments) in
 466     let uri,exp_named_subst,typeno,args =
 467      match termty with
 468         C.MutInd (uri,typeno,exp_named_subst) -> (uri,exp_named_subst,typeno,[])
 469       | C.Appl ((C.MutInd (uri,typeno,exp_named_subst))::args) ->
 470           (uri,exp_named_subst,typeno,args)
 471       | _ -> raise NotAnInductiveTypeToEliminate
 472     in
 473      let eliminator_uri =
 474       let buri = U.buri_of_uri uri in
 475       let name =
 476         let o,_ = CicEnvironment.get_obj CicUniv.empty_ugraph uri in
 477        match o with
 478           C.InductiveDefinition (tys,_,_,_) ->
 479            let (name,_,_,_) = List.nth tys typeno in
 480             name
 481         | _ -> assert false
 482       in
 483       let ty_ty,_ = T.type_of_aux' metasenv' context ty CicUniv.empty_ugraph in
 484       let ext =
 485        match ty_ty with
 486           C.Sort C.Prop -> "_ind"
 487         | C.Sort C.Set  -> "_rec"
 488         | C.Sort C.CProp -> "_rec"
 489         | C.Sort (C.Type _)-> "_rect"
 490         | C.Meta (_,_) -> raise TheTypeOfTheCurrentGoalIsAMetaICannotChooseTheRightElimiantionPrinciple
 491         | _ -> assert false
 492       in
 493        U.uri_of_string (buri ^ "/" ^ name ^ ext ^ ".con")
 494      in
 495       let eliminator_ref = C.Const (eliminator_uri,exp_named_subst) in
 496        let ety,_ =
 497          T.type_of_aux' metasenv' context eliminator_ref CicUniv.empty_ugraph in
 498         let rec find_args_no =
 499          function
 500             C.Prod (_,_,t) -> 1 + find_args_no t
 501           | C.Cast (s,_) -> find_args_no s
 502           | C.LetIn (_,_,t) -> 0 + find_args_no t
 503           | _ -> 0
 504         in
 505          let args_no = find_args_no ety in
 506          let term_to_refine =
 507           let rec make_tl base_case =
 508            function
 509               0 -> [base_case]
 510             | n -> (C.Implicit None)::(make_tl base_case (n - 1))
 511           in
 512            C.Appl (eliminator_ref :: make_tl term (args_no - 1))
 513          in
 514           let metasenv', term_to_refine' =
 515            CicMkImplicit.expand_implicits metasenv' [] context term_to_refine in
 516           let refined_term,_,metasenv'',_ =
 517            CicRefine.type_of_aux' metasenv' context term_to_refine'
 518              CicUniv.empty_ugraph
 519           in
 520            let new_goals =
 521             ProofEngineHelpers.compare_metasenvs
 522              ~oldmetasenv:metasenv ~newmetasenv:metasenv''
 523            in
 524            let proof' = curi,metasenv'',proofbo,proofty in
 525             let proof'', new_goals' =
 526              apply_tactic (apply_tac ~term:refined_term) (proof',goal)
 527             in
 528              (* The apply_tactic can have closed some of the new_goals *)
 529              let patched_new_goals =
 530               let (_,metasenv''',_,_) = proof'' in
 531                List.filter
 532                 (function i -> List.exists (function (j,_,_) -> j=i) metasenv'''
 533                 ) new_goals @ new_goals'
 534              in
 535               proof'', patched_new_goals
 536  in
 537   mk_tactic (elim_tac ~term)
 538 ;;
 539
 540 let elim_intros_tac ?(mk_fresh_name_callback = FreshNamesGenerator.mk_fresh_name ~subst:[])
 541                     ?depth ?using what =
 542  Tacticals.then_ ~start:(elim_tac ~term:what)
 543   ~continuation:(intros_tac ~mk_fresh_name_callback ?howmany:depth ())
 544 ;;
 545
 546 (* The simplification is performed only on the conclusion *)
 547 let elim_intros_simpl_tac ?(mk_fresh_name_callback = FreshNamesGenerator.mk_fresh_name ~subst:[])
 548                           ?depth ?using what =
 549  Tacticals.then_ ~start:(elim_tac ~term:what)
 550   ~continuation:
 551    (Tacticals.thens
 552      ~start:(intros_tac ~mk_fresh_name_callback ?howmany:depth ())
 553      ~continuations:
 554        [ReductionTactics.simpl_tac
 555          ~pattern:(ProofEngineTypes.conclusion_pattern None)])
 556 ;;