helm/software/matita/contribs/formal_topology/overlap/basic_pairs.ma

   1 (**************************************************************************)
   2 (*       ___                                                              *)
   3 (*      ||M||                                                             *)
   4 (*      ||A||       A project by Andrea Asperti                           *)
   5 (*      ||T||                                                             *)
   6 (*      ||I||       Developers:                                           *)
   7 (*      ||T||         The HELM team.                                      *)
   8 (*      ||A||         http://helm.cs.unibo.it                             *)
   9 (*      \   /                                                             *)
  10 (*       \ /        This file is distributed under the terms of the       *)
  11 (*        v         GNU General Public License Version 2                  *)
  12 (*                                                                        *)
  13 (**************************************************************************)
  14
  15 include "relations.ma".
  16 include "notation.ma".
  17
  18 record basic_pair: Type1 ≝
  19  { concr: REL;
  20    form: REL;
  21    rel: arrows1 ? concr form
  22  }.
  23
  24 interpretation "basic pair relation" 'Vdash2 x y c = (fun21 ??? (rel c) x y).
  25 interpretation "basic pair relation (non applied)" 'Vdash c = (rel c).
  26
  27 alias symbol "eq" = "setoid1 eq".
  28 alias symbol "compose" = "category1 composition".
  29 record relation_pair (BP1,BP2: basic_pair): Type1 ≝
  30  { concr_rel: arrows1 ? (concr BP1) (concr BP2);
  31    form_rel: arrows1 ? (form BP1) (form BP2);
  32    commute: ⊩ ∘ concr_rel = form_rel ∘ ⊩
  33  }.
  34
  35
  36 interpretation "concrete relation" 'concr_rel r = (concr_rel ?? r).
  37 interpretation "formal relation" 'form_rel r = (form_rel ?? r).
  38
  39 definition relation_pair_equality:
  40  ∀o1,o2. equivalence_relation1 (relation_pair o1 o2).
  41  intros;
  42  constructor 1;
  43   [ apply (λr,r'. ⊩ ∘ r \sub\c = ⊩ ∘ r' \sub\c);
  44   | simplify;
  45     intros;
  46     apply refl1;
  47   | simplify;
  48     intros 2;
  49     apply sym1;
  50   | simplify;
  51     intros 3;
  52     apply trans1;
  53   ]
  54 qed.
  55
  56 definition relation_pair_setoid: basic_pair → basic_pair → setoid1.
  57  intros;
  58  constructor 1;
  59   [ apply (relation_pair b b1)
  60   | apply relation_pair_equality
  61   ]
  62 qed.
  63
  64 definition relation_pair_of_relation_pair_setoid :
  65   ∀P,Q. relation_pair_setoid P Q → relation_pair P Q ≝ λP,Q,x.x.
  66 coercion relation_pair_of_relation_pair_setoid.
  67
  68 lemma eq_to_eq':
  69   ∀o1,o2.∀r,r':relation_pair_setoid o1 o2. r=r' → r \sub\f ∘ ⊩ = r'\sub\f ∘ ⊩.
  70  intros 7 (o1 o2 r r' H c1 f2);
  71  split; intro H1;
  72   [ lapply (fi ?? (commute ?? r c1 f2) H1) as H2;
  73     lapply (if ?? (H c1 f2) H2) as H3;
  74     apply (if ?? (commute ?? r' c1 f2) H3);
  75   | lapply (fi ?? (commute ?? r' c1 f2) H1) as H2;
  76     lapply (fi ?? (H c1 f2) H2) as H3;
  77     apply (if ?? (commute ?? r c1 f2) H3);
  78   ]
  79 qed.
  80
  81 definition id_relation_pair: ∀o:basic_pair. relation_pair o o.
  82  intro;
  83  constructor 1;
  84   [1,2: apply id1;
  85   | lapply (id_neutral_right1 ? (concr o) ? (⊩)) as H;
  86     lapply (id_neutral_left1 ?? (form o) (⊩)) as H1;
  87     apply (.= H);
  88     apply (H1 \sup -1);]
  89 qed.
  90
  91 lemma relation_pair_composition:
  92   ∀o1,o2,o3: basic_pair.
  93   relation_pair_setoid o1 o2 → relation_pair_setoid o2 o3 → relation_pair_setoid o1 o3.
  94 intros 3 (o1 o2 o3);
  95   intros (r r1);
  96     constructor 1;
  97      [ apply (r1 \sub\c ∘ r \sub\c)
  98      | apply (r1 \sub\f ∘ r \sub\f)
  99      | lapply (commute ?? r) as H;
 100        lapply (commute ?? r1) as H1;
 101        alias symbol "trans" = "trans1".
 102        alias symbol "assoc" = "category1 assoc".
 103        apply (.= ASSOC);
 104        apply (.= #‡H1);
 105        alias symbol "invert" = "setoid1 symmetry".
 106        apply (.= ASSOC ^ -1);
 107        apply (.= H‡#);
 108        apply ASSOC]
 109 qed.
 110
 111 lemma relation_pair_composition_is_morphism:
 112   ∀o1,o2,o3: basic_pair.
 113   ∀a,a':relation_pair_setoid o1 o2.
 114   ∀b,b':relation_pair_setoid o2 o3.
 115    a=a' → b=b' →
 116     relation_pair_composition o1 o2 o3 a b
 117     = relation_pair_composition o1 o2 o3 a' b'.
 118 intros 3 (o1 o2 o3);
 119     intros;
 120     change with (⊩ ∘ (b\sub\c ∘ a\sub\c) = ⊩ ∘ (b'\sub\c ∘ a'\sub\c));
 121     change in e with (⊩ ∘ a \sub\c = ⊩ ∘ a' \sub\c);
 122     change in e1 with (⊩ ∘ b \sub\c = ⊩ ∘ b' \sub\c);
 123     apply (.= ASSOC);
 124     apply (.= #‡e1);
 125     apply (.= #‡(commute ?? b'));
 126     apply (.= ASSOC ^ -1);
 127     apply (.= e‡#);
 128     apply (.= ASSOC);
 129     apply (.= #‡(commute ?? b')\sup -1);
 130     apply (ASSOC ^ -1);
 131 qed.
 132
 133 definition relation_pair_composition_morphism:
 134  ∀o1,o2,o3. binary_morphism1 (relation_pair_setoid o1 o2) (relation_pair_setoid o2 o3) (relation_pair_setoid o1 o3).
 135  intros;
 136  constructor 1;
 137   [ apply relation_pair_composition;
 138   | apply relation_pair_composition_is_morphism;]
 139 qed.
 140
 141 lemma relation_pair_composition_morphism_assoc:
 142 Πo1:basic_pair
 143 .Πo2:basic_pair
 144  .Πo3:basic_pair
 145   .Πo4:basic_pair
 146    .Πa12:relation_pair_setoid o1 o2
 147     .Πa23:relation_pair_setoid o2 o3
 148      .Πa34:relation_pair_setoid o3 o4
 149       .relation_pair_composition_morphism o1 o3 o4
 150        (relation_pair_composition_morphism o1 o2 o3 a12 a23) a34
 151        =relation_pair_composition_morphism o1 o2 o4 a12
 152         (relation_pair_composition_morphism o2 o3 o4 a23 a34).
 153    intros;
 154     change with (⊩ ∘ (a34\sub\c ∘ (a23\sub\c ∘ a12\sub\c)) =
 155                  ⊩ ∘ ((a34\sub\c ∘ a23\sub\c) ∘ a12\sub\c));
 156     alias symbol "refl" = "refl1".
 157     alias symbol "prop2" = "prop21".
 158     apply (ASSOC‡#);
 159 qed.
 160
 161 lemma relation_pair_composition_morphism_respects_id:
 162   ∀o1,o2:basic_pair.∀a:relation_pair_setoid o1 o2.
 163   relation_pair_composition_morphism o1 o1 o2 (id_relation_pair o1) a=a.
 164    intros;
 165     change with (⊩ ∘ (a\sub\c ∘ (id_relation_pair o1)\sub\c) = ⊩ ∘ a\sub\c);
 166     apply ((id_neutral_right1 ????)‡#);
 167 qed.
 168
 169 lemma relation_pair_composition_morphism_respects_id_r:
 170   ∀o1,o2:basic_pair.∀a:relation_pair_setoid o1 o2.
 171   relation_pair_composition_morphism o1 o2 o2 a (id_relation_pair o2)=a.
 172   intros;
 173     change with (⊩ ∘ ((id_relation_pair o2)\sub\c ∘ a\sub\c) = ⊩ ∘ a\sub\c);
 174     apply ((id_neutral_left1 ????)‡#);
 175 qed.
 176
 177 definition BP: category1.
 178  constructor 1;
 179   [ apply basic_pair
 180   | apply relation_pair_setoid
 181   | apply id_relation_pair
 182   | apply relation_pair_composition_morphism
 183   | apply relation_pair_composition_morphism_assoc;
 184   | apply relation_pair_composition_morphism_respects_id;
 185   | apply relation_pair_composition_morphism_respects_id_r;]
 186 qed.
 187
 188 definition basic_pair_of_BP : objs1 BP → basic_pair ≝ λx.x.
 189 coercion basic_pair_of_BP.
 190
 191 definition relation_pair_setoid_of_arrows1_BP :
 192   ∀P,Q. arrows1 BP P Q → relation_pair_setoid P Q ≝ λP,Q,x.x.
 193 coercion relation_pair_setoid_of_arrows1_BP.
 194
 195 definition BPext: ∀o: BP. form o ⇒ Ω \sup (concr o).
 196  intros; constructor 1;
 197   [ apply (ext ? ? (rel o));
 198   | intros;
 199     apply (.= #‡e);
 200     apply refl1]
 201 qed.
 202
 203 definition BPextS: ∀o: BP. Ω \sup (form o) ⇒ Ω \sup (concr o).
 204  intros; constructor 1;
 205   [ apply (minus_image ?? (rel o));
 206   | intros; apply (#‡e); ]
 207 qed.
 208
 209 definition fintersects: ∀o: BP. binary_morphism1 (form o) (form o) (Ω \sup (form o)).
 210  intros (o); constructor 1;
 211   [ apply (λa,b: form o.{c | BPext o c ⊆ BPext o a ∩ BPext o b });
 212     intros; simplify; apply (.= (†e)‡#); apply refl1
 213   | intros; split; simplify; intros;
 214      [ apply (. #‡((†e^-1)‡(†e1^-1))); assumption
 215      | apply (. #‡((†e)‡(†e1))); assumption]]
 216 qed.
 217
 218 interpretation "fintersects" 'fintersects U V = (fun21 ??? (fintersects ?) U V).
 219
 220 definition fintersectsS:
 221  ∀o:BP. binary_morphism1 (Ω \sup (form o)) (Ω \sup (form o)) (Ω \sup (form o)).
 222  intros (o); constructor 1;
 223   [ apply (λo: basic_pair.λa,b: Ω \sup (form o).{c | BPext o c ⊆ BPextS o a ∩ BPextS o b });
 224     intros; simplify; apply (.= (†e)‡#); apply refl1
 225   | intros; split; simplify; intros;
 226      [ apply (. #‡((†e^-1)‡(†e1^-1))); assumption
 227      | apply (. #‡((†e)‡(†e1))); assumption]]
 228 qed.
 229
 230 interpretation "fintersectsS" 'fintersects U V = (fun21 ??? (fintersectsS ?) U V).
 231
 232 definition relS: ∀o: BP. binary_morphism1 (concr o) (Ω \sup (form o)) CPROP.
 233  intros (o); constructor 1;
 234   [ apply (λx:concr o.λS: Ω \sup (form o).∃y:form o.y ∈ S ∧ x ⊩⎽o y);
 235   | intros; split; intros; cases e2; exists [1,3: apply w]
 236      [ apply (. (#‡e1^-1)‡(e^-1‡#)); assumption
 237      | apply (. (#‡e1)‡(e‡#)); assumption]]
 238 qed.
 239
 240 interpretation "basic pair relation for subsets" 'Vdash2 x y c = (fun21 (concr ?) ?? (relS c) x y).
 241 interpretation "basic pair relation for subsets (non applied)" 'Vdash c = (fun21 ??? (relS c)).