helm/software/helena/src/basic_rg/brg.ml

   1 (*
   2     ||M||  This file is part of HELM, an Hypertextual, Electronic
   3     ||A||  Library of Mathematics, developed at the Computer Science
   4     ||T||  Department, University of Bologna, Italy.
   5     ||I||
   6     ||T||  HELM is free software; you can redistribute it and/or
   7     ||A||  modify it under the terms of the GNU General Public License
   8     \   /  version 2 or (at your option) any later version.
   9      \ /   This software is distributed as is, NO WARRANTY.
  10       V_______________________________________________________________ *)
  11
  12 (* kernel version: basic, relative, global *)
  13 (* note          : ufficial basic \lambda\delta version 3 *)
  14
  15 module N = Layer
  16 module E = Entity
  17
  18 type uri = E.uri
  19 type attrs = E.node_attrs
  20
  21 (* x-reduced abstractions are output by RTM only *)
  22 type bind = Void                          (*                         *)
  23           | Abst of bool * N.layer * term (* x-reduced?, layer, type *)
  24           | Abbr of term                  (* body                    *)
  25
  26 and term = Sort of attrs * int         (* attrs, hierarchy index *)
  27          | LRef of attrs * int         (* attrs, position index *)
  28          | GRef of attrs * uri         (* attrs, reference *)
  29          | Cast of attrs * term * term (* attrs, type, term *)
  30          | Appl of attrs * term * term (* attrs, argument, function *)
  31          | Bind of attrs * bind * term (* attrs, binder, scope *)
  32
  33 type entity = term E.entity (* attrs, uri, binder *)
  34
  35 type lenv = Null
  36 (* Cons: tail, relative local environment, attrs, binder *)
  37           | Cons of lenv * lenv * attrs * bind
  38
  39 type manager = (N.status -> entity -> bool) * (unit -> unit)
  40
  41 (* Currified constructors ***************************************************)
  42
  43 let abst x n w = Abst (x, n, w)
  44
  45 let abbr v = Abbr v
  46
  47 let lref a i = LRef (a, i)
  48
  49 let cast a u t = Cast (a, u, t)
  50
  51 let appl a u t = Appl (a, u, t)
  52
  53 let bind a b t = Bind (a, b, t)
  54
  55 let bind_abst x n a u t = Bind (a, Abst (x, n, u), t)
  56
  57 let bind_abbr a u t = Bind (a, Abbr u, t)
  58
  59 let bind_void a t = Bind (a, Void, t)
  60
  61 (* local environment handling functions *************************************)
  62
  63 let empty = Null
  64
  65 let push e c a b = Cons (e, c, a, b)
  66
  67 let rec get i = function
  68    | Null                         -> empty, empty, E.empty_node, Void
  69    | Cons (e, c, a, b) when i = 0 -> e, c, a, b
  70    | Cons (e, _, _, _)            -> get (pred i) e
  71
  72 let get e i = get i e
  73
  74 (* used in BrgOutput.pp_lenv *)
  75 let rec fold_right f map e x = match e with
  76    | Null              -> f x
  77    | Cons (e, c, a, b) -> fold_right (map f e c a b) map e x
  78
  79 let rec mem err f e b = match e with
  80    | Null              -> err ()
  81    | Cons (e, _, a, _) ->
  82       if a.E.n_name = b.E.n_name then f () else mem err f e b