helm/software/helena/src/basic_rg/brgReduction.ml

   1 (*
   2     ||M||  This file is part of HELM, an Hypertextual, Electronic
   3     ||A||  Library of Mathematics, developed at the Computer Science
   4     ||T||  Department, University of Bologna, Italy.
   5     ||I||
   6     ||T||  HELM is free software; you can redistribute it and/or
   7     ||A||  modify it under the terms of the GNU General Public License
   8     \   /  version 2 or (at your option) any later version.
   9      \ /   This software is distributed as is, NO WARRANTY.
  10       V_______________________________________________________________ *)
  11
  12 module U  = NUri
  13 module S  = Share
  14 module L  = Log
  15 module G  = Options
  16 module H  = Hierarchy
  17 module N  = Layer
  18 module E  = Entity
  19 module O  = Output
  20 module B  = Brg
  21 module BO = BrgOutput
  22 module BE = BrgEnvironment
  23
  24 type rtm = {
  25    e: B.lenv;                 (* environment              *)
  26    s: (B.lenv * B.term) list; (* stack                    *)
  27    l: int;                    (* level                    *)
  28    n: int option;             (* expected type iterations *)
  29 }
  30
  31 type message = (rtm, B.term) L.message
  32
  33 (* Internal functions *******************************************************)
  34
  35 let level = 5
  36
  37 let sublevel = succ level
  38
  39 let log1 st s c t =
  40    let s1, s2 = s ^ " in the environment", "the term" in
  41    L.log st BO.specs (pred level) (L.et_items1 s1 c s2 t)
  42
  43 let log2 st s cu u ct t =
  44    let s1, s2, s3 = s ^ " in the environment (expected)", "the term", "and in the environment (inferred)" in
  45    L.log st BO.specs (pred level) (L.et_items2 s1 cu s2 u ~sc2:s3 ~c2:ct s2 t)
  46
  47 let rec list_and map = function
  48    | hd1 :: tl1, hd2 :: tl2 ->
  49       if map hd1 hd2 then list_and map (tl1, tl2) else false
  50    | l1, l2                 -> l1 = l2
  51
  52 let zero = Some 0
  53
  54 (* check closure *)
  55 let are_alpha_convertible err f t1 t2 =
  56    let rec aux f = function
  57       | B.Sort (_, p1), B.Sort (_, p2)
  58       | B.LRef (_, p1), B.LRef (_, p2)               ->
  59          if p1 = p2 then f () else err ()
  60       | B.GRef (_, u1), B.GRef (_, u2)               ->
  61          if U.eq u1 u2 then f () else err ()
  62       | B.Cast (_, v1, t1), B.Cast (_, v2, t2)
  63       | B.Appl (_, _, v1, t1), B.Appl (_, _, v2, t2) ->
  64          let f _ = aux f (t1, t2) in
  65          aux f (v1, v2)
  66       | B.Bind (_, b1, t1), B.Bind (_, b2, t2)       ->
  67          let f _ = aux f (t1, t2) in
  68          aux_bind f (b1, b2)
  69       | _                                            -> err ()
  70    and aux_bind f = function
  71       | B.Abbr v1, B.Abbr v2                                             -> aux f (v1, v2)
  72       | B.Abst (r1, n1, v1), B.Abst (r2, n2, v2) when r1 = r2 && n1 = n2 -> aux f (v1, v2)
  73       | B.Void, B.Void                                                   -> f ()
  74       | _                                                                -> err ()
  75    in
  76    if S.eq t1 t2 then f () else aux f (t1, t2)
  77
  78 let assert_tstep m vo = match m.n with
  79    | Some n -> n > 0
  80    | None   -> vo
  81
  82 let tstep m = match m.n with
  83    | Some n -> {m with n = Some (pred n)}
  84    | None   -> m
  85
  86 let tsteps m = match m.n with
  87    | Some n -> n
  88    | None   -> 0
  89
  90 let get m i =
  91    let _, c, a, b = B.get m.e i in c, a, b
  92
  93 (* to share *)
  94 let rec step st m r =
  95    if !G.ct >= sublevel then
  96    log1 st (Printf.sprintf "entering R.step: l=%u, n=%s," m.l (match m.n with Some n -> string_of_int n | None -> "infinite")) m.e r;
  97    match r with
  98    | B.Sort (a, h)                       ->
  99       if assert_tstep m false then
 100          step st (tstep m) (B.Sort (a, H.apply h))
 101       else m, r, None
 102    | B.GRef (_, uri)                     ->
 103       begin match BE.get_entity uri with
 104          | _, _, _, E.Abbr v ->
 105             if !G.expand then begin
 106                if !G.summary then O.add ~gdelta:1 ();
 107                step st m v
 108             end else
 109                m, r, Some v
 110          | _, _, _, E.Abst w ->
 111             if assert_tstep m true then begin
 112                if !G.summary then O.add ~grt:1 ();
 113                step st (tstep m) w
 114             end else
 115              m, r, None
 116          | _, _, _, E.Void   ->
 117             assert false
 118       end
 119    | B.LRef (_, i)                       ->
 120       begin match get m i with
 121          | c, _, B.Abbr v         ->
 122             if !G.summary then O.add ~ldelta:1 ();
 123             step st {m with e = c} v
 124          | c, a, B.Abst (_, _, w) ->
 125             if assert_tstep m true then begin
 126                if !G.summary then O.add ~lrt:1 ();
 127                step st {(tstep m) with e = c} w
 128             end else
 129                m, B.LRef (a, i), None
 130          | _, _, B.Void           ->
 131             assert false
 132       end
 133    | B.Cast (_, u, t)                    ->
 134       if assert_tstep m false then begin
 135          if !G.summary then O.add ~e:1 ();
 136          step st (tstep m) u
 137       end else begin
 138          if !G.summary then O.add ~epsilon:1 ();
 139          step st m t
 140       end
 141    | B.Appl (_, _, v, t)                 ->
 142       step st {m with s = (m.e, v) :: m.s} t
 143    | B.Bind (a, B.Abst (false, n, w), t) ->
 144       let i = tsteps m in
 145       if !G.summary then O.add ~x:i ();
 146       let n = if i = 0 then n else N.minus st n i in
 147       let r = B.Bind (a, B.Abst (true, n, w), t) in
 148       step st m r
 149    | B.Bind (a, B.Abst (true, n, w), t)  ->
 150       if !G.si || N.is_not_zero st n then begin match m.s with
 151          | []          ->
 152             m, B.Bind (a, B.Abst (true, n, w), t), None
 153          | (c, v) :: s ->
 154 (*
 155             if !G.cc && not (N.assert_not_zero st n) then assert false;
 156 *)
 157             if !G.summary then O.add ~beta:1 ~theta:(List.length s) ();
 158             let v = B.Cast (E.empty_node, w, v) in
 159             let e = B.push m.e c a (B.abbr v) in
 160             step st {m with e = e; s = s} t
 161       end else begin
 162          if !G.summary then O.add ~upsilon:1 ();
 163          let e = B.push m.e m.e a B.Void in (**) (* this is wrong in general *)
 164          step st {m with e = e} t
 165       end
 166    | B.Bind (a, b, t)        ->
 167       if !G.summary then O.add ~theta:(List.length m.s) ();
 168       let e = B.push m.e m.e a b in
 169       step st {m with e = e} t
 170
 171 let assert_iterations m1 m2 =
 172    m1.n = m2.n
 173
 174 let reset m ?(e=m.e) n =
 175    {m with e = e; n = n; s = []}
 176
 177 let push m a b =
 178    let a, l = match b with
 179       | B.Abst _ -> {a with E.n_apix = m.l}, succ m.l
 180       | _        -> a, m.l
 181    in
 182    let e = B.push m.e m.e a b in
 183    {m with e = e; l = l}
 184
 185 let rec ac_nfs st (m1, t1, r1) (m2, t2, r2) =
 186    if !G.ct >= level then log2 st "Now converting nfs" m1.e t1 m2.e t2;
 187    match t1, r1, t2, r2 with
 188       | B.Sort (_, h1), _, B.Sort (_, h2), _               ->
 189          h1 = h2
 190       | B.LRef ({E.n_apix = e1}, _), _,
 191         B.LRef ({E.n_apix = e2}, _), _                     ->
 192          if e1 = e2 then ac_stacks st m1 m2 else false
 193       | B.GRef (_, u1), None, B.GRef (_, u2), None   ->
 194          if U.eq u1 u2 && assert_iterations m1 m2 then ac_stacks st m1 m2 else false
 195       | B.GRef ({E.n_apix = e1}, u1), Some v1,
 196         B.GRef ({E.n_apix = e2}, u2), Some v2              ->
 197          if e1 < e2 then begin
 198             if !G.summary then O.add ~gdelta:1 ();
 199             ac_nfs st (m1, t1, r1) (step st m2 v2)
 200          end else if e2 < e1 then begin
 201             if !G.summary then O.add ~gdelta:1 ();
 202             ac_nfs st (step st m1 v1) (m2, t2, r2)
 203          end else if U.eq u1 u2 && assert_iterations m1 m2 && ac_stacks st m1 m2 then true
 204          else begin
 205             if !G.summary then O.add ~gdelta:2 ();
 206             ac st m1 v1 m2 v2
 207          end
 208       | _, _, B.GRef _, Some v2                            ->
 209          if !G.summary then O.add ~gdelta:1 ();
 210          ac_nfs st (m1, t1, r1) (step st m2 v2)
 211       | B.GRef _, Some v1, _, _                            ->
 212          if !G.summary then O.add ~gdelta:1 ();
 213          ac_nfs st (step st m1 v1) (m2, t2, r2)
 214       | B.Bind (a1, (B.Abst (true, n1, w1) as b1), t1), _,
 215         B.Bind (a2, (B.Abst (true, n2, w2) as b2), t2), _  ->
 216          if ((!G.cc && N.assert_equal st n1 n2) || N.are_equal st n1 n2) &&
 217             ac st (reset m1 zero) w1 (reset m2 zero) w2
 218          then ac st (push m1 a1 b1) t1 (push m2 a2 b2) t2
 219          else false
 220       | B.Sort _, _, B.Bind (a, B.Abst (true, n, _), t), _ ->
 221          if !G.si then
 222             if !G.cc && not (N.assert_zero st n) then false else begin
 223             if !G.summary then O.add ~upsilon:1 ();
 224             ac st (push m1 a B.Void) t1 (push m2 a B.Void) t end
 225          else false
 226       | _                                                  -> false
 227
 228 and ac st m1 t1 m2 t2 =
 229 (*   L.warn "entering R.are_convertible"; *)
 230    ac_nfs st (step st m1 t1) (step st m2 t2)
 231
 232 and ac_stacks st m1 m2 =
 233 (*   L.warn "entering R.are_convertible_stacks"; *)
 234    if List.length m1.s <> List.length m2.s then false else
 235    let map (c1, v1) (c2, v2) =
 236       let m1, m2 = reset m1 ~e:c1 zero, reset m2 ~e:c2 zero in
 237       ac st m1 v1 m2 v2
 238    in
 239    list_and map (m1.s, m2.s)
 240
 241 let rec ih_nfs st (m, t, r) =
 242    match t, r with
 243       | B.GRef _, Some v ->
 244          if !G.summary then O.add ~gdelta:1 ();
 245          ih st m v
 246       | _                -> m, t
 247
 248 and ih st m t = ih_nfs st (step st m t)
 249
 250 (* Interface functions ******************************************************)
 251
 252 let empty_rtm = {
 253    e = B.empty; s = []; l = 0; n = None
 254 }
 255
 256 let get m i =
 257    assert (m.s = []);
 258    let _, _, _, b = B.get m.e i in b
 259
 260 let xwhd st m n t =
 261    if !G.ct >= level then log1 st "Now scanning" m.e t;
 262    ih st (reset m n) t
 263
 264 let are_convertible st m1 n1 t1 m2 n2 t2 =
 265    if !G.ct >= level then log2 st "Now converting" m1.e t1 m2.e t2;
 266    let r = ac st (reset m1 n1) t1 (reset m2 n2) t2 in
 267    r
 268 (*    let err _ = in
 269       if S.eq mu mw then are_alpha_convertible err f u w else err () *)
 270
 271 (* error reporting **********************************************************)
 272
 273 let pp_term st m och t = BO.specs.L.pp_term st m.e och t
 274
 275 let pp_lenv st och m = BO.specs.L.pp_lenv st och m.e
 276
 277 let specs = {
 278    L.pp_term = pp_term; L.pp_lenv = pp_lenv
 279 }