helm/on-line/xslt/toplevel_header.xsl

   1 <?xml version="1.0"?>
   2 <xsl:stylesheet version="1.0"
   3   xmlns:xsl="http://www.w3.org/1999/XSL/Transform"
   4   xmlns:ht="http://www.cs.unibo.it/helm/namespaces/helm-theory"
   5   xmlns:helm="http://www.cs.unibo.it/helm"
   6   xmlns:html="http://www.w3.org/1999/xhtml">
   7
   8 <!-- add theory's breadcrumb trail -->
   9 <xsl:template name="breadcrumb_trail">
  10   <xsl:param name="path" select="''" />
  11   <xsl:param name="acc" select="''" />
  12   <xsl:choose>
  13     <xsl:when test="contains($path, '/')">
  14       <xsl:variable name="segment" select="substring-before($path,'/')" />
  15       <xsl:variable name="newacc" select="concat($acc, $segment, '/')" />
  16       <html:a style="text-decoration: none"
  17         href="{$newacc}" helm:helm_link="href">
  18         <xsl:value-of select="$segment" />
  19       </html:a>
  20       <xsl:text>/</xsl:text>
  21       <xsl:call-template name="breadcrumb_trail">
  22         <xsl:with-param name="path" select="substring-after($path,'/')" />
  23         <xsl:with-param name="acc" select="$newacc" />
  24       </xsl:call-template>
  25     </xsl:when>
  26     <xsl:otherwise>
  27       <xsl:value-of select="$path" />
  28     </xsl:otherwise>
  29   </xsl:choose>
  30 </xsl:template>
  31
  32 <xsl:template name="add_breadcrumb_trail">
  33   <xsl:param name="CICURI" select="''"/>
  34   <xsl:variable name="prefix" select="substring-before($CICURI, ':')" />
  35   <html:table width="100%"><xsl:text>
  36     </xsl:text>
  37     <html:tr><xsl:text>
  38       </xsl:text>
  39       <html:td><xsl:text>
  40         </xsl:text>
  41         <html:span
  42           style="font-family: sans-serif; font-weight: bold; font-size: 120%">
  43           <html:a style="text-decoration: none"
  44             href="{concat($prefix, ':/')}" helm:helm_link="href">
  45             <xsl:value-of select="concat($prefix, ':')" />
  46           </html:a>
  47           <xsl:text>/</xsl:text>
  48           <xsl:call-template name="breadcrumb_trail">
  49             <xsl:with-param name="path"
  50               select="substring($CICURI, string-length($prefix)+3)" />
  51             <xsl:with-param name="acc" select="concat($prefix, ':/')" />
  52           </xsl:call-template>
  53         </html:span><xsl:text>
  54       </xsl:text>
  55       </html:td><xsl:text>
  56       </xsl:text>
  57       <html:td style="text-align:right"><xsl:text>
  58         </xsl:text>
  59         <html:span style="font-family:sans-serif">
  60           [<html:a href="http://mowgli.cs.unibo.it:58085/getpage?url=index.html&amp;preprocess=true&amp;param.keys=d_c%2CC1%2CHC2%2CL&amp;param.thkeys=T1%2CT2%2CL%2CE&amp;param.embedkeys=d_c%2CTC1%2CHC2%2CL&amp;param.doctype-public=-//W3C//DTD%20XHTML%201.0%20Transitional//EN&amp;param.encoding=iso-8859-1&amp;param.thencoding=iso-8859-1&amp;param.media-type=text/html&amp;param.thmedia-type=text/html&amp;param.CICURI=dummy:query_result&amp;param.naturalLanguage=yes&amp;param.annotations=no&amp;param.processorURL=http://mowgli.cs.unibo.it:58080/" target="_top">search</html:a>]
  61         </html:span><xsl:text>
  62       </xsl:text>
  63       </html:td><xsl:text>
  64     </xsl:text>
  65     </html:tr>
  66   </html:table><xsl:text>
  67   </xsl:text>
  68   <html:hr />
  69 </xsl:template>
  70
  71 </xsl:stylesheet>