helm/ocaml/tactics/variousTactics.ml

   1 (* Copyright (C) 2002, HELM Team.
   2  *
   3  * This file is part of HELM, an Hypertextual, Electronic
   4  * Library of Mathematics, developed at the Computer Science
   5  * Department, University of Bologna, Italy.
   6  *
   7  * HELM is free software; you can redistribute it and/or
   8  * modify it under the terms of the GNU General Public License
   9  * as published by the Free Software Foundation; either version 2
  10  * of the License, or (at your option) any later version.
  11  *
  12  * HELM is distributed in the hope that it will be useful,
  13  * but WITHOUT ANY WARRANTY; without even the implied warranty of
  14  * MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the
  15  * GNU General Public License for more details.
  16  *
  17  * You should have received a copy of the GNU General Public License
  18  * along with HELM; if not, write to the Free Software
  19  * Foundation, Inc., 59 Temple Place - Suite 330, Boston,
  20  * MA  02111-1307, USA.
  21  *
  22  * For details, see the HELM World-Wide-Web page,
  23  * http://cs.unibo.it/helm/.
  24  *)
  25
  26
  27 (* TODO se ce n'e' piu' di una, prende la prima che trova... sarebbe meglio
  28 chiedere: find dovrebbe restituire una lista di hyp (?) da passare all'utonto con una
  29 funzione di callback che restituisce la (sola) hyp da applicare *)
  30
  31 let assumption_tac =
  32  let module PET = ProofEngineTypes in
  33  let assumption_tac status =
  34   let (proof, goal) = status in
  35   let module C = Cic in
  36   let module R = CicReduction in
  37   let module S = CicSubstitution in
  38   let module PT = PrimitiveTactics in
  39   let _,metasenv,_,_ = proof in
  40   let _,context,ty = CicUtil.lookup_meta goal metasenv in
  41   let rec find n = function
  42       hd::tl ->
  43         (match hd with
  44              (Some (_, C.Decl t)) when
  45                fst (R.are_convertible context (S.lift n t) ty
  46                        CicUniv.empty_ugraph) -> n
  47            | (Some (_, C.Def (_,Some ty'))) when
  48                fst (R.are_convertible context (S.lift n ty') ty
  49                        CicUniv.empty_ugraph) -> n
  50            | (Some (_, C.Def (t,None))) ->
  51                let ty_t, u = (* TASSI: FIXME *)
  52                  CicTypeChecker.type_of_aux' metasenv context (S.lift n t)
  53                    CicUniv.empty_ugraph in
  54                let b,_ = R.are_convertible context ty_t ty u in
  55                  if b then n else find (n+1) tl
  56            | _ -> find (n+1) tl
  57          )
  58       | [] -> raise (PET.Fail "Assumption: No such assumption")
  59      in PET.apply_tactic (PT.apply_tac ~term:(C.Rel (find 1 context))) status
  60  in
  61   PET.mk_tactic assumption_tac
  62 ;;
  63
  64 (* ANCORA DA DEBUGGARE *)
  65
  66 exception UnableToDetectTheTermThatMustBeGeneralizedYouMustGiveItExplicitly;;
  67 exception TheSelectedTermsMustLiveInTheGoalContext
  68 exception AllSelectedTermsMustBeConvertible;;
  69 exception CannotGeneralizeInHypotheses;;
  70
  71 (* serve una funzione che cerchi nel ty dal basso a partire da term, i lambda
  72 e li aggiunga nel context, poi si conta la lunghezza di questo nuovo
  73 contesto e si lifta di tot... COSA SIGNIFICA TUTTO CIO'?????? *)
  74
  75 let generalize_tac
  76  ?(mk_fresh_name_callback = FreshNamesGenerator.mk_fresh_name ~subst:[])
  77  pattern
  78  =
  79   let module PET = ProofEngineTypes in
  80   let generalize_tac mk_fresh_name_callback
  81        ~pattern:(term,hyps_pat,concl_pat) status
  82   =
  83    if hyps_pat <> [] then raise CannotGeneralizeInHypotheses ;
  84    let (proof, goal) = status in
  85    let module C = Cic in
  86    let module P = PrimitiveTactics in
  87    let module T = Tacticals in
  88     let _,metasenv,_,_ = proof in
  89     let _,context,ty = CicUtil.lookup_meta goal metasenv in
  90     let terms_with_context =
  91      ProofEngineHelpers.select ~context ~term:ty ~pattern:(term,concl_pat) in
  92     let typ,term =
  93      match terms_with_context, term with
  94         [], None ->
  95          raise UnableToDetectTheTermThatMustBeGeneralizedYouMustGiveItExplicitly
  96       | _, Some term
  97       | (_,term)::_, None ->
  98          fst
  99           (CicTypeChecker.type_of_aux' metasenv context term
 100             CicUniv.empty_ugraph),
 101          term in
 102     (* We need to check:
 103         1. whether they live in the context of the goal;
 104            if they do they are also well-typed since they are closed subterms
 105            of a well-typed term in the well-typed context of the well-typed
 106            term
 107         2. whether they are convertible
 108     *)
 109     ignore (
 110      (* TASSI: FIXME *)
 111      List.fold_left
 112       (fun u (context_of_t,t) ->
 113         (* 1 *)
 114         begin
 115          try
 116           ignore
 117            (CicMetaSubst.delift_rels [] metasenv
 118              (List.length context_of_t - List.length context) t)
 119          with
 120           CicMetaSubst.DeliftingARelWouldCaptureAFreeVariable ->
 121            raise TheSelectedTermsMustLiveInTheGoalContext
 122         end;
 123         (* 2 *)
 124         let b,u1 = CicReduction.are_convertible context term t u in
 125          if not b then
 126           raise AllSelectedTermsMustBeConvertible
 127          else
 128           u1
 129       ) CicUniv.empty_ugraph terms_with_context) ;
 130     PET.apply_tactic
 131      (T.thens
 132        ~start:
 133          (P.cut_tac
 134           (C.Prod(
 135             (mk_fresh_name_callback metasenv context C.Anonymous ~typ:typ),
 136             typ,
 137             (ProofEngineReduction.replace_lifting_csc 1
 138               ~equality:(==)
 139               ~what:(List.map snd terms_with_context)
 140               ~with_what:(List.map (function _ -> C.Rel 1) terms_with_context)
 141               ~where:ty)
 142           )))
 143        ~continuations:
 144          [(P.apply_tac ~term:(C.Appl [C.Rel 1; CicSubstitution.lift 1 term])) ;
 145            T.id_tac])
 146        status
 147  in
 148   PET.mk_tactic (generalize_tac mk_fresh_name_callback ~pattern)
 149 ;;