helm/software/helena/src/basic_rg/brgValidity.ml

   1 (*
   2     ||M||  This file is part of HELM, an Hypertextual, Electronic
   3     ||A||  Library of Mathematics, developed at the Computer Science
   4     ||T||  Department, University of Bologna, Italy.
   5     ||I||
   6     ||T||  HELM is free software; you can redistribute it and/or
   7     ||A||  modify it under the terms of the GNU General Public License
   8     \   /  version 2 or (at your option) any later version.
   9      \ /   This software is distributed as is, NO WARRANTY.
  10       V_______________________________________________________________ *)
  11
  12 module L  = Log
  13 module E  = Entity
  14 module B  = Brg
  15 module BE = BrgEnvironment
  16 module BR = BrgReduction
  17
  18 (* Internal functions *******************************************************)
  19
  20 let level = 4
  21
  22 let message1 st1 m t1 =
  23    L.et_items1 "In the environment" m st1 t1
  24
  25 let log1 s m t =
  26    let s =  s ^ " the term" in
  27    L.log BR.specs level (message1 s m t)
  28
  29 let error1 err s m t =
  30    err (message1 s m t)
  31
  32 let message2 m1 t1 m2 t2 =
  33    let sm2, st2 = "In the environment", "the term" in
  34    let sm1, st1 = "is valid, but in the environment", "it must be of type" in
  35    L.et_items2 sm2 m2 st2 t2 ~sc2:sm1 ~c2:m1 st1 t1
  36
  37 let error2 err m1 t1 m2 t2 =
  38    err (message2 m1 t1 m2 t2)
  39
  40 let zero = Some 0
  41
  42 let one = Some 1
  43
  44 let assert_convertibility err f st m u t =
  45    if BR.are_convertible st m zero u m one t then f () else
  46    error2 err m u m t
  47
  48 let assert_applicability err f st m v t =
  49    match BR.xwhd st m None t with
  50       | _, B.Sort _                      ->
  51          error1 err "not a function" m t
  52       | mw, B.Bind (_, B.Abst (_, w), _) ->
  53          if BR.are_convertible st mw zero w m one v then f () else
  54          error2 err mw w m v
  55       | _                                -> assert false (**)
  56
  57 let rec b_validate err f st m x =
  58    log1 "Now checking" m x;
  59    match x with
  60    | B.Sort _         -> f ()
  61    | B.LRef (_, i)    ->
  62       begin match BR.get m i with
  63          | B.Abst _
  64          | B.Abbr _ -> f ()
  65          | B.Void   ->
  66             error1 err "reference to excluded variable" m x
  67       end
  68    | B.GRef (_, uri)  ->
  69       begin match BE.get_entity uri with
  70          | _, _, E.Abst _
  71          | _, _, E.Abbr _ -> f ()
  72          | _, _, E.Void   ->
  73             error1 err "reference to unknown entry" m x
  74       end
  75    | B.Bind (a, b, t) ->
  76       let f () = b_validate err f st (BR.push m a b) t in
  77       begin match b with
  78          | B.Abst (n, u) -> validate err f st m u
  79          | B.Abbr v      -> validate err f st m v
  80          | B.Void        -> f ()
  81       end
  82    | B.Appl (_, v, t)        ->
  83       let f () = assert_applicability err f st m v t in
  84       let f () = b_validate err f st m t in
  85       validate err f st m v
  86    | B.Cast (_, u, t)        ->
  87       let f () = assert_convertibility err f st m u t in
  88       let f () = b_validate err f st m t in
  89       validate err f st m u
  90
  91 (* Interface functions ******************************************************)
  92
  93 and validate err f st m x =
  94    let f () = L.unbox level; f () in
  95    L.box level; b_validate err f st m x