helm/software/matita/contribs/ng_assembly/freescale/opcode_base_lemmas.ma

   1 (**************************************************************************)
   2 (*       ___                                                              *)
   3 (*      ||M||                                                             *)
   4 (*      ||A||       A project by Andrea Asperti                           *)
   5 (*      ||T||                                                             *)
   6 (*      ||I||       Developers:                                           *)
   7 (*      ||T||         The HELM team.                                      *)
   8 (*      ||A||         http://helm.cs.unibo.it                             *)
   9 (*      \   /                                                             *)
  10 (*       \ /        This file is distributed under the terms of the       *)
  11 (*        v         GNU General Public License Version 2                  *)
  12 (*                                                                        *)
  13 (**************************************************************************)
  14
  15 (* ********************************************************************** *)
  16 (*                          Progetto FreeScale                            *)
  17 (*                                                                        *)
  18 (*   Sviluppato da: Ing. Cosimo Oliboni, oliboni@cs.unibo.it              *)
  19 (*   Ultima modifica: 05/08/2009                                          *)
  20 (*                                                                        *)
  21 (* ********************************************************************** *)
  22
  23 include "num/bool_lemmas.ma".
  24 include "freescale/opcode_base.ma".
  25
  26 (* ********************************************** *)
  27 (* MATTONI BASE PER DEFINIRE LE TABELLE DELLE MCU *)
  28 (* ********************************************** *)
  29
  30 ndefinition mcu_type_destruct_aux ≝
  31 Πm1,m2:mcu_type.ΠP:Prop.m1 = m2 →
  32  match eq_mcutype m1 m2 with [ true ⇒ P → P | false ⇒ P ].
  33
  34 ndefinition mcutype_destruct : mcu_type_destruct_aux.
  35  #m1; #m2; #P; #H;
  36  nrewrite < H;
  37  nelim m1;
  38  nnormalize;
  39  napply (λx.x).
  40 nqed.
  41
  42 nlemma symmetric_eqmcutype : symmetricT mcu_type bool eq_mcutype.
  43  #m1; #m2;
  44  nelim m1;
  45  nelim m2;
  46  nnormalize;
  47  napply refl_eq.
  48 nqed.
  49
  50 nlemma eqmcutype_to_eq : ∀m1,m2:mcu_type.(eq_mcutype m1 m2 = true) → (m1 = m2).
  51  #m1; #m2;
  52  ncases m1;
  53  ncases m2;
  54  nnormalize;
  55  ##[ ##1,6,11,16: #H; napply refl_eq
  56  ##| ##*: #H; napply (bool_destruct … H)
  57  ##]
  58 nqed.
  59
  60 nlemma eq_to_eqmcutype : ∀m1,m2.m1 = m2 → eq_mcutype m1 m2 = true.
  61  #m1; #m2;
  62  ncases m1;
  63  ncases m2;
  64  nnormalize;
  65  ##[ ##1,6,11,16: #H; napply refl_eq
  66  ##| ##*: #H; napply (mcutype_destruct … H)
  67  ##]
  68 nqed.
  69
  70 nlemma decidable_mcutype : ∀x,y:mcu_type.decidable (x = y).
  71  #x; #y;
  72  nnormalize;
  73  nelim x;
  74  nelim y;
  75  ##[ ##1,6,11,16: napply (or2_intro1 (? = ?) (? ≠ ?) …); napply refl_eq
  76  ##| ##*: napply (or2_intro2 (? = ?) (? ≠ ?) …);
  77           nnormalize; #H;
  78           napply False_ind;
  79           napply (mcutype_destruct … H)
  80  ##]
  81 nqed.
  82
  83 nlemma neqmcutype_to_neq : ∀m1,m2:mcu_type.(eq_mcutype m1 m2 = false) → (m1 ≠ m2).
  84  #m1; #m2;
  85  ncases m1;
  86  ncases m2;
  87  nnormalize;
  88  ##[ ##1,6,11,16: #H; napply (bool_destruct … H)
  89  ##| ##*: #H; #H1; napply (mcutype_destruct … H1)
  90  ##]
  91 nqed.
  92
  93 nlemma neq_to_neqmcutype : ∀m1,m2.m1 ≠ m2 → eq_mcutype m1 m2 = false.
  94  #m1; #m2;
  95  ncases m1;
  96  ncases m2;
  97  nnormalize;
  98  ##[ ##1,6,11,16: #H; nelim (H (refl_eq …))
  99  ##| ##*: #H; napply refl_eq
 100  ##]
 101 nqed.