helm/software/components/content_pres/cicNotationParser.ml

   1 (* Copyright (C) 2005, HELM Team.
   2  *
   3  * This file is part of HELM, an Hypertextual, Electronic
   4  * Library of Mathematics, developed at the Computer Science
   5  * Department, University of Bologna, Italy.
   6  *
   7  * HELM is free software; you can redistribute it and/or
   8  * modify it under the terms of the GNU General Public License
   9  * as published by the Free Software Foundation; either version 2
  10  * of the License, or (at your option) any later version.
  11  *
  12  * HELM is distributed in the hope that it will be useful,
  13  * but WITHOUT ANY WARRANTY; without even the implied warranty of
  14  * MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the
  15  * GNU General Public License for more details.
  16  *
  17  * You should have received a copy of the GNU General Public License
  18  * along with HELM; if not, write to the Free Software
  19  * Foundation, Inc., 59 Temple Place - Suite 330, Boston,
  20  * MA  02111-1307, USA.
  21  *
  22  * For details, see the HELM World-Wide-Web page,
  23  * http://helm.cs.unibo.it/
  24  *)
  25
  26 (* $Id$ *)
  27
  28 open Printf
  29
  30 module Ast = CicNotationPt
  31 module Env = CicNotationEnv
  32
  33 exception Parse_error of string
  34 exception Level_not_found of int
  35
  36 let min_precedence = 0
  37 let max_precedence = 100
  38
  39 type ('a,'b,'c,'d) grammars = {
  40   level1_pattern: 'a Grammar.Entry.e;
  41   level2_ast: 'b Grammar.Entry.e;
  42   level2_ast_grammar : Grammar.g;
  43   term: 'b Grammar.Entry.e;
  44   let_defs: 'c Grammar.Entry.e;
  45   protected_binder_vars: 'd Grammar.Entry.e;
  46   level2_meta: 'b Grammar.Entry.e;
  47 }
  48
  49 let initial_grammars () =
  50   let level1_pattern_grammar =
  51     Grammar.gcreate (CicNotationLexer.level1_pattern_lexer ()) in
  52   let level2_ast_grammar =
  53     Grammar.gcreate (CicNotationLexer.level2_ast_lexer ()) in
  54   let level2_meta_grammar =
  55     Grammar.gcreate (CicNotationLexer.level2_meta_lexer ()) in
  56   let level1_pattern =
  57     Grammar.Entry.create level1_pattern_grammar "level1_pattern" in
  58   let level2_ast = Grammar.Entry.create level2_ast_grammar "level2_ast" in
  59   let term = Grammar.Entry.create level2_ast_grammar "term" in
  60   let let_defs = Grammar.Entry.create level2_ast_grammar "let_defs" in
  61   let protected_binder_vars =
  62     Grammar.Entry.create level2_ast_grammar "protected_binder_vars" in
  63   let level2_meta = Grammar.Entry.create level2_meta_grammar "level2_meta" in
  64   { level1_pattern=level1_pattern;
  65     level2_ast=level2_ast;
  66     term=term;
  67     let_defs=let_defs;
  68     protected_binder_vars=protected_binder_vars;
  69     level2_meta=level2_meta;
  70     level2_ast_grammar=level2_ast_grammar;
  71 }
  72 ;;
  73
  74 let grammars = ref (initial_grammars ());;
  75
  76 let int_of_string s =
  77   try
  78     Pervasives.int_of_string s
  79   with Failure _ ->
  80     failwith (sprintf "Lexer failure: string_of_int \"%s\" failed" s)
  81
  82 (** {2 Grammar extension} *)
  83
  84 let level_of precedence =
  85   if precedence < min_precedence || precedence > max_precedence then
  86     raise (Level_not_found precedence);
  87   string_of_int precedence
  88
  89 let gram_symbol s = Gramext.Stoken ("SYMBOL", s)
  90 let gram_ident s = Gramext.Stoken ("IDENT", s)
  91 let gram_number s = Gramext.Stoken ("NUMBER", s)
  92 let gram_keyword s = Gramext.Stoken ("", s)
  93 let gram_term = function
  94   | Ast.Self _ -> Gramext.Sself
  95   | Ast.Level precedence ->
  96       Gramext.Snterml
  97         (Grammar.Entry.obj (!grammars.term: 'a Grammar.Entry.e),
  98          level_of precedence)
  99 ;;
 100
 101 let gram_of_literal =
 102   function
 103   | `Symbol s -> gram_symbol s
 104   | `Keyword s -> gram_keyword s
 105   | `Number s -> gram_number s
 106
 107 type binding =
 108   | NoBinding
 109   | Binding of string * Env.value_type
 110   | Env of (string * Env.value_type) list
 111
 112 let make_action action bindings =
 113   let rec aux (vl : CicNotationEnv.t) =
 114     function
 115       [] -> Gramext.action (fun (loc: Ast.location) -> action vl loc)
 116     | NoBinding :: tl -> Gramext.action (fun _ -> aux vl tl)
 117     (* LUCA: DEFCON 3 BEGIN *)
 118     | Binding (name, Env.TermType l) :: tl ->
 119         Gramext.action
 120           (fun (v:Ast.term) ->
 121             aux ((name, (Env.TermType l, Env.TermValue v))::vl) tl)
 122     | Binding (name, Env.StringType) :: tl ->
 123         Gramext.action
 124           (fun (v:string) ->
 125             aux ((name, (Env.StringType, Env.StringValue v)) :: vl) tl)
 126     | Binding (name, Env.NumType) :: tl ->
 127         Gramext.action
 128           (fun (v:string) ->
 129             aux ((name, (Env.NumType, Env.NumValue v)) :: vl) tl)
 130     | Binding (name, Env.OptType t) :: tl ->
 131         Gramext.action
 132           (fun (v:'a option) ->
 133             aux ((name, (Env.OptType t, Env.OptValue v)) :: vl) tl)
 134     | Binding (name, Env.ListType t) :: tl ->
 135         Gramext.action
 136           (fun (v:'a list) ->
 137             aux ((name, (Env.ListType t, Env.ListValue v)) :: vl) tl)
 138     | Env _ :: tl ->
 139         Gramext.action (fun (v:CicNotationEnv.t) -> aux (v @ vl) tl)
 140     (* LUCA: DEFCON 3 END *)
 141   in
 142     aux [] (List.rev bindings)
 143
 144 let flatten_opt =
 145   let rec aux acc =
 146     function
 147       [] -> List.rev acc
 148     | NoBinding :: tl -> aux acc tl
 149     | Env names :: tl -> aux (List.rev names @ acc) tl
 150     | Binding (name, ty) :: tl -> aux ((name, ty) :: acc) tl
 151   in
 152   aux []
 153
 154   (* given a level 1 pattern computes the new RHS of "term" grammar entry *)
 155 let extract_term_production pattern =
 156   let rec aux = function
 157     | Ast.AttributedTerm (_, t) -> aux t
 158     | Ast.Literal l -> aux_literal l
 159     | Ast.Layout l -> aux_layout l
 160     | Ast.Magic m -> aux_magic m
 161     | Ast.Variable v -> aux_variable v
 162     | t ->
 163         prerr_endline (CicNotationPp.pp_term t);
 164         assert false
 165   and aux_literal =
 166     function
 167     | `Symbol s -> [NoBinding, gram_symbol s]
 168     | `Keyword s ->
 169         (* assumption: s will be registered as a keyword with the lexer *)
 170         [NoBinding, gram_keyword s]
 171     | `Number s -> [NoBinding, gram_number s]
 172   and aux_layout = function
 173     | Ast.Sub (p1, p2) -> aux p1 @ [NoBinding, gram_symbol "\\sub "] @ aux p2
 174     | Ast.Sup (p1, p2) -> aux p1 @ [NoBinding, gram_symbol "\\sup "] @ aux p2
 175     | Ast.Below (p1, p2) -> aux p1 @ [NoBinding, gram_symbol "\\below "] @ aux p2
 176     | Ast.Above (p1, p2) -> aux p1 @ [NoBinding, gram_symbol "\\above "] @ aux p2
 177     | Ast.Frac (p1, p2) -> aux p1 @ [NoBinding, gram_symbol "\\frac "] @ aux p2
 178     | Ast.InfRule (p1, p2, p3) -> [NoBinding, gram_symbol "\\infrule "] @ aux p1 @ aux p2 @ aux p3
 179     | Ast.Atop (p1, p2) -> aux p1 @ [NoBinding, gram_symbol "\\atop "] @ aux p2
 180     | Ast.Over (p1, p2) -> aux p1 @ [NoBinding, gram_symbol "\\over "] @ aux p2
 181     | Ast.Root (p1, p2) ->
 182         [NoBinding, gram_symbol "\\root "] @ aux p2
 183         @ [NoBinding, gram_symbol "\\of "] @ aux p1
 184     | Ast.Sqrt p -> [NoBinding, gram_symbol "\\sqrt "] @ aux p
 185     | Ast.Break -> []
 186     | Ast.Box (_, pl) -> List.flatten (List.map aux pl)
 187     | Ast.Group pl -> List.flatten (List.map aux pl)
 188     | Ast.Mstyle (_,pl) -> List.flatten (List.map aux pl)
 189     | Ast.Mpadded (_,pl) -> List.flatten (List.map aux pl)
 190     | Ast.Maction l -> List.flatten (List.map aux l)
 191   and aux_magic magic =
 192     match magic with
 193     | Ast.Opt p ->
 194         let p_bindings, p_atoms, p_names, p_action = inner_pattern p in
 195         let action (env_opt : CicNotationEnv.t option) (loc : Ast.location) =
 196           match env_opt with
 197           | Some env -> List.map Env.opt_binding_some env
 198           | None -> List.map Env.opt_binding_of_name p_names
 199         in
 200         [ Env (List.map Env.opt_declaration p_names),
 201           Gramext.srules
 202             [ [ Gramext.Sopt (Gramext.srules [ p_atoms, p_action ]) ],
 203               Gramext.action action ] ]
 204     | Ast.List0 (p, _)
 205     | Ast.List1 (p, _) ->
 206         let p_bindings, p_atoms, p_names, p_action = inner_pattern p in
 207         let action (env_list : CicNotationEnv.t list) (loc : Ast.location) =
 208           CicNotationEnv.coalesce_env p_names env_list
 209         in
 210         let gram_of_list s =
 211           match magic with
 212           | Ast.List0 (_, None) -> Gramext.Slist0 s
 213           | Ast.List1 (_, None) -> Gramext.Slist1 s
 214           | Ast.List0 (_, Some l) -> Gramext.Slist0sep (s, gram_of_literal l,false)
 215           | Ast.List1 (_, Some l) -> Gramext.Slist1sep (s, gram_of_literal l,false)
 216           | _ -> assert false
 217         in
 218         [ Env (List.map Env.list_declaration p_names),
 219           Gramext.srules
 220             [ [ gram_of_list (Gramext.srules [ p_atoms, p_action ]) ],
 221               Gramext.action action ] ]
 222     | _ -> assert false
 223   and aux_variable =
 224     function
 225     | Ast.NumVar s -> [Binding (s, Env.NumType), gram_number ""]
 226     | Ast.TermVar (s,(Ast.Self level|Ast.Level level as lv)) ->
 227         [Binding (s, Env.TermType level), gram_term lv]
 228     | Ast.IdentVar s -> [Binding (s, Env.StringType), gram_ident ""]
 229     | Ast.Ascription (p, s) -> assert false (* TODO *)
 230     | Ast.FreshVar _ -> assert false
 231   and inner_pattern p =
 232     let p_bindings, p_atoms = List.split (aux p) in
 233     let p_names = flatten_opt p_bindings in
 234     let action =
 235       make_action (fun (env : CicNotationEnv.t) (loc : Ast.location) -> env)
 236         p_bindings
 237     in
 238     p_bindings, p_atoms, p_names, action
 239   in
 240   aux pattern
 241
 242 type rule_id = Grammar.token Gramext.g_symbol list
 243
 244 let compare_rule_id x y =
 245   let rec aux = function
 246     | [],[] -> 0
 247     | [],_ -> ~-1
 248     | _,[] -> 1
 249     | ((s1::tl1) as x),((s2::tl2) as y) ->
 250         if Gramext.eq_symbol s1 s2 then aux (tl1,tl2)
 251         else Pervasives.compare x y
 252   in
 253     aux (x,y)
 254
 255   (* mapping: rule_id -> owned keywords. (rule_id, string list) Hashtbl.t *)
 256 let initial_owned_keywords () = Hashtbl.create 23
 257 let owned_keywords = ref (initial_owned_keywords ())
 258
 259 type checked_l1_pattern = CL1P of CicNotationPt.term * int
 260
 261 let check_l1_pattern level1_pattern pponly level associativity =
 262   let variables = ref 0 in
 263   let symbols = ref 0 in
 264   let rec aux = function
 265     | Ast.AttributedTerm (att, t) -> Ast.AttributedTerm (att,aux t)
 266     | Ast.Literal _ as l -> incr symbols; l
 267     | Ast.Layout l -> Ast.Layout (aux_layout l)
 268     | Ast.Magic m -> Ast.Magic (aux_magic m)
 269     | Ast.Variable v -> (aux_variable v)
 270     | t -> assert false
 271   and aux_layout = function
 272     | Ast.Sub (p1, p2)   -> let p1 = aux p1 in let p2 = aux p2 in Ast.Sub (p1, p2)
 273     | Ast.Sup (p1, p2)   -> let p1 = aux p1 in let p2 = aux p2 in Ast.Sup (p1, p2)
 274     | Ast.Below (p1, p2) -> let p1 = aux p1 in let p2 = aux p2 in Ast.Below (p1, p2)
 275     | Ast.Above (p1, p2) -> let p1 = aux p1 in let p2 = aux p2 in Ast.Above (p1, p2)
 276     | Ast.Frac (p1, p2)  -> let p1 = aux p1 in let p2 = aux p2 in Ast.Frac (p1, p2)
 277     | Ast.InfRule (p1, p2, p3)  -> let p1 = aux p1 in let p2 = aux p2 in let p3 = aux p3 in Ast.InfRule (p1, p2, p3)
 278     | Ast.Atop (p1, p2)  -> let p1 = aux p1 in let p2 = aux p2 in Ast.Atop (p1, p2)
 279     | Ast.Over (p1, p2)  -> let p1 = aux p1 in let p2 = aux p2 in Ast.Over (p1, p2)
 280     | Ast.Root (p1, p2)  -> let p1 = aux p1 in let p2 = aux p2 in Ast.Root (p1, p2)
 281     | Ast.Sqrt p -> Ast.Sqrt (aux p)
 282     | Ast.Break as t -> t
 283     | Ast.Box (b, pl) -> Ast.Box(b, List.map aux pl)
 284     | Ast.Group pl -> Ast.Group (List.map aux pl)
 285     | Ast.Mstyle (l,pl) -> Ast.Mstyle (l, List.map aux pl)
 286     | Ast.Mpadded (l,pl) -> Ast.Mpadded (l, List.map aux pl)
 287     | Ast.Maction l as t ->
 288         if not pponly then
 289         raise(Parse_error("Maction can be used only in output notations"))
 290         else t
 291   and aux_magic magic =
 292     match magic with
 293     | Ast.Opt p -> Ast.Opt (aux p)
 294     | Ast.List0 (p, x) -> Ast.List0 (aux p, x)
 295     | Ast.List1 (p, x) -> Ast.List1 (aux p, x)
 296     | _ -> assert false
 297   and aux_variable =
 298     function
 299     | Ast.NumVar _ as t -> Ast.Variable t
 300     | Ast.TermVar (s,Ast.Self _) when associativity <> Gramext.NonA ->
 301         incr variables;
 302         if !variables > 2 then
 303           raise (Parse_error ("Exactly 2 variables must be specified in an "^
 304           "associative notation"));
 305         (match !variables, associativity with
 306         | 1,Gramext.LeftA ->
 307              Ast.Variable (Ast.TermVar (s, Ast.Self level))
 308         | 1,Gramext.RightA ->
 309              Ast.Variable (Ast.TermVar (s, Ast.Self (level+1)))
 310         | 2,Gramext.LeftA ->
 311              Ast.Variable (Ast.TermVar (s, Ast.Self (level+1)))
 312         | 2,Gramext.RightA ->
 313              Ast.Variable (Ast.TermVar (s, Ast.Level (level-1)))
 314         | _ -> assert false)
 315     | Ast.TermVar (s,Ast.Level _) when associativity <> Gramext.NonA ->
 316           raise (Parse_error ("Variables can not be declared with a " ^
 317             "precedence in an associative notation"))
 318        (*avoid camlp5 divergence due to non-Sself recursion at the same level *)
 319     | Ast.TermVar (s,Ast.Level l) when l<=level && !variables=0 && !symbols=0->
 320        raise(Parse_error("Left recursive rule with precedence not greater " ^
 321         "than " ^ string_of_int level ^ " is not allowed to avoid divergence"))
 322     | Ast.TermVar _ as t -> incr variables; Ast.Variable t
 323     | Ast.IdentVar _ as t -> Ast.Variable t
 324     | Ast.Ascription _ -> assert false (* TODO *)
 325     | Ast.FreshVar _ -> assert false
 326   in
 327   if associativity <> Gramext.NonA && level = min_precedence then
 328     raise (Parse_error ("You can not specify an associative notation " ^
 329     "at level "^string_of_int min_precedence ^ "; increase it"));
 330   let cp = aux level1_pattern in
 331 (*   prerr_endline ("checked_pattern: " ^ CicNotationPp.pp_term cp); *)
 332   if !variables <> 2 && associativity <> Gramext.NonA then
 333     raise (Parse_error ("Exactly 2 variables must be specified in an "^
 334      "associative notation"));
 335   CL1P (cp,level)
 336 ;;
 337
 338 let extend (CL1P (level1_pattern,precedence)) action =
 339   let p_bindings, p_atoms =
 340     List.split (extract_term_production level1_pattern)
 341   in
 342   let level = level_of precedence in
 343   let _ =
 344     Grammar.extend
 345       [ Grammar.Entry.obj (!grammars.term: 'a Grammar.Entry.e),
 346         Some (Gramext.Level level),
 347         [ None,
 348           Some (*Gramext.NonA*) Gramext.NonA,
 349           [ p_atoms,
 350             (make_action
 351               (fun (env: CicNotationEnv.t) (loc: Ast.location) ->
 352                 (action env loc))
 353               p_bindings) ]]]
 354   in
 355   let keywords = CicNotationUtil.keywords_of_term level1_pattern in
 356   let rule_id = p_atoms in
 357   List.iter CicNotationLexer.add_level2_ast_keyword keywords;
 358   Hashtbl.add !owned_keywords rule_id keywords;  (* keywords may be [] *)
 359   rule_id
 360
 361 let delete rule_id =
 362   let atoms = rule_id in
 363   (try
 364     let keywords = Hashtbl.find !owned_keywords rule_id in
 365     List.iter CicNotationLexer.remove_level2_ast_keyword keywords
 366   with Not_found -> assert false);
 367   Grammar.delete_rule !grammars.term atoms
 368
 369 (** {2 Grammar} *)
 370
 371 let parse_level1_pattern_ref = ref (fun _ _ -> assert false)
 372 let parse_level2_ast_ref = ref (fun _ -> assert false)
 373 let parse_level2_meta_ref = ref (fun _ -> assert false)
 374
 375 let fold_cluster binder terms ty body =
 376   List.fold_right
 377     (fun term body -> Ast.Binder (binder, (term, ty), body))
 378     terms body  (* terms are names: either Ident or FreshVar *)
 379
 380 let fold_exists terms ty body =
 381   List.fold_right
 382     (fun term body ->
 383       let lambda = Ast.Binder (`Lambda, (term, ty), body) in
 384       Ast.Appl [ Ast.Symbol ("exists", 0); lambda ])
 385     terms body
 386
 387 let fold_binder binder pt_names body =
 388   List.fold_right
 389     (fun (names, ty) body -> fold_cluster binder names ty body)
 390     pt_names body
 391
 392 let return_term loc term = Ast.AttributedTerm (`Loc loc, term)
 393 let return_term_of_level loc term l =
 394   Ast.AttributedTerm (`Loc loc, term l)
 395
 396   (* create empty precedence level for "term" *)
 397 let initialize_grammars () =
 398   let dummy_action =
 399     Gramext.action (fun _ ->
 400       failwith "internal error, lexer generated a dummy token")
 401   in
 402   (* Needed since campl4 on "delete_rule" remove the precedence level if it gets
 403    * empty after the deletion. The lexer never generate the Stoken below. *)
 404   let dummy_prod = [ [ Gramext.Stoken ("DUMMY", "") ], dummy_action ] in
 405   let mk_level_list first last =
 406     let rec aux acc = function
 407       | i when i < first -> acc
 408       | i ->
 409           aux
 410             ((Some (level_of i), Some Gramext.NonA, dummy_prod)
 411              :: acc)
 412             (i - 1)
 413     in
 414     aux [] last
 415   in
 416   Grammar.extend
 417     [ Grammar.Entry.obj (!grammars.term: 'a Grammar.Entry.e),
 418       None,
 419       mk_level_list min_precedence max_precedence ];
 420 (* {{{ Grammar for concrete syntax patterns, notation level 1 *)
 421   begin
 422   let level1_pattern = !grammars.level1_pattern in
 423 EXTEND
 424   GLOBAL: level1_pattern;
 425
 426   level1_pattern: [
 427     [ p = l1_pattern; EOI -> fun l -> CicNotationUtil.boxify (p l) ]
 428   ];
 429   l1_pattern: [
 430     [ p = LIST1 l1_simple_pattern ->
 431         fun l -> List.map (fun x -> x l) p ]
 432   ];
 433   literal: [
 434     [ s = SYMBOL -> `Symbol s
 435     | k = QKEYWORD -> `Keyword k
 436     | n = NUMBER -> `Number n
 437     ]
 438   ];
 439   sep:       [ [ "sep";      sep = literal -> sep ] ];
 440   l1_magic_pattern: [
 441     [ "list0"; p = l1_simple_pattern; sep = OPT sep ->
 442             fun l -> Ast.List0 (p l, sep)
 443     | "list1"; p = l1_simple_pattern; sep = OPT sep ->
 444             fun l -> Ast.List1 (p l, sep)
 445     | "opt";   p = l1_simple_pattern -> fun l -> Ast.Opt (p l)
 446     ]
 447   ];
 448   l1_pattern_variable: [
 449     [ "term"; precedence = NUMBER; id = IDENT ->
 450         Ast.TermVar (id, Ast.Level (int_of_string precedence))
 451     | "number"; id = IDENT -> Ast.NumVar id
 452     | "ident"; id = IDENT -> Ast.IdentVar id
 453     ]
 454   ];
 455   mstyle: [
 456     [ id = IDENT;
 457       v = [ IDENT | NUMBER | COLOR | FLOATWITHUNIT ] -> id, v]];
 458   mpadded: [
 459     [ id = IDENT;
 460       v = [ PERCENTAGE ] -> id, v]];
 461   l1_simple_pattern:
 462     [ "layout" LEFTA
 463       [ p1 = SELF; SYMBOL "\\sub "; p2 = SELF ->
 464           return_term_of_level loc
 465             (fun l -> Ast.Layout (Ast.Sub (p1 l, p2 l)))
 466       | p1 = SELF; SYMBOL "\\sup "; p2 = SELF ->
 467           return_term_of_level loc
 468             (fun l -> Ast.Layout (Ast.Sup (p1 l, p2 l)))
 469       | p1 = SELF; SYMBOL "\\below "; p2 = SELF ->
 470           return_term_of_level loc
 471             (fun l -> Ast.Layout (Ast.Below (p1 l, p2 l)))
 472       | p1 = SELF; SYMBOL "\\above "; p2 = SELF ->
 473           return_term_of_level loc
 474             (fun l -> Ast.Layout (Ast.Above (p1 l, p2 l)))
 475       | p1 = SELF; SYMBOL "\\over "; p2 = SELF ->
 476           return_term_of_level loc
 477             (fun l -> Ast.Layout (Ast.Over (p1 l, p2 l)))
 478       | p1 = SELF; SYMBOL "\\atop "; p2 = SELF ->
 479           return_term_of_level loc
 480             (fun l -> Ast.Layout (Ast.Atop (p1 l, p2 l)))
 481       | p1 = SELF; SYMBOL "\\frac "; p2 = SELF ->
 482           return_term_of_level loc
 483             (fun l -> Ast.Layout (Ast.Frac (p1 l, p2 l)))
 484       | SYMBOL "\\infrule "; p1 = SELF; p2 = SELF; p3 = SELF ->
 485           return_term_of_level loc
 486             (fun l -> Ast.Layout (Ast.InfRule (p1 l, p2 l, p3 l)))
 487       | SYMBOL "\\sqrt "; p = SELF ->
 488           return_term_of_level loc (fun l -> Ast.Layout (Ast.Sqrt p l))
 489       | SYMBOL "\\root "; index = SELF; SYMBOL "\\of "; arg = SELF ->
 490           return_term_of_level loc
 491             (fun l -> Ast.Layout (Ast.Root (arg l, index l)))
 492       | "hbox"; LPAREN; p = l1_pattern; RPAREN ->
 493           return_term_of_level loc
 494             (fun l -> Ast.Layout (Ast.Box ((Ast.H, false, false), p l)))
 495       | "vbox"; LPAREN; p = l1_pattern; RPAREN ->
 496           return_term_of_level loc
 497             (fun l -> Ast.Layout (Ast.Box ((Ast.V, false, false), p l)))
 498       | "hvbox"; LPAREN; p = l1_pattern; RPAREN ->
 499           return_term_of_level loc
 500             (fun l -> Ast.Layout (Ast.Box ((Ast.HV, false, false), p l)))
 501       | "hovbox"; LPAREN; p = l1_pattern; RPAREN ->
 502           return_term_of_level loc
 503             (fun l -> Ast.Layout (Ast.Box ((Ast.HOV, false, false), p l)))
 504       | "break" -> return_term_of_level loc (fun _ -> Ast.Layout Ast.Break)
 505       | "mstyle"; m = LIST1 mstyle ; LPAREN; t = l1_pattern; RPAREN ->
 506           return_term_of_level loc
 507             (fun l ->
 508                Ast.Layout (Ast.Mstyle (m, t l)))
 509       | "mpadded"; m = LIST1 mpadded ; LPAREN; t = l1_pattern; RPAREN ->
 510           return_term_of_level loc
 511             (fun l ->
 512                Ast.Layout (Ast.Mpadded (m, t l)))
 513       | "maction"; m = LIST1 [ LPAREN; l = l1_pattern; RPAREN -> l ] ->
 514            return_term_of_level loc
 515             (fun l -> Ast.Layout (Ast.Maction (List.map (fun x ->
 516               CicNotationUtil.group (x l)) m)))
 517       | LPAREN; p = l1_pattern; RPAREN ->
 518           return_term_of_level loc (fun l -> CicNotationUtil.group (p l))
 519       ]
 520     | "simple" NONA
 521       [ i = IDENT ->
 522          return_term_of_level loc
 523            (fun l -> Ast.Variable (Ast.TermVar (i,Ast.Self l)))
 524       | m = l1_magic_pattern ->
 525              return_term_of_level loc (fun l -> Ast.Magic (m l))
 526       | v = l1_pattern_variable ->
 527              return_term_of_level loc (fun _ -> Ast.Variable v)
 528       | l = literal -> return_term_of_level loc (fun _ -> Ast.Literal l)
 529       ]
 530     ];
 531   END
 532   end;
 533 (* }}} *)
 534 (* {{{ Grammar for ast magics, notation level 2 *)
 535   begin
 536   let level2_meta = !grammars.level2_meta in
 537 EXTEND
 538   GLOBAL: level2_meta;
 539   l2_variable: [
 540     [ "term"; precedence = NUMBER; id = IDENT ->
 541         Ast.TermVar (id,Ast.Level (int_of_string precedence))
 542     | "number"; id = IDENT -> Ast.NumVar id
 543     | "ident"; id = IDENT -> Ast.IdentVar id
 544     | "fresh"; id = IDENT -> Ast.FreshVar id
 545     | "anonymous" -> Ast.TermVar ("_",Ast.Self 0) (* is the level relevant?*)
 546     | id = IDENT -> Ast.TermVar (id,Ast.Self 0)
 547     ]
 548   ];
 549   l2_magic: [
 550     [ "fold"; kind = [ "left" -> `Left | "right" -> `Right ];
 551       base = level2_meta; "rec"; id = IDENT; recursive = level2_meta ->
 552         Ast.Fold (kind, base, [id], recursive)
 553     | "default"; some = level2_meta; none = level2_meta ->
 554         Ast.Default (some, none)
 555     | "if"; p_test = level2_meta;
 556       "then"; p_true = level2_meta;
 557       "else"; p_false = level2_meta ->
 558         Ast.If (p_test, p_true, p_false)
 559     | "fail" -> Ast.Fail
 560     ]
 561   ];
 562   level2_meta: [
 563     [ magic = l2_magic -> Ast.Magic magic
 564     | var = l2_variable -> Ast.Variable var
 565     | blob = UNPARSED_AST ->
 566         !parse_level2_ast_ref (Ulexing.from_utf8_string blob)
 567     ]
 568   ];
 569 END
 570   end;
 571 (* }}} *)
 572 (* {{{ Grammar for ast patterns, notation level 2 *)
 573   begin
 574   let level2_ast = !grammars.level2_ast in
 575   let term = !grammars.term in
 576   let let_defs = !grammars.let_defs in
 577   let protected_binder_vars = !grammars.protected_binder_vars in
 578 EXTEND
 579   GLOBAL: level2_ast term let_defs protected_binder_vars;
 580   level2_ast: [ [ p = term -> p ] ];
 581   sort: [
 582     [ "Prop" -> `Prop
 583     | "Set" -> `Set
 584     | "Type"; SYMBOL "["; n = [ NUMBER| IDENT ]; SYMBOL "]" -> `NType n
 585     | "Type" -> `Type (CicUniv.fresh ())
 586     | "CProp"; SYMBOL "["; n = [ NUMBER| IDENT ]; SYMBOL "]" -> `NCProp n
 587     | "CProp" -> `CProp (CicUniv.fresh ())
 588     ]
 589   ];
 590   explicit_subst: [
 591     [ SYMBOL "\\subst ";  (* to avoid catching frequent "a [1]" cases *)
 592       SYMBOL "[";
 593       substs = LIST1 [
 594         i = IDENT; SYMBOL <:unicode<Assign>> (* ≔ *); t = term -> (i, t)
 595       ] SEP SYMBOL ";";
 596       SYMBOL "]" ->
 597         substs
 598     ]
 599   ];
 600   meta_subst: [
 601     [ s = SYMBOL "_" -> None
 602     | p = term -> Some p ]
 603   ];
 604   meta_substs: [
 605     [ SYMBOL "["; substs = LIST0 meta_subst; SYMBOL "]" -> substs ]
 606   ];
 607   possibly_typed_name: [
 608     [ LPAREN; id = single_arg; SYMBOL ":"; typ = term; RPAREN ->
 609         id, Some typ
 610     | arg = single_arg -> arg, None
 611     | id = PIDENT -> Ast.Ident (id, None), None
 612     | SYMBOL "_" -> Ast.Ident ("_", None), None
 613     | LPAREN; id = PIDENT; SYMBOL ":"; typ = term; RPAREN ->
 614         Ast.Ident (id, None), Some typ
 615     | LPAREN; SYMBOL "_"; SYMBOL ":"; typ = term; RPAREN ->
 616         Ast.Ident ("_", None), Some typ
 617     ]
 618   ];
 619   match_pattern: [
 620     [ SYMBOL "_" -> Ast.Wildcard
 621     | id = IDENT -> Ast.Pattern (id, None, [])
 622     | LPAREN; id = IDENT; vars = LIST1 possibly_typed_name; RPAREN ->
 623        Ast.Pattern (id, None, vars)
 624     | id = IDENT; vars = LIST1 possibly_typed_name ->
 625        Ast.Pattern (id, None, vars)
 626     ]
 627   ];
 628   binder: [
 629     [ SYMBOL <:unicode<Pi>>     (* Π *) -> `Pi
 630     | SYMBOL <:unicode<forall>> (* ∀ *) -> `Forall
 631     | SYMBOL <:unicode<lambda>> (* λ *) -> `Lambda
 632     ]
 633   ];
 634   arg: [
 635     [ LPAREN; names = LIST1 IDENT SEP SYMBOL ",";
 636       SYMBOL ":"; ty = term; RPAREN ->
 637         List.map (fun n -> Ast.Ident (n, None)) names, Some ty
 638     | name = IDENT -> [Ast.Ident (name, None)], None
 639     | blob = UNPARSED_META ->
 640         let meta = !parse_level2_meta_ref (Ulexing.from_utf8_string blob) in
 641         match meta with
 642         | Ast.Variable (Ast.FreshVar _) -> [meta], None
 643         | Ast.Variable (Ast.TermVar ("_",_)) -> [Ast.Ident ("_", None)], None
 644         | _ -> failwith "Invalid bound name."
 645    ]
 646   ];
 647   single_arg: [
 648     [ name = IDENT -> Ast.Ident (name, None)
 649     | blob = UNPARSED_META ->
 650         let meta = !parse_level2_meta_ref (Ulexing.from_utf8_string blob) in
 651         match meta with
 652         | Ast.Variable (Ast.FreshVar _)
 653         | Ast.Variable (Ast.IdentVar _) -> meta
 654         | Ast.Variable (Ast.TermVar ("_",_)) -> Ast.Ident ("_", None)
 655         | _ -> failwith "Invalid index name."
 656     ]
 657   ];
 658   let_defs: [
 659     [ defs = LIST1 [
 660         name = single_arg;
 661         args = LIST1 arg;
 662         index_name = OPT [ "on"; id = single_arg -> id ];
 663         ty = OPT [ SYMBOL ":" ; p = term -> p ];
 664         SYMBOL <:unicode<def>> (* ≝ *); body = term ->
 665           let rec position_of name p = function
 666             | [] -> None, p
 667             | n :: _ when n = name -> Some p, p
 668             | _ :: tl -> position_of name (p + 1) tl
 669           in
 670           let rec find_arg name n = function
 671             | [] ->
 672                 Ast.fail loc (sprintf "Argument %s not found"
 673                   (CicNotationPp.pp_term name))
 674             | (l,_) :: tl ->
 675                 (match position_of name 0 l with
 676                 | None, len -> find_arg name (n + len) tl
 677                 | Some where, len -> n + where)
 678           in
 679           let index =
 680             match index_name with
 681             | None -> 0
 682             | Some index_name -> find_arg index_name 0 args
 683           in
 684           let args =
 685            List.concat
 686             (List.map
 687              (function (names,ty) -> List.map (function x -> x,ty) names
 688              ) args)
 689           in
 690            args, (name, ty), body, index
 691       ] SEP "and" ->
 692         defs
 693     ]
 694   ];
 695   binder_vars: [
 696     [ vars = [ l =
 697         [ l = LIST1 single_arg SEP SYMBOL "," -> l
 698         | l = LIST1 [ PIDENT | SYMBOL "_" ] SEP SYMBOL "," ->
 699             List.map (fun x -> Ast.Ident(x,None)) l
 700       ] -> l ];
 701       typ = OPT [ SYMBOL ":"; t = term -> t ] -> (vars, typ)
 702     ]
 703   ];
 704   protected_binder_vars: [
 705     [ LPAREN; vars = binder_vars; RPAREN -> vars
 706     ]
 707   ];
 708   maybe_protected_binder_vars: [
 709     [ vars = binder_vars -> vars
 710     | vars = protected_binder_vars -> vars
 711     ]
 712   ];
 713   term: LEVEL "10"
 714   [
 715     [ "let";
 716      var =
 717       [ LPAREN; id = single_arg; SYMBOL ":"; typ = term; RPAREN ->
 718           id, Some typ
 719       | id = IDENT; ty = OPT [ SYMBOL ":"; typ = term -> typ] ->
 720           Ast.Ident(id,None), ty ];
 721       SYMBOL <:unicode<def>> (* ≝ *);
 722       p1 = term; "in"; p2 = term ->
 723         return_term loc (Ast.LetIn (var, p1, p2))
 724     | LETCOREC; defs = let_defs; "in";
 725       body = term ->
 726         return_term loc (Ast.LetRec (`CoInductive, defs, body))
 727     | LETREC; defs = let_defs; "in";
 728       body = term ->
 729         return_term loc (Ast.LetRec (`Inductive, defs, body))
 730     ]
 731   ];
 732   term: LEVEL "20"
 733     [
 734       [ b = binder; (vars, typ) = maybe_protected_binder_vars; SYMBOL "."; body = term LEVEL "19" ->
 735           return_term loc (fold_cluster b vars typ body)
 736       ]
 737     ];
 738   term: LEVEL "70"
 739     [
 740       [ p1 = term; p2 = term LEVEL "71" ->
 741           let rec aux = function
 742             | Ast.Appl (hd :: tl)
 743             | Ast.AttributedTerm (_, Ast.Appl (hd :: tl)) ->
 744                 aux hd @ tl
 745             | term -> [term]
 746           in
 747           return_term loc (Ast.Appl (aux p1 @ [p2]))
 748       ]
 749     ];
 750   term: LEVEL "90"
 751     [
 752       [ id = IDENT -> return_term loc (Ast.Ident (id, None))
 753       | id = IDENT; s = explicit_subst ->
 754           return_term loc (Ast.Ident (id, Some s))
 755       | s = CSYMBOL -> return_term loc (Ast.Symbol (s, 0))
 756       | u = URI -> return_term loc (Ast.Uri (u, None))
 757       | r = NREF -> return_term loc (Ast.NRef (NReference.reference_of_string r))
 758       | n = NUMBER -> return_term loc (Ast.Num (n, 0))
 759       | IMPLICIT -> return_term loc (Ast.Implicit `JustOne)
 760       | SYMBOL <:unicode<ldots>> -> return_term loc (Ast.Implicit `Vector)
 761       | PLACEHOLDER -> return_term loc Ast.UserInput
 762       | m = META -> return_term loc (Ast.Meta (int_of_string m, []))
 763       | m = META; s = meta_substs ->
 764           return_term loc (Ast.Meta (int_of_string m, s))
 765       | s = sort -> return_term loc (Ast.Sort s)
 766       | "match"; t = term;
 767         indty_ident = OPT [ "in"; id = IDENT -> id, None ];
 768         outtyp = OPT [ "return"; ty = term -> ty ];
 769         "with"; SYMBOL "[";
 770         patterns = LIST0 [
 771           lhs = match_pattern; SYMBOL <:unicode<Rightarrow>> (* ⇒ *);
 772           rhs = term ->
 773             lhs, rhs
 774         ] SEP SYMBOL "|";
 775         SYMBOL "]" ->
 776           return_term loc (Ast.Case (t, indty_ident, outtyp, patterns))
 777       | LPAREN; p1 = term; SYMBOL ":"; p2 = term; RPAREN ->
 778           return_term loc (Ast.Cast (p1, p2))
 779       | LPAREN; p = term; RPAREN -> p
 780       | blob = UNPARSED_META ->
 781           !parse_level2_meta_ref (Ulexing.from_utf8_string blob)
 782       ]
 783     ];
 784 END
 785   end
 786 (* }}} *)
 787 ;;
 788
 789 let _ = initialize_grammars ();;
 790
 791 let history = ref [];;
 792
 793 let push () =
 794   CicNotationLexer.push ();
 795   history := (!owned_keywords,!grammars) :: !history;
 796   owned_keywords := (initial_owned_keywords ());
 797   grammars := initial_grammars ();
 798   initialize_grammars ()
 799 ;;
 800
 801 let pop () =
 802   CicNotationLexer.pop ();
 803   match !history with
 804   | [] -> assert false
 805   | (kw,gram) :: old_history ->
 806       owned_keywords := kw;
 807       grammars := gram;
 808       history := old_history
 809 ;;
 810
 811 (** {2 API implementation} *)
 812
 813 let exc_located_wrapper f =
 814   try
 815     f ()
 816   with
 817   | Ploc.Exc (floc, Stream.Error msg) ->
 818       raise (HExtlib.Localized (floc, Parse_error msg))
 819   | Ploc.Exc (floc, HExtlib.Localized (_,exn)) ->
 820       raise (HExtlib.Localized (floc, (Parse_error (Printexc.to_string exn))))
 821   | Ploc.Exc (floc, exn) ->
 822       raise (HExtlib.Localized (floc, (Parse_error (Printexc.to_string exn))))
 823
 824 let parse_level1_pattern precedence lexbuf =
 825   exc_located_wrapper
 826     (fun () -> Grammar.Entry.parse !grammars.level1_pattern (Obj.magic lexbuf) precedence)
 827
 828 let parse_level2_ast lexbuf =
 829   exc_located_wrapper
 830     (fun () -> Grammar.Entry.parse !grammars.level2_ast (Obj.magic lexbuf))
 831
 832 let parse_level2_meta lexbuf =
 833   exc_located_wrapper
 834     (fun () -> Grammar.Entry.parse !grammars.level2_meta (Obj.magic lexbuf))
 835
 836 let _ =
 837   parse_level1_pattern_ref := parse_level1_pattern;
 838   parse_level2_ast_ref := parse_level2_ast;
 839   parse_level2_meta_ref := parse_level2_meta
 840
 841 let parse_term lexbuf =
 842   exc_located_wrapper
 843     (fun () -> (Grammar.Entry.parse !grammars.term (Obj.magic lexbuf)))
 844
 845 let level2_ast_grammar () = !grammars.level2_ast_grammar
 846 let term  () = !grammars.term
 847 let let_defs  () = !grammars.let_defs
 848 let protected_binder_vars  () = !grammars.protected_binder_vars
 849
 850
 851 (** {2 Debugging} *)
 852
 853 let print_l2_pattern () =
 854   Grammar.print_entry Format.std_formatter (Grammar.Entry.obj !grammars.term);
 855   Format.pp_print_flush Format.std_formatter ();
 856   flush stdout
 857
 858 (* vim:set encoding=utf8 foldmethod=marker: *)