helm/software/components/binaries/matitaprover/matitaprover.ml

   1 (*
   2     ||M||  This file is part of HELM, an Hypertextual, Electronic
   3     ||A||  Library of Mathematics, developed at the Computer Science
   4     ||T||  Department, University of Bologna, Italy.
   5     ||I||
   6     ||T||  HELM is free software; you can redistribute it and/or
   7     ||A||  modify it under the terms of the GNU General Public License
   8     \   /  version 2 or (at your option) any later version.
   9      \ /   This software is distributed as is, NO WARRANTY.
  10       V_______________________________________________________________ *)
  11
  12 (* $Id: orderings.ml 9869 2009-06-11 22:52:38Z denes $ *)
  13
  14 module OT = struct type t = string  let compare = Pervasives.compare end
  15 module HC = Map.Make(OT)
  16
  17 type leaf = int * string
  18
  19 let cache = ref HC.empty
  20 let num = ref 100
  21
  22 let hash s =
  23   try HC.find s !cache
  24   with Not_found ->
  25           cache := HC.add s (!num,s) !cache;
  26           decr num;
  27           HC.find s !cache
  28 ;;
  29
  30 hash "==";;
  31 hash "_";;
  32
  33 let problem_file = ref "no-file-given";;
  34 let tptppath = ref "/";;
  35 let seconds = ref 300;;
  36
  37 let fail_msg () =
  38       print_endline ("% SZS status Timeout for " ^
  39         Filename.basename !problem_file)
  40 ;;
  41
  42 module type LeafComparer =
  43   sig
  44     val cmp : leaf -> leaf -> int
  45   end
  46 ;;
  47
  48 module MakeBlob(C:LeafComparer) : Terms.Blob
  49   with type t = leaf and type input = Ast.term = struct
  50         type t = leaf
  51         let eq a b = a == b
  52         let compare a b = C.cmp a b
  53         let eqP = hash "=="
  54         let pp (_,a) =  a
  55         type input = Ast.term
  56         let rec embed m = function
  57             | Ast.Variable name ->
  58                 (try m, List.assoc name m
  59                  with Not_found ->
  60                     let t = Terms.Var ~-(List.length m) in
  61                     (name,t)::m, t)
  62             | Ast.Constant name -> m, Terms.Leaf (hash name)
  63             | Ast.Function (name,args) ->
  64                 let m, args =
  65                   HExtlib.list_mapi_acc
  66                     (fun x _ m -> embed m x) m args
  67                 in
  68                 m, Terms.Node (Terms.Leaf (hash name):: args)
  69         ;;
  70         let saturate bo ty =
  71           let vars, ty = embed [] ty in
  72           let _, bo = embed vars bo in
  73           let bo = Terms.Node (bo :: List.map snd (List.rev vars)) in
  74           bo, ty
  75         ;;
  76         let embed t = snd(embed [] t);;
  77
  78   end
  79 ;;
  80
  81 let success_msg bag l (pp : ?margin:int -> leaf Terms.unit_clause -> string) =
  82   print_endline ("% SZS status Unsatisfiable for " ^
  83     Filename.basename !problem_file);
  84   print_endline ("% SZS output start CNFRefutation for " ^
  85     Filename.basename !problem_file);
  86   flush stdout;
  87   List.iter (fun x ->
  88     let (cl,_,_) = Terms.get_from_bag x bag in
  89     print_endline (pp ~margin:max_int
  90       cl)) l;
  91   print_endline ("% SZS output end CNFRefutation for " ^
  92     Filename.basename !problem_file)
  93 ;;
  94
  95 let start_msg passives g_passives (pp : leaf Terms.unit_clause -> string) =
  96   let prefix = string_of_int (Unix.getpid ()) in
  97   let prerr_endline s = prerr_endline (prefix ^ ": " ^ s) in
  98   prerr_endline "Facts:";
  99   List.iter (fun x -> prerr_endline (" " ^ pp x)) passives;
 100   prerr_endline "Goal:";
 101   prerr_endline (" " ^ pp g_passives);
 102   prerr_endline "Order:";
 103   prerr_endline " ...fixme...";
 104   prerr_endline "Strategy:";
 105   prerr_endline " ...fixme...";
 106 ;;
 107
 108 let report_error s =  prerr_endline (string_of_int (Unix.getpid())^": "^s);;
 109
 110 module Main(C:LeafComparer) = struct
 111  let main goal hypotheses =
 112    let module B = MakeBlob(C) in
 113    let module Pp = Pp.Pp(B) in
 114    let module P = Paramod.Paramod(B) in
 115    let bag = Terms.empty_bag, 0 in
 116    let bag, g_passives = P.mk_goal bag goal in
 117    let bag, passives =
 118      HExtlib.list_mapi_acc (fun x _ b -> P.mk_passive b x) bag hypotheses
 119    in
 120    start_msg passives g_passives Pp.pp_unit_clause;
 121    match
 122      P.paramod
 123       ~max_steps:max_int bag ~g_passives:[g_passives] ~passives
 124    with
 125    | P.Error s -> report_error s; 3
 126    | P.Unsatisfiable ((bag,_,l)::_) ->
 127          success_msg bag l Pp.pp_unit_clause; 0
 128    | P.Unsatisfiable ([]) ->
 129          report_error "Unsatisfiable but no solution output"; 3
 130    | P.GaveUp -> 2
 131    | P.Timeout _ -> 1
 132  ;;
 133 end
 134
 135 let print_status p =
 136   let print_endline s = prerr_endline (string_of_int p ^ ": " ^ s) in
 137     function
 138     | Unix.WEXITED 0 ->
 139         print_endline ("status Unsatisfiable for " ^
 140           Filename.basename !problem_file);
 141     | Unix.WEXITED 1 ->
 142         print_endline ("status Timeout for " ^
 143           Filename.basename !problem_file);
 144     | Unix.WEXITED 2 ->
 145         print_endline ("status GaveUp for " ^
 146           Filename.basename !problem_file);
 147     | Unix.WEXITED 3 ->
 148         print_endline ("status Error for " ^
 149           Filename.basename !problem_file);
 150     | Unix.WEXITED _ -> assert false
 151     | Unix.WSIGNALED s -> print_endline ("killed by signal " ^ string_of_int s)
 152     | Unix.WSTOPPED _ -> print_endline "stopped"
 153  ;;
 154
 155 let killall l =
 156   List.iter (fun pid -> try Unix.kill pid 9 with _ -> ()) l
 157 ;;
 158
 159 let main () =
 160   let childs = ref [] in
 161   let _ =
 162     Sys.signal 24 (Sys.Signal_handle
 163       (fun _ -> fail_msg (); killall !childs; exit 1))
 164   in
 165   let _ =
 166     Sys.signal Sys.sigalrm
 167       (Sys.Signal_handle (fun _ -> fail_msg (); killall !childs; exit 1))
 168   in
 169   Arg.parse [
 170    "--tptppath", Arg.String (fun p -> tptppath := p),
 171      ("[path]  TPTP lib root, default " ^ !tptppath);
 172    "--timeout", Arg.Int (fun p -> seconds := p),
 173      ("[seconds]  timeout, default " ^ string_of_int !seconds);
 174    ] (fun x -> problem_file := x) "
 175 Matitaprover is the first order automatic prover that equips the
 176 Matita interactive theorem prover (http://matita.cs.unibo.it).
 177
 178 Developed by A.Asperti, M.Denes and E.Tassi, released under GPL-2.1
 179
 180 If --tptppath is given, instead of the problem file you can just give the
 181 problem name with the .p suffix (e.g. BOO001-1.p)
 182
 183 If --tptppath is not given, included files (i.e. axiom sets) are searched
 184 in the current directory only.
 185
 186 usage: matitaprover [options] problemfile";
 187   let hypotheses, goals = Tptp_cnf.parse ~tptppath:!tptppath !problem_file in
 188   let goal = match goals with [x] -> x | _ -> assert false in
 189   let _ = Unix.alarm !seconds in
 190   childs :=
 191     List.map
 192       (fun f ->
 193          let pid = Unix.fork () in
 194          if pid = 0 then (exit (f ())) else pid)
 195     [
 196       (fun () ->
 197         let module M = Main(struct let cmp (a,_) (b,_) = compare a b end) in
 198         M.main goal hypotheses)
 199     ;
 200 (*
 201       (fun () ->
 202         let module M = Main(struct let cmp (a,_) (b,_) = compare b a end) in
 203         M.main goal hypotheses)
 204 *)
 205     ];
 206   let rec aux () =
 207     if List.length !childs = 0 then
 208       (fail_msg (); exit 1)
 209     else
 210      match Unix.wait () with
 211      | p, (Unix.WEXITED 0 as s) ->
 212          print_status p s;
 213          killall !childs; exit 0;
 214      | p, s ->
 215          print_status p s;
 216          childs := List.filter ((<>)p) !childs; aux ()
 217   in
 218    aux ()
 219 ;;
 220
 221 main ()