helm/searchEngine/searchEngine.ml

   1 (* Copyright (C) 2002-2005, HELM Team.
   2  *
   3  * This file is part of HELM, an Hypertextual, Electronic
   4  * Library of Mathematics, developed at the Computer Science
   5  * Department, University of Bologna, Italy.
   6  *
   7  * HELM is free software; you can redistribute it and/or
   8  * modify it under the terms of the GNU General Public License
   9  * as published by the Free Software Foundation; either version 2
  10  * of the License, or (at your option) any later version.
  11  *
  12  * HELM is distributed in the hope that it will be useful,
  13  * but WITHOUT ANY WARRANTY; without even the implied warranty of
  14  * MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the
  15  * GNU General Public License for more details.
  16  *
  17  * You should have received a copy of the GNU General Public License
  18  * along with HELM; if not, write to the Free Software
  19  * Foundation, Inc., 59 Temple Place - Suite 330, Boston,
  20  * MA  02111-1307, USA.
  21  *
  22  * For details, see the HELM World-Wide-Web page,
  23  * http://cs.unibo.it/helm/.
  24  *)
  25
  26 open Printf
  27
  28 let debug = true
  29 let debug_print s = if debug then prerr_endline s
  30 let _ = Http_common.debug := false
  31
  32 exception Chat_unfinished
  33 exception Unbound_identifier of string
  34 exception Invalid_action of string  (* invalid action for "/search" method *)
  35
  36   (** raised by elim when a MutInd is required but not found *)
  37 exception Not_a_MutInd
  38
  39 let daemon_name = "Whelp"
  40 let configuration_file = "/projects/helm/etc/whelp.conf.xml"
  41
  42 let placeholders = [
  43   "ACTION"; "ADVANCED"; "ADVANCED_CHECKED"; "CHOICES"; "CURRENT_CHOICES";
  44   "EXPRESSION"; "ID"; "IDEN"; "ID_TO_URIS"; "INTERPRETATIONS";
  45   "INTERPRETATIONS_LABELS"; "MSG"; "NEW_ALIASES"; "NEXT_LINK"; "NO_CHOICES";
  46   "PAGE"; "PAGES"; "PREV_LINK"; "QUERY_KIND"; "QUERY_SUMMARY"; "RESULTS";
  47   "SEARCH_ENGINE_URL"; "SIMPLE_CHECKED"; "TITLE";
  48 ]
  49
  50 let tag =
  51   let regexps = Hashtbl.create 25 in
  52   List.iter
  53     (fun tag -> Hashtbl.add regexps tag (Pcre.regexp (sprintf "@%s@" tag)))
  54     placeholders;
  55   fun name ->
  56     try
  57       Hashtbl.find regexps name
  58     with Not_found -> assert false
  59
  60   (* First of all we load the configuration *)
  61 let _ = Helm_registry.load_from configuration_file
  62 let port = Helm_registry.get_int "search_engine.port"
  63 let pages_dir = Helm_registry.get "search_engine.html_dir"
  64
  65 let moogle_TPL = pages_dir ^ "/moogle.html"
  66 let choices_TPL = pages_dir ^ "/moogle_chat.html"
  67
  68 let my_own_url =
  69  let ic = Unix.open_process_in "hostname -f" in
  70  let hostname = input_line ic in
  71  ignore (Unix.close_process_in ic);
  72  sprintf "http://%s:%d" hostname port
  73 let _ = Helm_registry.set "search_engine.my_own_url" my_own_url
  74
  75 let bad_request body outchan =
  76   Http_daemon.respond_error ~code:(`Status (`Client_error `Bad_request)) ~body
  77     outchan
  78
  79   (** chain application of Pcre substitutions *)
  80 let rec apply_substs substs line =
  81   match substs with
  82   | [] -> line
  83   | (rex, templ) :: rest -> apply_substs rest (Pcre.replace ~rex ~templ line)
  84   (** fold like function on files *)
  85 let fold_file f init fname =
  86   let inchan = open_in fname in
  87   let rec fold_lines' value =
  88     try
  89       let line = input_line inchan in
  90       fold_lines' (f value line)
  91     with End_of_file -> value
  92   in
  93   let res = (try fold_lines' init with e -> (close_in inchan; raise e)) in
  94   close_in inchan;
  95   res
  96   (** iter like function on files *)
  97 let iter_file f = fold_file (fun _ line -> f line) ()
  98 let javascript_quote s =
  99  let rex = Pcre.regexp "'" in
 100  let rex' = Pcre.regexp "\"" in
 101   Pcre.replace ~rex ~templ:"\\'"
 102    (Pcre.replace ~rex:rex' ~templ:"\\\"" s)
 103 let string_tail s =
 104   let len = String.length s in
 105   String.sub s 1 (len-1)
 106 let nonvar s =
 107   let len = String.length s in
 108   let suffix = String.sub s (len-4) 4 in
 109   not (suffix  = ".var")
 110
 111 let add_param_substs params =
 112   List.map
 113     (fun (key,value) ->
 114       let key' = (Pcre.extract ~pat:"param\\.(.*)" key).(1) in
 115       Pcre.regexp ("@" ^ key' ^ "@"), value)
 116     (List.filter
 117       (fun ((key,_) as p) -> Pcre.pmatch ~pat:"^param\\." key)
 118       params)
 119
 120 let page_RE = Pcre.regexp "&param\\.page=\\d+"
 121 let identifier_RE = Pcre.regexp "^\\s*\\w+\\s*$"
 122
 123 let query_kind_of_req (req: Http_types.request) =
 124   match req#path with
 125   | "/match" -> "Match"
 126   | "/hint" -> "Hint"
 127   | "/locate" -> "Locate"
 128   | "/elim" -> "Elim"
 129   | _ -> ""
 130
 131   (* given a uri with a query part in input try to find in it a string
 132    * "&param_name=..." (where param_name is given). If found its value will be
 133    * set to param_value. If not, a trailing "&param_name=param_value" (where
 134    * both are given) is added to the input string *)
 135 let patch_param param_name param_value url =
 136   let rex = Pcre.regexp (sprintf "&%s=[^&]*" (Pcre.quote param_name)) in
 137   if Pcre.pmatch ~rex url then
 138     Pcre.replace ~rex ~templ:(sprintf "%s=%s" param_name param_value) url
 139   else
 140     sprintf "%s&%s=%s" url param_name param_value
 141
 142   (** HTML encoding, e.g.: "<" -> "&lt;" *)
 143 let html_encode = Netencoding.Html.encode_from_latin1
 144
 145 let send_results results
 146   ?(id_to_uris = CicTextualParser2.EnvironmentP3.of_string "")
 147    (req: Http_types.request) outchan
 148   =
 149   let query_kind = query_kind_of_req req in
 150   let interp = try req#param "interp" with Http_types.Param_not_found _ -> "" in
 151   let page_link anchor page =
 152     try
 153       let this = req#param "this" in
 154       let target =
 155         (patch_param "param.interp" interp
 156            (patch_param "param.page" (string_of_int page)
 157               this))
 158       in
 159       let target = Pcre.replace ~pat:"&" ~templ:"&amp;" target in
 160       sprintf "<a href=\"%s\">%s</a>" target anchor
 161     with Http_types.Param_not_found _ -> ""
 162   in
 163   Http_daemon.send_basic_headers ~code:(`Code 200) outchan ;
 164   Http_daemon.send_header "Content-Type" "text/xml" outchan;
 165   Http_daemon.send_CRLF outchan ;
 166   let subst =
 167     match results with
 168     | `Results results ->
 169         let page = try int_of_string (req#param "page") with _ -> 1 in
 170         let results_no = List.length results in
 171         let results_per_page =
 172           Helm_registry.get_int "search_engine.results_per_page"
 173         in
 174         let pages =
 175           if results_no mod results_per_page = 0 then
 176             results_no / results_per_page
 177           else
 178             results_no / results_per_page + 1
 179         in
 180         let pages = if pages = 0 then 1 else pages in
 181         let (summary, results) = MooglePp.theory_of_result page results in
 182         [ tag "PAGE", string_of_int page;
 183           tag "PAGES", string_of_int pages;
 184           tag "PREV_LINK", (if page > 1 then page_link "Prev" (page-1) else "");
 185           tag "NEXT_LINK",
 186             (if page < pages then page_link "Next" (page+1) else "");
 187           tag "QUERY_KIND", query_kind;
 188           tag "QUERY_SUMMARY", summary;
 189           tag "RESULTS", results ]
 190     | `Error msg ->
 191         [ tag "PAGE", "1";
 192           tag "PAGES", "1";
 193           tag "PREV_LINK", "";
 194           tag "NEXT_LINK", "";
 195           tag "QUERY_KIND", query_kind;
 196           tag "QUERY_SUMMARY", "error";
 197           tag "RESULTS", msg ]
 198   in
 199   let advanced =
 200     try
 201       req#param "advanced"
 202     with Http_types.Param_not_found _ -> "no"
 203   in
 204   let subst =
 205     (tag "SEARCH_ENGINE_URL", my_own_url) ::
 206     (tag "ADVANCED", advanced) ::
 207     (tag "EXPRESSION", html_encode (req#param "expression")) ::
 208     add_param_substs req#params @
 209     (if advanced = "no" then
 210       [ tag "SIMPLE_CHECKED", "checked='true'";
 211         tag "ADVANCED_CHECKED", "" ]
 212     else
 213       [ tag "SIMPLE_CHECKED", "";
 214         tag "ADVANCED_CHECKED", "checked='true'" ]) @
 215     subst
 216   in
 217   iter_file
 218     (fun line ->
 219       let new_aliases =
 220         CicTextualParser2.EnvironmentP3.to_string id_to_uris
 221       in
 222       let processed_line =
 223         apply_substs
 224           (* CSC: Bug here: this is a string, not an array! *)
 225           ((tag "NEW_ALIASES", "'" ^ javascript_quote new_aliases ^ "'") ::
 226             subst)
 227           line
 228       in
 229       output_string outchan (processed_line ^ "\n"))
 230     moogle_TPL
 231
 232 let exec_action dbd (req: Http_types.request) outchan =
 233   let term_str = req#param "expression" in
 234   try
 235     if req#path = "/elim" && not (Pcre.pmatch ~rex:identifier_RE term_str) then
 236       raise Not_a_MutInd;
 237     let (context, metasenv) = ([], []) in
 238     let id_to_uris_raw =
 239       try req#param "aliases"
 240       with Http_types.Param_not_found _ -> ""
 241     in
 242     let parse_interpretation_choices choices =
 243       List.map int_of_string (Pcre.split ~pat:" " choices) in
 244     let parse_choices choices_raw =
 245       let choices = Pcre.split ~pat:";" choices_raw in
 246       List.fold_left
 247         (fun f x ->
 248            match Pcre.split ~pat:"\\s" x with
 249              | ""::id::tail
 250              | id::tail when id<>"" ->
 251                  (fun id' ->
 252                     if id = id' then
 253                       Some (List.map (fun u -> Netencoding.Url.decode u) tail)
 254                     else
 255                       f id')
 256              | _ -> failwith "Can't parse choices")
 257         (fun _ -> None)
 258         choices
 259     in
 260     let id_to_uris = CicTextualParser2.EnvironmentP3.of_string id_to_uris_raw in
 261     let id_to_choices =
 262       try
 263         parse_choices (req#param "choices")
 264       with Http_types.Param_not_found _ -> (fun _ -> None)
 265     in
 266     let interpretation_choices =
 267       try
 268         let choices_raw = req#param "interpretation_choices" in
 269         if choices_raw = "" then None
 270         else Some (parse_interpretation_choices choices_raw)
 271       with Http_types.Param_not_found _ -> None
 272     in
 273     let module Chat: DisambiguateTypes.Callbacks =
 274       struct
 275         let interactive_user_uri_choice ~selection_mode ?ok
 276           ?enable_button_for_non_vars ~(title: string) ~(msg: string)
 277           ~(id: string) (choices: string list)
 278         =
 279           match id_to_choices id with
 280           | Some choices -> choices
 281           | None -> List.filter nonvar choices
 282
 283         let interactive_interpretation_choice interpretations =
 284           match interpretation_choices with
 285           | Some l -> l
 286           | None ->
 287               let html_interpretations =
 288                 MooglePp.html_of_interpretations interpretations
 289               in
 290               Http_daemon.send_basic_headers ~code:(`Code 200) outchan ;
 291               Http_daemon.send_CRLF outchan ;
 292               let advanced =
 293                 try
 294                   req#param "advanced"
 295                 with Http_types.Param_not_found _ -> "no"
 296               in
 297               let query_kind = query_kind_of_req req in
 298               iter_file
 299                 (fun line ->
 300                    let processed_line =
 301                      apply_substs
 302                        [ tag "SEARCH_ENGINE_URL", my_own_url;
 303                          tag "ADVANCED", advanced;
 304                          tag "INTERPRETATIONS", html_interpretations;
 305                          tag "CURRENT_CHOICES", req#param "choices";
 306                          tag "EXPRESSION", html_encode (req#param "expression");
 307                          tag "QUERY_KIND", query_kind;
 308                          tag "QUERY_SUMMARY", "disambiguation";
 309                          tag "ACTION", string_tail req#path ]
 310                        line
 311                    in
 312                    output_string outchan (processed_line ^ "\n"))
 313                 choices_TPL;
 314               raise Chat_unfinished
 315
 316         let input_or_locate_uri ~title ?id () =
 317           match id with
 318           | Some id -> raise (Unbound_identifier id)
 319           | None -> assert false
 320       end
 321     in
 322     let module Disambiguate' = Disambiguate.Make(Chat) in
 323     let ast = CicTextualParser2.parse_term (Stream.of_string term_str) in
 324     let (id_to_uris, metasenv, term) =
 325       match
 326         Disambiguate'.disambiguate_term ~dbd ~context ~metasenv
 327           ~aliases:id_to_uris ast
 328       with
 329       | [id_to_uris,metasenv,term,_] -> id_to_uris,metasenv,term
 330       | _ -> assert false
 331     in
 332     let uris =
 333       match req#path with
 334       | "/match" -> MetadataQuery.match_term ~dbd term
 335       | "/hint" ->
 336           let status = ProofEngineTypes.initial_status term metasenv in
 337           let intros = PrimitiveTactics.intros_tac () in
 338           let subgoals = ProofEngineTypes.apply_tactic intros status in
 339           (match subgoals with
 340           | proof, [goal] ->
 341               let (uri,metasenv,bo,ty) = proof in
 342               List.map fst (MetadataQuery.experimental_hint ~dbd (proof, goal))
 343           | _ -> assert false)
 344       | "/elim" ->
 345           let uri =
 346             match term with
 347             | Cic.MutInd (uri, typeno, _) ->
 348                 UriManager.string_of_uriref (uri, [typeno])
 349             | _ -> raise Not_a_MutInd
 350           in
 351           MetadataQuery.elim ~dbd uri
 352       | _ -> assert false
 353     in
 354     send_results ~id_to_uris (`Results uris) req outchan
 355   with
 356   | Not_a_MutInd ->
 357       send_results (`Error (MooglePp.pp_error "Not an inductive type"
 358         ("elim requires as input an identifier corresponding to an inductive"
 359          ^ " type")))
 360         req outchan
 361
 362 let callback dbd (req: Http_types.request) outchan =
 363   try
 364     debug_print (sprintf "Received request: %s" req#path);
 365     (match req#path with
 366     | "/getpage" ->
 367           (* TODO implement "is_permitted" *)
 368         (let is_permitted page = not (Pcre.pmatch ~pat:"/" page) in
 369         let page = req#param "url" in
 370         let fname = sprintf "%s/%s" pages_dir page in
 371         let preprocess =
 372           (try
 373             bool_of_string (req#param "preprocess")
 374           with Invalid_argument _ | Http_types.Param_not_found _ -> false)
 375         in
 376         (match page with
 377         | page when is_permitted page && Sys.file_exists fname ->
 378             Http_daemon.send_basic_headers ~code:(`Code 200) outchan;
 379             Http_daemon.send_header "Content-Type" "text/html" outchan;
 380             Http_daemon.send_CRLF outchan;
 381             if preprocess then begin
 382               iter_file
 383                 (fun line ->
 384                   output_string outchan
 385                     ((apply_substs
 386                        ((tag "SEARCH_ENGINE_URL", my_own_url) ::
 387                         (tag "ADVANCED", "no") ::
 388                         (tag "RESULTS", "") ::
 389                         add_param_substs req#params)
 390                        line) ^
 391                     "\n"))
 392                 fname
 393             end else
 394               Http_daemon.send_file ~src:(Http_types.FileSrc fname) outchan
 395         | page -> Http_daemon.respond_forbidden ~url:page outchan))
 396     | "/help" -> Http_daemon.respond ~body:daemon_name outchan
 397     | "/locate" ->
 398         let initial_expression =
 399           try req#param "expression" with Http_types.Param_not_found _ -> ""
 400         in
 401         let expression =
 402           Pcre.replace ~pat:"\\s*$"
 403             (Pcre.replace ~pat:"^\\s*" initial_expression)
 404         in
 405         if expression = "" then
 406           send_results (`Results []) req outchan
 407         else begin
 408           let results = MetadataQuery.locate ~dbd expression in
 409           send_results (`Results results) req outchan
 410         end
 411     | "/hint"
 412     | "/elim"
 413     | "/match" -> exec_action dbd req outchan
 414     | invalid_request ->
 415         Http_daemon.respond_error ~code:(`Status (`Client_error `Bad_request))
 416           outchan);
 417     debug_print (sprintf "%s done!" req#path)
 418   with
 419   | Chat_unfinished -> ()
 420   | Http_types.Param_not_found attr_name ->
 421       bad_request (sprintf "Parameter '%s' is missing" attr_name) outchan
 422   | CicTextualParser2.Parse_error (_, msg) ->
 423       send_results (`Error (MooglePp.pp_error "Parse error" msg)) req outchan
 424   | Unbound_identifier id ->
 425       send_results (`Error (MooglePp.pp_error "Unbound identifier" id)) req
 426         outchan
 427   | exn ->
 428       let exn_string = Printexc.to_string exn in
 429       debug_print exn_string;
 430       let msg = MooglePp.pp_error "Uncaught exception" exn_string in
 431       send_results (`Error msg) req outchan
 432
 433 let restore_environment () =
 434   match
 435     Helm_registry.get_opt Helm_registry.get "search_engine.environment_dump"
 436   with
 437   | None -> ()
 438   | Some fname ->
 439       printf "Restoring Cic environment from %s ... " fname; flush stdout;
 440       let ic = open_in fname in
 441       CicEnvironment.restore_from_channel ic;
 442       close_in ic;
 443       printf "done!\n"; flush stdout
 444
 445 let _ =
 446   printf "%s started and listening on port %d\n" daemon_name port;
 447   printf "Current directory is %s\n" (Sys.getcwd ());
 448   printf "HTML directory is %s\n" pages_dir;
 449   flush stdout;
 450   Unix.putenv "http_proxy" "";
 451   let dbd =
 452     Mysql.quick_connect
 453       ~host:(Helm_registry.get "db.host")
 454       ~database:(Helm_registry.get "db.database")
 455       ~user:(Helm_registry.get "db.user")
 456       ()
 457   in
 458   restore_environment ();
 459   Http_daemon.start' ~port (callback dbd);
 460   printf "%s is terminating, bye!\n" daemon_name
 461