helm/software/lambda-delta/automath/autOutput.ml

   1 (*
   2     ||M||  This file is part of HELM, an Hypertextual, Electronic
   3     ||A||  Library of Mathematics, developed at the Computer Science
   4     ||T||  Department, University of Bologna, Italy.
   5     ||I||
   6     ||T||  HELM is free software; you can redistribute it and/or
   7     ||A||  modify it under the terms of the GNU General Public License
   8     \   /  version 2 or (at your option) any later version.
   9      \ /   This software is distributed as is, NO WARRANTY.
  10       V_______________________________________________________________ *)
  11
  12 module P = Printf
  13 module L = Log
  14 module A = Aut
  15 module R = AutProcess
  16
  17 type counters = {
  18    sections: int;
  19    contexts: int;
  20    blocks:   int;
  21    decls:    int;
  22    defs:     int;
  23    sorts:    int;
  24    grefs:    int;
  25    appls:    int;
  26    absts:    int;
  27    pars:     int;
  28    xnodes:   int
  29 }
  30
  31 let initial_counters = {
  32    sections = 0; contexts = 0; blocks = 0; decls = 0; defs = 0;
  33    sorts = 0; grefs = 0; appls = 0; absts = 0; pars = 0; xnodes = 0
  34 }
  35
  36 let rec count_term f c = function
  37    | A.Sort _         ->
  38       f {c with sorts = succ c.sorts; xnodes = succ c.xnodes}
  39    | A.GRef (_, ts)   ->
  40       let c = {c with grefs = succ c.grefs} in
  41       let c = {c with pars = c.pars + List.length ts} in
  42       let c = {c with xnodes = succ c.xnodes + List.length ts} in
  43       Cps.list_fold_left f count_term c ts
  44    | A.Appl (v, t)    ->
  45       let c = {c with appls = succ c.appls; xnodes = succ c.xnodes} in
  46       let f c = count_term f c t in
  47       count_term f c v
  48    | A.Abst (_, w, t) ->
  49       let c = {c with absts = succ c.absts; xnodes = succ c.xnodes} in
  50       let f c = count_term f c t in
  51       count_term f c w
  52
  53 let count_item f c = function
  54    | A.Section _        ->
  55       f {c with sections = succ c.sections}
  56    | A.Context _        ->
  57       f {c with contexts = succ c.contexts}
  58    | A.Block (_, w)     ->
  59       let c = {c with blocks = succ c.blocks; xnodes = succ c.xnodes} in
  60       count_term f c w
  61    | A.Decl (_, w)      ->
  62       let c = {c with decls = succ c.decls; xnodes = succ c.xnodes} in
  63       count_term f c w
  64    | A.Def (_, w, _, t) ->
  65       let c = {c with defs = succ c.defs; xnodes = succ c.xnodes} in
  66       let f c = count_term f c t in
  67       count_term f c w
  68
  69 let print_counters f c =
  70    let terms = c.sorts + c.grefs + c.appls + c.absts in
  71    let items = c.sections + c.contexts + c.blocks + c.decls + c.defs in
  72    L.warn (P.sprintf "  Automath representation summary");
  73    L.warn (P.sprintf "    Total book items:         %7u" items);
  74    L.warn (P.sprintf "      Section items:          %7u" c.sections);
  75    L.warn (P.sprintf "      Context items:          %7u" c.contexts);
  76    L.warn (P.sprintf "      Block items:            %7u" c.blocks);
  77    L.warn (P.sprintf "      Declaration items:      %7u" c.decls);
  78    L.warn (P.sprintf "      Definition items:       %7u" c.defs);
  79    L.warn (P.sprintf "    Total Parameter items:    %7u" c.pars);
  80    L.warn (P.sprintf "      Application items:      %7u" c.pars);
  81    L.warn (P.sprintf "    Total term items:         %7u" terms);
  82    L.warn (P.sprintf "      Sort items:             %7u" c.sorts);
  83    L.warn (P.sprintf "      Reference items:        %7u" c.grefs);
  84    L.warn (P.sprintf "      Application items:      %7u" c.appls);
  85    L.warn (P.sprintf "      Abstraction items:      %7u" c.absts);
  86    L.warn (P.sprintf "    Global Int. Complexity:   unknown");
  87    L.warn (P.sprintf "      + Abbreviation nodes:   %7u" c.xnodes);
  88    f ()
  89
  90 let print_process_counters f c =
  91    let f iao iar iac =
  92       L.warn (P.sprintf "  Automath process summary");
  93       L.warn (P.sprintf "    Implicit after opening:   %7u" iao);
  94       L.warn (P.sprintf "    Implicit after reopening: %7u" iar);
  95       L.warn (P.sprintf "    Implicit after closing:   %7u" iac);
  96       f ()
  97    in
  98    R.get_counters f c