helm/software/components/binaries/matitaprover/matitaprover.ml

   1 (*
   2     ||M||  This file is part of HELM, an Hypertextual, Electronic
   3     ||A||  Library of Mathematics, developed at the Computer Science
   4     ||T||  Department, University of Bologna, Italy.
   5     ||I||
   6     ||T||  HELM is free software; you can redistribute it and/or
   7     ||A||  modify it under the terms of the GNU General Public License
   8     \   /  version 2 or (at your option) any later version.
   9      \ /   This software is distributed as is, NO WARRANTY.
  10       V_______________________________________________________________ *)
  11
  12 (* $Id: orderings.ml 9869 2009-06-11 22:52:38Z denes $ *)
  13
  14 module OT = struct type t = string  let compare = Pervasives.compare end
  15 module HC = Map.Make(OT)
  16
  17 type leaf = int * string
  18
  19 let cache = ref HC.empty
  20 let num = ref 100
  21
  22 let hash s =
  23   try HC.find s !cache
  24   with Not_found ->
  25           cache := HC.add s (!num,s) !cache;
  26           decr num;
  27           HC.find s !cache
  28 ;;
  29
  30 hash "==";;
  31 hash "_";;
  32
  33 let problem_file = ref "no-file-given";;
  34 let tptppath = ref "/";;
  35 let seconds = ref 300;;
  36
  37 let fail_msg () =
  38       print_endline ("% SZS status Timeout for " ^
  39         Filename.basename !problem_file)
  40 ;;
  41
  42 module type LeafComparer =
  43   sig
  44     val cmp : leaf -> leaf -> int
  45   end
  46 ;;
  47
  48 module MakeBlob(C:LeafComparer) : Terms.Blob
  49   with type t = leaf and type input = Ast.term = struct
  50         type t = leaf
  51         let eq a b = a == b
  52         let compare a b = C.cmp a b
  53         let eqP = hash "=="
  54         let pp (_,a) =  a
  55         type input = Ast.term
  56         let rec embed m = function
  57             | Ast.Variable name ->
  58                 (try m, List.assoc name m
  59                  with Not_found ->
  60                     let t = Terms.Var ~-(List.length m) in
  61                     (name,t)::m, t)
  62             | Ast.Constant name -> m, Terms.Leaf (hash name)
  63             | Ast.Function (name,args) ->
  64                 let m, args =
  65                   HExtlib.list_mapi_acc
  66                     (fun x _ m -> embed m x) m args
  67                 in
  68                 m, Terms.Node (Terms.Leaf (hash name):: args)
  69         ;;
  70         let saturate bo ty =
  71           let vars, ty = embed [] ty in
  72           let _, bo = embed vars bo in
  73           let bo = Terms.Node (bo :: List.map snd (List.rev vars)) in
  74           bo, ty
  75         ;;
  76         let embed t = snd(embed [] t);;
  77
  78   end
  79 ;;
  80
  81 let success_msg bag l (pp : ?margin:int -> leaf Terms.unit_clause -> string) ord =
  82   (* TODO: do some sort of poor man lock (open + OEXCL) so that
  83    *       just one thread at a time prints the proof *)
  84   print_endline ("% SZS status Unsatisfiable for " ^
  85     Filename.basename !problem_file);
  86   print_endline ("% SZS output start CNFRefutation for " ^
  87     Filename.basename !problem_file);
  88   flush stdout;
  89   List.iter (fun x ->
  90     let (cl,_,_) = Terms.get_from_bag x bag in
  91     print_endline (pp ~margin:max_int
  92       cl)) l;
  93   print_endline ("% SZS output end CNFRefutation for " ^
  94     Filename.basename !problem_file);
  95   let prefix = string_of_int (Unix.getpid ()) in
  96   let prerr_endline s = prerr_endline (prefix ^ ": " ^ s) in
  97   let times = Unix.times () in
  98   prerr_endline ("solved " ^ !problem_file ^ " in " ^ string_of_float
  99     (times.Unix.tms_utime +. times.Unix.tms_stime) ^ " using " ^ ord);
 100 ;;
 101
 102 let start_msg stats passives g_passives (pp : ?margin:int -> leaf Terms.unit_clause -> string) oname =
 103   let prefix = string_of_int (Unix.getpid ()) in
 104   let prerr_endline s = prerr_endline (prefix ^ ": " ^ s) in
 105   prerr_endline "Facts:";
 106   List.iter (fun x -> prerr_endline (" " ^ pp x)) passives;
 107   prerr_endline "Goal:";
 108   prerr_endline (" " ^ pp g_passives);
 109   prerr_endline "Order:";
 110   prerr_endline ("  " ^ oname);
 111   prerr_endline "Leaf order:";
 112   List.iter (fun ((_,name), (a,b,c,gp,l)) ->
 113      prerr_endline (" " ^name ^ " " ^ string_of_int a ^ " " ^
 114        string_of_int b ^ " " ^
 115        string_of_int c ^ " " ^
 116        String.concat "," (List.map string_of_int gp) ^
 117        String.concat "," (List.map snd l))) stats;
 118 ;;
 119
 120 let report_error s =  prerr_endline (string_of_int (Unix.getpid())^": "^s);;
 121
 122 module Main(P : Paramod.Paramod with type t = leaf) = struct
 123
 124  let run stats goal hypotheses pp_unit_clause name =
 125    let bag = Terms.empty_bag, 0 in
 126    let bag, g_passives = P.mk_goal bag goal in
 127    let bag, passives =
 128      HExtlib.list_mapi_acc (fun x _ b -> P.mk_passive b x) bag hypotheses
 129    in
 130    start_msg stats passives g_passives pp_unit_clause name;
 131    match
 132      P.paramod
 133       ~max_steps:max_int bag ~g_passives:[g_passives] ~passives
 134    with
 135    | P.Error s -> report_error s; 3
 136    | P.Unsatisfiable ((bag,_,l)::_) ->
 137          success_msg bag l pp_unit_clause name; 0
 138    | P.Unsatisfiable ([]) ->
 139          report_error "Unsatisfiable but no solution output"; 3
 140    | P.GaveUp -> 2
 141    | P.Timeout _ -> 1
 142  ;;
 143 end
 144
 145  let compute_stats goal hypotheses =
 146    let module C =
 147      struct type t = leaf let cmp (a,_) (b,_) = Pervasives.compare a b end
 148    in
 149    let module B = MakeBlob(C) in
 150    let module Pp = Pp.Pp(B) in
 151    let module O = Orderings.NRKBO(B) in
 152    let module P = Paramod.Paramod(O) in
 153    let module Stats = Stats.Stats(O) in
 154    let bag = Terms.empty_bag, 0 in
 155    let bag, g_passives = P.mk_goal bag goal in
 156    let bag, passives =
 157      HExtlib.list_mapi_acc (fun x _ b -> P.mk_passive b x) bag hypotheses
 158    in
 159    let data = Stats.parse_symbols passives g_passives in
 160    let data =
 161      List.map
 162        (fun (name, n_occ, arity, n_gocc, g_pos) ->
 163           name, (n_occ, arity, n_gocc, g_pos, Stats.dependencies name passives))
 164        data
 165    in
 166    List.sort
 167      (fun (n1,(o1,a1,go1,p1,d1)) (n2,(o2,a2,go2,p2,d2)) ->
 168         Pervasives.compare
 169           (a1,o1,go1,p1,d1) (a2,o2,go2,p2,d2))
 170      data
 171  ;;
 172
 173 let worker order goal hypotheses =
 174    let stats = compute_stats goal hypotheses in
 175    let module C =
 176      struct
 177       let cmp =
 178         let raw = List.map snd stats in
 179         let rec pos x = function
 180           | ((y,_)::tl) when y = x -> 0
 181           | _::tl -> 1 + pos x tl
 182           | [] -> assert false
 183         in
 184         if List.length raw =
 185            List.length (HExtlib.list_uniq raw)
 186         then
 187           (prerr_endline "NO CLASH, using fixed ground order";
 188            fun a b ->
 189             Pervasives.compare
 190               (pos a stats)
 191               (pos b stats))
 192         else
 193           (prerr_endline "CLASH, statistics insufficient";
 194             fun (a,_) (b,_) -> Pervasives.compare a b)
 195       ;;
 196      end
 197    in
 198    let module B = MakeBlob(C) in
 199    let module Pp = Pp.Pp(B) in
 200    match order with
 201    | `NRKBO ->
 202        let module O = Orderings.NRKBO(B) in
 203        let module Main = Main(Paramod.Paramod(O)) in
 204        Main.run stats goal hypotheses Pp.pp_unit_clause O.name
 205    | `KBO ->
 206        let module O = Orderings.KBO(B) in
 207        let module Main = Main(Paramod.Paramod(O)) in
 208        Main.run stats goal hypotheses Pp.pp_unit_clause O.name
 209    | `LPO ->
 210        let module O = Orderings.LPO(B) in
 211        let module Main = Main(Paramod.Paramod(O)) in
 212        Main.run stats goal hypotheses Pp.pp_unit_clause O.name
 213 ;;
 214
 215 let print_status p =
 216   let print_endline s = prerr_endline (string_of_int p ^ ": " ^ s) in
 217     function
 218     | Unix.WEXITED 0 ->
 219         print_endline ("status Unsatisfiable for " ^
 220           Filename.basename !problem_file);
 221     | Unix.WEXITED 1 ->
 222         print_endline ("status Timeout for " ^
 223           Filename.basename !problem_file);
 224     | Unix.WEXITED 2 ->
 225         print_endline ("status GaveUp for " ^
 226           Filename.basename !problem_file);
 227     | Unix.WEXITED 3 ->
 228         print_endline ("status Error for " ^
 229           Filename.basename !problem_file);
 230     | Unix.WEXITED _ -> assert false
 231     | Unix.WSIGNALED s -> print_endline ("killed by signal " ^ string_of_int s)
 232     | Unix.WSTOPPED _ -> print_endline "stopped"
 233  ;;
 234
 235 let killall l =
 236   List.iter (fun pid -> try Unix.kill pid 9 with _ -> ()) l
 237 ;;
 238
 239 let main () =
 240   let childs = ref [] in
 241   let _ =
 242     Sys.signal 24 (Sys.Signal_handle
 243       (fun _ -> fail_msg (); killall !childs; exit 1))
 244   in
 245   let _ =
 246     Sys.signal Sys.sigalrm
 247       (Sys.Signal_handle (fun _ -> fail_msg (); killall !childs; exit 1))
 248   in
 249   Arg.parse [
 250    "--tptppath", Arg.String (fun p -> tptppath := p),
 251      ("[path]  TPTP lib root, default " ^ !tptppath);
 252    "--timeout", Arg.Int (fun p -> seconds := p),
 253      ("[seconds]  timeout, default " ^ string_of_int !seconds);
 254    ] (fun x -> problem_file := x) "
 255 Matitaprover is the first order automatic prover that equips the
 256 Matita interactive theorem prover (http://matita.cs.unibo.it).
 257
 258 Developed by A.Asperti, M.Denes and E.Tassi, released under GPL version 2
 259 or at your option any later version.
 260
 261 If --tptppath is given, instead of the problem file you can just give the
 262 problem name with the .p suffix (e.g. BOO001-1.p)
 263
 264 If --tptppath is not given, included files (i.e. axiom sets) are searched
 265 in the current directory only.
 266
 267 usage: matitaprover [options] problemfile";
 268   let hypotheses, goals = Tptp_cnf.parse ~tptppath:!tptppath !problem_file in
 269   let goal = match goals with [x] -> x | _ -> assert false in
 270   let _ = Unix.alarm !seconds in
 271   childs :=
 272     List.map
 273       (fun f ->
 274          let pid = Unix.fork () in
 275          if pid = 0 then (exit (f ())) else pid)
 276     [
 277       (fun () -> worker `NRKBO goal hypotheses)
 278     ;
 279       (fun () -> worker `KBO goal hypotheses)
 280     ;
 281       (fun () -> worker `LPO goal hypotheses)
 282     ];
 283   let rec aux () =
 284     if List.length !childs = 0 then
 285       (fail_msg (); exit 1)
 286     else
 287      match Unix.wait () with
 288      | p, (Unix.WEXITED 0 as s) ->
 289          print_status p s;
 290          killall !childs; exit 0;
 291      | p, s ->
 292          print_status p s;
 293          childs := List.filter ((<>)p) !childs; aux ()
 294   in
 295    aux ()
 296 ;;
 297
 298 main ()