helm/software/components/grafite_parser/grafiteDisambiguate.ml

   1 (*
   2  *
   3  * This file is part of HELM, an Hypertextual, Electronic
   4  * Library of Mathematics, developed at the Computer Science
   5  * Department, University of Bologna, Italy.
   6  *
   7  * HELM is free software; you can redistribute it and/or
   8  * modify it under the terms of the GNU General Public License
   9  * as published by the Free Software Foundation; either version 2
  10  * of the License, or (at your option) any later version.
  11  *
  12  * HELM is distributed in the hope that it will be useful,
  13  * but WITHOUT ANY WARRANTY; without even the implied warranty of
  14  * MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the
  15  * GNU General Public License for more details.
  16  *
  17  * You should have received a copy of the GNU General Public License
  18  * along with HELM; if not, write to the Free Software
  19  * Foundation, Inc., 59 Temple Place - Suite 330, Boston,
  20  * MA  02111-1307, USA.
  21  *
  22  * For details, see the HELM World-Wide-Web page,
  23  * http://helm.cs.unibo.it/
  24  *)
  25
  26 (* $Id$ *)
  27
  28 exception BaseUriNotSetYet
  29
  30 type tactic =
  31  (CicNotationPt.term, CicNotationPt.term,
  32   CicNotationPt.term GrafiteAst.reduction, string)
  33    GrafiteAst.tactic
  34
  35 type lazy_tactic =
  36   (Cic.term, Cic.lazy_term, Cic.lazy_term GrafiteAst.reduction, string)
  37     GrafiteAst.tactic
  38
  39 let singleton msg = function
  40   | [x], _ -> x
  41   | l, _   ->
  42       let debug =
  43          Printf.sprintf "GrafiteDisambiguate.singleton (%s): %u interpretations"
  44          msg (List.length l)
  45       in
  46       HLog.debug debug; assert false
  47
  48 let __Implicit = "__Implicit__"
  49 let __Closed_Implicit = "__Closed_Implicit__"
  50
  51 let cic_mk_choice = function
  52   | LexiconAst.Symbol_alias (name, _, dsc) ->
  53      if name = __Implicit then
  54        dsc, `Sym_interp (fun _ -> Cic.Implicit None)
  55      else if name = __Closed_Implicit then
  56        dsc, `Sym_interp (fun _ -> Cic.Implicit (Some `Closed))
  57      else
  58        DisambiguateChoices.cic_lookup_symbol_by_dsc name dsc
  59   | LexiconAst.Number_alias (_, dsc) ->
  60      DisambiguateChoices.lookup_num_by_dsc dsc
  61   | LexiconAst.Ident_alias (name, uri) ->
  62      uri, `Sym_interp
  63       (fun l->assert(l = []);CicUtil.term_of_uri (UriManager.uri_of_string uri))
  64 ;;
  65
  66 let ncic_mk_choice = function
  67   | LexiconAst.Symbol_alias (name, _, dsc) ->
  68      if name = __Implicit then
  69        dsc, `Sym_interp (fun _ -> NCic.Implicit `Term)
  70      else if name = __Closed_Implicit then
  71        dsc, `Sym_interp (fun _ -> NCic.Implicit `Closed)
  72      else
  73        DisambiguateChoices.lookup_symbol_by_dsc
  74         ~mk_implicit:(function
  75            | true -> NCic.Implicit `Closed
  76            | false -> NCic.Implicit `Term)
  77         ~mk_appl:(function
  78            (NCic.Appl l)::tl -> NCic.Appl (l@tl) | l -> NCic.Appl l)
  79         ~term_of_uri:(fun uri ->
  80            fst (OCic2NCic.convert_term uri (CicUtil.term_of_uri uri)))
  81         ~term_of_nref:(fun nref -> NCic.Const nref)
  82        name dsc
  83   | LexiconAst.Number_alias (_, dsc) ->
  84        let desc,f = DisambiguateChoices.lookup_num_by_dsc dsc in
  85        desc, `Num_interp
  86          (fun num ->
  87             fst (OCic2NCic.convert_term
  88               (UriManager.uri_of_string "cic:/xxx/x.con")
  89               (match f with `Num_interp f -> f num | _ -> assert false)))
  90   | LexiconAst.Ident_alias (name, uri) ->
  91      uri, `Sym_interp
  92       (fun l->assert(l = []);
  93         try
  94          let nref = NReference.reference_of_string uri in
  95           NCic.Const nref
  96         with
  97          NReference.IllFormedReference _ ->
  98           let uri = UriManager.uri_of_string uri in
  99            fst (OCic2NCic.convert_term uri (CicUtil.term_of_uri uri)))
 100 ;;
 101
 102
 103 let mk_implicit b =
 104   match b with
 105   | false ->
 106       LexiconAst.Symbol_alias (__Implicit,-1,"Fake Implicit")
 107   | true ->
 108       LexiconAst.Symbol_alias (__Closed_Implicit,-1,"Fake Closed Implicit")
 109 ;;
 110
 111 let lookup_in_library
 112   interactive_user_uri_choice input_or_locate_uri item
 113 =
 114   let mk_ident_alias id u =
 115     LexiconAst.Ident_alias (id,UriManager.string_of_uri u)
 116   in
 117   let mk_num_alias instance =
 118     List.map
 119      (fun dsc,_ -> LexiconAst.Number_alias (instance,dsc))
 120      (DisambiguateChoices.lookup_num_choices())
 121   in
 122   let mk_symbol_alias symb ino (dsc, _,_) =
 123      LexiconAst.Symbol_alias (symb,ino,dsc)
 124   in
 125   let dbd = LibraryDb.instance () in
 126   let choices_of_id id =
 127     let uris = Whelp.locate ~dbd id in
 128      match uris with
 129       | [] ->
 130          (match
 131            (input_or_locate_uri
 132              ~title:("URI matching \"" ^ id ^ "\" unknown.")
 133              ?id:(Some id) ())
 134          with
 135          | None -> []
 136          | Some uri -> [uri])
 137       | [uri] -> [uri]
 138       | _ ->
 139           interactive_user_uri_choice ~selection_mode:`MULTIPLE
 140            ?ok:(Some "Try selected.")
 141            ?enable_button_for_non_vars:(Some true)
 142            ~title:"Ambiguous input."
 143            ~msg: ("Ambiguous input \"" ^ id ^
 144               "\". Please, choose one or more interpretations:")
 145            ~id
 146            uris
 147   in
 148   match item with
 149   | DisambiguateTypes.Id id ->
 150       let uris = choices_of_id id in
 151       List.map (mk_ident_alias id) uris
 152   | DisambiguateTypes.Symbol (symb, ino) ->
 153    (try
 154      List.map (mk_symbol_alias symb ino)
 155       (TermAcicContent.lookup_interpretations symb)
 156     with
 157      TermAcicContent.Interpretation_not_found -> [])
 158   | DisambiguateTypes.Num instance -> mk_num_alias instance
 159 ;;
 160
 161 let nlookup_in_library
 162   interactive_user_uri_choice input_or_locate_uri item
 163 =
 164   match item with
 165   | DisambiguateTypes.Id id ->
 166      (try
 167        let references = NCicLibrary.resolve id in
 168         List.map
 169          (fun u -> LexiconAst.Ident_alias (id,NReference.string_of_reference u)
 170          ) references @
 171         lookup_in_library interactive_user_uri_choice input_or_locate_uri item
 172       with
 173        NCicEnvironment.ObjectNotFound _ ->
 174         lookup_in_library interactive_user_uri_choice input_or_locate_uri item)
 175   | _ -> lookup_in_library interactive_user_uri_choice input_or_locate_uri item
 176 ;;
 177
 178 let fix_instance item l =
 179  match item with
 180     DisambiguateTypes.Symbol (_,n) ->
 181      List.map
 182       (function
 183           LexiconAst.Symbol_alias (s,_,d) -> LexiconAst.Symbol_alias (s,n,d)
 184         | _ -> assert false
 185       ) l
 186   | DisambiguateTypes.Num n ->
 187      List.map
 188       (function
 189           LexiconAst.Number_alias (_,d) -> LexiconAst.Number_alias (n,d)
 190         | _ -> assert false
 191       ) l
 192   | DisambiguateTypes.Id _ -> l
 193 ;;
 194
 195
 196   (** @param term not meaningful when context is given *)
 197 let disambiguate_term expty text prefix_len lexicon_status_ref context metasenv
 198 term =
 199   let lexicon_status = !lexicon_status_ref in
 200   let (diff, metasenv, subst, cic, _) =
 201     singleton "first"
 202       (CicDisambiguate.disambiguate_term
 203         ~aliases:lexicon_status#lstatus.LexiconEngine.aliases
 204         ~expty ~universe:(Some lexicon_status#lstatus.LexiconEngine.multi_aliases)
 205         ~lookup_in_library
 206         ~mk_choice:cic_mk_choice
 207         ~mk_implicit ~fix_instance
 208         ~description_of_alias:LexiconAst.description_of_alias
 209         ~context ~metasenv ~subst:[] (text,prefix_len,term))
 210   in
 211   let lexicon_status = LexiconEngine.set_proof_aliases lexicon_status diff in
 212   lexicon_status_ref := lexicon_status;
 213   metasenv,(*subst,*) cic
 214 ;;
 215
 216 let disambiguate_nterm expty estatus context metasenv subst thing
 217 =
 218   let diff, metasenv, subst, cic =
 219     singleton "first"
 220       (NCicDisambiguate.disambiguate_term
 221         ~rdb:estatus
 222         ~aliases:estatus#lstatus.LexiconEngine.aliases
 223         ~expty
 224         ~universe:(Some estatus#lstatus.LexiconEngine.multi_aliases)
 225         ~lookup_in_library:nlookup_in_library
 226         ~mk_choice:ncic_mk_choice
 227         ~mk_implicit ~fix_instance
 228         ~description_of_alias:LexiconAst.description_of_alias
 229         ~context ~metasenv ~subst thing)
 230   in
 231   let estatus = LexiconEngine.set_proof_aliases estatus diff in
 232    metasenv, subst, estatus, cic
 233 ;;
 234
 235
 236   (** disambiguate_lazy_term (circa): term -> (unit -> status) * lazy_term
 237    * rationale: lazy_term will be invoked in different context to obtain a term,
 238    * each invocation will disambiguate the term and can add aliases. Once all
 239    * disambiguations have been performed, the first returned function can be
 240    * used to obtain the resulting aliases *)
 241 let disambiguate_lazy_term expty text prefix_len lexicon_status_ref term =
 242   (fun context metasenv ugraph ->
 243     let lexicon_status = !lexicon_status_ref in
 244     let (diff, metasenv, _, cic, ugraph) =
 245       singleton "second"
 246         (CicDisambiguate.disambiguate_term
 247           ~lookup_in_library
 248           ~mk_choice:cic_mk_choice
 249           ~mk_implicit ~fix_instance
 250           ~description_of_alias:LexiconAst.description_of_alias
 251           ~initial_ugraph:ugraph ~aliases:lexicon_status#lstatus.LexiconEngine.aliases
 252           ~universe:(Some lexicon_status#lstatus.LexiconEngine.multi_aliases)
 253           ~context ~metasenv ~subst:[]
 254           (text,prefix_len,term) ~expty) in
 255     let lexicon_status = LexiconEngine.set_proof_aliases lexicon_status diff in
 256     lexicon_status_ref := lexicon_status;
 257     cic, metasenv, ugraph)
 258 ;;
 259
 260 let disambiguate_pattern
 261   text prefix_len lexicon_status_ref (wanted, hyp_paths, goal_path)
 262 =
 263   let interp path =CicDisambiguate.interpretate_path [] path in
 264   let goal_path = HExtlib.map_option interp goal_path in
 265   let hyp_paths = List.map (fun (name, path) -> name, interp path) hyp_paths in
 266   let wanted =
 267    match wanted with
 268       None -> None
 269     | Some wanted ->
 270        let wanted =
 271          disambiguate_lazy_term None text prefix_len lexicon_status_ref wanted
 272        in
 273        Some wanted
 274   in
 275   (wanted, hyp_paths, goal_path)
 276 ;;
 277
 278 type pattern =
 279   CicNotationPt.term Disambiguate.disambiguator_input option *
 280   (string * NCic.term) list * NCic.term option
 281
 282 let disambiguate_npattern (text, prefix_len, (wanted, hyp_paths, goal_path)) =
 283   let interp path = NCicDisambiguate.disambiguate_path path in
 284   let goal_path = HExtlib.map_option interp goal_path in
 285   let hyp_paths = List.map (fun (name, path) -> name, interp path) hyp_paths in
 286   let wanted =
 287     match wanted with None -> None | Some x -> Some (text,prefix_len,x)
 288   in
 289    (wanted, hyp_paths, goal_path)
 290 ;;
 291
 292 let disambiguate_reduction_kind text prefix_len lexicon_status_ref = function
 293   | `Unfold (Some t) ->
 294       let t =
 295          disambiguate_lazy_term None text prefix_len lexicon_status_ref t in
 296       `Unfold (Some t)
 297   | `Normalize
 298   | `Simpl
 299   | `Unfold None
 300   | `Whd as kind -> kind
 301 ;;
 302
 303 let disambiguate_auto_params
 304   disambiguate_term metasenv context (terms, params)
 305 =
 306     let metasenv, terms =
 307       List.fold_right
 308        (fun t (metasenv, terms) ->
 309          let metasenv,t = disambiguate_term context metasenv t in
 310          metasenv,t::terms) terms (metasenv, [])
 311     in
 312     metasenv, (terms, params)
 313 ;;
 314
 315 let disambiguate_just disambiguate_term context metasenv =
 316  function
 317     `Term t ->
 318       let metasenv,t = disambiguate_term context metasenv t in
 319        metasenv, `Term t
 320   | `Auto params ->
 321       let metasenv,params = disambiguate_auto_params disambiguate_term metasenv
 322        context params
 323       in
 324        metasenv, `Auto params
 325 ;;
 326
 327 let rec disambiguate_tactic
 328   lexicon_status_ref context metasenv goal (text,prefix_len,tactic)
 329 =
 330   let disambiguate_term_hint =
 331     let _,_,expty =
 332       List.find (fun (x,_,_) -> Some x = goal) metasenv
 333     in
 334     disambiguate_term (Some expty) text prefix_len lexicon_status_ref in
 335   let disambiguate_term =
 336     disambiguate_term None text prefix_len lexicon_status_ref in
 337   let disambiguate_pattern =
 338     disambiguate_pattern text prefix_len lexicon_status_ref in
 339   let disambiguate_reduction_kind =
 340     disambiguate_reduction_kind text prefix_len lexicon_status_ref in
 341   let disambiguate_lazy_term =
 342     disambiguate_lazy_term None text prefix_len lexicon_status_ref in
 343   let disambiguate_tactic metasenv tac =
 344    disambiguate_tactic lexicon_status_ref context metasenv goal (text,prefix_len,tac)
 345   in
 346   let disambiguate_auto_params m p =
 347     disambiguate_auto_params disambiguate_term m context p
 348   in
 349    match tactic with
 350     (* Higher  order tactics *)
 351     | GrafiteAst.Progress (loc,tac) ->
 352         let metasenv,tac = disambiguate_tactic metasenv tac in
 353         metasenv,GrafiteAst.Progress (loc,tac)
 354     | GrafiteAst.Solve (loc,tacl) ->
 355         let metasenv,tacl =
 356          List.fold_right
 357           (fun tac (metasenv,tacl) ->
 358             let metasenv,tac = disambiguate_tactic metasenv tac in
 359              metasenv,tac::tacl
 360           ) tacl (metasenv,[])
 361         in
 362          metasenv,GrafiteAst.Solve (loc,tacl)
 363     | GrafiteAst.Try (loc,tac) ->
 364         let metasenv,tac = disambiguate_tactic metasenv tac in
 365         metasenv,GrafiteAst.Try (loc,tac)
 366     | GrafiteAst.First (loc,tacl) ->
 367         let metasenv,tacl =
 368          List.fold_right
 369           (fun tac (metasenv,tacl) ->
 370             let metasenv,tac = disambiguate_tactic metasenv tac in
 371              metasenv,tac::tacl
 372           ) tacl (metasenv,[])
 373         in
 374          metasenv,GrafiteAst.First (loc,tacl)
 375     | GrafiteAst.Seq (loc,tacl) ->
 376         let metasenv,tacl =
 377          List.fold_right
 378           (fun tac (metasenv,tacl) ->
 379             let metasenv,tac = disambiguate_tactic metasenv tac in
 380              metasenv,tac::tacl
 381           ) tacl (metasenv,[])
 382         in
 383          metasenv,GrafiteAst.Seq (loc,tacl)
 384     | GrafiteAst.Repeat (loc,tac) ->
 385         let metasenv,tac = disambiguate_tactic metasenv tac in
 386         metasenv,GrafiteAst.Repeat (loc,tac)
 387     | GrafiteAst.Do (loc,n,tac) ->
 388         let metasenv,tac = disambiguate_tactic metasenv tac in
 389         metasenv,GrafiteAst.Do (loc,n,tac)
 390     | GrafiteAst.Then (loc,tac,tacl) ->
 391         let metasenv,tac = disambiguate_tactic metasenv tac in
 392         let metasenv,tacl =
 393          List.fold_right
 394           (fun tac (metasenv,tacl) ->
 395             let metasenv,tac = disambiguate_tactic metasenv tac in
 396              metasenv,tac::tacl
 397           ) tacl (metasenv,[])
 398         in
 399          metasenv,GrafiteAst.Then (loc,tac,tacl)
 400     (* First order tactics *)
 401     | GrafiteAst.Absurd (loc, term) ->
 402         let metasenv,cic = disambiguate_term context metasenv term in
 403         metasenv,GrafiteAst.Absurd (loc, cic)
 404     | GrafiteAst.Apply (loc, term) ->
 405         let metasenv,cic = disambiguate_term context metasenv term in
 406         metasenv,GrafiteAst.Apply (loc, cic)
 407     | GrafiteAst.ApplyRule (loc, term) ->
 408         let metasenv,cic = disambiguate_term_hint context metasenv term in
 409         metasenv,GrafiteAst.ApplyRule (loc, cic)
 410     | GrafiteAst.ApplyP (loc, term) ->
 411         let metasenv,cic = disambiguate_term context metasenv term in
 412         metasenv,GrafiteAst.ApplyP (loc, cic)
 413     | GrafiteAst.ApplyS (loc, term, params) ->
 414         let metasenv, params = disambiguate_auto_params metasenv params in
 415         let metasenv,cic = disambiguate_term context metasenv term in
 416         metasenv,GrafiteAst.ApplyS (loc, cic, params)
 417     | GrafiteAst.Assumption loc ->
 418         metasenv,GrafiteAst.Assumption loc
 419     | GrafiteAst.AutoBatch (loc,params) ->
 420         let metasenv, params = disambiguate_auto_params metasenv params in
 421         metasenv,GrafiteAst.AutoBatch (loc,params)
 422     | GrafiteAst.Cases (loc, what, pattern, idents) ->
 423         let metasenv,what = disambiguate_term context metasenv what in
 424         let pattern = disambiguate_pattern pattern in
 425         metasenv,GrafiteAst.Cases (loc, what, pattern, idents)
 426     | GrafiteAst.Change (loc, pattern, with_what) ->
 427         let with_what = disambiguate_lazy_term with_what in
 428         let pattern = disambiguate_pattern pattern in
 429         metasenv,GrafiteAst.Change (loc, pattern, with_what)
 430     | GrafiteAst.Clear (loc,id) ->
 431         metasenv,GrafiteAst.Clear (loc,id)
 432     | GrafiteAst.ClearBody (loc,id) ->
 433        metasenv,GrafiteAst.ClearBody (loc,id)
 434     | GrafiteAst.Compose (loc, t1, t2, times, spec) ->
 435         let metasenv,t1 = disambiguate_term context metasenv t1 in
 436         let metasenv,t2 =
 437           match t2 with
 438           | None -> metasenv, None
 439           | Some t2 ->
 440               let m, t2 = disambiguate_term context metasenv t2 in
 441               m, Some t2
 442         in
 443         metasenv,   GrafiteAst.Compose (loc, t1, t2, times, spec)
 444     | GrafiteAst.Constructor (loc,n) ->
 445         metasenv,GrafiteAst.Constructor (loc,n)
 446     | GrafiteAst.Contradiction loc ->
 447         metasenv,GrafiteAst.Contradiction loc
 448     | GrafiteAst.Cut (loc, ident, term) ->
 449         let metasenv,cic = disambiguate_term context metasenv term in
 450         metasenv,GrafiteAst.Cut (loc, ident, cic)
 451     | GrafiteAst.Decompose (loc, names) ->
 452          metasenv,GrafiteAst.Decompose (loc, names)
 453     | GrafiteAst.Demodulate (loc, params) ->
 454         let metasenv, params = disambiguate_auto_params metasenv params in
 455         metasenv,GrafiteAst.Demodulate (loc, params)
 456     | GrafiteAst.Destruct (loc, Some terms) ->
 457         let map term (metasenv, terms) =
 458            let metasenv, term = disambiguate_term context metasenv term in
 459            metasenv, term :: terms
 460         in
 461         let metasenv, terms = List.fold_right map terms (metasenv, []) in
 462         metasenv, GrafiteAst.Destruct(loc, Some terms)
 463     | GrafiteAst.Destruct (loc, None) ->
 464         metasenv,GrafiteAst.Destruct(loc,None)
 465     | GrafiteAst.Exact (loc, term) ->
 466         let metasenv,cic = disambiguate_term context metasenv term in
 467         metasenv,GrafiteAst.Exact (loc, cic)
 468     | GrafiteAst.Elim (loc, what, Some using, pattern, specs) ->
 469         let metasenv,what = disambiguate_term context metasenv what in
 470         let metasenv,using = disambiguate_term context metasenv using in
 471         let pattern = disambiguate_pattern pattern in
 472         metasenv,GrafiteAst.Elim (loc, what, Some using, pattern, specs)
 473     | GrafiteAst.Elim (loc, what, None, pattern, specs) ->
 474         let metasenv,what = disambiguate_term context metasenv what in
 475         let pattern = disambiguate_pattern pattern in
 476         metasenv,GrafiteAst.Elim (loc, what, None, pattern, specs)
 477     | GrafiteAst.ElimType (loc, what, Some using, specs) ->
 478         let metasenv,what = disambiguate_term context metasenv what in
 479         let metasenv,using = disambiguate_term context metasenv using in
 480         metasenv,GrafiteAst.ElimType (loc, what, Some using, specs)
 481     | GrafiteAst.ElimType (loc, what, None, specs) ->
 482         let metasenv,what = disambiguate_term context metasenv what in
 483         metasenv,GrafiteAst.ElimType (loc, what, None, specs)
 484     | GrafiteAst.Exists loc ->
 485         metasenv,GrafiteAst.Exists loc
 486     | GrafiteAst.Fail loc ->
 487         metasenv,GrafiteAst.Fail loc
 488     | GrafiteAst.Fold (loc,red_kind, term, pattern) ->
 489         let pattern = disambiguate_pattern pattern in
 490         let term = disambiguate_lazy_term term in
 491         let red_kind = disambiguate_reduction_kind red_kind in
 492         metasenv,GrafiteAst.Fold (loc, red_kind, term, pattern)
 493     | GrafiteAst.FwdSimpl (loc, hyp, names) ->
 494        metasenv,GrafiteAst.FwdSimpl (loc, hyp, names)
 495     | GrafiteAst.Fourier loc ->
 496        metasenv,GrafiteAst.Fourier loc
 497     | GrafiteAst.Generalize (loc,pattern,ident) ->
 498         let pattern = disambiguate_pattern pattern in
 499         metasenv,GrafiteAst.Generalize (loc,pattern,ident)
 500     | GrafiteAst.IdTac loc ->
 501         metasenv,GrafiteAst.IdTac loc
 502     | GrafiteAst.Intros (loc, specs) ->
 503         metasenv,GrafiteAst.Intros (loc, specs)
 504     | GrafiteAst.Inversion (loc, term) ->
 505        let metasenv,term = disambiguate_term context metasenv term in
 506         metasenv,GrafiteAst.Inversion (loc, term)
 507     | GrafiteAst.LApply (loc, linear, depth, to_what, what, ident) ->
 508        let f term (metasenv, to_what) =
 509           let metasenv, term = disambiguate_term context metasenv term in
 510           metasenv, term :: to_what
 511        in
 512        let metasenv, to_what = List.fold_right f to_what (metasenv, []) in
 513        let metasenv, what = disambiguate_term context metasenv what in
 514        metasenv,GrafiteAst.LApply (loc, linear, depth, to_what, what, ident)
 515     | GrafiteAst.Left loc ->
 516        metasenv,GrafiteAst.Left loc
 517     | GrafiteAst.LetIn (loc, term, name) ->
 518         let metasenv,term = disambiguate_term context metasenv term in
 519         metasenv,GrafiteAst.LetIn (loc,term,name)
 520     | GrafiteAst.Reduce (loc, red_kind, pattern) ->
 521         let pattern = disambiguate_pattern pattern in
 522         let red_kind = disambiguate_reduction_kind red_kind in
 523         metasenv,GrafiteAst.Reduce(loc, red_kind, pattern)
 524     | GrafiteAst.Reflexivity loc ->
 525         metasenv,GrafiteAst.Reflexivity loc
 526     | GrafiteAst.Replace (loc, pattern, with_what) ->
 527         let pattern = disambiguate_pattern pattern in
 528         let with_what = disambiguate_lazy_term with_what in
 529         metasenv,GrafiteAst.Replace (loc, pattern, with_what)
 530     | GrafiteAst.Rewrite (loc, dir, t, pattern, names) ->
 531         let metasenv,term = disambiguate_term context metasenv t in
 532         let pattern = disambiguate_pattern pattern in
 533         metasenv,GrafiteAst.Rewrite (loc, dir, term, pattern, names)
 534     | GrafiteAst.Right loc ->
 535         metasenv,GrafiteAst.Right loc
 536     | GrafiteAst.Ring loc ->
 537         metasenv,GrafiteAst.Ring loc
 538     | GrafiteAst.Split loc ->
 539         metasenv,GrafiteAst.Split loc
 540     | GrafiteAst.Symmetry loc ->
 541         metasenv,GrafiteAst.Symmetry loc
 542     | GrafiteAst.Transitivity (loc, term) ->
 543         let metasenv,cic = disambiguate_term context metasenv term in
 544         metasenv,GrafiteAst.Transitivity (loc, cic)
 545       (* Nuovi casi *)
 546     | GrafiteAst.Assume (loc, id, term) ->
 547         let metasenv,cic = disambiguate_term context metasenv term in
 548         metasenv,GrafiteAst.Assume (loc, id, cic)
 549     | GrafiteAst.Suppose (loc, term, id, term') ->
 550         let metasenv,cic = disambiguate_term context metasenv term in
 551         let metasenv,cic' =
 552            match term' with
 553               None -> metasenv,None
 554             | Some t ->
 555                   let metasenv,t = disambiguate_term context metasenv t in
 556                   metasenv,Some t in
 557         metasenv,GrafiteAst.Suppose (loc, cic, id, cic')
 558     | GrafiteAst.Bydone (loc,just) ->
 559         let metasenv,just =
 560          disambiguate_just disambiguate_term context metasenv just
 561         in
 562          metasenv,GrafiteAst.Bydone (loc, just)
 563     | GrafiteAst.We_need_to_prove (loc,term,id,term') ->
 564         let metasenv,cic = disambiguate_term context metasenv term in
 565         let metasenv,cic' =
 566             match term' with
 567               None -> metasenv,None
 568             | Some t ->
 569                   let metasenv,t = disambiguate_term context metasenv t in
 570                   metasenv,Some t in
 571         metasenv,GrafiteAst.We_need_to_prove (loc,cic,id,cic')
 572     | GrafiteAst.By_just_we_proved (loc,just,term',id,term'') ->
 573         let metasenv,just =
 574          disambiguate_just disambiguate_term context metasenv just in
 575         let metasenv,cic' = disambiguate_term context metasenv term' in
 576         let metasenv,cic'' =
 577             match term'' with
 578               None -> metasenv,None
 579            |  Some t ->
 580                     let metasenv,t = disambiguate_term context metasenv t in
 581                      metasenv,Some t in
 582         metasenv,GrafiteAst.By_just_we_proved (loc,just,cic',id,cic'')
 583     | GrafiteAst.We_proceed_by_cases_on (loc, term, term') ->
 584         let metasenv,cic = disambiguate_term context metasenv term in
 585         let metasenv,cic' = disambiguate_term context metasenv term' in
 586         metasenv,GrafiteAst.We_proceed_by_cases_on (loc, cic, cic')
 587     | GrafiteAst.We_proceed_by_induction_on (loc, term, term') ->
 588         let metasenv,cic = disambiguate_term context metasenv term in
 589         let metasenv,cic' = disambiguate_term context metasenv term' in
 590         metasenv,GrafiteAst.We_proceed_by_induction_on (loc, cic, cic')
 591    | GrafiteAst.Byinduction (loc, term, id) ->
 592         let metasenv,cic = disambiguate_term context metasenv term in
 593         metasenv,GrafiteAst.Byinduction(loc, cic, id)
 594    | GrafiteAst.Thesisbecomes (loc, term) ->
 595         let metasenv,cic = disambiguate_term context metasenv term in
 596         metasenv,GrafiteAst.Thesisbecomes (loc, cic)
 597    | GrafiteAst.ExistsElim (loc, just, id1, term1, id2, term2) ->
 598         let metasenv,just =
 599          disambiguate_just disambiguate_term context metasenv just in
 600         let metasenv,cic' = disambiguate_term context metasenv term1 in
 601         let cic''= disambiguate_lazy_term term2 in
 602         metasenv,GrafiteAst.ExistsElim(loc, just, id1, cic', id2, cic'')
 603    | GrafiteAst.AndElim (loc, just, id, term1, id1, term2) ->
 604         let metasenv,just =
 605          disambiguate_just disambiguate_term context metasenv just in
 606         let metasenv,cic'= disambiguate_term context metasenv term1 in
 607         let metasenv,cic''= disambiguate_term context metasenv term2 in
 608         metasenv,GrafiteAst.AndElim(loc, just, id, cic', id1, cic'')
 609    | GrafiteAst.Case (loc, id, params) ->
 610         let metasenv,params' =
 611          List.fold_right
 612           (fun (id,term) (metasenv,params) ->
 613             let metasenv,cic = disambiguate_term context metasenv term in
 614              metasenv,(id,cic)::params
 615           ) params (metasenv,[])
 616         in
 617         metasenv,GrafiteAst.Case(loc, id, params')
 618    | GrafiteAst.RewritingStep (loc, term1, term2, term3, cont) ->
 619         let metasenv,cic =
 620          match term1 with
 621             None -> metasenv,None
 622           | Some (start,t) ->
 623              let metasenv,t = disambiguate_term context metasenv t in
 624               metasenv,Some (start,t) in
 625         let metasenv,cic'= disambiguate_term context metasenv term2 in
 626         let metasenv,cic'' =
 627          match term3 with
 628           | `SolveWith term ->
 629              let metasenv,term = disambiguate_term context metasenv term in
 630              metasenv, `SolveWith term
 631           | `Auto params ->
 632               let metasenv, params = disambiguate_auto_params metasenv params in
 633               metasenv,`Auto params
 634           | `Term t ->
 635              let metasenv,t = disambiguate_term context metasenv t in
 636               metasenv,`Term t
 637           | `Proof as t -> metasenv,t in
 638         metasenv,GrafiteAst.RewritingStep (loc, cic, cic', cic'', cont)
 639
 640 let disambiguate_obj estatus ?baseuri metasenv (text,prefix_len,obj) =
 641   let uri =
 642    let baseuri =
 643      match baseuri with Some x -> x | None -> raise BaseUriNotSetYet
 644    in
 645    let name =
 646      match obj with
 647      | CicNotationPt.Inductive (_,(name,_,_,_)::_)
 648      | CicNotationPt.Record (_,name,_,_) -> name ^ ".ind"
 649      | CicNotationPt.Theorem (_,name,_,_,_) -> name ^ ".con"
 650      | CicNotationPt.Inductive _ -> assert false
 651    in
 652      UriManager.uri_of_string (baseuri ^ "/" ^ name)
 653   in
 654 (*
 655  let _try_new cic =
 656   (NCicLibrary.clear_cache ();
 657    NCicEnvironment.invalidate ();
 658    OCic2NCic.clear ();
 659    let graph =
 660      match cic with
 661      | Some (Cic.CurrentProof (_,metasenv, _, ty,_,_)) ->
 662          let _, ugraph =
 663            CicTypeChecker.type_of_aux' metasenv [] ty CicUniv.empty_ugraph
 664          in
 665            ugraph
 666      | Some (Cic.Constant (_,_, ty,_,_)) ->
 667          let _, ugraph =
 668                  CicTypeChecker.type_of_aux' [] [] ty CicUniv.empty_ugraph
 669          in
 670            ugraph
 671      | _ -> CicUniv.empty_ugraph
 672    in
 673
 674 (*
 675    prerr_endline "PRIMA COERCIONS";
 676    let _,l = CicUniv.do_rank graph in
 677    List.iter (fun k ->
 678      prerr_endline (CicUniv.string_of_universe k ^ " = " ^ string_of_int
 679      (CicUniv.get_rank k))) l;
 680 *)
 681
 682    let graph =
 683        List.fold_left
 684          (fun graph (_,_,l) ->
 685            List.fold_left
 686              (fun graph (uri,_,_) ->
 687                 let _,g = CicTypeChecker.typecheck uri in
 688                 CicUniv.merge_ugraphs ~base_ugraph:graph ~increment:(g,uri))
 689              graph l)
 690        graph (CoercDb.to_list (CoercDb.dump ()))
 691    in
 692    ignore(CicUniv.do_rank graph);
 693
 694
 695 (*
 696    prerr_endline "DOPO COERCIONS";
 697    let _,l = CicUniv.do_rank graph in
 698    List.iter (fun k ->
 699      prerr_endline (CicUniv.string_of_universe k ^ " = " ^ string_of_int
 700      (CicUniv.get_rank k))) l;
 701 *)
 702
 703
 704    prerr_endline "INIZIO NUOVA DISAMBIGUAZIONE";
 705    let time = Unix.gettimeofday () in
 706        (try
 707          (match
 708           NCicDisambiguate.disambiguate_obj
 709            ~rdb:estatus
 710            ~lookup_in_library:nlookup_in_library
 711            ~description_of_alias:LexiconAst.description_of_alias
 712            ~mk_choice:ncic_mk_choice
 713            ~mk_implicit
 714            ~uri:(OCic2NCic.nuri_of_ouri uri)
 715            ~aliases:estatus#lstatus.LexiconEngine.aliases
 716            ~universe:(Some estatus#lstatus.LexiconEngine.multi_aliases)
 717            (text,prefix_len,obj)
 718          with
 719          | [_,_,_,obj],_ ->
 720           let time = Unix.gettimeofday () -. time in
 721 (*           NCicTypeChecker.typecheck_obj obj; *)
 722           prerr_endline ("NUOVA DISAMBIGUAZIONE OK: "^ string_of_float time);
 723 (*
 724           let obj =
 725             let u,i,m,_,o = obj in
 726             u,i,m,[],o
 727           in
 728 *)
 729           prerr_endline (NCicPp.ppobj obj)
 730          | _ ->
 731           prerr_endline ("NUOVA DISAMBIGUAZIONE AMBIGUO!!!!!!!!!  "))
 732        with
 733        | MultiPassDisambiguator.DisambiguationError (_,s) ->
 734         prerr_endline ("ERRORE NUOVA DISAMBIGUAZIONE ("
 735           ^UriManager.string_of_uri uri^
 736           "):\n" ^
 737          String.concat "\n"
 738           (List.map (fun _,_,x,_ -> snd (Lazy.force x)) (List.flatten s)))
 739 (*        | exn -> prerr_endline (Printexc.to_string exn) *)
 740        )
 741   )
 742  in
 743 *)
 744
 745
 746  try
 747 (*   let time = Unix.gettimeofday () in  *)
 748
 749
 750   let (diff, metasenv, _, cic, _) =
 751     singleton "third"
 752       (CicDisambiguate.disambiguate_obj
 753         ~lookup_in_library
 754         ~mk_choice:cic_mk_choice
 755         ~mk_implicit ~fix_instance
 756         ~description_of_alias:LexiconAst.description_of_alias
 757         ~aliases:estatus#lstatus.LexiconEngine.aliases
 758         ~universe:(Some estatus#lstatus.LexiconEngine.multi_aliases)
 759         ~uri:(Some uri)
 760         (text,prefix_len,obj))
 761   in
 762
 763
 764 (*
 765   let time = Unix.gettimeofday () -. time in
 766   prerr_endline ("VECCHIA DISAMBIGUAZIONE ("^
 767     UriManager.string_of_uri uri ^"): " ^ string_of_float time);
 768 *)
 769 (*    try_new (Some cic);   *)
 770
 771
 772   let estatus = LexiconEngine.set_proof_aliases estatus diff in
 773    estatus, metasenv, cic
 774
 775  with
 776  | Sys.Break as exn -> raise exn
 777  | exn ->
 778 (*    try_new None; *)
 779    raise exn
 780 ;;
 781
 782 let disambiguate_nobj estatus ?baseuri (text,prefix_len,obj) =
 783   let uri =
 784    let baseuri =
 785      match baseuri with Some x -> x | None -> raise BaseUriNotSetYet
 786    in
 787    let name =
 788      match obj with
 789      | CicNotationPt.Inductive (_,(name,_,_,_)::_)
 790      | CicNotationPt.Record (_,name,_,_) -> name ^ ".ind"
 791      | CicNotationPt.Theorem (_,name,_,_,_) -> name ^ ".con"
 792      | CicNotationPt.Inductive _ -> assert false
 793    in
 794      UriManager.uri_of_string (baseuri ^ "/" ^ name)
 795   in
 796   let diff, _, _, cic =
 797    singleton "third"
 798     (NCicDisambiguate.disambiguate_obj
 799       ~lookup_in_library:nlookup_in_library
 800       ~description_of_alias:LexiconAst.description_of_alias
 801       ~mk_choice:ncic_mk_choice
 802       ~mk_implicit ~fix_instance
 803       ~uri:(OCic2NCic.nuri_of_ouri uri)
 804       ~rdb:estatus
 805       ~aliases:estatus#lstatus.LexiconEngine.aliases
 806       ~universe:(Some estatus#lstatus.LexiconEngine.multi_aliases)
 807       (text,prefix_len,obj)) in
 808   let estatus = LexiconEngine.set_proof_aliases estatus diff in
 809    estatus, cic
 810 ;;
 811
 812 let disambiguate_command estatus ?baseuri metasenv (text,prefix_len,cmd)=
 813   match cmd with
 814    | GrafiteAst.Index(loc,key,uri) ->
 815        let lexicon_status_ref = ref estatus in
 816        let disambiguate_term =
 817          disambiguate_term None text prefix_len lexicon_status_ref [] in
 818        let disambiguate_term_option metasenv =
 819          function
 820              None -> metasenv,None
 821            | Some t ->
 822                let metasenv,t = disambiguate_term metasenv t in
 823                  metasenv, Some t
 824        in
 825        let metasenv,key = disambiguate_term_option metasenv key in
 826         !lexicon_status_ref,metasenv,GrafiteAst.Index(loc,key,uri)
 827    | GrafiteAst.Select (loc,uri) ->
 828         estatus, metasenv, GrafiteAst.Select(loc,uri)
 829    | GrafiteAst.Pump(loc,i) ->
 830         estatus, metasenv, GrafiteAst.Pump(loc,i)
 831    | GrafiteAst.PreferCoercion (loc,t) ->
 832        let lexicon_status_ref = ref estatus in
 833        let disambiguate_term =
 834          disambiguate_term None text prefix_len lexicon_status_ref [] in
 835       let metasenv,t = disambiguate_term metasenv t in
 836        !lexicon_status_ref, metasenv, GrafiteAst.PreferCoercion (loc,t)
 837    | GrafiteAst.Coercion (loc,t,b,a,s) ->
 838        let lexicon_status_ref = ref estatus in
 839        let disambiguate_term =
 840          disambiguate_term None text prefix_len lexicon_status_ref [] in
 841       let metasenv,t = disambiguate_term metasenv t in
 842        !lexicon_status_ref, metasenv, GrafiteAst.Coercion (loc,t,b,a,s)
 843    | GrafiteAst.Inverter (loc,n,indty,params) ->
 844        let lexicon_status_ref = ref estatus in
 845        let disambiguate_term =
 846          disambiguate_term None text prefix_len lexicon_status_ref [] in
 847        let metasenv,indty = disambiguate_term metasenv indty in
 848         !lexicon_status_ref, metasenv, GrafiteAst.Inverter (loc,n,indty,params)
 849    | GrafiteAst.Default _
 850    | GrafiteAst.Drop _
 851    | GrafiteAst.Include _
 852    | GrafiteAst.Print _
 853    | GrafiteAst.Qed _
 854    | GrafiteAst.Set _ as cmd ->
 855        estatus,metasenv,cmd
 856    | GrafiteAst.Obj (loc,obj) ->
 857        let estatus,metasenv,obj =
 858         disambiguate_obj estatus ?baseuri metasenv (text,prefix_len,obj)in
 859        estatus, metasenv, GrafiteAst.Obj (loc,obj)
 860    | GrafiteAst.Relation (loc,id,a,aeq,refl,sym,trans) ->
 861       let lexicon_status_ref = ref estatus in
 862       let disambiguate_term =
 863        disambiguate_term None text prefix_len lexicon_status_ref [] in
 864       let disambiguate_term_option metasenv =
 865        function
 866           None -> metasenv,None
 867        | Some t ->
 868           let metasenv,t = disambiguate_term metasenv t in
 869            metasenv, Some t
 870       in
 871       let metasenv,a = disambiguate_term metasenv a in
 872       let metasenv,aeq = disambiguate_term metasenv aeq in
 873       let metasenv,refl = disambiguate_term_option metasenv refl in
 874       let metasenv,sym = disambiguate_term_option metasenv sym in
 875       let metasenv,trans = disambiguate_term_option metasenv trans in
 876        !lexicon_status_ref, metasenv,
 877         GrafiteAst.Relation (loc,id,a,aeq,refl,sym,trans)
 878
 879 let disambiguate_macro
 880   lexicon_status_ref metasenv context (text,prefix_len, macro)
 881 =
 882  let disambiguate_term = disambiguate_term None text prefix_len lexicon_status_ref in
 883   let disambiguate_reduction_kind =
 884     disambiguate_reduction_kind text prefix_len lexicon_status_ref in
 885   match macro with
 886    | GrafiteAst.WMatch (loc,term) ->
 887       let metasenv,term = disambiguate_term context metasenv term in
 888        metasenv,GrafiteAst.WMatch (loc,term)
 889    | GrafiteAst.WInstance (loc,term) ->
 890       let metasenv,term = disambiguate_term context metasenv term in
 891        metasenv,GrafiteAst.WInstance (loc,term)
 892    | GrafiteAst.WElim (loc,term) ->
 893       let metasenv,term = disambiguate_term context metasenv term in
 894        metasenv,GrafiteAst.WElim (loc,term)
 895    | GrafiteAst.WHint (loc,term) ->
 896       let metasenv,term = disambiguate_term context metasenv term in
 897        metasenv,GrafiteAst.WHint (loc,term)
 898    | GrafiteAst.Check (loc,term) ->
 899       let metasenv,term = disambiguate_term context metasenv term in
 900        metasenv,GrafiteAst.Check (loc,term)
 901    | GrafiteAst.Eval (loc,kind,term) ->
 902       let metasenv, term = disambiguate_term context metasenv term in
 903       let kind = disambiguate_reduction_kind kind in
 904        metasenv,GrafiteAst.Eval (loc,kind,term)
 905    | GrafiteAst.AutoInteractive (loc, params) ->
 906       let metasenv, params =
 907         disambiguate_auto_params disambiguate_term metasenv context params in
 908       metasenv, GrafiteAst.AutoInteractive (loc, params)
 909    | GrafiteAst.Hint _
 910    | GrafiteAst.WLocate _
 911    | GrafiteAst.Inline _ as macro ->
 912       metasenv,macro