helm/software/helena/src/basic_rg/brgValidity.ml

   1 (*
   2     ||M||  This file is part of HELM, an Hypertextual, Electronic
   3     ||A||  Library of Mathematics, developed at the Computer Science
   4     ||T||  Department, University of Bologna, Italy.
   5     ||I||
   6     ||T||  HELM is free software; you can redistribute it and/or
   7     ||A||  modify it under the terms of the GNU General Public License
   8     \   /  version 2 or (at your option) any later version.
   9      \ /   This software is distributed as is, NO WARRANTY.
  10       V_______________________________________________________________ *)
  11
  12 module L  = Log
  13 module G  = Options
  14 module N  = Layer
  15 module E  = Entity
  16 module B  = Brg
  17 module BE = BrgEnvironment
  18 module BR = BrgReduction
  19
  20 (* Internal functions *******************************************************)
  21
  22 let level = 4
  23
  24 let warn s = L.warn (pred level) s
  25
  26 let message1 st1 m t1 =
  27    L.et_items1 "In the environment" m st1 t1
  28
  29 let log1 st s m t =
  30    let s =  s ^ " the term" in
  31    L.log st BR.specs (pred level) (message1 s m t)
  32
  33 let error1 err s m t =
  34    err (message1 s m t)
  35
  36 let message2 m1 t1 m2 t2 =
  37    let sm2, st2 = "In the environment", "the term" in
  38    let sm1, st1 = "is valid, but in the environment", "it must be of type" in
  39    L.et_items2 sm2 m2 st2 t2 ~sc2:sm1 ~c2:m1 st1 t1
  40
  41 let error2 err m1 t1 m2 t2 =
  42    err (message2 m1 t1 m2 t2)
  43
  44 let zero = Some 0
  45
  46 let one = Some 1
  47
  48 let assert_convertibility err f st m u t =
  49 IFDEF TRACE THEN
  50    if !G.ct >= level then warn "Asserting convertibility for cast"
  51 ELSE () END;
  52    if BR.are_convertible st m zero u m one t then f () else
  53    error2 err m u m t
  54
  55 let assert_applicability err f st m a v t =
  56    let mode, msg = if a.E.a_rest then one, "restricted" else None, "extended" in
  57 IFDEF TRACE THEN
  58    if !G.ct >= level then warn ("Asserting " ^ msg ^ " applicability")
  59 ELSE () END;
  60    match BR.xwhd st m mode t with
  61       | mw, B.Bind (_, B.Abst (true, n, w), _) ->
  62          if !G.cc && not (N.assert_not_zero st n) then error1 err "not a function" m t
  63          else begin
  64 IFDEF TRACE THEN
  65             if !G.ct >= level then warn "Asserting convertibility for application"
  66 ELSE () END;
  67             if BR.are_convertible st mw zero w m one v then f () else
  68             error2 err mw w m v
  69          end
  70       | _, B.Sort _                            ->
  71          error1 err "not a function" m t
  72       | _                                      -> assert false (**)
  73
  74 let rec b_validate err f st m y =
  75 IFDEF TRACE THEN
  76    if !G.ct >= level then log1 st "Now checking" m y
  77 ELSE () END;
  78    match y with
  79    | B.Sort _         -> f ()
  80    | B.LRef (_, i)    ->
  81       begin match BR.get m i with
  82          | B.Abst _
  83          | B.Abbr _ -> f ()
  84          | B.Void   ->
  85             error1 err "reference to excluded variable" m y
  86       end
  87    | B.GRef (_, uri)  ->
  88       begin match BE.get_entity uri with
  89          | _, _, _, E.Abst _
  90          | _, _, _, E.Abbr _ -> f ()
  91          | _, _, _, E.Void   ->
  92             error1 err "reference to unknown entry" m y
  93       end
  94    | B.Bind (y, b, t) ->
  95       let f () = b_validate err f st (BR.push m y b) t in
  96       begin match b with
  97          | B.Abst (_, n, u) -> validate err f st m u
  98          | B.Abbr v         -> validate err f st m v
  99          | B.Void           -> f ()
 100       end
 101    | B.Appl (a, v, t)       ->
 102       let f () = assert_applicability err f st m a v t in
 103       let f () = b_validate err f st m t in
 104       validate err f st m v
 105    | B.Cast (u, t)          ->
 106       let f () = assert_convertibility err f st m u t in
 107       let f () = b_validate err f st m t in
 108       validate err f st m u
 109
 110 (* Interface functions ******************************************************)
 111
 112 and validate err f st m t = b_validate err f st m t