helm/software/components/extlib/hExtlib.ml

   1 (* Copyright (C) 2005, HELM Team.
   2  *
   3  * This file is part of HELM, an Hypertextual, Electronic
   4  * Library of Mathematics, developed at the Computer Science
   5  * Department, University of Bologna, Italy.
   6  *
   7  * HELM is free software; you can redistribute it and/or
   8  * modify it under the terms of the GNU General Public License
   9  * as published by the Free Software Foundation; either version 2
  10  * of the License, or (at your option) any later version.
  11  *
  12  * HELM is distributed in the hope that it will be useful,
  13  * but WITHOUT ANY WARRANTY; without even the implied warranty of
  14  * MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the
  15  * GNU General Public License for more details.
  16  *
  17  * You should have received a copy of the GNU General Public License
  18  * along with HELM; if not, write to the Free Software
  19  * Foundation, Inc., 59 Temple Place - Suite 330, Boston,
  20  * MA  02111-1307, USA.
  21  *
  22  * For details, see the HELM World-Wide-Web page,
  23  * http://cs.unibo.it/helm/.
  24  *)
  25
  26 (* $Id$ *)
  27
  28 (** PROFILING *)
  29
  30 let profiling_enabled = ref true ;; (* ComponentsConf.profiling *)
  31
  32 let something_profiled = ref false ;;
  33
  34 let _ =
  35   if !something_profiled then
  36     at_exit
  37       (fun _ ->
  38         prerr_endline
  39          (Printf.sprintf "!! %39s ---------- --------- --------- ---------"
  40            (String.make 39 '-'));
  41         prerr_endline
  42          (Printf.sprintf "!! %-39s %10s %9s %9s %9s"
  43            "function" "#calls" "total" "max" "average"))
  44
  45 let profiling_printings = ref (fun _ -> true)
  46 let set_profiling_printings f = profiling_printings := f
  47
  48 type profiler = { profile : 'a 'b. ('a -> 'b) -> 'a -> 'b }
  49 let profile ?(enable = true) s =
  50  if !profiling_enabled && enable then
  51    let total = ref 0.0 in
  52    let calls = ref 0 in
  53    let max = ref 0.0 in
  54    let profile f x =
  55     if not !profiling_enabled then f x else
  56     let before = Unix.gettimeofday () in
  57     try
  58      incr calls;
  59      let res = f x in
  60      let after = Unix.gettimeofday () in
  61      let delta = after -. before in
  62       total := !total +. delta;
  63       if delta > !max then max := delta;
  64       res
  65     with
  66      exc ->
  67       let after = Unix.gettimeofday () in
  68       let delta = after -. before in
  69        total := !total +. delta;
  70        if delta > !max then max := delta;
  71        raise exc
  72    in
  73    at_exit
  74     (fun () ->
  75       if !profiling_printings s && !calls <> 0 then
  76        begin
  77         something_profiled := true;
  78         prerr_endline
  79          (Printf.sprintf "!! %-39s %10d %9.4f %9.4f %9.4f"
  80          s !calls !total !max (!total /. (float_of_int !calls)))
  81        end);
  82    { profile = profile }
  83  else
  84    { profile = fun f x -> f x }
  85
  86 (** {2 Optional values} *)
  87
  88 let map_option f = function None -> None | Some v -> Some (f v)
  89 let iter_option f = function None -> () | Some v -> f v
  90 let unopt = function None -> failwith "unopt: None" | Some v -> v
  91
  92 (** {2 String processing} *)
  93
  94 let split ?(sep = ' ') s =
  95   let pieces = ref [] in
  96   let rec aux idx =
  97     match (try Some (String.index_from s idx sep) with Not_found -> None) with
  98     | Some pos ->
  99         pieces := String.sub s idx (pos - idx) :: !pieces;
 100         aux (pos + 1)
 101     | None -> pieces := String.sub s idx (String.length s - idx) :: !pieces
 102   in
 103   aux 0;
 104   List.rev !pieces
 105
 106 let trim_blanks s =
 107   let rec find_left idx =
 108     match s.[idx] with
 109     | ' ' | '\t' | '\r' | '\n' -> find_left (idx + 1)
 110     | _ -> idx
 111   in
 112   let rec find_right idx =
 113     match s.[idx] with
 114     | ' ' | '\t' | '\r' | '\n' -> find_right (idx - 1)
 115     | _ -> idx
 116   in
 117   let s_len = String.length s in
 118   let left, right = find_left 0, find_right (s_len - 1) in
 119   String.sub s left (right - left + 1)
 120
 121 (** {2 Char processing} *)
 122
 123 let is_alpha c =
 124   let code = Char.code c in
 125   (code >= 65 && code <= 90) || (code >= 97 && code <= 122)
 126
 127 let is_digit c =
 128   let code = Char.code c in
 129   code >= 48 && code <= 57
 130
 131 let is_blank c =
 132   let code = Char.code c in
 133   code = 9 || code = 10 || code = 13 || code = 32
 134
 135 let is_alphanum c = is_alpha c || is_digit c
 136
 137 (** {2 List processing} *)
 138
 139 let flatten_map f l =
 140   List.flatten (List.map f l)
 141 ;;
 142
 143 let list_mapi f l =
 144   let rec aux k = function
 145     | [] -> []
 146     | h::tl -> f h k :: aux (k+1) tl
 147   in
 148      aux 0 l
 149 ;;
 150
 151 let list_mapi_acc f a l =
 152   let rec aux k a res = function
 153     | [] -> a, List.rev res
 154     | h::tl -> let a,h = f h k a in aux (k+1) a (h::res) tl
 155   in
 156    aux 0 a [] l
 157 ;;
 158
 159 let list_index p =
 160  let rec aux n =
 161   function
 162      [] -> None
 163    | he::_ when p he -> Some (n,he)
 164    | _::tl -> aux (n + 1) tl
 165  in
 166   aux 0
 167 ;;
 168
 169 let rec list_iter_default2 f l1 def l2 =
 170   match l1,l2 with
 171     | [], _ -> ()
 172     | a::ta, b::tb -> f a b; list_iter_default2 f ta def tb
 173     | a::ta, [] -> f a def; list_iter_default2 f ta def []
 174 ;;
 175
 176 let rec list_forall_default3 f l1 l2 def l3 =
 177   match l1,l2,l3 with
 178     | [], [], _ -> true
 179     | [], _, _
 180     | _, [], _ -> raise (Invalid_argument "list_forall_default3")
 181     | a::ta, b::tb, c::tc -> f a b c && list_forall_default3 f ta tb def tc
 182     | a::ta, b::tb, [] -> f a b def && list_forall_default3 f ta tb def []
 183 ;;
 184
 185 exception FailureAt of int;;
 186
 187 let list_forall_default3_var f l1 l2 def l3 =
 188   let rec aux f l1 l2 def l3 i =
 189     match l1,l2,l3 with
 190       | [], [], _ -> true
 191       | [], _, _
 192       | _, [], _ -> raise (Invalid_argument "list_forall_default3")
 193       | a::ta, b::tb, c::tc ->
 194           if f a b c then aux f ta tb def tc (i+1)
 195           else raise (FailureAt i)
 196       | a::ta, b::tb, [] ->
 197           if f a b def then aux f ta tb def [] (i+1)
 198           else raise (FailureAt i)
 199   in aux f l1 l2 def l3 0
 200 ;;
 201
 202 let sharing_map f l =
 203   let unchanged = ref true in
 204   let rec aux b = function
 205     | [] as t -> unchanged := b; t
 206     | he::tl ->
 207         let he1 = f he in
 208         he1 :: aux (b && he1 == he) tl
 209   in
 210   let l1 = aux true l in
 211   if !unchanged then l else l1
 212 ;;
 213
 214 let rec list_uniq ?(eq=(=)) = function
 215   | [] -> []
 216   | h::[] -> [h]
 217   | h1::h2::tl when eq h1 h2 -> list_uniq ~eq (h2 :: tl)
 218   | h1::tl (* when h1 <> h2 *) -> h1 :: list_uniq ~eq tl
 219
 220 let rec filter_map f =
 221   function
 222   | [] -> []
 223   | hd :: tl ->
 224       (match f hd with
 225       | None -> filter_map f tl
 226       | Some v -> v :: filter_map f tl)
 227
 228 let filter_map_acc f acc l =
 229   let acc, res =
 230    List.fold_left
 231     (fun (acc, res) t ->
 232        match f acc t with
 233        | None -> acc, res
 234        | Some (acc, x) -> acc, x::res)
 235     (acc,[]) l
 236   in
 237    acc, List.rev res
 238 ;;
 239
 240 let filter_map_monad f acc l =
 241   let acc, res =
 242    List.fold_left
 243     (fun (acc, res) t ->
 244        match f acc t with
 245        | acc, None -> acc, res
 246        | acc, Some x -> acc, x::res)
 247     (acc,[]) l
 248   in
 249    acc, List.rev res
 250 ;;
 251
 252 let list_rev_map_filter f l =
 253    let rec aux a = function
 254       | []       -> a
 255       | hd :: tl ->
 256          begin match f hd with
 257             | None   -> aux a tl
 258             | Some b -> aux (b :: a) tl
 259          end
 260    in
 261    aux [] l
 262
 263 let list_rev_map_filter_fold f v l =
 264    let rec aux v a = function
 265       | []       -> v, a
 266       | hd :: tl ->
 267          begin match f v hd with
 268             | v, None   -> aux v a tl
 269             | v, Some b -> aux v (b :: a) tl
 270          end
 271    in
 272    aux v [] l
 273
 274 let list_concat ?(sep = []) =
 275   let rec aux acc =
 276     function
 277     | [] -> []
 278     | [ last ] -> List.flatten (List.rev (last :: acc))
 279     | hd :: tl -> aux ([sep; hd] @ acc) tl
 280   in
 281   aux []
 282
 283 let list_iter_sep ~sep f =
 284   let rec aux =
 285     function
 286     | [] -> ()
 287     | [ last ] -> f last
 288     | hd :: tl -> f hd; sep (); aux tl
 289   in
 290   aux
 291
 292 let rec list_findopt f l =
 293   let rec aux k = function
 294     | [] -> None
 295     | x::tl ->
 296         (match f x k with
 297         | None -> aux (succ k) tl
 298         | Some _ as rc -> rc)
 299   in
 300   aux 0 l
 301
 302 let split_nth n l =
 303   let rec aux acc n l =
 304     match n, l with
 305     | 0, _ -> List.rev acc, l
 306     | n, [] -> raise (Failure "HExtlib.split_nth")
 307     | n, hd :: tl -> aux (hd :: acc) (n - 1) tl in
 308   aux [] n l
 309
 310 let list_last l =
 311   let l = List.rev l in
 312   try List.hd l with exn -> raise (Failure "HExtlib.list_last")
 313 ;;
 314
 315 let rec list_assoc_all a = function
 316    | []                      -> []
 317    | (x, y) :: tl when x = a -> y :: list_assoc_all a tl
 318    | _ :: tl                 -> list_assoc_all a tl
 319 ;;
 320
 321 (** {2 File predicates} *)
 322
 323 let is_dir fname =
 324   try
 325     (Unix.stat fname).Unix.st_kind = Unix.S_DIR
 326   with Unix.Unix_error _ -> false
 327
 328 let writable_dir path =
 329   try
 330     let file = path ^ "/prova_matita" in
 331     let oc = open_out file in
 332     close_out oc;
 333     Sys.remove file;
 334     true
 335   with Sys_error _ -> false
 336
 337
 338 let is_regular fname =
 339   try
 340     (Unix.stat fname).Unix.st_kind = Unix.S_REG
 341   with Unix.Unix_error _ -> false
 342
 343 let is_executable fname =
 344   try
 345     let stat = (Unix.stat fname) in
 346     stat.Unix.st_kind = Unix.S_REG &&
 347     (stat.Unix.st_perm land 0o001 > 0)
 348   with Unix.Unix_error _ -> false
 349
 350 let chmod mode filename =
 351    Unix.chmod filename mode
 352
 353 let mkdir path =
 354   let components = split ~sep:'/' path in
 355   let rec aux where = function
 356     | [] -> ()
 357     | piece::tl ->
 358         let path =
 359           if where = "" then piece else where ^ "/" ^ piece in
 360         (try
 361           Unix.mkdir path 0o755; chmod 0o2775 path
 362         with
 363         | Unix.Unix_error (Unix.EEXIST,_,_) -> ()
 364         | Unix.Unix_error (e,_,_) ->
 365             raise
 366               (Failure
 367                 ("Unix.mkdir " ^ path ^ " 0o2775 :" ^ (Unix.error_message e))));
 368         aux path tl
 369   in
 370   let where = if path.[0] = '/' then "/" else "" in
 371   aux where components
 372
 373 (** {2 Filesystem} *)
 374
 375 let input_file fname =
 376   let size = (Unix.stat fname).Unix.st_size in
 377   let buf = Buffer.create size in
 378   let ic = open_in fname in
 379   Buffer.add_channel buf ic size;
 380   close_in ic;
 381   Buffer.contents buf
 382
 383 let input_all ic =
 384   let size = 10240 in
 385   let buf = Buffer.create size in
 386   let s = String.create size in
 387   (try
 388     while true do
 389       let bytes = input ic s 0 size in
 390       if bytes = 0 then raise End_of_file
 391       else Buffer.add_substring buf s 0 bytes
 392     done
 393   with End_of_file -> ());
 394   Buffer.contents buf
 395
 396 let output_file ~filename ~text =
 397   let oc = open_out filename in
 398   output_string oc text;
 399   close_out oc;
 400   chmod 0o664 filename
 401
 402 let blank_split s =
 403   let len = String.length s in
 404   let buf = Buffer.create 0 in
 405   let rec aux acc i =
 406     if i >= len
 407     then begin
 408       if Buffer.length buf > 0
 409       then List.rev (Buffer.contents buf :: acc)
 410       else List.rev acc
 411     end else begin
 412       if is_blank s.[i] then
 413         if Buffer.length buf > 0 then begin
 414           let s = Buffer.contents buf in
 415           Buffer.clear buf;
 416           aux (s :: acc) (i + 1)
 417         end else
 418           aux acc (i + 1)
 419       else begin
 420         Buffer.add_char buf s.[i];
 421         aux acc (i + 1)
 422       end
 423     end
 424   in
 425   aux [] 0
 426
 427   (* Rules: * "~name" -> home dir of "name"
 428    * "~" -> value of $HOME if defined, home dir of the current user otherwise *)
 429 let tilde_expand s =
 430   let get_home login = (Unix.getpwnam login).Unix.pw_dir in
 431   let expand_one s =
 432     let len = String.length s in
 433     if len > 0 && s.[0] = '~' then begin
 434       let login_len = ref 1 in
 435       while !login_len < len && is_alphanum (s.[!login_len]) do
 436         incr login_len
 437       done;
 438       let login = String.sub s 1 (!login_len - 1) in
 439       try
 440         let home =
 441           if login = "" then
 442             try Sys.getenv "HOME" with Not_found -> get_home (Unix.getlogin ())
 443           else
 444             get_home login
 445         in
 446         home ^ String.sub s !login_len (len - !login_len)
 447       with Not_found | Invalid_argument _ -> s
 448     end else
 449       s
 450   in
 451   String.concat " " (List.map expand_one (blank_split s))
 452
 453 let find ?(test = fun _ -> true) path =
 454   let rec aux acc todo =
 455     match todo with
 456     | [] -> acc
 457     | path :: tl ->
 458         try
 459           let handle = Unix.opendir path in
 460           let dirs = ref [] in
 461           let matching_files = ref [] in
 462           (try
 463             while true do
 464               match Unix.readdir handle with
 465               | "." | ".." -> ()
 466               | entry ->
 467                   let qentry = path ^ "/" ^ entry in
 468                   (try
 469                     if is_dir qentry then
 470                       dirs := qentry :: !dirs
 471                     else if test qentry then
 472                       matching_files := qentry :: !matching_files;
 473                   with Unix.Unix_error _ -> ())
 474             done
 475           with End_of_file -> Unix.closedir handle);
 476           aux (!matching_files @ acc) (!dirs @ tl)
 477         with Unix.Unix_error _ -> aux acc tl
 478   in
 479   aux [] [path]
 480
 481 let safe_remove fname = if Sys.file_exists fname then Sys.remove fname
 482
 483 let is_dir_empty d =
 484  try
 485   let od = Unix.opendir d in
 486   let rec aux () =
 487    let name = Unix.readdir od in
 488    if name <> "." && name <> ".." then false else aux () in
 489   let res = try aux () with End_of_file -> true in
 490    Unix.closedir od;
 491    res
 492  with
 493   Unix.Unix_error _ -> true (* raised by Unix.opendir, we hope :-) *)
 494
 495 let safe_rmdir d = try Unix.rmdir d with Unix.Unix_error _ -> ()
 496
 497 let rec rmdir_descend d =
 498   if is_dir_empty d then
 499     begin
 500       safe_rmdir d;
 501       rmdir_descend (Filename.dirname d)
 502     end
 503
 504
 505 (** {2 Exception handling} *)
 506
 507 let finally at_end f arg =
 508   let res =
 509     try f arg
 510     with exn -> at_end (); raise exn
 511   in
 512   at_end ();
 513   res
 514
 515 (** {2 Localized exceptions } *)
 516
 517 exception Localized of Stdpp.location * exn
 518
 519 let loc_of_floc floc = Stdpp.first_pos floc, Stdpp.last_pos floc;;
 520
 521 let floc_of_loc (loc_begin, loc_end) =
 522  Stdpp.make_loc (loc_begin, loc_end)
 523
 524 let dummy_floc = floc_of_loc (0, 0)
 525
 526 let raise_localized_exception ~offset floc exn =
 527  let x, y = loc_of_floc floc in
 528  let x = offset + x in
 529  let y = offset + y in
 530  let floc = floc_of_loc (x,y) in
 531   raise (Localized (floc, exn))
 532
 533 let estimate_size x =
 534   4 * (String.length (Marshal.to_string x [])) / 1024
 535
 536 let normalize_path s =
 537   let s = Str.global_replace (Str.regexp "//") "/" s in
 538   let l = Str.split (Str.regexp "/") s in
 539   let rec aux acc = function
 540     | [] -> acc
 541     | he::"."::tl -> aux acc (he::tl)
 542     | he::".."::tl when he <> ".." -> aux [] (acc @ tl)
 543     | he::tl -> aux (acc@[he]) tl
 544   in
 545   (if Str.string_match (Str.regexp "^/") s 0 then "/" else "") ^
 546   String.concat "/" (aux [] l)
 547   ^ (if Str.string_match (Str.regexp "/$") s 0 then "/" else "")
 548 ;;
 549
 550 let find_in paths path =
 551    let rec aux = function
 552    | [] -> raise (Failure "find_in")
 553    | p :: tl ->
 554       let path = normalize_path (p ^ "/" ^ path) in
 555        try
 556          if (Unix.stat path).Unix.st_kind = Unix.S_REG then path
 557          else aux tl
 558        with Unix.Unix_error _ ->
 559                aux tl
 560    in
 561    try
 562      aux paths
 563    with Unix.Unix_error _ | Failure _ ->
 564      raise
 565        (Failure "find_in")
 566 ;;
 567
 568 let is_prefix_of_aux d1 d2 =
 569   let len1 = String.length d1 in
 570   let len2 = String.length d2 in
 571   if len2 < len1 then
 572     false, len1, len2
 573   else
 574     let pref = String.sub d2 0 len1 in
 575     pref = d1 && (len1 = len2 || d1.[len1-1] = '/' || d2.[len1] = '/'), len1, len2
 576
 577 let is_prefix_of d1 d2 =
 578   let b,_,_ = is_prefix_of_aux d1 d2 in b
 579 ;;
 580
 581 let chop_prefix prefix s =
 582   let b,lp,ls = is_prefix_of_aux prefix s in
 583   if b then
 584     String.sub s lp (ls - lp)
 585   else
 586     s
 587 ;;
 588
 589 let touch s =
 590   try close_out(open_out s) with Sys_error _ -> ()
 591 ;;
 592
 593 let rec mk_list x = function
 594   | 0 -> []
 595   | n -> x :: mk_list x (n-1)
 596 ;;
 597
 598 let list_seq start stop =
 599   if start > stop then [] else
 600   let rec aux pos =
 601     if pos = stop then []
 602     else pos :: (aux (pos+1))
 603   in
 604     aux start
 605 ;;
 606
 607 let rec list_skip n l =
 608   match n,l with
 609   | 0,_ -> l
 610   | n,_::l -> list_skip (n-1) l
 611   | _, [] -> assert false
 612 ;;
 613