helm/software/helena/src/basic_rg/brgGrafite.ml

   1 (*
   2     ||M||  This file is part of HELM, an Hypertextual, Electronic
   3     ||A||  Library of Mathematics, developed at the Computer Science
   4     ||T||  Department, University of Bologna, Italy.
   5     ||I||
   6     ||T||  HELM is free software; you can redistribute it and/or
   7     ||A||  modify it under the terms of the GNU General Public License
   8     \   /  version 2 or (at your option) any later version.
   9      \ /   This software is distributed as is, NO WARRANTY.
  10       V_______________________________________________________________ *)
  11
  12 module F = Filename
  13 module P = Printf
  14
  15 module U = NUri
  16 module C = Cps
  17 module G = Options
  18 module N = Layer
  19 module E = Entity
  20 module R = Alpha
  21 module B = Brg
  22
  23 (* Internal functions *******************************************************)
  24
  25 let ok = ref true
  26
  27 let base = "matita"
  28
  29 let ext = ".ma"
  30
  31 let width = 70
  32
  33 let out_preamble och =
  34    let ich = open_in !G.ma_preamble in
  35    let rec aux () = P.fprintf och "%s\n" (input_line ich); aux () in
  36    try aux () with End_of_file -> close_in ich
  37
  38 let out_top_comment och msg =
  39    let padding = width - String.length msg in
  40    let padding = if padding >= 0 then padding else 0 in
  41    P.fprintf och "(* %s %s*)\n\n" msg (String.make padding '*')
  42
  43 let out_comment och msg =
  44    P.fprintf och "(* %s *)\n" msg
  45
  46 let out_include och src =
  47    P.fprintf och "include \"%s.ma\".\n\n" src
  48
  49 let out_uri och u =
  50    let str = U.string_of_uri u in
  51    let rec aux i =
  52      let c = str.[i] in
  53      if c = '.' then () else begin
  54         output_char och (if c = '/' then '_' else c);
  55         aux (succ i)
  56      end
  57    in
  58    let rec strip i n =
  59       if n <= 0 then succ i else
  60       strip (String.index_from str (succ i) '/') (pred n)
  61    in
  62    aux (strip 0 3)
  63
  64 let out_name och a =
  65    let f n = function
  66       | true  -> P.fprintf och "%s" n
  67       | false -> C.err ()
  68    in
  69    E.name C.err f a
  70
  71 let rec out_term st p e och = function
  72    | B.Sort (_, h)           ->
  73       let sort = if h = 0 then "Type[0]" else if h = 1 then "Prop" else assert false in
  74       P.fprintf och "%s" sort
  75    | B.LRef (_, i)           ->
  76       let _, _, a, b = B.get e i in
  77       P.fprintf och "%a" out_name a
  78    | B.GRef (_, s)           ->
  79       P.fprintf och "%a" out_uri s
  80    | B.Cast (_, u, t)        ->
  81       P.fprintf och "(%a : %a)" (out_term st false e) t (out_term st false e) u
  82    | B.Appl (_, v, t)        ->
  83       let pt = match t with B.Appl _ -> false | _ -> true in
  84       let op, cp = if p then "(", ")" else "", "" in
  85       P.fprintf och "%s%a %a%s" op (out_term st pt e) t (out_term st true e) v cp
  86    | B.Bind (a, B.Abst (n, w), t) ->
  87       let op, cp = if p then "(", ")" else "", "" in
  88       let a = R.alpha B.mem e a in
  89       let ee = B.push e B.empty a (B.abst n w) in
  90       let binder = match N.to_string st n, a.E.n_sort with
  91          | "1", 0 -> "Π"
  92          | "1", 1 -> "∀"
  93          | "2", _ -> "λ"
  94          | _      -> ok := false; "?"
  95       in
  96       P.fprintf och "%s%s%a:%a.%a%s"
  97          op binder out_name a (out_term st false e) w (out_term st false ee) t cp
  98    | B.Bind (a, B.Abbr v, t) ->
  99       let op, cp = if p then "(", ")" else "", "" in
 100       let a = R.alpha B.mem e a in
 101       let ee = B.push e B.empty a (B.abbr v) in
 102       P.fprintf och "%slet %a ≝ %a in %a%s"
 103          op out_name a (out_term st false e) v (out_term st false ee) t cp
 104    | B.Bind (a, B.Void, t)   -> C.err ()
 105
 106 (* Interface functions ******************************************************)
 107
 108 let open_out fname =
 109    let dir = F.concat !G.ma_dir base in
 110    let path = F.concat dir fname in
 111    let och = open_out (path ^ ext) in
 112    out_preamble och;
 113    out_top_comment och (P.sprintf "This file was generated by %s: do not edit" G.version_string);
 114    out_include och "basics/pts";
 115    och
 116
 117 let output_entity st och (_, na, s, b) =
 118    out_comment och (P.sprintf "constant %u" na.E.n_apix);
 119    match b with
 120       | E.Abbr t ->
 121          P.fprintf och "definition %a ≝ %a.\n\n%!" out_uri s (out_term st false B.empty) t; !ok
 122       | E.Abst t ->
 123          P.fprintf och "axiom %a : %a.\n\n%!" out_uri s (out_term st false B.empty) t; !ok
 124       | E.Void   -> C.err ()
 125
 126 let close_out och = close_out och