helm/software/helena/src/basic_rg/brgValidity.ml

   1 (*
   2     ||M||  This file is part of HELM, an Hypertextual, Electronic
   3     ||A||  Library of Mathematics, developed at the Computer Science
   4     ||T||  Department, University of Bologna, Italy.
   5     ||I||
   6     ||T||  HELM is free software; you can redistribute it and/or
   7     ||A||  modify it under the terms of the GNU General Public License
   8     \   /  version 2 or (at your option) any later version.
   9      \ /   This software is distributed as is, NO WARRANTY.
  10       V_______________________________________________________________ *)
  11
  12 module L  = Log
  13 module G  = Options
  14 module N  = Layer
  15 module E  = Entity
  16 module B  = Brg
  17 module BE = BrgEnvironment
  18 module BR = BrgReduction
  19
  20 (* Internal functions *******************************************************)
  21
  22 let level = 4
  23
  24 let warn s = L.warn (pred level) s
  25
  26 let message1 st1 m t1 =
  27    L.et_items1 "In the environment" m st1 t1
  28
  29 let log1 st s m t =
  30    let s =  s ^ " the term" in
  31    L.log st BR.specs (pred level) (message1 s m t)
  32
  33 let error1 err s m t =
  34    err (message1 s m t)
  35
  36 let message2 m1 t1 m2 t2 =
  37    let sm2, st2 = "In the environment", "the term" in
  38    let sm1, st1 = "is valid, but in the environment", "it must be of type" in
  39    L.et_items2 sm2 m2 st2 t2 ~sc2:sm1 ~c2:m1 st1 t1
  40
  41 let error2 err m1 t1 m2 t2 =
  42    err (message2 m1 t1 m2 t2)
  43
  44 let zero = Some 0
  45
  46 let one = Some 1
  47
  48 let assert_convertibility err f st m u t =
  49    if !G.ct >= level then warn "Asserting convertibility for cast";
  50    if BR.are_convertible st m zero u m one t then f () else
  51    error2 err m u m t
  52
  53 let assert_applicability err f st m x v t =
  54    let mode, msg = if x then None, "extended" else one, "restricted" in
  55    if !G.ct >= level then warn ("Asserting " ^ msg ^ " applicability");
  56    match BR.xwhd st m mode t with
  57       | mw, B.Bind (_, B.Abst (true, n, w), _) ->
  58          if !G.cc && not (N.assert_not_zero st n) then error1 err "not a function" m t
  59          else begin
  60             if !G.ct >= level then warn "Asserting convertibility for application";
  61             if BR.are_convertible st mw zero w m one v then f () else
  62             error2 err mw w m v
  63          end
  64       | _, B.Sort _                            ->
  65          error1 err "not a function" m t
  66       | _                                      -> assert false (**)
  67
  68 let rec b_validate err f st m y =
  69    if !G.ct >= level then log1 st "Now checking" m y;
  70    match y with
  71    | B.Sort _         -> f ()
  72    | B.LRef (_, i)    ->
  73       begin match BR.get m i with
  74          | B.Abst _
  75          | B.Abbr _ -> f ()
  76          | B.Void   ->
  77             error1 err "reference to excluded variable" m y
  78       end
  79    | B.GRef (_, uri)  ->
  80       begin match BE.get_entity uri with
  81          | _, _, _, E.Abst _
  82          | _, _, _, E.Abbr _ -> f ()
  83          | _, _, _, E.Void   ->
  84             error1 err "reference to unknown entry" m y
  85       end
  86    | B.Bind (y, b, t) ->
  87       let f () = b_validate err f st (BR.push m y b) t in
  88       begin match b with
  89          | B.Abst (_, n, u) -> validate err f st m u
  90          | B.Abbr v         -> validate err f st m v
  91          | B.Void           -> f ()
  92       end
  93    | B.Appl (x, v, t)       ->
  94       let f () = assert_applicability err f st m x v t in
  95       let f () = b_validate err f st m t in
  96       validate err f st m v
  97    | B.Cast (u, t)          ->
  98       let f () = assert_convertibility err f st m u t in
  99       let f () = b_validate err f st m t in
 100       validate err f st m u
 101
 102 (* Interface functions ******************************************************)
 103
 104 and validate err f st m t = b_validate err f st m t