helm/software/helena/src/basic_rg/brgGrafite.ml

   1 (*
   2     ||M||  This file is part of HELM, an Hypertextual, Electronic
   3     ||A||  Library of Mathematics, developed at the Computer Science
   4     ||T||  Department, University of Bologna, Italy.
   5     ||I||
   6     ||T||  HELM is free software; you can redistribute it and/or
   7     ||A||  modify it under the terms of the GNU General Public License
   8     \   /  version 2 or (at your option) any later version.
   9      \ /   This software is distributed as is, NO WARRANTY.
  10       V_______________________________________________________________ *)
  11
  12 module KF = Filename
  13 module KP = Printf
  14
  15 module U  = NUri
  16 module C  = Cps
  17 module G  = Options
  18 module N  = Layer
  19 module E  = Entity
  20 module R  = Alpha
  21 module B  = Brg
  22
  23 IFDEF MANAGER THEN
  24
  25 (* Internal functions *******************************************************)
  26
  27 let ok = ref true
  28
  29 let base = "matita"
  30
  31 let ext = ".ma"
  32
  33 let width = 70
  34
  35 let out_preamble och =
  36    let ich = open_in !G.preamble in
  37    let rec aux () = KP.fprintf och "%s\n" (input_line ich); aux () in
  38    try aux () with End_of_file -> close_in ich
  39
  40 let out_top_comment och msg =
  41    let padding = width - String.length msg in
  42    let padding = if padding >= 0 then padding else 0 in
  43    KP.fprintf och "(* %s %s*)\n\n" msg (String.make padding '*')
  44
  45 let out_comment och msg =
  46    KP.fprintf och "(* %s *)\n" msg
  47
  48 let out_include och src =
  49    KP.fprintf och "include \"%s.ma\".\n\n" src
  50
  51 let out_uri och u =
  52    let str = U.string_of_uri u in
  53    let rec aux i =
  54      let c = str.[i] in
  55      if c = '.' then () else begin
  56         output_char och (if c = '/' then '_' else c);
  57         aux (succ i)
  58      end
  59    in
  60    let rec strip i n =
  61       if n <= 0 then succ i else
  62       strip (String.index_from str (succ i) '/') (pred n)
  63    in
  64    aux (strip 0 3)
  65
  66 let out_name och a =
  67    let f n = function
  68       | true  -> KP.fprintf och "%s" n
  69       | false -> KP.fprintf och "_"
  70    in
  71    let err () = f "" false in
  72    E.name err f a
  73
  74 let rec out_term st p e och = function
  75    | B.Sort k                        ->
  76       let sort = if k = 0 then "Type[0]" else if k = 1 then "Prop" else assert false in
  77       KP.fprintf och "%s" sort
  78    | B.LRef (_, i)                   ->
  79       let _, _, _, y, b = B.get e i in
  80       KP.fprintf och "%a" out_name y
  81    | B.GRef (_, s)                   ->
  82       KP.fprintf och "%a" out_uri s
  83    | B.Cast (u, t)                   ->
  84       KP.fprintf och "(%a : %a)" (out_term st false e) t (out_term st false e) u
  85    | B.Appl (_, v, t)                ->
  86       let pt = match t with B.Appl _ -> false | _ -> true in
  87       let op, cp = if p then "(", ")" else "", "" in
  88       KP.fprintf och "%s%a %a%s" op (out_term st pt e) t (out_term st true e) v cp
  89    | B.Bind (y, B.Abst (r, n, w), t) ->
  90       let op, cp = if p then "(", ")" else "", "" in
  91       let y = R.alpha B.mem e y in
  92       let ee = B.push e B.empty E.empty_node y (B.abst r n w) in
  93       let binder = match N.to_string st n, fst y.E.b_main with
  94          | "1", 0 -> "Π"
  95          | "1", 1 -> "∀"
  96          | "2", _ -> "λ"
  97          | _      -> ok := false; "?"
  98       in
  99       KP.fprintf och "%s%s%a:%a.%a%s"
 100          op binder out_name y (out_term st false e) w (out_term st false ee) t cp
 101    | B.Bind (y, B.Abbr v, t)         ->
 102       let op, cp = if p then "(", ")" else "", "" in
 103       let y = R.alpha B.mem e y in
 104       let ee = B.push e B.empty E.empty_node y (B.abbr v) in
 105       KP.fprintf och "%slet %a ≝ %a in %a%s"
 106          op out_name y (out_term st false e) v (out_term st false ee) t cp
 107    | B.Bind (a, B.Void, t)           -> C.err ()
 108
 109 let close_out och () = close_out och
 110
 111 let output_entity och st (_, na, u, b) =
 112    out_comment och (KP.sprintf "constant %u" na.E.n_apix);
 113    match b with
 114       | E.Abbr v ->
 115          KP.fprintf och "definition %a ≝ %a.\n\n%!" out_uri u (out_term st false B.empty) v; !ok
 116       | E.Abst w ->
 117          KP.fprintf och "axiom %a : %a.\n\n%!" out_uri u (out_term st false B.empty) w; !ok
 118       | E.Void   -> C.err ()
 119
 120 (* Interface functions ******************************************************)
 121
 122 let open_out fname =
 123    let dir = KF.concat !G.manager_dir base in
 124    let path = KF.concat dir fname in
 125    let och = open_out (path ^ ext) in
 126    out_preamble och;
 127    out_top_comment och (KP.sprintf "This file was generated by %s: do not edit" G.version_string);
 128    out_include och "basics/pts";
 129    output_entity och, close_out och
 130
 131 END