helm/software/helena/src/basic_rg/brgType.ml

   1 (*
   2     ||M||  This file is part of HELM, an Hypertextual, Electronic
   3     ||A||  Library of Mathematics, developed at the Computer Science
   4     ||T||  Department, University of Bologna, Italy.
   5     ||I||
   6     ||T||  HELM is free software; you can redistribute it and/or
   7     ||A||  modify it under the terms of the GNU General Public License
   8     \   /  version 2 or (at your option) any later version.
   9      \ /   This software is distributed as is, NO WARRANTY.
  10       V_______________________________________________________________ *)
  11
  12 module U  = NUri
  13 module C  = Cps
  14 module S  = Share
  15 module L  = Log
  16 module G  = Options
  17 module H  = Hierarchy
  18 module N  = Layer
  19 module E  = Entity
  20 module B  = Brg
  21 module BE = BrgEnvironment
  22 module BS = BrgSubstitution
  23 module BR = BrgReduction
  24
  25 (* Internal functions *******************************************************)
  26
  27 let level = 3
  28
  29 let message1 st1 m t1 =
  30    L.et_items1 "In the environment" m st1 t1
  31
  32 let log1 st s m t =
  33    let s =  s ^ " the term" in
  34    L.log st BR.specs level (message1 s m t)
  35
  36 let error1 err s m t =
  37    err (message1 s m t)
  38
  39 let message3 m t1 t2 ?mu t3 =
  40    let sm, st1, st2 = "In the environment", "the term", "is of type" in
  41    match mu with
  42       | Some mu ->
  43          let smu, st3 = "but in the environment", "it must be of type" in
  44          L.et_items3 sm m st1 t1 st2 t2 ~sc3:smu ~c3:mu st3 t3
  45       | None    ->
  46          let st3 = "but it must be of type" in
  47          L.et_items3 sm m st1 t1 st2 t2 st3 t3
  48
  49 let error3 err m t1 t2 ?mu t3 =
  50    err (message3 m t1 t2 ?mu t3)
  51
  52 let zero = Some 0
  53
  54 let assert_convertibility err f st m u w v =
  55    if BR.are_convertible st m zero u m zero w then f () else
  56    error3 err m v w u
  57
  58 let assert_applicability err f st m u w v =
  59    match BR.xwhd st m None u with
  60       | _, B.Sort _                      ->
  61          error1 err "not a function type" m u
  62       | mu, B.Bind (_, B.Abst (_, u), _) ->
  63          if BR.are_convertible st mu zero u m zero w then f () else
  64          error3 err m v w ~mu u
  65       | _                                -> assert false (**)
  66
  67 let rec b_type_of err f st m x =
  68    if !G.trace >= level then log1 st "Now checking" m x;
  69    match x with
  70    | B.Sort (a, h)           ->
  71       let h = H.apply h in f x (B.Sort (a, h))
  72    | B.LRef (_, i)           ->
  73       begin match BR.get m i with
  74          | B.Abst (_, w)     ->
  75             f x (BS.lift (succ i) (0) w)
  76          | B.Abbr (B.Cast (_, w, _)) ->
  77             f x (BS.lift (succ i) (0) w)
  78          | B.Abbr _                  -> assert false
  79          | B.Void                    ->
  80             error1 err "reference to excluded variable" m x
  81       end
  82    | B.GRef (_, uri)         ->
  83       begin match BE.get_entity uri with
  84          | _, _, _, E.Abst w                  -> f x w
  85          | _, _, _, E.Abbr (B.Cast (_, w, _)) -> f x w
  86          | _, _, _, E.Abbr _                  -> assert false
  87          | _, _, _, E.Void                    ->
  88             error1 err "reference to unknown entry" m x
  89       end
  90    | B.Bind (a, B.Abbr v, t) ->
  91       let f xv xt tt =
  92          f (S.sh2 v xv t xt x (B.bind_abbr a)) (B.bind_abbr a xv tt)
  93       in
  94       let f xv m = b_type_of err (f xv) st m t in
  95       let f xv = f xv (BR.push m a (B.abbr xv)) in
  96       let f xv vv = match xv with
  97          | B.Cast _ -> f xv
  98          | _        -> f (B.Cast (E.empty_node, vv, xv))
  99       in
 100       type_of err f st m v
 101    | B.Bind (a, B.Abst (n, u), t) ->
 102       let f xu xt tt =
 103          f (S.sh2 u xu t xt x (B.bind_abst n a)) (B.bind_abst (N.minus st n 1) a xu tt)
 104       in
 105       let f xu m = b_type_of err (f xu) st m t in
 106       let f xu _ = f xu (BR.push m a (B.abst n xu)) in
 107       type_of err f st m u
 108    | B.Bind (a, B.Void, t)   ->
 109       let f xt tt =
 110          f (S.sh1 t xt x (B.bind_void a)) (B.bind_void a tt)
 111       in
 112       b_type_of err f st (BR.push m a B.Void) t
 113
 114    | B.Appl (a, v, t)        ->
 115       let f xv vv xt tt =
 116          let f _ = f (S.sh2 v xv t xt x (B.appl a)) (B.appl a xv tt) in
 117          assert_applicability err f st m tt vv xv
 118       in
 119       let f xv vv = b_type_of err (f xv vv) st m t in
 120       type_of err f st m v
 121    | B.Cast (a, u, t)        ->
 122       let f xu xt tt =
 123          let f _ = f (S.sh2 u xu t xt x (B.cast a)) xu in
 124          assert_convertibility err f st m xu tt xt
 125       in
 126       let f xu _ = b_type_of err (f xu) st m t in
 127       type_of err f st m u
 128
 129 (* Interface functions ******************************************************)
 130
 131 and type_of err f st m x = b_type_of err f st m x