helm/software/helena/src/complete_rg/crgOutput.ml

   1 (*
   2     ||M||  This file is part of HELM, an Hypertextual, Electronic
   3     ||A||  Library of Mathematics, developed at the Computer Science
   4     ||T||  Department, University of Bologna, Italy.
   5     ||I||
   6     ||T||  HELM is free software; you can redistribute it and/or
   7     ||A||  modify it under the terms of the GNU General Public License
   8     \   /  version 2 or (at your option) any later version.
   9      \ /   This software is distributed as is, NO WARRANTY.
  10       V_______________________________________________________________ *)
  11
  12 module P = Printf
  13 module U = NUri
  14 module C = Cps
  15 module L = Log
  16 module J = Marks
  17 module N = Level
  18 module E = Entity
  19 module D = Crg
  20
  21 (* nodes count **************************************************************)
  22
  23 let level = 2
  24
  25 type counters = {
  26    eabsts: int;
  27    eabbrs: int;
  28    evoids: int;
  29    tsorts: int;
  30    tlrefs: int;
  31    tgrefs: int;
  32    tcasts: int;
  33    tappls: int;
  34    tabsts: int;
  35    tabbrs: int;
  36    tvoids: int;
  37    uris  : D.uri list;
  38    nodes : int;
  39    xnodes: int
  40 }
  41
  42 let initial_counters = {
  43    eabsts = 0; eabbrs = 0; evoids = 0;
  44    tsorts = 0; tlrefs = 0; tgrefs = 0; tcasts = 0; tappls = 0;
  45    tabsts = 0; tabbrs = 0; tvoids = 0;
  46    uris = []; nodes = 0; xnodes = 0
  47 }
  48
  49 let rec count_term f c e = function
  50    | D.TSort _          ->
  51       f {c with tsorts = succ c.tsorts; nodes = succ c.nodes}
  52    | D.TLRef (_, i)     ->
  53       begin match D.get e i with
  54          | _, _, D.Abbr _ ->
  55             f {c with tlrefs = succ c.tlrefs; xnodes = succ c.xnodes}
  56          | _              ->
  57             f {c with tlrefs = succ c.tlrefs; nodes = succ c.nodes}
  58       end
  59    | D.TGRef (_, u)     ->
  60       let c =
  61          if C.list_mem ~eq:U.eq u c.uris
  62          then {c with nodes = succ c.nodes}
  63          else {c with xnodes = succ c.xnodes}
  64       in
  65       f {c with tgrefs = succ c.tgrefs}
  66    | D.TCast (_, v, t)  ->
  67       let c = {c with tcasts = succ c.tcasts} in
  68       let f c = count_term f c e t in
  69       count_term f c e v
  70    | D.TAppl (_, v, t)  ->
  71       let c = {c with tappls = succ c.tappls} in
  72       let f c = count_term f c e t in
  73       count_term f c e v
  74    | D.TProj (_, d, t)  ->
  75       D.shift (count_term f c e) d t
  76    | D.TBind (a, b, t)  ->
  77       let f c e = count_term f c e t in
  78       count_binder f c e a b
  79
  80 and count_binder f c e a b = match b with
  81    | D.Abst (_, w) ->
  82       let c = {c with tabsts = succ c.tabsts; nodes = succ c.nodes} in
  83       let f c = D.push_bind (f c) a b e in
  84       count_term f c e w
  85    | D.Abbr v      ->
  86       let c = {c with tabbrs = succ c.tabbrs; xnodes = succ c.xnodes} in
  87       let f c = D.push_bind (f c) a b e in
  88       count_term f c e v
  89    | D.Void        ->
  90       let c = {c with tvoids = succ c.tvoids; xnodes = succ c.xnodes} in
  91       D.push_bind (f c) a b e
  92
  93 let count_entity f c = function
  94    | _, _, u, E.Abst w ->
  95       let c = {c with
  96          eabsts = succ c.eabsts; nodes = succ c.nodes; uris = u :: c.uris
  97       } in
  98       count_term f c D.ESort w
  99    | _, _, _, E.Abbr v ->
 100       let c = {c with eabbrs = succ c.eabbrs; xnodes = succ c.xnodes} in
 101       count_term f c D.ESort v
 102    | _, _, _, E.Void   -> assert false
 103
 104 let print_counters f c =
 105    let terms =
 106       c.tsorts + c.tgrefs + c.tgrefs + c.tcasts + c.tappls + c.tabsts +
 107       c.tabbrs
 108    in
 109    let items = c.eabsts + c.eabbrs in
 110    let nodes = c.nodes + c.xnodes in
 111    let marks = J.marks () in
 112    L.warn level (P.sprintf "Intermediate representation summary (complete_rg)");
 113    L.warn level (P.sprintf "  Total entry items:        %7u" items);
 114    L.warn level (P.sprintf "    Declaration items:      %7u" c.eabsts);
 115    L.warn level (P.sprintf "    Definition items:       %7u" c.eabbrs);
 116    L.warn level (P.sprintf "  Total term items:         %7u" terms);
 117    L.warn level (P.sprintf "    Sort items:             %7u" c.tsorts);
 118    L.warn level (P.sprintf "    Local reference items:  %7u" c.tlrefs);
 119    L.warn level (P.sprintf "    Global reference items: %7u" c.tgrefs);
 120    L.warn level (P.sprintf "    Explicit Cast items:    %7u" c.tcasts);
 121    L.warn level (P.sprintf "    Application items:      %7u" c.tappls);
 122    L.warn level (P.sprintf "    Abstraction items:      %7u" c.tabsts);
 123    L.warn level (P.sprintf "    Abbreviation items:     %7u" c.tabbrs);
 124    L.warn level (P.sprintf "  Ambiguous abstractions:   %7u" marks);
 125    L.warn level (P.sprintf "  Global Int. Complexity:   %7u" c.nodes);
 126    L.warn level (P.sprintf "    + Abbreviation nodes:   %7u" nodes);
 127    f ()
 128
 129 (* term/environment pretty printer ******************************************)
 130
 131 let pp_attrs out a =
 132    let f s b = if b then out (P.sprintf "%s;" s) else out (P.sprintf "~%s;" s) in
 133    E.name ignore f a;
 134    let f i = out (P.sprintf "+%i;" i) in
 135    E.apix ignore f a
 136
 137 let rec pp_term out = function
 138    | D.TSort (a, l)    -> pp_attrs out a; out (P.sprintf "*%u" l)
 139    | D.TLRef (a, i   ) -> pp_attrs out a; out (P.sprintf "#%u" i)
 140    | D.TGRef (a, u)    -> pp_attrs out a; out (P.sprintf "$")
 141    | D.TCast (a, x, y) -> pp_attrs out a; out "<"; pp_term out x; out ">."; pp_term out y
 142    | D.TAppl (a, x, y) -> pp_attrs out a; out "("; pp_term out x; out ")."; pp_term out y
 143    | D.TBind (a, x, y) -> pp_attrs out a; pp_bind out x; out "."; pp_term out y
 144    | D.TProj (a, x, y) -> pp_attrs out a; out "{"; pp_lenv out x; out "}."; pp_term out y
 145
 146 and pp_bind out = function
 147    | D.Abst (n, x) ->
 148       out "[:"; pp_term out x; out "]"; out (N.to_string n)
 149    | D.Abbr x      -> out "[="; pp_term out x; out "]";
 150    | D.Void        -> out "[]"
 151
 152 and pp_lenv out = function
 153    | D.ESort           -> ()
 154    | D.EBind (x, a, y) -> pp_lenv out x; pp_attrs out a; pp_bind out y
 155    | D.EAppl (x, a, y) -> pp_lenv out x; out "("; pp_term out y; out ")"
 156    | D.EProj (x, a, y) -> pp_lenv out x; out "{"; pp_lenv out y; out "}"