helm/ocaml/tactics/variousTactics.ml

   1 (* Copyright (C) 2002, HELM Team.
   2  *
   3  * This file is part of HELM, an Hypertextual, Electronic
   4  * Library of Mathematics, developed at the Computer Science
   5  * Department, University of Bologna, Italy.
   6  *
   7  * HELM is free software; you can redistribute it and/or
   8  * modify it under the terms of the GNU General Public License
   9  * as published by the Free Software Foundation; either version 2
  10  * of the License, or (at your option) any later version.
  11  *
  12  * HELM is distributed in the hope that it will be useful,
  13  * but WITHOUT ANY WARRANTY; without even the implied warranty of
  14  * MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the
  15  * GNU General Public License for more details.
  16  *
  17  * You should have received a copy of the GNU General Public License
  18  * along with HELM; if not, write to the Free Software
  19  * Foundation, Inc., 59 Temple Place - Suite 330, Boston,
  20  * MA  02111-1307, USA.
  21  *
  22  * For details, see the HELM World-Wide-Web page,
  23  * http://cs.unibo.it/helm/.
  24  *)
  25
  26
  27 (* TODO se ce n'e' piu' di una, prende la prima che trova... sarebbe meglio
  28 chiedere: find dovrebbe restituire una lista di hyp (?) da passare all'utonto con una
  29 funzione di callback che restituisce la (sola) hyp da applicare *)
  30
  31 let assumption_tac =
  32  let module PET = ProofEngineTypes in
  33  let assumption_tac status =
  34   let (proof, goal) = status in
  35   let module C = Cic in
  36   let module R = CicReduction in
  37   let module S = CicSubstitution in
  38   let module PT = PrimitiveTactics in
  39   let _,metasenv,_,_ = proof in
  40   let _,context,ty = CicUtil.lookup_meta goal metasenv in
  41   let rec find n = function
  42       hd::tl ->
  43         (match hd with
  44              (Some (_, C.Decl t)) when
  45                fst (R.are_convertible context (S.lift n t) ty
  46                        CicUniv.empty_ugraph) -> n
  47            | (Some (_, C.Def (_,Some ty'))) when
  48                fst (R.are_convertible context (S.lift n ty') ty
  49                        CicUniv.empty_ugraph) -> n
  50            | (Some (_, C.Def (t,None))) ->
  51                let ty_t, u = (* TASSI: FIXME *)
  52                  CicTypeChecker.type_of_aux' metasenv context (S.lift n t)
  53                    CicUniv.empty_ugraph in
  54                let b,_ = R.are_convertible context ty_t ty u in
  55                  if b then n else find (n+1) tl
  56            | _ -> find (n+1) tl
  57          )
  58       | [] -> raise (PET.Fail "Assumption: No such assumption")
  59      in PET.apply_tactic (PT.apply_tac ~term:(C.Rel (find 1 context))) status
  60  in
  61   PET.mk_tactic assumption_tac
  62 ;;
  63
  64 (* ANCORA DA DEBUGGARE *)
  65
  66 exception UnableToDetectTheTermThatMustBeGeneralizedYouMustGiveItExplicitly;;
  67 exception TheSelectedTermsMustLiveInTheGoalContext
  68 exception AllSelectedTermsMustBeConvertible;;
  69 exception GeneralizationInHypothesesNotImplementedYet;;
  70
  71 let generalize_tac
  72  ?(mk_fresh_name_callback = FreshNamesGenerator.mk_fresh_name ~subst:[])
  73  pattern
  74  =
  75   let module PET = ProofEngineTypes in
  76   let generalize_tac mk_fresh_name_callback
  77        ~pattern:(term,hyps_pat,concl_pat) status
  78   =
  79    if hyps_pat <> [] then raise GeneralizationInHypothesesNotImplementedYet;
  80    let (proof, goal) = status in
  81    let module C = Cic in
  82    let module P = PrimitiveTactics in
  83    let module T = Tacticals in
  84     let uri,metasenv,pbo,pty = proof in
  85     let (_,context,ty) as conjecture = CicUtil.lookup_meta goal metasenv in
  86     let subst,metasenv,u,selected_hyps,terms_with_context =
  87      ProofEngineHelpers.select ~metasenv ~ugraph:CicUniv.empty_ugraph
  88       ~conjecture ~pattern in
  89     let context = CicMetaSubst.apply_subst_context subst context in
  90     let metasenv = CicMetaSubst.apply_subst_metasenv subst metasenv in
  91     let pbo = CicMetaSubst.apply_subst subst pbo in
  92     let pty = CicMetaSubst.apply_subst subst pty in
  93     let status = (uri,metasenv,pbo,pty),goal in
  94     let term =
  95      match term with
  96         None -> None
  97       | Some term -> Some (CicMetaSubst.apply_subst subst term) in
  98     let u,typ,term =
  99      match terms_with_context, term with
 100         [], None ->
 101          raise UnableToDetectTheTermThatMustBeGeneralizedYouMustGiveItExplicitly
 102       | _, Some term
 103       | (_,term)::_, None ->
 104          let typ,u =
 105           CicTypeChecker.type_of_aux' ~subst metasenv context term u
 106          in
 107           u,typ,term
 108     in
 109     (* We need to check:
 110         1. whether they live in the context of the goal;
 111            if they do they are also well-typed since they are closed subterms
 112            of a well-typed term in the well-typed context of the well-typed
 113            term
 114         2. whether they are convertible
 115     *)
 116     ignore (
 117      (* TASSI: FIXME *)
 118      List.fold_left
 119       (fun u (context_of_t,t) ->
 120         (* 1 *)
 121         begin
 122          try
 123           ignore
 124            (CicMetaSubst.delift_rels [] metasenv
 125              (List.length context_of_t - List.length context) t)
 126          with
 127           CicMetaSubst.DeliftingARelWouldCaptureAFreeVariable ->
 128            raise TheSelectedTermsMustLiveInTheGoalContext
 129         end;
 130         (* 2 *)
 131         let b,u1 = CicReduction.are_convertible ~subst context term t u in
 132          if not b then
 133           raise AllSelectedTermsMustBeConvertible
 134          else
 135           u1
 136       ) u terms_with_context) ;
 137     PET.apply_tactic
 138      (T.thens
 139        ~start:
 140          (P.cut_tac
 141           (C.Prod(
 142             (mk_fresh_name_callback metasenv context C.Anonymous ~typ:typ),
 143             typ,
 144             (ProofEngineReduction.replace_lifting_csc 1
 145               ~equality:(==)
 146               ~what:(List.map snd terms_with_context)
 147               ~with_what:(List.map (function _ -> C.Rel 1) terms_with_context)
 148               ~where:ty)
 149           )))
 150        ~continuations:
 151          [(P.apply_tac ~term:(C.Appl [C.Rel 1; CicSubstitution.lift 1 term])) ;
 152            T.id_tac])
 153        status
 154  in
 155   PET.mk_tactic (generalize_tac mk_fresh_name_callback ~pattern)
 156 ;;