helm/software/helena/src/basic_rg/brgReduction.ml

   1 (*
   2     ||M||  This file is part of HELM, an Hypertextual, Electronic
   3     ||A||  Library of Mathematics, developed at the Computer Science
   4     ||T||  Department, University of Bologna, Italy.
   5     ||I||
   6     ||T||  HELM is free software; you can redistribute it and/or
   7     ||A||  modify it under the terms of the GNU General Public License
   8     \   /  version 2 or (at your option) any later version.
   9      \ /   This software is distributed as is, NO WARRANTY.
  10       V_______________________________________________________________ *)
  11
  12 module U  = NUri
  13 module S  = Share
  14 module L  = Log
  15 module G  = Options
  16 module H  = Hierarchy
  17 module N  = Layer
  18 module E  = Entity
  19 module O  = Output
  20 module B  = Brg
  21 module BO = BrgOutput
  22 module BE = BrgEnvironment
  23
  24 type rtm = {
  25    e: B.lenv;                 (* environment              *)
  26    s: (B.lenv * B.term) list; (* stack                    *)
  27    l: int;                    (* level                    *)
  28    n: int option;             (* expected type iterations *)
  29 }
  30
  31 type message = (rtm, B.term) L.message
  32
  33 (* Internal functions *******************************************************)
  34
  35 let level = 5
  36
  37 let sublevel = succ level
  38
  39 let log1 st s c t =
  40    let s1, s2 = s ^ " in the environment", "the term" in
  41    L.log st BO.specs (pred level) (L.et_items1 s1 c s2 t)
  42
  43 let log2 st s cu u ct t =
  44    let s1, s2, s3 = s ^ " in the environment (expected)", "the term", "and in the environment (inferred)" in
  45    L.log st BO.specs (pred level) (L.et_items2 s1 cu s2 u ~sc2:s3 ~c2:ct s2 t)
  46
  47 let rec list_and map = function
  48    | hd1 :: tl1, hd2 :: tl2 ->
  49       if map hd1 hd2 then list_and map (tl1, tl2) else false
  50    | l1, l2                 -> l1 = l2
  51
  52 let zero = Some 0
  53
  54 (* check closure *)
  55 let are_alpha_convertible err f t1 t2 =
  56    let rec aux f = function
  57       | B.Sort (_, p1), B.Sort (_, p2)
  58       | B.LRef (_, p1), B.LRef (_, p2)               ->
  59          if p1 = p2 then f () else err ()
  60       | B.GRef (_, u1), B.GRef (_, u2)               ->
  61          if U.eq u1 u2 then f () else err ()
  62       | B.Cast (_, v1, t1), B.Cast (_, v2, t2)
  63       | B.Appl (_, _, v1, t1), B.Appl (_, _, v2, t2) ->
  64          let f _ = aux f (t1, t2) in
  65          aux f (v1, v2)
  66       | B.Bind (_, b1, t1), B.Bind (_, b2, t2)       ->
  67          let f _ = aux f (t1, t2) in
  68          aux_bind f (b1, b2)
  69       | _                                            -> err ()
  70    and aux_bind f = function
  71       | B.Abbr v1, B.Abbr v2                                             -> aux f (v1, v2)
  72       | B.Abst (r1, n1, v1), B.Abst (r2, n2, v2) when r1 = r2 && n1 = n2 -> aux f (v1, v2)
  73       | B.Void, B.Void                                                   -> f ()
  74       | _                                                                -> err ()
  75    in
  76    if S.eq t1 t2 then f () else aux f (t1, t2)
  77
  78 let assert_tstep m vo = match m.n with
  79    | Some n -> n > 0
  80    | None   -> vo
  81
  82 let tstep m = match m.n with
  83    | Some n -> {m with n = Some (pred n)}
  84    | None   -> m
  85
  86 let tsteps m = match m.n with
  87    | Some n -> n
  88    | None   -> 0
  89
  90 let get m i =
  91    let _, c, a, b = B.get m.e i in c, a, b
  92
  93 (* to share *)
  94 let rec step st m r =
  95    if !G.ct >= sublevel then
  96    log1 st (Printf.sprintf "entering R.step: l=%u, n=%s," m.l (match m.n with Some n -> string_of_int n | None -> "infinite")) m.e r;
  97    match r with
  98    | B.Sort (a, h)                       ->
  99       if assert_tstep m false then
 100          step st (tstep m) (B.Sort (a, H.apply h))
 101       else m, r, None
 102    | B.GRef (_, uri)                     ->
 103       begin match BE.get_entity uri with
 104          | _, a, _, E.Abbr v ->
 105                m, B.gref a uri, Some v
 106          | _, _, _, E.Abst w ->
 107             if assert_tstep m true then begin
 108                if !G.summary then O.add ~grt:1 ();
 109                step st (tstep m) w
 110             end else
 111                m, r, None
 112          | _, _, _, E.Void   ->
 113             assert false
 114       end
 115    | B.LRef (_, i)                       ->
 116       begin match get m i with
 117          | c, _, B.Abbr v         ->
 118             if !G.summary then O.add ~ldelta:1 ();
 119             step st {m with e = c} v
 120          | c, a, B.Abst (_, _, w) ->
 121             if assert_tstep m true then begin
 122                if !G.summary then O.add ~lrt:1 ();
 123                step st {(tstep m) with e = c} w
 124             end else
 125                m, B.lref a i, None
 126          | _, _, B.Void           ->
 127             assert false
 128       end
 129    | B.Cast (_, u, t)                    ->
 130       if assert_tstep m false then begin
 131          if !G.summary then O.add ~e:1 ();
 132          step st (tstep m) u
 133       end else begin
 134          if !G.summary then O.add ~epsilon:1 ();
 135          step st m t
 136       end
 137    | B.Appl (_, _, v, t)                 ->
 138       step st {m with s = (m.e, v) :: m.s} t
 139    | B.Bind (a, B.Abst (false, n, w), t) ->
 140       let i = tsteps m in
 141       if !G.summary then O.add ~x:i ();
 142       let n = if i = 0 then n else N.minus st n i in
 143       let r = B.Bind (a, B.Abst (true, n, w), t) in
 144       step st m r
 145    | B.Bind (a, B.Abst (true, n, w), t)  ->
 146       if !G.si || N.is_not_zero st n then begin match m.s with
 147          | []          ->
 148             m, B.Bind (a, B.Abst (true, n, w), t), None
 149          | (c, v) :: s ->
 150             if !G.summary then O.add ~beta:1 ~theta:(List.length s) ();
 151             let v = B.Cast (E.empty_node, w, v) in
 152             let e = B.push m.e c a (B.abbr v) in
 153             step st {m with e = e; s = s} t
 154       end else begin
 155          if !G.summary then O.add ~upsilon:1 ();
 156          let e = B.push m.e m.e a B.Void in (**) (* this is wrong in general *)
 157          step st {m with e = e} t
 158       end
 159    | B.Bind (a, b, t)        ->
 160       if !G.summary then O.add ~theta:(List.length m.s) ();
 161       let e = B.push m.e m.e a b in
 162       step st {m with e = e} t
 163
 164 let assert_iterations m1 m2 =
 165    m1.n = m2.n
 166
 167 let reset m ?(e=m.e) n =
 168    {m with e = e; n = n; s = []}
 169
 170 let push m a b =
 171    let a, l = match b with
 172       | B.Abst _ -> {a with E.n_apix = m.l}, succ m.l
 173       | _        -> a, m.l
 174    in
 175    let e = B.push m.e m.e a b in
 176    {m with e = e; l = l}
 177
 178 let rec ac_nfs st (m1, t1, r1) (m2, t2, r2) =
 179    if !G.ct >= level then log2 st "Now converting nfs" m1.e t1 m2.e t2;
 180    match t1, r1, t2, r2 with
 181       | B.Sort (_, h1), _, B.Sort (_, h2), _               ->
 182          h1 = h2
 183       | B.LRef ({E.n_apix = e1}, _), _,
 184         B.LRef ({E.n_apix = e2}, _), _                     ->
 185          if e1 = e2 then ac_stacks st m1 m2 else false
 186       | B.GRef (_, u1), None, B.GRef (_, u2), None   ->
 187          if U.eq u1 u2 && assert_iterations m1 m2 then ac_stacks st m1 m2 else false
 188       | B.GRef ({E.n_apix = e1}, u1), Some v1,
 189         B.GRef ({E.n_apix = e2}, u2), Some v2              ->
 190          if U.eq u1 u2 && assert_iterations m1 m2 && ac_stacks st m1 m2 then true
 191          else if e1 < e2 then begin
 192             if !G.summary then O.add ~gdelta:1 ();
 193             ac_nfs st (m1, t1, r1) (step st m2 v2)
 194          end else if e2 < e1 then begin
 195             if !G.summary then O.add ~gdelta:1 ();
 196             ac_nfs st (step st m1 v1) (m2, t2, r2)
 197          end else begin
 198             if !G.summary then O.add ~gdelta:2 ();
 199             ac st m1 v1 m2 v2
 200          end
 201       | _, _, B.GRef _, Some v2                            ->
 202          if !G.summary then O.add ~gdelta:1 ();
 203          ac_nfs st (m1, t1, r1) (step st m2 v2)
 204       | B.GRef _, Some v1, _, _                            ->
 205          if !G.summary then O.add ~gdelta:1 ();
 206          ac_nfs st (step st m1 v1) (m2, t2, r2)
 207       | B.Bind (a1, (B.Abst (true, n1, w1) as b1), t1), _,
 208         B.Bind (a2, (B.Abst (true, n2, w2) as b2), t2), _  ->
 209          if ((!G.cc && N.assert_equal st n1 n2) || N.are_equal st n1 n2) &&
 210             ac st (reset m1 zero) w1 (reset m2 zero) w2
 211          then ac st (push m1 a1 b1) t1 (push m2 a2 b2) t2
 212          else false
 213       | B.Sort _, _, B.Bind (a, B.Abst (true, n, _), t), _ ->
 214          if !G.si then
 215             if !G.cc && not (N.assert_zero st n) then false else begin
 216             if !G.summary then O.add ~upsilon:1 ();
 217             ac st (push m1 a B.Void) t1 (push m2 a B.Void) t end
 218          else false
 219       | _                                                  -> false
 220
 221 and ac st m1 t1 m2 t2 =
 222 (*   L.warn "entering R.are_convertible"; *)
 223    ac_nfs st (step st m1 t1) (step st m2 t2)
 224
 225 and ac_stacks st m1 m2 =
 226 (*   L.warn "entering R.are_convertible_stacks"; *)
 227    if List.length m1.s <> List.length m2.s then false else
 228    let map (c1, v1) (c2, v2) =
 229       let m1, m2 = reset m1 ~e:c1 zero, reset m2 ~e:c2 zero in
 230       ac st m1 v1 m2 v2
 231    in
 232    list_and map (m1.s, m2.s)
 233
 234 let rec ih_nfs st (m, t, r) =
 235    match t, r with
 236       | B.GRef _, Some v ->
 237          if !G.summary then O.add ~gdelta:1 ();
 238          ih st m v
 239       | _                -> m, t
 240
 241 and ih st m t = ih_nfs st (step st m t)
 242
 243 (* Interface functions ******************************************************)
 244
 245 let empty_rtm = {
 246    e = B.empty; s = []; l = 0; n = None
 247 }
 248
 249 let get m i =
 250    assert (m.s = []);
 251    let _, _, _, b = B.get m.e i in b
 252
 253 let xwhd st m n t =
 254    if !G.ct >= level then log1 st "Now scanning" m.e t;
 255    ih st (reset m n) t
 256
 257 let are_convertible st m1 n1 t1 m2 n2 t2 =
 258    if !G.ct >= level then log2 st "Now converting" m1.e t1 m2.e t2;
 259    let r = ac st (reset m1 n1) t1 (reset m2 n2) t2 in
 260    r
 261 (*    let err _ = in
 262       if S.eq mu mw then are_alpha_convertible err f u w else err () *)
 263
 264 (* error reporting **********************************************************)
 265
 266 let pp_term st m och t = BO.specs.L.pp_term st m.e och t
 267
 268 let pp_lenv st och m = BO.specs.L.pp_lenv st och m.e
 269
 270 let specs = {
 271    L.pp_term = pp_term; L.pp_lenv = pp_lenv
 272 }