helm/ocaml/tactics/proofEngineHelpers.ml

   1 (* Copyright (C) 2002, HELM Team.
   2  *
   3  * This file is part of HELM, an Hypertextual, Electronic
   4  * Library of Mathematics, developed at the Computer Science
   5  * Department, University of Bologna, Italy.
   6  *
   7  * HELM is free software; you can redistribute it and/or
   8  * modify it under the terms of the GNU General Public License
   9  * as published by the Free Software Foundation; either version 2
  10  * of the License, or (at your option) any later version.
  11  *
  12  * HELM is distributed in the hope that it will be useful,
  13  * but WITHOUT ANY WARRANTY; without even the implied warranty of
  14  * MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the
  15  * GNU General Public License for more details.
  16  *
  17  * You should have received a copy of the GNU General Public License
  18  * along with HELM; if not, write to the Free Software
  19  * Foundation, Inc., 59 Temple Place - Suite 330, Boston,
  20  * MA  02111-1307, USA.
  21  *
  22  * For details, see the HELM World-Wide-Web page,
  23  * http://cs.unibo.it/helm/.
  24  *)
  25
  26 exception Bad_pattern of string
  27
  28 let new_meta_of_proof ~proof:(_, metasenv, _, _) =
  29   CicMkImplicit.new_meta metasenv []
  30
  31 let subst_meta_in_proof proof meta term newmetasenv =
  32  let uri,metasenv,bo,ty = proof in
  33    (* empty context is ok for term since it wont be used by apply_subst *)
  34    (* hack: since we do not know the context and the type of term, we
  35       create a substitution with cc =[] and type = Implicit; they will be
  36       in  any case dropped by apply_subst, but it would be better to rewrite
  37       the code. Cannot we just use apply_subst_metasenv, etc. ?? *)
  38   let subst_in = CicMetaSubst.apply_subst [meta,([], term,Cic.Implicit None)] in
  39    let metasenv' =
  40     newmetasenv @ (List.filter (function (m,_,_) -> m <> meta) metasenv)
  41    in
  42     let metasenv'' =
  43      List.map
  44       (function i,canonical_context,ty ->
  45         let canonical_context' =
  46          List.map
  47           (function
  48               Some (n,Cic.Decl s) -> Some (n,Cic.Decl (subst_in s))
  49             | Some (n,Cic.Def (s,None)) -> Some (n,Cic.Def ((subst_in s),None))
  50             | None -> None
  51             | Some (_,Cic.Def (_,Some _)) -> assert false
  52           ) canonical_context
  53         in
  54          i,canonical_context',(subst_in ty)
  55       ) metasenv'
  56     in
  57      let bo' = subst_in bo in
  58      (* Metavariables can appear also in the *statement* of the theorem
  59       * since the parser does not reject as statements terms with
  60       * metavariable therein *)
  61      let ty' = subst_in ty in
  62       let newproof = uri,metasenv'',bo',ty' in
  63        (newproof, metasenv'')
  64
  65 (*CSC: commento vecchio *)
  66 (* refine_meta_with_brand_new_metasenv meta term subst_in newmetasenv     *)
  67 (* This (heavy) function must be called when a tactic can instantiate old *)
  68 (* metavariables (i.e. existential variables). It substitues the metasenv *)
  69 (* of the proof with the result of removing [meta] from the domain of     *)
  70 (* [newmetasenv]. Then it replaces Cic.Meta [meta] with [term] everywhere *)
  71 (* in the current proof. Finally it applies [apply_subst_replacing] to    *)
  72 (*  current proof.                                                        *)
  73 (*CSC: A questo punto perche' passare un bo' gia' istantiato, se tanto poi *)
  74 (*CSC: ci ripasso sopra apply_subst!!!                                     *)
  75 (*CSC: Attenzione! Ora questa funzione applica anche [subst_in] a *)
  76 (*CSC: [newmetasenv].                                             *)
  77 let subst_meta_and_metasenv_in_proof proof meta subst_in newmetasenv =
  78  let (uri,_,bo,ty) = proof in
  79   let bo' = subst_in bo in
  80   (* Metavariables can appear also in the *statement* of the theorem
  81    * since the parser does not reject as statements terms with
  82    * metavariable therein *)
  83   let ty' = subst_in ty in
  84   let metasenv' =
  85    List.fold_right
  86     (fun metasenv_entry i ->
  87       match metasenv_entry with
  88          (m,canonical_context,ty) when m <> meta ->
  89            let canonical_context' =
  90             List.map
  91              (function
  92                  None -> None
  93                | Some (i,Cic.Decl t) -> Some (i,Cic.Decl (subst_in t))
  94                | Some (i,Cic.Def (t,None))  ->
  95                   Some (i,Cic.Def ((subst_in t),None))
  96                | Some (_,Cic.Def (_,Some _))  -> assert false
  97              ) canonical_context
  98            in
  99             (m,canonical_context',subst_in ty)::i
 100        | _ -> i
 101     ) newmetasenv []
 102   in
 103    let newproof = uri,metasenv',bo',ty' in
 104     (newproof, metasenv')
 105
 106 let compare_metasenvs ~oldmetasenv ~newmetasenv =
 107  List.map (function (i,_,_) -> i)
 108   (List.filter
 109    (function (i,_,_) ->
 110      not (List.exists (fun (j,_,_) -> i=j) oldmetasenv)) newmetasenv)
 111 ;;
 112
 113 (** finds the _pointers_ to subterms that are alpha-equivalent to wanted in t *)
 114 let find_subterms ~subst ~metasenv ~ugraph ~wanted ~context t =
 115   let rec find subst metasenv ugraph context w t =
 116    try
 117     let subst,metasenv,ugraph =
 118      CicUnification.fo_unif_subst subst context metasenv w t ugraph
 119     in
 120       subst,metasenv,ugraph,[context,t]
 121    with
 122      CicUnification.UnificationFailure _
 123    | CicUnification.Uncertain _ ->
 124       match t with
 125       | Cic.Sort _
 126       | Cic.Rel _ -> subst,metasenv,ugraph,[]
 127       | Cic.Meta (_, ctx) ->
 128           List.fold_left (
 129             fun (subst,metasenv,ugraph,acc) e ->
 130               match e with
 131               | None -> subst,metasenv,ugraph,acc
 132               | Some t ->
 133                  let subst,metasenv,ugraph,res =
 134                   find subst metasenv ugraph context w t
 135                  in
 136                   subst,metasenv,ugraph, res @ acc
 137           ) (subst,metasenv,ugraph,[]) ctx
 138       | Cic.Lambda (name, t1, t2)
 139       | Cic.Prod (name, t1, t2) ->
 140          let subst,metasenv,ugraph,rest1 =
 141           find subst metasenv ugraph context w t1 in
 142          let subst,metasenv,ugraph,rest2 =
 143           find subst metasenv ugraph (Some (name, Cic.Decl t1)::context)
 144            (CicSubstitution.lift 1 w) t2
 145          in
 146           subst,metasenv,ugraph,rest1 @ rest2
 147       | Cic.LetIn (name, t1, t2) ->
 148          let subst,metasenv,ugraph,rest1 =
 149           find subst metasenv ugraph context w t1 in
 150          let subst,metasenv,ugraph,rest2 =
 151           find subst metasenv ugraph (Some (name, Cic.Def (t1,None))::context)
 152            (CicSubstitution.lift 1 w) t2
 153          in
 154           subst,metasenv,ugraph,rest1 @ rest2
 155       | Cic.Appl l ->
 156           List.fold_left
 157            (fun (subst,metasenv,ugraph,acc) t ->
 158              let subst,metasenv,ugraph,res =
 159               find subst metasenv ugraph context w t
 160              in
 161               subst,metasenv,ugraph,res @ acc)
 162            (subst,metasenv,ugraph,[]) l
 163       | Cic.Cast (t, ty) ->
 164          let subst,metasenv,ugraph,rest =
 165           find subst metasenv ugraph context w t in
 166          let subst,metasenv,ugraph,resty =
 167           find subst metasenv ugraph context w ty
 168          in
 169           subst,metasenv,ugraph,rest @ resty
 170       | Cic.Implicit _ -> assert false
 171       | Cic.Const (_, esubst)
 172       | Cic.Var (_, esubst)
 173       | Cic.MutInd (_, _, esubst)
 174       | Cic.MutConstruct (_, _, _, esubst) ->
 175           List.fold_left
 176            (fun (subst,metasenv,ugraph,acc) (_, t) ->
 177              let subst,metasenv,ugraph,res =
 178               find subst metasenv ugraph context w t
 179              in
 180               subst,metasenv,ugraph,res @ acc)
 181            (subst,metasenv,ugraph,[]) esubst
 182       | Cic.MutCase (_, _, outty, indterm, patterns) ->
 183          let subst,metasenv,ugraph,resoutty =
 184           find subst metasenv ugraph context w outty in
 185          let subst,metasenv,ugraph,resindterm =
 186           find subst metasenv ugraph context w indterm in
 187          let subst,metasenv,ugraph,respatterns =
 188           List.fold_left
 189            (fun (subst,metasenv,ugraph,acc) p ->
 190              let subst,metaseng,ugraph,res =
 191               find subst metasenv ugraph context w p
 192              in
 193               subst,metasenv,ugraph,res @ acc
 194            ) (subst,metasenv,ugraph,[]) patterns
 195          in
 196           subst,metasenv,ugraph,resoutty @ resindterm @ respatterns
 197       | Cic.Fix (_, funl) ->
 198          let tys =
 199           List.map (fun (n,_,ty,_) -> Some (Cic.Name n,(Cic.Decl ty))) funl
 200          in
 201           List.fold_left (
 202             fun (subst,metasenv,ugraph,acc) (_, _, ty, bo) ->
 203              let subst,metasenv,ugraph,resty =
 204               find subst metasenv ugraph context w ty in
 205              let subst,metasenv,ugraph,resbo =
 206               find subst metasenv ugraph (tys @ context) w bo
 207              in
 208               subst,metasenv,ugraph, resty @ resbo @ acc
 209           ) (subst,metasenv,ugraph,[]) funl
 210       | Cic.CoFix (_, funl) ->
 211          let tys =
 212           List.map (fun (n,ty,_) -> Some (Cic.Name n,(Cic.Decl ty))) funl
 213          in
 214           List.fold_left (
 215             fun (subst,metasenv,ugraph,acc) (_, ty, bo) ->
 216              let subst,metasenv,ugraph,resty =
 217               find subst metasenv ugraph context w ty in
 218              let subst,metasenv,ugraph,resbo =
 219               find subst metasenv ugraph (tys @ context) w bo
 220              in
 221               subst,metasenv,ugraph, resty @ resbo @ acc
 222           ) (subst,metasenv,ugraph,[]) funl
 223   in
 224   find subst metasenv ugraph context wanted t
 225
 226 let select_in_term ~metasenv ~context ~ugraph ~term ~pattern:(wanted,where) =
 227   let add_ctx context name entry =
 228       (Some (name, entry)) :: context
 229   in
 230   let map2 error_msg f l1 l2 =
 231     try
 232       List.map2 f l1 l2
 233     with
 234     | Invalid_argument _ -> raise (Bad_pattern error_msg)
 235   in
 236   let rec aux context where term =
 237     match (where, term) with
 238     | Cic.Implicit (Some `Hole), t -> [context,t]
 239     | Cic.Implicit (Some `Type), t -> []
 240     | Cic.Implicit None,_ -> []
 241     | Cic.Meta (_, ctxt1), Cic.Meta (_, ctxt2) ->
 242         List.concat
 243           (map2 "wrong number of argument in explicit substitution"
 244             (fun t1 t2 ->
 245               (match (t1, t2) with
 246                   Some t1, Some t2 -> aux context t1 t2
 247                 | _ -> []))
 248             ctxt1 ctxt2)
 249     | Cic.Cast (te1, ty1), Cic.Cast (te2, ty2) ->
 250        aux context te1 te2 @ aux context ty1 ty2
 251     | Cic.Prod (Cic.Anonymous, s1, t1), Cic.Prod (name, s2, t2)
 252     | Cic.Lambda (Cic.Anonymous, s1, t1), Cic.Lambda (name, s2, t2) ->
 253         aux context s1 s2 @ aux (add_ctx context name (Cic.Decl s2)) t1 t2
 254     | Cic.Prod (Cic.Name n1, s1, t1),
 255       Cic.Prod ((Cic.Name n2) as name , s2, t2)
 256     | Cic.Lambda (Cic.Name n1, s1, t1),
 257       Cic.Lambda ((Cic.Name n2) as name, s2, t2) when n1 = n2->
 258         aux context s1 s2 @ aux (add_ctx context name (Cic.Decl s2)) t1 t2
 259     | Cic.Prod (name1, s1, t1), Cic.Prod (name2, s2, t2)
 260     | Cic.Lambda (name1, s1, t1), Cic.Lambda (name2, s2, t2) -> []
 261     | Cic.LetIn (Cic.Anonymous, s1, t1), Cic.LetIn (name, s2, t2) ->
 262         aux context s1 s2 @ aux (add_ctx context name (Cic.Def (s2,None))) t1 t2
 263     | Cic.LetIn (Cic.Name n1, s1, t1),
 264       Cic.LetIn ((Cic.Name n2) as name, s2, t2) when n1 = n2->
 265         aux context s1 s2 @ aux (add_ctx context name (Cic.Def (s2,None))) t1 t2
 266     | Cic.LetIn (name1, s1, t1), Cic.LetIn (name2, s2, t2) -> []
 267     | Cic.Appl terms1, Cic.Appl terms2 -> auxs context terms1 terms2
 268     | Cic.Var (_, subst1), Cic.Var (_, subst2)
 269     | Cic.Const (_, subst1), Cic.Const (_, subst2)
 270     | Cic.MutInd (_, _, subst1), Cic.MutInd (_, _, subst2)
 271     | Cic.MutConstruct (_, _, _, subst1), Cic.MutConstruct (_, _, _, subst2) ->
 272         auxs context (List.map snd subst1) (List.map snd subst2)
 273     | Cic.MutCase (_, _, out1, t1, pat1), Cic.MutCase (_ , _, out2, t2, pat2) ->
 274         aux context out1 out2 @ aux context t1 t2 @ auxs context pat1 pat2
 275     | Cic.Fix (_, funs1), Cic.Fix (_, funs2) ->
 276        let tys =
 277         List.map (fun (n,_,ty,_) -> Some (Cic.Name n,(Cic.Decl ty))) funs2
 278        in
 279         List.concat
 280           (map2 "wrong number of mutually recursive functions"
 281             (fun (_, _, ty1, bo1) (_, _, ty2, bo2) ->
 282               aux context ty1 ty2 @ aux (tys @ context) bo1 bo2)
 283             funs1 funs2)
 284     | Cic.CoFix (_, funs1), Cic.CoFix (_, funs2) ->
 285        let tys =
 286         List.map (fun (n,ty,_) -> Some (Cic.Name n,(Cic.Decl ty))) funs2
 287        in
 288         List.concat
 289           (map2 "wrong number of mutually co-recursive functions"
 290             (fun (_, ty1, bo1) (_, ty2, bo2) ->
 291               aux context ty1 ty2 @ aux (tys @ context) bo1 bo2)
 292             funs1 funs2)
 293     | x,y ->
 294         raise (Bad_pattern
 295                 (Printf.sprintf "Pattern %s versus term %s"
 296                   (CicPp.ppterm x)
 297                   (CicPp.ppterm y)))
 298   and auxs context terms1 terms2 =  (* as aux for list of terms *)
 299     List.concat (map2 "wrong number of arguments in application"
 300       (fun t1 t2 -> aux context t1 t2) terms1 terms2)
 301   in
 302    let context_len = List.length context in
 303    let roots = aux context where term in
 304     match wanted with
 305        None -> [],metasenv,ugraph,roots
 306      | Some wanted ->
 307         let rec find_in_roots =
 308          function
 309             [] -> [],metasenv,ugraph,[]
 310           | (context',where)::tl ->
 311              let subst,metasenv,ugraph,tl' = find_in_roots tl in
 312              let context'_len = List.length context' in
 313              let subst,metasenv,ugraph,found =
 314               let wanted =
 315                CicSubstitution.lift (context'_len - context_len) wanted
 316               in
 317                find_subterms ~subst ~metasenv ~ugraph ~wanted ~context where
 318              in
 319               subst,metasenv,ugraph,found @ tl'
 320         in
 321          find_in_roots roots
 322
 323 (** create a pattern from a term and a list of subterms.
 324 * the pattern is granted to have a ? for every subterm that has no selected
 325 * subterms
 326 * @param equality equality function used while walking the term. Defaults to
 327 * physical equality (==) *)
 328 let pattern_of ?(equality=(==)) ~term terms =
 329   let (===) x y = equality x y in
 330   let not_found = false, Cic.Implicit None in
 331   let rec aux t =
 332     match t with
 333     | t when List.exists (fun t' -> t === t') terms ->
 334        true,Cic.Implicit (Some `Hole)
 335     | Cic.Var (uri, subst) ->
 336        let b,subst = aux_subst subst in
 337         if b then
 338          true,Cic.Var (uri, subst)
 339         else
 340          not_found
 341     | Cic.Meta (i, ctxt) ->
 342         let b,ctxt =
 343           List.fold_right
 344            (fun e (b,ctxt) ->
 345              match e with
 346                 None -> b,None::ctxt
 347               | Some t -> let bt,t = aux t in b||bt ,Some t::ctxt
 348            ) ctxt (false,[])
 349         in
 350          if b then
 351           true,Cic.Meta (i, ctxt)
 352          else
 353           not_found
 354     | Cic.Cast (te, ty) ->
 355        let b1,te = aux te in
 356        let b2,ty = aux ty in
 357         if b1||b2 then true,Cic.Cast (te, ty)
 358         else
 359          not_found
 360     | Cic.Prod (name, s, t) ->
 361        let b1,s = aux s in
 362        let b2,t = aux t in
 363         if b1||b2 then
 364          true, Cic.Prod (name, s, t)
 365         else
 366          not_found
 367     | Cic.Lambda (name, s, t) ->
 368        let b1,s = aux s in
 369        let b2,t = aux t in
 370         if b1||b2 then
 371          true, Cic.Lambda (name, s, t)
 372         else
 373          not_found
 374     | Cic.LetIn (name, s, t) ->
 375        let b1,s = aux s in
 376        let b2,t = aux t in
 377         if b1||b2 then
 378          true, Cic.LetIn (name, s, t)
 379         else
 380          not_found
 381     | Cic.Appl terms ->
 382        let b,terms =
 383         List.fold_right
 384          (fun t (b,terms) ->
 385            let bt,t = aux t in
 386             b||bt,t::terms
 387          ) terms (false,[])
 388        in
 389         if b then
 390          true,Cic.Appl terms
 391         else
 392          not_found
 393     | Cic.Const (uri, subst) ->
 394        let b,subst = aux_subst subst in
 395         if b then
 396          true, Cic.Const (uri, subst)
 397         else
 398          not_found
 399     | Cic.MutInd (uri, tyno, subst) ->
 400        let b,subst = aux_subst subst in
 401         if b then
 402          true, Cic.MutInd (uri, tyno, subst)
 403         else
 404          not_found
 405     | Cic.MutConstruct (uri, tyno, consno, subst) ->
 406        let b,subst = aux_subst subst in
 407         if b then
 408          true, Cic.MutConstruct (uri, tyno, consno, subst)
 409         else
 410          not_found
 411     | Cic.MutCase (uri, tyno, outty, t, pat) ->
 412        let b1,outty = aux outty in
 413        let b2,t = aux t in
 414        let b3,pat =
 415         List.fold_right
 416          (fun t (b,pat) ->
 417            let bt,t = aux t in
 418             bt||b,t::pat
 419          ) pat (false,[])
 420        in
 421         if b1 || b2 || b3 then
 422          true, Cic.MutCase (uri, tyno, outty, t, pat)
 423         else
 424          not_found
 425     | Cic.Fix (funno, funs) ->
 426         let b,funs =
 427           List.fold_right
 428            (fun (name, i, ty, bo) (b,funs) ->
 429              let b1,ty = aux ty in
 430              let b2,bo = aux bo in
 431               b||b1||b2, (name, i, ty, bo)::funs) funs (false,[])
 432         in
 433          if b then
 434           true, Cic.Fix (funno, funs)
 435          else
 436           not_found
 437     | Cic.CoFix (funno, funs) ->
 438         let b,funs =
 439           List.fold_right
 440            (fun (name, ty, bo) (b,funs) ->
 441              let b1,ty = aux ty in
 442              let b2,bo = aux bo in
 443               b||b1||b2, (name, ty, bo)::funs) funs (false,[])
 444         in
 445          if b then
 446           true, Cic.CoFix (funno, funs)
 447          else
 448           not_found
 449     | Cic.Rel _
 450     | Cic.Sort _
 451     | Cic.Implicit _ -> not_found
 452   and aux_subst subst =
 453     List.fold_right
 454      (fun (uri, t) (b,subst) ->
 455        let b1,t = aux t in
 456         b||b1,(uri, t)::subst) subst (false,[])
 457   in
 458    snd (aux term)
 459
 460 exception Fail of string
 461
 462   (** select metasenv conjecture pattern
 463   * select all subterms of [conjecture] matching [pattern].
 464   * It returns the set of matched terms (that can be compared using physical
 465   * equality to the subterms of [conjecture]) together with their contexts.
 466   * The representation of the set mimics the ProofEngineTypes.pattern type:
 467   * a list of hypothesis (names of) together with the list of its matched
 468   * subterms (and their contexts) + the list of matched subterms of the
 469   * with their context conclusion. Note: in the result the list of hypothesis
 470   * has an entry for each entry in the context and in the same order.
 471   * Of course the list of terms (with their context) associated to the
 472   * hypothesis name may be empty.
 473   *
 474   * @raise Bad_pattern
 475   * *)
 476   let select ~metasenv ~ugraph ~conjecture:(_,context,ty)
 477        ~pattern:(what,hyp_patterns,goal_pattern)
 478   =
 479    let find_pattern_for name =
 480      try Some (snd (List.find (fun (n, pat) -> Cic.Name n = name) hyp_patterns))
 481      with Not_found -> None in
 482    let subst,metasenv,ugraph,ty_terms =
 483     select_in_term ~metasenv ~context ~ugraph ~term:ty
 484      ~pattern:(what,goal_pattern) in
 485    let context_len = List.length context in
 486    let subst,metasenv,ugraph,context_terms =
 487     let subst,metasenv,ugraph,res,_ =
 488      (List.fold_right
 489       (fun entry (subst,metasenv,ugraph,res,context) ->
 490         match entry with
 491           None -> subst,metasenv,ugraph,(None::res),(None::context)
 492         | Some (name,Cic.Decl term) ->
 493             (match find_pattern_for name with
 494             | None ->
 495                subst,metasenv,ugraph,((Some (`Decl []))::res),(entry::context)
 496             | Some pat ->
 497                try
 498                 let what =
 499                  match what with
 500                     None -> None
 501                   | Some what ->
 502                      let what,subst',metasenv' =
 503                       CicMetaSubst.delift_rels [] metasenv
 504                        (context_len - List.length context) what
 505                      in
 506                       assert (subst' = []);
 507                       assert (metasenv' = metasenv);
 508                       Some what in
 509                 let subst,metasenv,ugraph,terms =
 510                  select_in_term ~metasenv ~context ~ugraph ~term
 511                   ~pattern:(what,pat)
 512                 in
 513                  subst,metasenv,ugraph,((Some (`Decl terms))::res),
 514                   (entry::context)
 515                with
 516                 CicMetaSubst.DeliftingARelWouldCaptureAFreeVariable ->
 517                  raise
 518                   (Fail
 519                     ("The term the user wants to convert is not closed " ^
 520                      "in the context of the position of the substitution.")))
 521         | Some (name,Cic.Def (bo, ty)) ->
 522             (match find_pattern_for name with
 523             | None ->
 524                let selected_ty=match ty with None -> None | Some _ -> Some [] in
 525                 subst,metasenv,ugraph,((Some (`Def ([],selected_ty)))::res),
 526                  (entry::context)
 527             | Some pat ->
 528                try
 529                 let what =
 530                  match what with
 531                     None -> None
 532                   | Some what ->
 533                      let what,subst',metasenv' =
 534                       CicMetaSubst.delift_rels [] metasenv
 535                        (context_len - List.length context) what
 536                      in
 537                       assert (subst' = []);
 538                       assert (metasenv' = metasenv);
 539                       Some what in
 540                 let subst,metasenv,ugraph,terms_bo =
 541                  select_in_term ~metasenv ~context ~ugraph ~term:bo
 542                   ~pattern:(what,pat) in
 543                 let subst,metasenv,ugraph,terms_ty =
 544                  match ty with
 545                     None -> subst,metasenv,ugraph,None
 546                   | Some ty ->
 547                      let subst,metasenv,ugraph,res =
 548                       select_in_term ~metasenv ~context ~ugraph ~term:ty
 549                        ~pattern:(what,pat)
 550                      in
 551                       subst,metasenv,ugraph,Some res
 552                 in
 553                  subst,metasenv,ugraph,((Some (`Def (terms_bo,terms_ty)))::res),
 554                   (entry::context)
 555                with
 556                 CicMetaSubst.DeliftingARelWouldCaptureAFreeVariable ->
 557                  raise
 558                   (Fail
 559                     ("The term the user wants to convert is not closed " ^
 560                      "in the context of the position of the substitution.")))
 561       ) context (subst,metasenv,ugraph,[],[]))
 562     in
 563      subst,metasenv,ugraph,res
 564    in
 565     subst,metasenv,ugraph,context_terms, ty_terms
 566
 567 (** locate_in_term equality what where context
 568 * [what] must match a subterm of [where] according to [equality]
 569 * It returns the matched terms together with their contexts in [where]
 570 * [equality] defaults to physical equality
 571 * [context] must be the context of [where]
 572 *)
 573 let locate_in_term ?(equality=(fun _ -> (==))) what ~where context =
 574   let add_ctx context name entry =
 575       (Some (name, entry)) :: context in
 576   let rec aux context where =
 577    if equality context what where then [context,where]
 578    else
 579     match where with
 580     | Cic.Implicit _
 581     | Cic.Meta _
 582     | Cic.Rel _
 583     | Cic.Sort _
 584     | Cic.Var _
 585     | Cic.Const _
 586     | Cic.MutInd _
 587     | Cic.MutConstruct _ -> []
 588     | Cic.Cast (te, ty) -> aux context te @ aux context ty
 589     | Cic.Prod (name, s, t)
 590     | Cic.Lambda (name, s, t) ->
 591         aux context s @ aux (add_ctx context name (Cic.Decl s)) t
 592     | Cic.LetIn (name, s, t) ->
 593         aux context s @ aux (add_ctx context name (Cic.Def (s,None))) t
 594     | Cic.Appl tl -> auxs context tl
 595     | Cic.MutCase (_, _, out, t, pat) ->
 596         aux context out @ aux context t @ auxs context pat
 597     | Cic.Fix (_, funs) ->
 598        let tys =
 599         List.map (fun (n,_,ty,_) -> Some (Cic.Name n,(Cic.Decl ty))) funs
 600        in
 601         List.concat
 602           (List.map
 603             (fun (_, _, ty, bo) ->
 604               aux context ty @ aux (tys @ context) bo)
 605             funs)
 606     | Cic.CoFix (_, funs) ->
 607        let tys =
 608         List.map (fun (n,ty,_) -> Some (Cic.Name n,(Cic.Decl ty))) funs
 609        in
 610         List.concat
 611           (List.map
 612             (fun (_, ty, bo) ->
 613               aux context ty @ aux (tys @ context) bo)
 614             funs)
 615   and auxs context tl =  (* as aux for list of terms *)
 616     List.concat (List.map (fun t -> aux context t) tl)
 617   in
 618    aux context where
 619
 620 (** locate_in_conjecture equality what where context
 621 * [what] must match a subterm of [where] according to [equality]
 622 * It returns the matched terms together with their contexts in [where]
 623 * [equality] defaults to physical equality
 624 * [context] must be the context of [where]
 625 *)
 626 let locate_in_conjecture ?(equality=fun _ -> (==)) what (_,context,ty) =
 627  let context,res =
 628   List.fold_right
 629    (fun entry (context,res) ->
 630      match entry with
 631         None -> entry::context, res
 632       | Some (_, Cic.Decl ty) ->
 633          let res = res @ locate_in_term what ~where:ty context in
 634          let context' = entry::context in
 635           context',res
 636       | Some (_, Cic.Def (bo,ty)) ->
 637          let res = res @ locate_in_term what ~where:bo context in
 638          let res =
 639           match ty with
 640              None -> res
 641            | Some ty ->
 642               res @ locate_in_term what ~where:ty context in
 643          let context' = entry::context in
 644           context',res
 645    ) context ([],[])
 646  in
 647   res @ locate_in_term what ~where:ty context
 648
 649 (* saturate_term newmeta metasenv context ty                                  *)
 650 (* Given a type [ty] (a backbone), it returns its head and a new metasenv in  *)
 651 (* which there is new a META for each hypothesis, a list of arguments for the *)
 652 (* new applications and the index of the last new META introduced. The nth    *)
 653 (* argument in the list of arguments is just the nth new META.                *)
 654 let saturate_term newmeta metasenv context ty =
 655  let module C = Cic in
 656  let module S = CicSubstitution in
 657   let rec aux newmeta ty =
 658    let ty' = ty in
 659    match ty' with
 660       C.Cast (he,_) -> aux newmeta he
 661 (* CSC: patch to generate ?1 : ?2 : Type in place of ?1 : Type to simulate ?1 :< Type
 662       (* If the expected type is a Type, then also Set is OK ==>
 663       *  we accept any term of type Type *)
 664       (*CSC: BUG HERE: in this way it is possible for the term of
 665       * type Type to be different from a Sort!!! *)
 666     | C.Prod (name,(C.Sort (C.Type _) as s),t) ->
 667        (* TASSI: ask CSC if BUG HERE refers to the C.Cast or C.Propd case *)
 668        let irl =
 669          CicMkImplicit.identity_relocation_list_for_metavariable context
 670        in
 671         let newargument = C.Meta (newmeta+1,irl) in
 672          let (res,newmetasenv,arguments,lastmeta) =
 673           aux (newmeta + 2) (S.subst newargument t)
 674          in
 675           res,
 676            (newmeta,[],s)::(newmeta+1,context,C.Meta (newmeta,[]))::newmetasenv,
 677            newargument::arguments,lastmeta
 678 *)
 679     | C.Prod (name,s,t) ->
 680        let irl =
 681          CicMkImplicit.identity_relocation_list_for_metavariable context
 682        in
 683         let newargument = C.Meta (newmeta,irl) in
 684          let (res,newmetasenv,arguments,lastmeta) =
 685           aux (newmeta + 1) (S.subst newargument t)
 686          in
 687          let s' = CicReduction.normalize ~delta:false context s in
 688           res,(newmeta,context,s')::newmetasenv,newargument::arguments,lastmeta
 689           (** NORMALIZE RATIONALE
 690            * we normalize the target only NOW since we may be in this case:
 691            * A1 -> A2 -> T where T = (\lambda x.A3 -> P) k
 692            * and we want a mesasenv with ?1:A1 and ?2:A2 and not
 693            * ?1, ?2, ?3 (that is the one we whould get if we start from the
 694            * beta-normalized A1 -> A2 -> A3 -> P **)
 695     | t -> (CicReduction.normalize ~delta:false context t),[],[],newmeta
 696   in
 697    (* WARNING: here we are using the invariant that above the most *)
 698    (* recente new_meta() there are no used metas.                  *)
 699    let (res,newmetasenv,arguments,lastmeta) = aux newmeta ty in
 700     res,metasenv @ newmetasenv,arguments,lastmeta
 701
 702 let lookup_type metasenv context hyp =
 703    let rec aux p = function
 704       | Some (Cic.Name name, Cic.Decl t) :: _ when name = hyp -> p, t
 705       | Some (Cic.Name name, Cic.Def (_, Some t)) :: _ when name = hyp -> p, t
 706       | Some (Cic.Name name, Cic.Def (u, _)) :: tail when name = hyp ->
 707          p, fst (CicTypeChecker.type_of_aux' metasenv tail u CicUniv.empty_ugraph)
 708       | _ :: tail -> aux (succ p) tail
 709       | [] -> raise (ProofEngineTypes.Fail "lookup_type: not premise in the current goal")
 710    in
 711    aux 1 context