helm/software/components/ng_paramodulation/orderings.ml

   1 (*
   2     ||M||  This file is part of HELM, an Hypertextual, Electronic
   3     ||A||  Library of Mathematics, developed at the Computer Science
   4     ||T||  Department, University of Bologna, Italy.
   5     ||I||
   6     ||T||  HELM is free software; you can redistribute it and/or
   7     ||A||  modify it under the terms of the GNU General Public License
   8     \   /  version 2 or (at your option) any later version.
   9      \ /   This software is distributed as is, NO WARRANTY.
  10       V_______________________________________________________________ *)
  11
  12 (* $Id$ *)
  13
  14 type aux_comparison = XEQ | XLE | XGE | XLT | XGT | XINCOMPARABLE | XINVERTIBLE
  15
  16 module type Blob =
  17   sig
  18     include Terms.Blob
  19
  20     (* This order relation should be:
  21      * - stable for instantiation
  22      * - total on ground terms
  23      *
  24      *)
  25     val compare_terms :
  26           t Terms.foterm -> t Terms.foterm -> Terms.comparison
  27
  28     val compute_clause_weight : 't Terms.clause -> int
  29
  30     val name : string
  31
  32   end
  33
  34 type weight = int * (int * int) list;;
  35
  36 let rec eq_foterm f x y =
  37     x == y ||
  38     match x, y with
  39     | Terms.Leaf t1, Terms.Leaf t2 -> f t1 t2
  40     | Terms.Var i, Terms.Var j -> i = j
  41     | Terms.Node l1, Terms.Node l2 -> List.for_all2 (eq_foterm f) l1 l2
  42     | _ -> false
  43 ;;
  44
  45 let string_of_weight (cw, mw) =
  46   let s =
  47     String.concat ", "
  48       (List.map (function (m, w) -> Printf.sprintf "(%d,%d)" m w) mw)
  49   in
  50   Printf.sprintf "[%d; %s]" cw s
  51 ;;
  52
  53 let weight_of_term term =
  54     let vars_dict = Hashtbl.create 5 in
  55     let rec aux = function
  56       | Terms.Var i ->
  57           (try
  58              let oldw = Hashtbl.find vars_dict i in
  59              Hashtbl.replace vars_dict i (oldw+1)
  60            with Not_found ->
  61              Hashtbl.add vars_dict i 1);
  62           0
  63       | Terms.Leaf _ -> 1
  64       | Terms.Node l -> List.fold_left (+) 0 (List.map aux l)
  65     in
  66     let w = aux term in
  67     let l =
  68       Hashtbl.fold (fun meta metaw resw -> (meta, metaw)::resw) vars_dict []
  69     in
  70     let compare w1 w2 =
  71       match w1, w2 with
  72       | (m1, _), (m2, _) -> m1 - m2
  73     in
  74     (w, List.sort compare l) (* from the smallest meta to the bigest *)
  75 ;;
  76
  77 let compute_literal_weight l =
  78     let weight_of_polynomial w m =
  79       let factor = 2 in
  80       w + factor * List.fold_left (fun acc (_,occ) -> acc+occ) 0 m
  81     in
  82     match l with
  83     | Terms.Predicate t ->
  84         let w, m = weight_of_term t in
  85         weight_of_polynomial w m
  86     | Terms.Equation (_,x,_,Terms.Lt)
  87     | Terms.Equation (x,_,_,Terms.Gt) ->
  88         let w, m = weight_of_term x in
  89         weight_of_polynomial w m
  90     | Terms.Equation (l,r,_,Terms.Eq)
  91     | Terms.Equation (l,r,_,Terms.Incomparable)
  92     | Terms.Equation (l,r,_,Terms.Invertible) ->
  93         let wl, ml = weight_of_term l in
  94         let wr, mr = weight_of_term r in
  95         weight_of_polynomial (wl+wr) (ml@mr)
  96 ;;
  97
  98 let compute_clause_weight (_,nl,pl,_,_) =
  99   List.fold_left (fun acc (lit,_) -> compute_literal_weight lit + acc) 0 (nl@pl)
 100
 101 let compute_goal_weight = compute_clause_weight;;
 102
 103 (* Riazanov: 3.1.5 pag 38 *)
 104 (* Compare weights normalized in a new way :
 105  * Variables should be sorted from the lowest index to the highest
 106  * Variables which do not occur in the term should not be present
 107  * in the normalized polynomial
 108  *)
 109 let compare_weights (h1, w1) (h2, w2) =
 110   let rec aux hdiff (lt, gt) diffs w1 w2 =
 111     match w1, w2 with
 112       | ((var1, w1)::tl1) as l1, (((var2, w2)::tl2) as l2) ->
 113           if var1 = var2 then
 114             let diffs = (w1 - w2) + diffs in
 115             let r = Pervasives.compare w1 w2 in
 116             let lt = lt or (r < 0) in
 117             let gt = gt or (r > 0) in
 118               if lt && gt then XINCOMPARABLE else
 119                 aux hdiff (lt, gt) diffs tl1 tl2
 120           else if var1 < var2 then
 121             if lt then XINCOMPARABLE else
 122               aux hdiff (false,true) (diffs+w1) tl1 l2
 123           else
 124             if gt then XINCOMPARABLE else
 125               aux hdiff (true,false) (diffs-w2) l1 tl2
 126       | [], (_,w2)::tl2 ->
 127           if gt then XINCOMPARABLE else
 128             aux hdiff (true,false) (diffs-w2) [] tl2
 129       | (_,w1)::tl1, [] ->
 130           if lt then XINCOMPARABLE else
 131             aux hdiff (false,true) (diffs+w1) tl1 []
 132       | [], [] ->
 133           if lt then
 134             if hdiff <= 0 then XLT
 135             else if (- diffs) >= hdiff then XLE else XINCOMPARABLE
 136           else if gt then
 137             if hdiff >= 0 then XGT
 138             else if diffs >= (- hdiff) then XGE else XINCOMPARABLE
 139           else
 140             if hdiff < 0 then XLT
 141             else if hdiff > 0 then XGT
 142             else XEQ
 143   in
 144     aux (h1-h2) (false,false) 0 w1 w2
 145 ;;
 146
 147 (* Riazanov: p. 40, relation >>>
 148  * if head_only=true then it is not >>> but helps case 2 of 3.14 p 39 *)
 149 let rec aux_ordering b_compare ?(head_only=false) t1 t2 =
 150   match t1, t2 with
 151   (* We want to discard any identity equality. *
 152    * If we give back XEQ, no inference rule    *
 153    * will be applied on this equality          *)
 154   | Terms.Var i, Terms.Var j when i = j ->
 155       XEQ
 156   (* 1. *)
 157   | Terms.Var _, _
 158   | _, Terms.Var _ -> XINCOMPARABLE
 159   (* 2.a *)
 160   | Terms.Leaf a1, Terms.Leaf a2 ->
 161       let cmp = b_compare a1 a2 in
 162       if cmp = 0 then XEQ else if cmp < 0 then XLT else XGT
 163   | Terms.Leaf _, Terms.Node _ -> XLT
 164   | Terms.Node _, Terms.Leaf _ -> XGT
 165   (* 2.b *)
 166   | Terms.Node l1, Terms.Node l2 ->
 167       let rec cmp t1 t2 =
 168         match t1, t2 with
 169         | [], [] -> XEQ
 170         | _, [] -> (* XGT *) assert false (* hd symbols were eq *)
 171         | [], _ -> (* XLT *) assert false (* hd symbols were eq *)
 172         | hd1::tl1, hd2::tl2 ->
 173             let o = aux_ordering b_compare ~head_only hd1 hd2 in
 174             if o = XEQ && not head_only then cmp tl1 tl2 else o
 175       in
 176       cmp l1 l2
 177 ;;
 178
 179 let compare_terms o x y =
 180     match o x y with
 181       | XINCOMPARABLE -> Terms.Incomparable
 182       | XGT -> Terms.Gt
 183       | XLT -> Terms.Lt
 184       | XEQ -> Terms.Eq
 185       | XINVERTIBLE -> Terms.Invertible
 186       | _ -> assert false
 187 ;;
 188
 189 module NRKBO (B : Terms.Blob) = struct
 190   let name = "nrkbo"
 191   include B
 192
 193   module Pp = Pp.Pp(B)
 194
 195   let eq_foterm = eq_foterm B.eq;;
 196
 197   let compute_clause_weight = compute_clause_weight;;
 198   let compute_goal_weight = compute_goal_weight;;
 199
 200   (* Riazanov: p. 40, relation >_n *)
 201   let nonrec_kbo t1 t2 =
 202     let w1 = weight_of_term t1 in
 203     let w2 = weight_of_term t2 in
 204     match compare_weights w1 w2 with
 205     | XLE ->  (* this is .> *)
 206         if aux_ordering B.compare t1 t2 = XLT then XLT else XINCOMPARABLE
 207     | XGE ->
 208         if aux_ordering B.compare t1 t2 = XGT then XGT else XINCOMPARABLE
 209     | XEQ -> let res = aux_ordering B.compare t1 t2 in
 210         if res = XINCOMPARABLE && are_invertible t1 t2 then XINVERTIBLE
 211         else res
 212     | res -> res
 213   ;;
 214
 215   let compare_terms = compare_terms nonrec_kbo;;
 216
 217   let profiler = HExtlib.profile ~enable:true "compare_terms(nrkbo)";;
 218   let compare_terms x y =
 219     profiler.HExtlib.profile (compare_terms x) y
 220   ;;
 221
 222 end
 223
 224 module KBO (B : Terms.Blob) = struct
 225   let name = "kbo"
 226   include B
 227
 228   module Pp = Pp.Pp(B)
 229
 230   let eq_foterm = eq_foterm B.eq;;
 231
 232   let compute_clause_weight = compute_clause_weight;;
 233   let compute_goal_weight = compute_goal_weight;;
 234
 235   (* Riazanov: p. 38, relation > *)
 236   let rec kbo t1 t2 =
 237     let aux = aux_ordering B.compare ~head_only:true in
 238     let rec cmp t1 t2 =
 239       match t1, t2 with
 240       | [], [] -> XEQ
 241       | _, [] -> XGT
 242       | [], _ -> XLT
 243       | hd1::tl1, hd2::tl2 ->
 244           let o = kbo hd1 hd2 in
 245           if o = XEQ then cmp tl1 tl2
 246           else o
 247     in
 248     let w1 = weight_of_term t1 in
 249     let w2 = weight_of_term t2 in
 250     let comparison = compare_weights w1 w2 in
 251     match comparison with
 252     | XLE ->
 253         let r = aux t1 t2 in
 254         if r = XLT then XLT
 255         else if r = XEQ then (
 256           match t1, t2 with
 257           | Terms.Node (_::tl1), Terms.Node (_::tl2) ->
 258               if cmp tl1 tl2 = XLT then XLT else XINCOMPARABLE
 259           | _, _ -> assert false
 260         ) else XINCOMPARABLE
 261     | XGE ->
 262         let r = aux t1 t2 in
 263         if r = XGT then XGT
 264         else if r = XEQ then (
 265           match t1, t2 with
 266           | Terms.Node (_::tl1), Terms.Node (_::tl2) ->
 267               if cmp tl1 tl2 = XGT then XGT else XINCOMPARABLE
 268           | _, _ ->  assert false
 269         ) else XINCOMPARABLE
 270     | XEQ ->
 271         let r = aux t1 t2 in
 272         if r = XEQ then (
 273           match t1, t2 with
 274           | Terms.Var i, Terms.Var j when i=j -> XEQ
 275           | Terms.Node (_::tl1), Terms.Node (_::tl2) -> cmp tl1 tl2
 276           | _, _ ->  XINCOMPARABLE
 277         ) else r
 278     | res -> res
 279   ;;
 280
 281   let compare_terms = compare_terms kbo;;
 282
 283   let profiler = HExtlib.profile ~enable:true "compare_terms(kbo)";;
 284   let compare_terms x y =
 285     profiler.HExtlib.profile (compare_terms x) y
 286   ;;
 287
 288 end
 289
 290 module LPO (B : Terms.Blob) = struct
 291   let name = "lpo"
 292   include B
 293
 294   module Pp = Pp.Pp(B)
 295
 296   let eq_foterm = eq_foterm B.eq;;
 297
 298   let compute_clause_weight = compute_clause_weight;;
 299   let compute_goal_weight = compute_goal_weight;;
 300
 301   let rec lpo s t =
 302     match s,t with
 303       | s, t when eq_foterm s t ->
 304           XEQ
 305       | Terms.Var _, Terms.Var _ ->
 306           XINCOMPARABLE
 307       | _, Terms.Var i ->
 308           if (List.mem i (Terms.vars_of_term s)) then XGT
 309           else XINCOMPARABLE
 310       | Terms.Var i,_ ->
 311           if (List.mem i (Terms.vars_of_term t)) then XLT
 312           else XINCOMPARABLE
 313       | Terms.Node (hd1::tl1), Terms.Node (hd2::tl2) ->
 314           let rec ge_subterm t ol = function
 315             | [] -> (false, ol)
 316             | x::tl ->
 317                 let res = lpo x t in
 318                 match res with
 319                   | XGT | XEQ -> (true,res::ol)
 320                   | o -> ge_subterm t (o::ol) tl
 321           in
 322           let (res, l_ol) = ge_subterm t [] tl1 in
 323             if res then XGT
 324             else let (res, r_ol) = ge_subterm s [] tl2 in
 325               if res then XLT
 326               else begin
 327                 let rec check_subterms t = function
 328                   | _,[] -> true
 329                   | o::ol,_::tl ->
 330                       if o = XLT then check_subterms t (ol,tl)
 331                       else false
 332                   | [], x::tl ->
 333                       if lpo x t = XLT then check_subterms t ([],tl)
 334                       else false
 335                 in
 336                 match aux_ordering B.compare hd1 hd2 with
 337                   | XGT -> if check_subterms s (r_ol,tl2) then XGT
 338                     else XINCOMPARABLE
 339                   | XLT -> if check_subterms t (l_ol,tl1) then XLT
 340                     else XINCOMPARABLE
 341                   | XEQ ->
 342                       let lex = List.fold_left2
 343                         (fun acc si ti -> if acc = XEQ then lpo si ti else acc)
 344                         XEQ tl1 tl2
 345                       in
 346                  (match lex with
 347                     | XGT ->
 348                         if List.for_all (fun x -> lpo s x = XGT) tl2 then XGT
 349                       else XINCOMPARABLE
 350                     | XLT ->
 351                         if List.for_all (fun x -> lpo x t = XLT) tl1 then XLT
 352                       else XINCOMPARABLE
 353                     | o -> o)
 354               | XINCOMPARABLE -> XINCOMPARABLE
 355               | _ -> assert false
 356           end
 357       | _,_ -> aux_ordering B.compare s t
 358
 359   ;;
 360
 361   let compare_terms = compare_terms lpo;;
 362
 363   let profiler = HExtlib.profile ~enable:true "compare_terms(lpo)";;
 364   let compare_terms x y =
 365     profiler.HExtlib.profile (compare_terms x) y
 366   ;;
 367
 368 end
 369