helm/software/components/ng_library/nCicLibrary.ml

   1 (*
   2     ||M||  This file is part of HELM, an Hypertextual, Electronic
   3     ||A||  Library of Mathematics, developed at the Computer Science
   4     ||T||  Department, University of Bologna, Italy.
   5     ||I||
   6     ||T||  HELM is free software; you can redistribute it and/or
   7     ||A||  modify it under the terms of the GNU General Public License
   8     \   /  version 2 or (at your option) any later version.
   9      \ /   This software is distributed as is, NO WARRANTY.
  10       V_______________________________________________________________ *)
  11
  12 (* $Id$ *)
  13
  14 exception LibraryOutOfSync of string Lazy.t
  15
  16 let magic = 2;;
  17
  18 let refresh_uri uri = NUri.uri_of_string (NUri.string_of_uri uri);;
  19
  20 let refresh_uri_in_universe =
  21  List.map (fun (x,u) -> x, refresh_uri u)
  22 ;;
  23
  24 let rec refresh_uri_in_term =
  25  function
  26   | NCic.Meta (i,(n,NCic.Ctx l)) ->
  27      NCic.Meta (i,(n,NCic.Ctx (List.map refresh_uri_in_term l)))
  28   | NCic.Meta _ as t -> t
  29   | NCic.Const (NReference.Ref (u,spec)) ->
  30      NCic.Const (NReference.reference_of_spec (refresh_uri u) spec)
  31   | NCic.Sort (NCic.Type l) -> NCic.Sort (NCic.Type (refresh_uri_in_universe l))
  32   | NCic.Match (NReference.Ref (uri,spec),outtype,term,pl) ->
  33      let r = NReference.reference_of_spec (refresh_uri uri) spec in
  34      let outtype = refresh_uri_in_term outtype in
  35      let term = refresh_uri_in_term term in
  36      let pl = List.map refresh_uri_in_term pl in
  37       NCic.Match (r,outtype,term,pl)
  38   | t -> NCicUtils.map (fun _ _ -> ()) () (fun _ -> refresh_uri_in_term) t
  39 ;;
  40
  41 let refresh_uri_in_obj (uri,height,metasenv,subst,obj_kind) =
  42  assert (metasenv = []);
  43  assert (subst = []);
  44  refresh_uri uri,height,metasenv,subst,
  45   NCicUntrusted.map_obj_kind refresh_uri_in_term obj_kind
  46 ;;
  47
  48 let path_of_baseuri ?(no_suffix=false) baseuri =
  49  let uri = NUri.string_of_uri baseuri in
  50  let path = String.sub uri 4 (String.length uri - 4) in
  51  let path = Helm_registry.get "matita.basedir" ^ path in
  52  let dirname = Filename.dirname path in
  53   HExtlib.mkdir dirname;
  54   if no_suffix then
  55    path
  56   else
  57    path ^ ".ng"
  58 ;;
  59
  60 let require_path path =
  61  let ch = open_in path in
  62  let mmagic,dump = Marshal.from_channel ch in
  63   close_in ch;
  64   if mmagic <> magic then
  65    raise (LibraryOutOfSync (lazy "The library is out of sync with the implementation. Please recompile the library."))
  66   else
  67    dump
  68 ;;
  69
  70 let require0 ~baseuri = require_path (path_of_baseuri baseuri);;
  71
  72 let db_path () = Helm_registry.get "matita.basedir" ^ "/ng_db.ng";;
  73
  74
  75 type timestamp =
  76  [ `Obj of NUri.uri * NCic.obj
  77  | `Constr of NCic.universe * NCic.universe] list *
  78  (NUri.uri * string * NReference.reference) list *
  79  NCic.obj NUri.UriMap.t *
  80  NUri.uri list
  81 ;;
  82
  83 let time0 = [],[],NUri.UriMap.empty,[];;
  84 let storage = ref [];;
  85 let local_aliases = ref [];;
  86 let cache = ref NUri.UriMap.empty;;
  87 let includes = ref [];;
  88
  89 let load_db,set_global_aliases,get_global_aliases,add_deps,get_deps,remove_deps=
  90  let global_aliases = ref [] in
  91  let rev_includes_map = ref NUri.UriMap.empty in
  92  let store_db () =
  93   let ch = open_out (db_path ()) in
  94   Marshal.to_channel ch (magic,(!global_aliases,!rev_includes_map)) [];
  95   close_out ch in
  96  let load_db () =
  97   HExtlib.mkdir (Helm_registry.get "matita.basedir");
  98   try
  99    let ga,im = require_path (db_path ()) in
 100    let ga =
 101     List.map
 102      (fun (uri,name,NReference.Ref (uri2,spec)) ->
 103        refresh_uri uri,name,NReference.reference_of_spec (refresh_uri uri2) spec
 104      ) ga in
 105    let im =
 106     NUri.UriMap.fold
 107      (fun u l im -> NUri.UriMap.add (refresh_uri u) (List.map refresh_uri l) im
 108      ) im NUri.UriMap.empty
 109    in
 110     global_aliases := ga;
 111     rev_includes_map := im
 112   with
 113    Sys_error _ -> () in
 114  let get_deps u =
 115   let get_deps_one_step u =
 116     try NUri.UriMap.find u !rev_includes_map with Not_found -> [] in
 117   let rec aux res =
 118    function
 119       [] -> res
 120     | he::tl ->
 121        if List.mem he res then
 122         aux res tl
 123        else
 124         aux (he::res) (get_deps_one_step he @ tl)
 125   in
 126    aux [] [u] in
 127  let remove_deps u =
 128   rev_includes_map := NUri.UriMap.remove u !rev_includes_map;
 129   rev_includes_map :=
 130    NUri.UriMap.map
 131     (fun l -> List.filter (fun uri -> not (NUri.eq u uri)) l) !rev_includes_map;
 132   store_db ()
 133  in
 134   load_db,
 135   (fun ga -> global_aliases := ga; store_db ()),
 136   (fun () -> !global_aliases),
 137   (fun u l ->
 138     rev_includes_map := NUri.UriMap.add u (l @ get_deps u) !rev_includes_map;
 139     store_db ()),
 140   get_deps,
 141   remove_deps
 142 ;;
 143
 144 let init = load_db;;
 145
 146 type automation_cache = NDiscriminationTree.DiscriminationTree.t
 147
 148 class type g_auto_status =
 149  object
 150   method auto_cache : automation_cache
 151  end
 152
 153 class auto_status =
 154  object(self)
 155   val auto_cache = NDiscriminationTree.DiscriminationTree.empty
 156   method auto_cache = auto_cache
 157   method set_auto_cache v = {< auto_cache = v >}
 158   method set_auto_status
 159    : 'status. #g_auto_status as 'status -> 'self
 160    = fun o -> self#set_auto_cache o#auto_cache
 161  end
 162
 163 class type g_status =
 164  object
 165   inherit NRstatus.g_status
 166   method timestamp: timestamp
 167  end
 168
 169 class status =
 170  object(self)
 171   inherit NRstatus.status
 172   val timestamp = (time0 : timestamp)
 173   method timestamp = timestamp
 174   method set_timestamp v = {< timestamp = v >}
 175   method set_library_status
 176    : 'status. #g_status as 'status -> 'self
 177    = fun o -> self#set_timestamp o#timestamp
 178  end
 179
 180 let time_travel status =
 181  let sto,ali,cac,inc = status#timestamp in
 182   let diff_len = List.length !storage - List.length sto in
 183   let to_be_deleted,_ = HExtlib.split_nth diff_len !storage in
 184    if List.length to_be_deleted > 0 then
 185      NCicEnvironment.invalidate_item (HExtlib.list_last to_be_deleted);
 186    storage := sto; local_aliases := ali; cache := cac; includes := inc
 187 ;;
 188
 189 let serialize ~baseuri dump =
 190  let ch = open_out (path_of_baseuri baseuri) in
 191  Marshal.to_channel ch (magic,dump) [];
 192  close_out ch;
 193  List.iter
 194   (function
 195    | `Obj (uri,obj) ->
 196        let ch = open_out (path_of_baseuri uri) in
 197        Marshal.to_channel ch (magic,obj) [];
 198        close_out ch
 199    | `Constr _ -> ()
 200   ) !storage;
 201  set_global_aliases (!local_aliases @ get_global_aliases ());
 202  List.iter (fun u -> add_deps u [baseuri]) !includes;
 203  time_travel (new status)
 204 ;;
 205
 206 type obj = string * Obj.t
 207
 208
 209 class type g_dumpable_status =
 210  object
 211   inherit g_status
 212   inherit g_auto_status
 213   method dump: obj list
 214  end
 215
 216 class dumpable_status =
 217  object(self)
 218   inherit status
 219   inherit auto_status
 220   val dump = ([] : obj list)
 221   method dump = dump
 222   method set_dump v = {< dump = v >}
 223   method set_dumpable_status : 'status. #g_dumpable_status as 'status -> 'self
 224    = fun o -> ((self#set_dump o#dump)#set_coercion_status o)#set_auto_status o
 225  end
 226
 227 type 'a register_type =
 228  < run: 'status.
 229     'a -> refresh_uri_in_universe:(NCic.universe ->
 230       NCic.universe) -> refresh_uri_in_term:(NCic.term -> NCic.term) ->
 231        (#dumpable_status as 'status) -> 'status >
 232
 233 module Serializer =
 234  struct
 235   let require1 = ref (object method run : 'status. obj -> (#dumpable_status as 'status) -> 'status  = fun _ -> assert false end (* unknown data*))
 236   let already_registered = ref []
 237
 238   let register =
 239    object
 240     method run : 'a.  string -> 'a register_type -> ('a -> obj)
 241     = fun tag require ->
 242      assert (not (List.mem tag !already_registered));
 243      already_registered := tag :: !already_registered;
 244      let old_require1 = !require1 in
 245      require1 :=
 246        object
 247         method run : 'status. obj -> (#dumpable_status as 'status) -> 'status =
 248          fun ((tag',data) as x) ->
 249          if tag=tag' then
 250           require#run (Obj.magic data) ~refresh_uri_in_universe ~refresh_uri_in_term
 251          else
 252           old_require1#run x
 253        end;
 254      (fun x -> tag,Obj.repr x)
 255    end
 256
 257   let serialize = serialize
 258
 259   let require ~baseuri status =
 260    includes := baseuri::!includes;
 261    let dump = require0 ~baseuri in
 262     List.fold_right !require1#run dump status
 263 end
 264
 265
 266 let decompile ~baseuri =
 267  let baseuris = get_deps baseuri in
 268  List.iter (fun baseuri ->
 269   remove_deps baseuri;
 270   HExtlib.safe_remove (path_of_baseuri baseuri);
 271   let basepath = path_of_baseuri ~no_suffix:true baseuri in
 272   try
 273    let od = Unix.opendir basepath in
 274    let rec aux names =
 275     try
 276      let name = Unix.readdir od in
 277       if name <> "." && name <> ".." then aux (name::names) else aux names
 278     with
 279      End_of_file -> names in
 280    let names = List.map (fun name -> basepath ^ "/" ^ name) (aux []) in
 281     Unix.closedir od;
 282     List.iter Unix.unlink names;
 283     HExtlib.rmdir_descend basepath;
 284     set_global_aliases
 285      (List.filter
 286       (fun (_,_,NReference.Ref (nuri,_)) ->
 287         Filename.dirname (NUri.string_of_uri nuri) <> NUri.string_of_uri baseuri
 288       ) (get_global_aliases ()))
 289   with
 290    Unix.Unix_error _ -> () (* raised by Unix.opendir, we hope :-) *)
 291  ) baseuris
 292 ;;
 293
 294 LibraryClean.set_decompile_cb
 295  (fun ~baseuri -> decompile ~baseuri:(NUri.uri_of_string baseuri));;
 296
 297 let fetch_obj uri =
 298  let obj = require0 ~baseuri:uri in
 299   refresh_uri_in_obj obj
 300 ;;
 301
 302 let resolve name =
 303  try
 304   HExtlib.filter_map
 305    (fun (_,name',nref) -> if name'=name then Some nref else None)
 306    (!local_aliases @ get_global_aliases ())
 307  with
 308   Not_found -> raise (NCicEnvironment.ObjectNotFound (lazy name))
 309 ;;
 310
 311 let aliases_of uri =
 312   HExtlib.filter_map
 313    (fun (uri',_,nref) ->
 314      if NUri.eq uri' uri then Some nref else None) !local_aliases
 315 ;;
 316
 317 let add_obj status ((u,_,_,_,_) as obj) =
 318  NCicEnvironment.check_and_add_obj obj;
 319  storage := (`Obj (u,obj))::!storage;
 320   let _,height,_,_,obj = obj in
 321   let references =
 322    match obj with
 323       NCic.Constant (_,name,None,_,_) ->
 324        [u,name,NReference.reference_of_spec u NReference.Decl]
 325     | NCic.Constant (_,name,Some _,_,_) ->
 326        [u,name,NReference.reference_of_spec u (NReference.Def height)]
 327     | NCic.Fixpoint (is_ind,fl,_) ->
 328        HExtlib.list_mapi
 329         (fun (_,name,recno,_,_) i ->
 330           if is_ind then
 331            u,name,NReference.reference_of_spec u(NReference.Fix(i,recno,height))
 332           else
 333            u,name,NReference.reference_of_spec u (NReference.CoFix i)) fl
 334     | NCic.Inductive (inductive,leftno,il,_) ->
 335        List.flatten
 336         (HExtlib.list_mapi
 337          (fun (_,iname,_,cl) i ->
 338            HExtlib.list_mapi
 339             (fun (_,cname,_) j->
 340               u,cname,
 341                NReference.reference_of_spec u (NReference.Con (i,j+1,leftno))
 342             ) cl @
 343            [u,iname,
 344              NReference.reference_of_spec u
 345               (NReference.Ind (inductive,i,leftno))]
 346          ) il)
 347   in
 348   local_aliases := references @ !local_aliases;
 349   status#set_timestamp (!storage,!local_aliases,!cache,!includes)
 350 ;;
 351
 352 let add_constraint status u1 u2 =
 353   NCicEnvironment.add_lt_constraint u1 u2;
 354   storage := (`Constr (u1,u2)) :: !storage;
 355   status#set_timestamp (!storage,!local_aliases,!cache,!includes)
 356 ;;
 357
 358 let get_obj u =
 359  try
 360   List.assq u
 361    (HExtlib.filter_map
 362     (function `Obj (u,o) -> Some (u,o) | _ -> None )
 363     !storage)
 364  with Not_found ->
 365   try fetch_obj u
 366   with Sys_error _ ->
 367    try NUri.UriMap.find u !cache
 368    with Not_found ->
 369     let ouri = NCic2OCic.ouri_of_nuri u in
 370     try
 371       let o,_ = CicEnvironment.get_obj CicUniv.oblivion_ugraph ouri in
 372       let l = OCic2NCic.convert_obj ouri o in
 373       List.iter (fun (u,_,_,_,_ as o) -> cache:= NUri.UriMap.add u o !cache) l;
 374       HExtlib.list_last l
 375     with CicEnvironment.Object_not_found u ->
 376       raise (NCicEnvironment.ObjectNotFound
 377                (lazy (NUri.string_of_uri (OCic2NCic.nuri_of_ouri u))))
 378 ;;
 379
 380 let clear_cache () = cache := NUri.UriMap.empty;;
 381
 382 NCicEnvironment.set_get_obj get_obj;;
 383 NCicPp.set_get_obj get_obj;;