helm/software/helena/src/basic_rg/brgLP.ml

   1 (*
   2     ||M||  This file is part of HELM, an Hypertextual, Electronic
   3     ||A||  Library of Mathematics, developed at the Computer Science
   4     ||T||  Department, University of Bologna, Italy.
   5     ||I||
   6     ||T||  HELM is free software; you can redistribute it and/or
   7     ||A||  modify it under the terms of the GNU General Public License
   8     \   /  version 2 or (at your option) any later version.
   9      \ /   This software is distributed as is, NO WARRANTY.
  10       V_______________________________________________________________ *)
  11
  12 module KF = Filename
  13 module KP = Printf
  14
  15 module U  = NUri
  16 module C  = Cps
  17 module G  = Options
  18 module N  = Layer
  19 module E  = Entity
  20 module R  = Alpha
  21 module B  = Brg
  22
  23 IFDEF MANAGER THEN
  24
  25 (* Internal functions *******************************************************)
  26
  27 let version = KP.sprintf "This file was generated by %s: do not edit" (G.version_string true)
  28
  29 let ok = ref true
  30
  31 let uris = ref []
  32
  33 let chunk = ref 0
  34
  35 let sub_och = ref stdout
  36
  37 let top_age = 7000
  38
  39 let size = 250
  40
  41 let base = "lp"
  42
  43 let ext_lp = ".elpi"
  44 let ext_tj = ".mod"
  45 let ext_tj_sig = ".sig"
  46
  47 let reserved = ["pi"; "sigma"; "nil"; "delay"; "in"; "with"; "resume"; "context"]
  48
  49 let alpha n =
  50    if List.mem n reserved then !G.alpha ^ n else n
  51
  52 let out_preamble och =
  53    let ich = open_in !G.preamble in
  54    let rec aux () = KP.fprintf och "%s\n" (input_line ich); aux () in
  55    try aux () with End_of_file -> close_in ich
  56
  57 let out_top_comment och msg =
  58    KP.fprintf och "%% %s\n\n" msg
  59
  60 let out_comment och msg =
  61    KP.fprintf och "%% %s\n" msg
  62
  63 let out_clause och msg =
  64    KP.fprintf och "%s\n\n" msg
  65
  66 let out_uri och u =
  67    let str = U.string_of_uri u in
  68    let rec aux i =
  69      let c = str.[i] in
  70      if c = '.' then () else begin
  71         output_char och (if c = '/' then '_' else c);
  72         aux (succ i)
  73      end
  74    in
  75    let rec strip i n =
  76       if n <= 0 then succ i else
  77       strip (String.index_from str (succ i) '/') (pred n)
  78    in
  79    aux (strip 0 3)
  80
  81 let out_name och a =
  82    let f n = function
  83       | true  -> KP.fprintf och "%s" (alpha n)
  84       | false -> KP.fprintf och "_"
  85    in
  86    let err () = f "" false in
  87    E.name err f a
  88
  89 let rec out_term st e och = function
  90    | B.Sort k                        ->
  91       let sort = if k = 0 then "k+set" else if k = 1 then "k+prop" else assert false in
  92       KP.fprintf och "(sort %s)" sort
  93    | B.LRef (_, i)                   ->
  94       let _, _, _, y, b = B.get e i in
  95       KP.fprintf och "%a" out_name y
  96    | B.GRef (_, s)                   ->
  97       KP.fprintf och "%a" out_uri s
  98    | B.Cast (u, t)                   ->
  99       KP.fprintf och "(cast %a %a)" (out_term st e) u (out_term st e) t
 100    | B.Appl (x, v, t)                ->
 101       let c = if x then "appx" else "appr" in
 102       KP.fprintf och "(%s %a %a)" c (out_term st e) v (out_term st e) t
 103    | B.Bind (y, B.Abst (r, n, w), t) ->
 104       let y = R.alpha B.mem e y in
 105       let ee = B.push e B.empty E.empty_node y (B.abst r n w) in
 106       let c = if r then "prod" else "abst" in
 107       let l = match N.to_string st n with
 108          | "1" -> "l+1"
 109          | "2" -> "l+2"
 110          | _   -> ok := false; "?"
 111       in
 112       KP.fprintf och "(%s %s %a %a\\ %a)"
 113          c l (out_term st e) w out_name y (out_term st ee) t
 114    | B.Bind (y, B.Abbr v, t)         ->
 115       let y = R.alpha B.mem e y in
 116       let ee = B.push e B.empty E.empty_node y (B.abbr v) in
 117       KP.fprintf och "(abbr %a %a\\ %a)"
 118           (out_term st e) v out_name y (out_term st ee) t
 119    | B.Bind (_, B.Void, _)           -> C.err ()
 120
 121 (* elpi variant 1 ***********************************************************)
 122
 123 let output_entity_lp1 och st (_, na, u, b) =
 124    if na.E.n_apix <= !G.last then begin
 125    match b with
 126       | E.Abbr v ->
 127          KP.fprintf och "(gdef+1 c+%u %a\n %a\\\n" na.E.n_apix (out_term st B.empty) v out_uri u;
 128          uris := (true, u) :: !uris; !ok
 129       | E.Abst w ->
 130          KP.fprintf och "(gdec+1 c+%u %a\n%a\\\n" na.E.n_apix (out_term st B.empty) w out_uri u;
 131          uris := (false, u) :: !uris; !ok
 132       | E.Void   -> C.err ()
 133    end else !ok
 134
 135 let close_out_lp1 och () =
 136    let aux_sep _ = KP.fprintf och "%s" ")" in
 137    KP.fprintf och "%s" "gtop";
 138    List.iter aux_sep !uris;
 139    out_clause och "\n\n.";
 140    close_out och
 141
 142 (* elpi variant 2 ***********************************************************)
 143
 144 let output_entity_lp2 och st (_, na, u, b) =
 145    if na.E.n_apix <= !G.last then begin
 146    match b with
 147       | E.Abbr v ->
 148          KP.fprintf och "g+line %a c+%u\n       %a\n.\n\n"
 149             out_uri u na.E.n_apix (out_term st B.empty) v;
 150          uris := (true, u) :: !uris; !ok
 151       | E.Abst w ->
 152          KP.fprintf och "g+line %a c+%u\n       %a\n.\n\n"
 153             out_uri u na.E.n_apix (out_term st B.empty) w;
 154          uris := (false, u) :: !uris; !ok
 155       | E.Void   -> C.err ()
 156    end else !ok
 157
 158 let close_out_lp2 och () =
 159    let aux_name (b, s) =
 160       let gde = if b then "gdef+2" else "gdec+2" in
 161       KP.fprintf och "(%s %a\n" gde out_uri s
 162    in
 163    let aux_sep _ = KP.fprintf och "%s" ")" in
 164    if !G.first > 0 then begin
 165       let s = KP.sprintf "tv+c C T :- $lt C c+%u, !." !G.first in
 166       out_clause och s;
 167       out_clause och "tv+c C T :- tv+ T."
 168    end;
 169    out_clause och "main :- grundlagen.";
 170    out_clause och "grundlagen :- gv+";
 171    List.iter aux_name (List.rev !uris);
 172    KP.fprintf och "%s" "gtop";
 173    List.iter aux_sep !uris;
 174    out_clause och "\n\n.";
 175    close_out och
 176
 177 (* teyjus variant 2 *************************************************)
 178
 179 let append_out name =
 180    open_out_gen [Open_append; Open_creat; Open_text] 0o666 name
 181
 182 let sub_close () = if !sub_och <> stdout then close_out !sub_och
 183
 184 let mk_name chunk =
 185    let dir = KF.concat !G.manager_dir base in
 186    let name = KP.sprintf "grundlagen%02u" chunk in
 187    dir, name
 188
 189 let output_entity_tj2 och st (_, na, u, b) =
 190    if na.E.n_apix <= !G.last then begin
 191    if pred na.E.n_apix mod size = 0 then begin
 192       sub_close ();
 193       incr chunk;
 194       let dir, name = mk_name !chunk in
 195       let soch = open_out (KF.concat dir name ^ ext_tj_sig) in
 196       out_preamble soch;
 197       out_top_comment soch version;
 198       out_clause soch (KP.sprintf "sig %s." name);
 199       out_clause soch "accum_sig grundlagen.";
 200       out_clause soch (KP.sprintf "type line+%02u t -> int -> t -> o." !chunk);
 201       close_out soch;
 202       let soch = open_out (KF.concat dir name ^ ext_tj) in
 203       out_preamble soch;
 204       out_top_comment soch version;
 205       out_clause soch (KP.sprintf "module %s." name);
 206       sub_och := soch
 207    end;
 208    out_comment !sub_och (KP.sprintf "constant %u" na.E.n_apix);
 209    match b with
 210       | E.Abbr v ->
 211          KP.fprintf !sub_och "line+%02u %a %u\n        %a\n.\n\n"
 212             !chunk out_uri u (top_age - na.E.n_apix) (out_term st B.empty) v;
 213          uris := (true, u) :: !uris; !ok
 214       | E.Abst w ->
 215          KP.fprintf !sub_och "line+%02u %a %u\n        %a\n.\n\n"
 216             !chunk out_uri u (top_age - na.E.n_apix) (out_term st B.empty) w;
 217          uris := (false, u) :: !uris; !ok
 218       | E.Void   -> C.err ()
 219    end else !ok
 220
 221 let close_out_tj2 och () =
 222    let out_name och (b, u) =
 223       let gde = if b then "gdef+2" else "gdec+2" in
 224       KP.fprintf och "(%s %a\n" gde out_uri u
 225    in
 226    let rec out_pars och p =
 227       if p > 0 then begin KP.fprintf och "%s" ")"; out_pars och (pred p) end
 228    in
 229    let rec out_list chunk pars first items uris = match first, items, uris with
 230       | true, _, _         ->
 231          let dir, name = mk_name chunk in
 232          let soch = append_out (KF.concat dir name ^ ext_tj) in
 233          out_clause soch (KP.sprintf "g+line R C T :- line+%02u R C T, !." chunk);
 234          KP.fprintf soch "g+list %u\n" chunk;
 235          sub_och := soch;
 236          out_list (succ chunk) pars false items uris
 237       | false, _, []       ->
 238          KP.fprintf !sub_och "gtop%a.\n\n" out_pars pars;
 239          sub_close ()
 240       | false, 0, _        ->
 241          KP.fprintf !sub_och "(genv %u)%a.\n\n" chunk out_pars pars;
 242          sub_close ();
 243          out_list chunk 0 true size uris
 244       | false, _, hd :: tl ->
 245          out_name !sub_och hd; out_list chunk (succ pars) false (pred items) tl
 246    in
 247    let rec out_accumulate c =
 248       if !chunk < c then KP.fprintf och "\n" else begin
 249          let _, name = mk_name c in
 250          KP.fprintf och "accumulate %s.\n" name;
 251          out_accumulate (succ c)
 252       end
 253    in
 254    sub_close ();
 255    out_list 1 0 true size (List.rev !uris);
 256    KP.fprintf och "accumulate helena.\n";
 257    out_accumulate 1;
 258    out_clause och "main :- grundlagen.";
 259    out_clause och "grundlagen :- gv+ (genv 1).";
 260    close_out och
 261
 262 (* teyjus variant 3 *************************************************)
 263
 264 let output_entity_tj3 och st (_, na, u, b) =
 265    if na.E.n_apix <= !G.last then begin
 266       out_comment och (KP.sprintf "constant %u" na.E.n_apix);
 267       let age = top_age - na.E.n_apix in
 268       match b with
 269          | E.Abbr v ->
 270             KP.fprintf och "g+line %a %u\n       %a\n.\n\n"
 271                out_uri u age (out_term st B.empty) v;
 272             KP.fprintf och "tv+ %a.\n\n" out_uri u;
 273             KP.fprintf och "r+exp %a M C E M V :- g+line %a C V.\n\n"
 274                out_uri u out_uri u;
 275             uris := (true, u) :: !uris; !ok
 276          | E.Abst w ->
 277             KP.fprintf och "g+line %a %u\n       %a\n.\n\n"
 278                out_uri u age (out_term st B.empty) w;
 279             KP.fprintf och "tv+ %a.\n\n" out_uri u;
 280             KP.fprintf och "r+exp %a M1 C E M2 W :- m+pred M1 M2, g+line %a C W.\n\n"
 281                out_uri u out_uri u;
 282             uris := (false, u) :: !uris; !ok
 283          | E.Void   -> C.err ()
 284    end else !ok
 285
 286 let close_out_tj3 och () =
 287    let out_name (_, u) =
 288       KP.fprintf och "gv+3 %a,\n" out_uri u
 289    in
 290    let rec out_list och chunk first items uris = match first, items, uris with
 291       | true, _, _         ->
 292          KP.fprintf och "chunk %u :-\n" chunk;
 293          out_list och (succ chunk) false items uris
 294       | false, _, []       -> KP.fprintf och "!.\n\n"; chunk
 295       | false, 0, _        ->
 296          KP.fprintf och "!.\n\n";
 297          out_list och chunk true size uris
 298       | false, _, hd :: tl ->
 299          out_name hd; out_list och chunk false (pred items) tl
 300    in
 301    let rec out_chunks och chunks c =
 302       if chunks < c then out_clause och "!." else begin
 303          KP.fprintf och "chunk %u,\n" c; out_chunks och chunks (succ c)
 304       end
 305    in
 306    let chunks = out_list och 1 true size (List.rev !uris) in
 307    out_clause och "main :- grundlagen.";
 308    KP.fprintf och "grundlagen :-\n";
 309    out_chunks och (pred chunks) 1;
 310    close_out och
 311
 312 (* Interface functions ******************************************************)
 313
 314 let open_out_lp1 fname =
 315    let dir = KF.concat !G.manager_dir base in
 316    let path = KF.concat dir fname in
 317    let och = open_out (path ^ "1" ^ ext_lp) in
 318    out_preamble och;
 319    out_top_comment och version;
 320    out_clause och "accumulate helena.";
 321    out_clause och "main :- grundlagen.";
 322    out_clause och "grundlagen :- gv+";
 323    output_entity_lp1 och, close_out_lp1 och
 324
 325 let open_out_lp2 fname =
 326    let dir = KF.concat !G.manager_dir base in
 327    let path = KF.concat dir fname in
 328    let och = open_out (path ^ "2" ^ ext_lp) in
 329    out_preamble och;
 330    out_top_comment och version;
 331    out_clause och "accumulate helena.";
 332    output_entity_lp2 och, close_out_lp2 och
 333
 334 let open_out_tj2 fname =
 335    let dir = KF.concat !G.manager_dir base in
 336    let path = KF.concat dir fname ^ "2" in
 337    let och = open_out (path ^ ext_tj) in
 338    out_preamble och;
 339    out_top_comment och version;
 340    out_clause och "module grundlagen.";
 341    output_entity_tj2 och, close_out_tj2 och
 342
 343 let open_out_tj3 fname =
 344    let dir = KF.concat !G.manager_dir base in
 345    let path = KF.concat dir fname in
 346    let och = open_out (path ^ "3" ^ ext_tj) in
 347    out_preamble och;
 348    out_top_comment och version;
 349    out_clause och "module grundlagen.";
 350    out_clause och "accumulate helena.";
 351    output_entity_tj3 och, close_out_tj3 och
 352
 353 END