helm/ocaml/utf8_macros/make_table.ml

   1 (* Copyright (C) 2004, HELM Team.
   2  *
   3  * This file is part of HELM, an Hypertextual, Electronic
   4  * Library of Mathematics, developed at the Computer Science
   5  * Department, University of Bologna, Italy.
   6  *
   7  * HELM is free software; you can redistribute it and/or
   8  * modify it under the terms of the GNU General Public License
   9  * as published by the Free Software Foundation; either version 2
  10  * of the License, or (at your option) any later version.
  11  *
  12  * HELM is distributed in the hope that it will be useful,
  13  * but WITHOUT ANY WARRANTY; without even the implied warranty of
  14  * MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the
  15  * GNU General Public License for more details.
  16  *
  17  * You should have received a copy of the GNU General Public License
  18  * along with HELM; if not, write to the Free Software
  19  * Foundation, Inc., 59 Temple Place - Suite 330, Boston,
  20  * MA  02111-1307, USA.
  21  *
  22  * For details, see the HELM World-Wide-Web page,
  23  * http://helm.cs.unibo.it/
  24  *)
  25
  26 open Printf
  27
  28 let debug = false
  29 let debug_print s = if debug then prerr_endline (Lazy.force s)
  30
  31   (* source files for tables xml parsing (if unmarshall=false) *)
  32 let xml_tables = [
  33 (*
  34   `Entities, "/usr/share/gtkmathview/entities-table.xml";
  35   `Dictionary, "/usr/share/editex/dictionary-tex.xml"
  36 *)
  37   `Entities, "data/entities-table.xml";
  38   `Dictionary, "data/dictionary-tex.xml";
  39   `Entities, "data/extra-entities.xml";
  40   (** extra-entities.xml should be the last one since it is used to override
  41    * previous mappings. Add there overrides as needed. *)
  42 ]
  43
  44 let iter_gen record_tag name_field value_field f fname =
  45   let start_element tag attrs =
  46     if tag = record_tag then
  47       try
  48         let name = List.assoc name_field attrs in
  49         let value = List.assoc value_field attrs in
  50         f name value
  51       with Not_found -> ()
  52   in
  53   let callbacks = {
  54     XmlPushParser.default_callbacks with
  55       XmlPushParser.start_element = Some start_element
  56   } in
  57   let xml_parser = XmlPushParser.create_parser callbacks in
  58   XmlPushParser.parse xml_parser (`File fname)
  59
  60 let iter_entities_file    = iter_gen "entity" "name" "value"
  61 let iter_dictionary_file  = iter_gen "entry" "name" "val"
  62
  63 let parse_from_xml () =
  64   let (macro2utf8, utf82macro) = (Hashtbl.create 2000, Hashtbl.create 2000) in
  65   let add_macro macro utf8 =
  66     debug_print (lazy (sprintf "Adding macro %s = '%s'" macro utf8));
  67     Hashtbl.replace macro2utf8 macro utf8;
  68     Hashtbl.replace utf82macro utf8 macro
  69   in
  70   let fill_table () =
  71     List.iter
  72       (fun (typ, fname) ->
  73         match typ with
  74         | `Entities -> iter_entities_file add_macro fname
  75         | `Dictionary -> iter_dictionary_file add_macro fname)
  76       xml_tables
  77   in
  78   fill_table ();
  79   macro2utf8, utf82macro
  80
  81 let main () =
  82   let oc = open_out Sys.argv.(1) in
  83   output_string oc "(* GENERATED by make_table: DO NOT EDIT! *)\n";
  84   output_string oc "let macro2utf8 = Hashtbl.create 2000\n";
  85   output_string oc "let utf82macro = Hashtbl.create 2000\n";
  86   let macro2utf8, utf82macro = parse_from_xml () in
  87   Hashtbl.iter
  88     (fun macro utf8 ->
  89       fprintf oc "let _ = Hashtbl.replace macro2utf8 \"%s\" \"%s\"\n"
  90         macro (String.escaped utf8))
  91     macro2utf8;
  92   Hashtbl.iter
  93     (fun utf8 macro ->
  94       fprintf oc "let _ = Hashtbl.replace utf82macro \"%s\" \"%s\"\n"
  95         (String.escaped utf8) macro)
  96     utf82macro;
  97   close_out oc
  98
  99 let _ = main ()
 100