helm/software/helena/src/toplevel/top.ml

   1 (*
   2     ||M||  This file is part of HELM, an Hypertextual, Electronic
   3     ||A||  Library of Mathematics, developed at the Computer Science
   4     ||T||  Department, University of Bologna, Italy.
   5     ||I||
   6     ||T||  HELM is free software; you can redistribute it and/or
   7     ||A||  modify it under the terms of the GNU General Public License
   8     \   /  version 2 or (at your option) any later version.
   9      \ /   This software is distributed as is, NO WARRANTY.
  10       V_______________________________________________________________ *)
  11
  12 module F  = Filename
  13 module P  = Printf
  14 module U  = NUri
  15 module C  = Cps
  16 module L  = Log
  17 module Y  = Time
  18 module G  = Options
  19 module H  = Hierarchy
  20 module O  = Output
  21 module E  = Entity
  22 module S  = Status
  23 module DO = CrgOutput
  24 module TD = TxtCrg
  25 module AA = AutProcess
  26 module AO = AutOutput
  27 module AD = AutCrg
  28 module XL = XmlLibrary
  29 module XD = XmlCrg
  30 module BD = BrgCrg
  31 module BO = BrgOutput
  32 module BR = BrgReduction
  33 module BU = BrgUntrusted
  34 module ZD = BagCrg
  35 module ZO = BagOutput
  36 module ZT = BagType
  37 module ZU = BagUntrusted
  38
  39 type status = {
  40    kst: S.status;
  41    tst: TD.status;
  42    pst: AA.status;
  43    ast: AD.status;
  44    ac : AO.counters;
  45    dc : DO.counters;
  46    bc : BO.counters;
  47    zc : ZO.counters;
  48 }
  49
  50 let flush_all () = L.flush 0; L.flush_err ()
  51
  52 let bag_error s msg =
  53    L.error ZO.specs (L.Warn s :: L.Loc :: msg); flush_all ()
  54
  55 let brg_error s msg =
  56    L.error BR.specs (L.Warn s :: L.Loc :: msg); flush_all ()
  57
  58 let initial_status () = {
  59    kst = S.initial_status ();
  60    tst = TD.initial_status ();
  61    pst = AA.initial_status ();
  62    ast = AD.initial_status ();
  63    ac  = AO.initial_counters;
  64    dc  = DO.initial_counters;
  65    bc  = BO.initial_counters;
  66    zc  = ZO.initial_counters;
  67 }
  68
  69 let refresh_status st = {st with
  70    kst = S.refresh_status st.kst;
  71    tst = TD.refresh_status st.tst;
  72    ast = AD.refresh_status st.ast;
  73 }
  74
  75 (* kernel related ***********************************************************)
  76
  77 type kernel_entity = BrgEntity of Brg.entity
  78                    | BagEntity of Bag.entity
  79                    | CrgEntity of Crg.entity
  80
  81 let print_counters st = function
  82    | G.Crg -> DO.print_counters C.start st.dc
  83    | G.Brg -> BO.print_counters C.start st.bc
  84    | G.Bag -> ZO.print_counters C.start st.zc
  85
  86 let xlate_entity entity = match !G.kernel, entity with
  87    | G.Brg, CrgEntity e ->
  88       let f e = (BrgEntity e) in E.xlate f BD.brg_of_crg e
  89    | G.Bag, CrgEntity e ->
  90       let f e = (BagEntity e) in E.xlate f ZD.bag_of_crg e
  91    | _, entity          -> entity
  92
  93 let pp_progress e =
  94    let f a u =
  95       let s = U.string_of_uri u in
  96       let err () = L.warn (P.sprintf "%s" s) in
  97       let f i = L.warn (P.sprintf "[%u] %s" i s) in
  98       E.mark err f a
  99    in
 100    match e with
 101       | CrgEntity e -> E.common f e
 102       | BrgEntity e -> E.common f e
 103       | BagEntity e -> E.common f e
 104
 105 let count_entity st = function
 106    | BrgEntity e -> {st with bc = BO.count_entity C.start st.bc e}
 107    | BagEntity e -> {st with zc = ZO.count_entity C.start st.zc e}
 108    | CrgEntity e -> {st with dc = DO.count_entity C.start st.dc e}
 109
 110 let export_entity = function
 111    | CrgEntity e -> XL.export_entity XD.export_term e
 112    | BrgEntity e -> XL.export_entity BO.export_term e
 113    | BagEntity e -> XL.export_entity ZO.export_term e
 114
 115 let type_check st k =
 116    let brg_err msg = brg_error "Type Error" msg; failwith "Interrupted" in
 117    let ok _ _ = st in
 118    match k with
 119       | BrgEntity entity -> BU.type_check brg_err ok st.kst entity
 120       | BagEntity entity -> ZU.type_check ok st.kst entity
 121       | CrgEntity _      -> st
 122
 123 (* extended lexer ***********************************************************)
 124
 125 type 'token lexer = {
 126    parse : Lexing.lexbuf -> 'token;
 127    mutable tokbuf: 'token option;
 128    mutable unget : bool
 129 }
 130
 131 let initial_lexer parse = {
 132    parse = parse; tokbuf = None; unget = false
 133 }
 134
 135 let token xl lexbuf = match xl.tokbuf with
 136    | Some token when xl.unget ->
 137       xl.unget <- false; token
 138    | _                        ->
 139       let token = xl.parse lexbuf in
 140       xl.tokbuf <- Some token; token
 141
 142 (* input related ************************************************************)
 143
 144 type input = Text | Automath
 145
 146 type input_entity = TxtEntity of Txt.command
 147                   | AutEntity of Aut.command
 148                   | NoEntity
 149
 150 let type_of_input name =
 151    if F.check_suffix name ".hln" then Text
 152    else if F.check_suffix name ".aut" then
 153       let _ = H.set_sorts 0 ["Set"; "Prop"] in
 154       assert (H.set_graph "Z2");
 155       Automath
 156    else begin
 157       L.warn (P.sprintf "Unknown file type: %s" name); exit 2
 158    end
 159
 160 let txt_xl = initial_lexer TxtLexer.token
 161
 162 let aut_xl = initial_lexer AutLexer.token
 163
 164 let parbuf = ref [] (* parser buffer *)
 165
 166 let gen_text command =
 167    parbuf := TxtEntity command :: !parbuf
 168
 169 let entity_of_input lexbuf i = match i, !parbuf with
 170    | Automath, _    ->
 171       begin match AutParser.entry (token aut_xl) lexbuf with
 172          | Some e -> aut_xl.unget <- true; AutEntity e
 173          | None   -> NoEntity
 174       end
 175    | Text, []       ->
 176       begin match TxtParser.entry (token txt_xl) lexbuf with
 177          | Some e -> txt_xl.unget <- true; TxtEntity e
 178          | None   -> NoEntity
 179       end
 180    | Text, hd :: tl ->
 181       parbuf := tl; hd
 182
 183 let process_input f st = function
 184    | AutEntity e     ->
 185       let f pst e = f {st with pst = pst} (AutEntity e) in
 186       AA.process_command f st.pst e
 187    | xe              -> f st xe
 188
 189 let count_input st = function
 190    | AutEntity e -> {st with ac = AO.count_command C.start st.ac e}
 191    | xe          -> st
 192
 193 (****************************************************************************)
 194
 195 let stage = ref 3
 196 let progress = ref false
 197 let preprocess = ref false
 198 let root = ref ""
 199 let export = ref false
 200 let st = ref (initial_status ())
 201 let streaming = ref false (* parsing style (temporary) *)
 202
 203 let process_2 st entity =
 204    let st = if !L.level > 2 then count_entity st entity else st in
 205    if !export then export_entity entity;
 206    if !stage > 2 then type_check st entity else st
 207
 208 let process_1 st entity =
 209    if !progress then pp_progress entity;
 210    let st = if !L.level > 2 then count_entity st entity else st in
 211    if !export && !stage = 1 then export_entity entity;
 212    if !stage > 1 then process_2 st (xlate_entity entity) else st
 213
 214 let process_0 st entity =
 215    let f st entity =
 216       if !stage = 0 then st else
 217       match entity with
 218          | AutEntity e ->
 219             let err ast = {st with ast = ast} in
 220             let g ast e = process_1 {st with ast = ast} (CrgEntity e) in
 221             AD.crg_of_aut err g st.ast e
 222          | TxtEntity e ->
 223             let crr tst = {st with tst = tst} in
 224             let d tst e = process_1 {st with tst = tst} (CrgEntity e) in
 225             TD.crg_of_txt crr d gen_text st.tst e
 226          | NoEntity    -> assert false
 227    in
 228    let st = if !L.level > 2 then count_input st entity else st in
 229    if !preprocess then process_input f st entity else f st entity
 230
 231 let process_nostreaming st lexbuf input =
 232    let id x = x in
 233    let rec aux1 book = match entity_of_input lexbuf input with
 234       | NoEntity -> List.rev book
 235       | e        -> aux1 (id e :: book)
 236    in
 237    let rec aux2 st = function
 238       | []           -> st
 239       | entity :: tl -> aux2 (process_0 st entity) tl
 240    in
 241    aux2 st (aux1 [])
 242
 243 let process_streaming st lexbuf input =
 244    let rec aux st = match entity_of_input lexbuf input with
 245       | NoEntity -> st
 246       | e        -> aux (process_0 st e)
 247    in
 248    aux st
 249
 250 (****************************************************************************)
 251
 252 let process st name =
 253    let process = if !streaming then process_streaming else process_nostreaming in
 254    let input = type_of_input name in
 255    let ich = open_in name in
 256    let lexbuf = Lexing.from_channel ich in
 257    let st = process st lexbuf input in
 258    close_in ich;
 259    if !stage > 2 && !G.cc && !G.si then XL.export_csys st.kst.S.cc;
 260    st, input
 261
 262 let main =
 263 try
 264    let version_string = "Helena 0.8.2 M - January 2011" in
 265    let print_version () = L.warn (version_string ^ "\n"); exit 0 in
 266    let set_hierarchy s =
 267       if H.set_graph s then () else
 268          L.warn (P.sprintf "Unknown type hierarchy: %s" s)
 269    in
 270    let set_kernel = function
 271       | "brg" -> G.kernel := G.Brg
 272       | "bag" -> G.kernel := G.Bag
 273       | s     -> L.warn (P.sprintf "Unknown kernel version: %s" s)
 274    in
 275    let set_summary i = L.level := i in
 276    let set_stage i = stage := i in
 277    let set_xdir s = G.xdir := s in
 278    let set_root s = root := s in
 279    let clear_options () =
 280       progress := false; export := false; preprocess := false;
 281       stage := 3; root := "";
 282       st := initial_status ();
 283       L.clear (); G.clear (); H.clear (); O.clear_reductions ();
 284       streaming := false;
 285    in
 286    let process_file name =
 287       if !L.level > 0 then Y.gmtime version_string;
 288       if !L.level > 1 then
 289          L.warn (P.sprintf "Processing file: %s" name);
 290       if !L.level > 0 then Y.utime_stamp "started";
 291       let base_name = Filename.chop_extension (Filename.basename name) in
 292       let cover = F.concat !root base_name in
 293       if !stage < 2 then G.kernel := G.Crg;
 294       G.cover := cover;
 295       let sst, input = process (refresh_status !st) name in
 296       st := sst;
 297       if !L.level > 0 then Y.utime_stamp "processed";
 298       if !L.level > 2 then begin
 299          AO.print_counters C.start !st.ac;
 300          if !preprocess then AO.print_process_counters C.start !st.pst;
 301          if !stage > 0 then print_counters !st G.Crg;
 302          if !stage > 1 then print_counters !st !G.kernel;
 303          if !stage > 2 then O.print_reductions ()
 304       end
 305    in
 306    let exit () =
 307       if !L.level > 0 then Y.utime_stamp "at exit";
 308       flush_all ()
 309    in
 310    let help =
 311       "Usage: helena [ -LPVXcgijopqx1 | -Ss <number> | -O <dir> | -hkr <string> ]* [ <file> ]*\n\n" ^
 312       "Summary levels: 0 just errors (default), 1 time stamps, 2 processed file names, \
 313        3 data information, 4 typing information, 5 reduction information\n\n" ^
 314        "Stages: 0 parsing, 1 to intermediate, 2 to untrusted, 3 to trusted (default)\n"
 315    in
 316    let help_L = " show lexer debug information" in
 317    let help_O = "<dir>  set location of output directory (XML) to <dir> (default: current directory)" in
 318    let help_P = " show parser debug information" in
 319    let help_S = "<number>  set summary level (see above)" in
 320    let help_V = " show version information" in
 321    let help_X = " clear options" in
 322
 323    let help_c = " read/write conversion constraints" in
 324    let help_g = " always expand global definitions" in
 325    let help_h = "<string>  set type hierarchy (default: \"Z1\")" in
 326    let help_i = " show local references by index" in
 327    let help_j = " show URI of processed kernel objects" in
 328    let help_k = "<string>  set kernel version (default: \"brg\")" in
 329    let help_o = " activate sort inclusion" in
 330    let help_p = " preprocess source" in
 331    let help_q = " disable quotation of identifiers" in
 332    let help_r = "<string>  set initial segment of URI hierarchy (default: empty)" in
 333    let help_s = "<number>  set translation stage (see above)" in
 334    let help_x = " export kernel entities (XML)" in
 335
 336    let help_1 = " parse files with streaming policy" in
 337    L.box 0; L.box_err ();
 338    at_exit exit;
 339    Arg.parse [
 340       ("-L", Arg.Set G.debug_lexer, help_L);
 341       ("-O", Arg.String set_xdir, help_O);
 342       ("-P", Arg.Set G.debug_parser, help_P);
 343       ("-S", Arg.Int set_summary, help_S);
 344       ("-V", Arg.Unit print_version, help_V);
 345       ("-X", Arg.Unit clear_options, help_X);
 346       ("-c", Arg.Set G.cc, help_c);
 347       ("-g", Arg.Set G.expand, help_g);
 348       ("-h", Arg.String set_hierarchy, help_h);
 349       ("-i", Arg.Set G.indexes, help_i);
 350       ("-j", Arg.Set progress, help_j);
 351       ("-k", Arg.String set_kernel, help_k);
 352       ("-o", Arg.Set G.si, help_o);
 353       ("-p", Arg.Set preprocess, help_p);
 354       ("-q", Arg.Set G.unquote, help_q);
 355       ("-r", Arg.String set_root, help_r);
 356       ("-s", Arg.Int set_stage, help_s);
 357       ("-x", Arg.Set export, help_x);
 358       ("-1", Arg.Set streaming, help_1);
 359    ] process_file help;
 360 with ZT.TypeError msg -> bag_error "Type Error" msg