helm/software/matita/contribs/ng_assembly/universe/universe.ma

   1 (**************************************************************************)
   2 (*       ___                                                              *)
   3 (*      ||M||                                                             *)
   4 (*      ||A||       A project by Andrea Asperti                           *)
   5 (*      ||T||                                                             *)
   6 (*      ||I||       Developers:                                           *)
   7 (*      ||T||         The HELM team.                                      *)
   8 (*      ||A||         http://helm.cs.unibo.it                             *)
   9 (*      \   /                                                             *)
  10 (*       \ /        This file is distributed under the terms of the       *)
  11 (*        v         GNU General Public License Version 2                  *)
  12 (*                                                                        *)
  13 (**************************************************************************)
  14
  15 (* ********************************************************************** *)
  16 (*                          Progetto FreeScale                            *)
  17 (*                                                                        *)
  18 (*   Sviluppato da: Ing. Cosimo Oliboni, oliboni@cs.unibo.it              *)
  19 (*   Sviluppo: 2008-2010                                                  *)
  20 (*                                                                        *)
  21 (* ********************************************************************** *)
  22
  23 include "common/list.ma".
  24 include "common/nat_lemmas.ma".
  25 include "common/prod.ma".
  26
  27 nlet rec nmember_natList (elem:nat) (l:ne_list nat) on l ≝
  28  match l with
  29   [ ne_nil h ⇒ ⊖(eq_nat elem h)
  30   | ne_cons h t ⇒ match eq_nat elem h with
  31    [ true ⇒ false | false ⇒ nmember_natList elem t ]
  32   ].
  33
  34 (* elem presente una ed una sola volta in l *)
  35 nlet rec member_natList (elem:nat) (l:ne_list nat) on l ≝
  36  match l with
  37   [ ne_nil h ⇒ eq_nat elem h
  38   | ne_cons h t ⇒ match eq_nat elem h with
  39     [ true ⇒ nmember_natList elem t | false ⇒ member_natList elem t ]
  40   ].
  41
  42 (* costruttore di un sottouniverso:
  43    S_EL cioe' uno qualsiasi degli elementi del sottouniverso
  44 *)
  45 ninductive S_UN (l:ne_list nat) : Type ≝
  46  S_EL : Πx:nat.((member_natList x l) = true) → S_UN l.
  47
  48 ndefinition getelem : ∀l.∀e:S_UN l.nat.
  49  #l; #s; nelim s;
  50  #u; #dim;
  51  napply u.
  52 nqed.
  53
  54 ndefinition eq_SUN ≝ λl.λx,y:S_UN l.eq_nat (getelem ? x) (getelem ? y).
  55
  56 ndefinition getdim : ∀l.∀e:S_UN l.member_natList (getelem ? e) l = true.
  57  #l; #s; nelim s;
  58  #u; #dim;
  59  napply dim.
  60 nqed.
  61
  62 nlemma SUN_destruct_1
  63  : ∀l.∀e1,e2.∀dim1,dim2.S_EL l e1 dim1 = S_EL l e2 dim2 → e1 = e2.
  64  #l; #e1; #e2; #dim1; #dim2; #H;
  65  nchange with (match S_EL l e2 dim2 with [ S_EL a _ ⇒ e1 = a ]);
  66  nrewrite < H;
  67  nnormalize;
  68  napply refl_eq.
  69 nqed.
  70
  71 (* destruct universale *)
  72 ndefinition SUN_destruct : ∀l.∀x,y:S_UN l.∀P:Prop.x = y → match eq_SUN l x y with [ true ⇒ P → P | false ⇒ P ].
  73  #l; #x; nelim x;
  74  #u1; #dim1;
  75  #y; nelim y;
  76  #u2; #dim2;
  77  #P;
  78  nchange with (? → (match eq_nat u1 u2 with [ true ⇒ P → P | false ⇒ P ]));
  79  #H;
  80  nrewrite > (SUN_destruct_1 l … H);
  81  nrewrite > (eq_to_eqnat u2 u2 (refl_eq …));
  82  nnormalize;
  83  napply (λx.x).
  84 nqed.
  85
  86 (* eq_to_eqxx universale *)
  87 nlemma eq_to_eqSUN : ∀l.∀x,y:S_UN l.x = y → eq_SUN l x y = true.
  88  #l; #x; nelim x;
  89  #u1; #dim1;
  90  #y; nelim y;
  91  #u2; #dim2;
  92  nchange with (? → eq_nat u1 u2 = true);
  93  #H; napply (eq_to_eqnat u1 u2);
  94  napply (SUN_destruct_1 l … H).
  95 nqed.
  96
  97 (* neqxx_to_neq universale *)
  98 nlemma neqSUN_to_neq : ∀l.∀x,y:S_UN l.eq_SUN l x y = false → x ≠ y.
  99  #l; #n1; #n2; #H;
 100  napply (not_to_not (n1 = n2) (eq_SUN l n1 n2 = true) …);
 101  ##[ ##1: napply (eq_to_eqSUN l n1 n2)
 102  ##| ##2: napply (eqfalse_to_neqtrue … H)
 103  ##]
 104 nqed.
 105
 106 (* eqxx_to_eq universale *)
 107 (* !!! evidente ma come si fa? *)
 108 naxiom eqSUN_to_eq_aux : ∀l,x,y.((getelem l x) = (getelem l y)) → x = y.
 109
 110 nlemma eqSUN_to_eq : ∀l.∀x,y:S_UN l.eq_SUN l x y = true → x = y.
 111  #l; #x; #y;
 112  nchange with ((eq_nat (getelem ? x) (getelem ? y) = true) → x = y);
 113  #H; napply (eqSUN_to_eq_aux l x y (eqnat_to_eq … H)).
 114 nqed.
 115
 116 (* neq_to_neqxx universale *)
 117 nlemma neq_to_neqSUN : ∀l.∀x,y:S_UN l.x ≠ y → eq_SUN l x y = false.
 118  #l; #n1; #n2; #H;
 119  napply (neqtrue_to_eqfalse (eq_SUN l n1 n2));
 120  napply (not_to_not (eq_SUN l n1 n2 = true) (n1 = n2) ? H);
 121  napply (eqSUN_to_eq l n1 n2).
 122 nqed.
 123
 124 (* decidibilita' universale *)
 125 nlemma decidable_SUN : ∀l.∀x,y:S_UN l.decidable (x = y).
 126  #l; #x; #y; nnormalize;
 127  napply (or2_elim (eq_SUN l x y = true) (eq_SUN l x y = false) ? (decidable_bexpr ?));
 128  ##[ ##1: #H; napply (or2_intro1 (x = y) (x ≠ y) (eqSUN_to_eq l … H))
 129  ##| ##2: #H; napply (or2_intro2 (x = y) (x ≠ y) (neqSUN_to_neq l … H))
 130  ##]
 131 nqed.
 132
 133 (* simmetria di uguaglianza universale *)
 134 nlemma symmetric_eqSUN : ∀l.symmetricT (S_UN l) bool (eq_SUN l).
 135  #l; #n1; #n2;
 136  napply (or2_elim (n1 = n2) (n1 ≠ n2) ? (decidable_SUN l n1 n2));
 137  ##[ ##1: #H; nrewrite > H; napply refl_eq
 138  ##| ##2: #H; nrewrite > (neq_to_neqSUN l n1 n2 H);
 139           napply (symmetric_eq ? (eq_SUN l n2 n1) false);
 140           napply (neq_to_neqSUN l n2 n1 (symmetric_neq ? n1 n2 H))
 141  ##]
 142 nqed.
 143
 144 (* scheletro di funzione generica ad 1 argomento *)
 145 nlet rec farg1_auxT (T:Type) (l:ne_list nat) on l ≝
 146  match l with
 147   [ ne_nil _ ⇒ T
 148   | ne_cons _ t ⇒ ProdT T (farg1_auxT T t)
 149   ].
 150
 151 nlemma farg1_auxDim : ∀h,t,x.eq_nat x h = false → member_natList x (h§§t) = true → member_natList x t = true.
 152  #h; #t; #x; #H; #H1;
 153  nnormalize in H1:(%);
 154  nrewrite > H in H1:(%);
 155  nnormalize;
 156  napply (λx.x).
 157 nqed.
 158
 159 nlet rec farg1 (T:Type) (l:ne_list nat) on l ≝
 160  match l with
 161   [ ne_nil h ⇒ λarg:farg1_auxT T «£h».λx:S_UN «£h».arg
 162   | ne_cons h t ⇒ λarg:farg1_auxT T (h§§t).λx:S_UN (h§§t).
 163    match eq_nat (getelem ? x) h
 164     return λy.eq_nat (getelem ? x) h = y → ?
 165    with
 166     [ true ⇒ λp:(eq_nat (getelem ? x) h = true).fst … arg
 167     | false ⇒ λp:(eq_nat (getelem ? x) h = false).
 168      farg1 T t
 169       (snd … arg)
 170       (S_EL t (getelem ? x) (farg1_auxDim h t (getelem ? x) p (getdim ? x)))
 171     ] (refl_eq ? (eq_nat (getelem ? x) h))
 172   ].
 173
 174 (* scheletro di funzione generica a 2 argomenti *)
 175 nlet rec farg2 (T:Type) (l,lfix:ne_list nat) on l ≝
 176  match l with
 177   [ ne_nil h ⇒ λarg:farg1_auxT (farg1_auxT T lfix) «£h».λx:S_UN «£h».farg1 T lfix arg
 178   | ne_cons h t ⇒ λarg:farg1_auxT (farg1_auxT T lfix) (h§§t).λx:S_UN (h§§t).
 179    match eq_nat (getelem ? x) h
 180     return λy.eq_nat (getelem ? x) h = y → ?
 181    with
 182     [ true ⇒ λp:(eq_nat (getelem ? x) h = true).farg1 T lfix (fst … arg)
 183     | false ⇒ λp:(eq_nat (getelem ? x) h = false).
 184      farg2 T t lfix
 185       (snd … arg)
 186       (S_EL t (getelem ? x) (farg1_auxDim h t (getelem ? x) p (getdim ? x)))
 187     ] (refl_eq ? (eq_nat (getelem ? x) h))
 188   ].
 189
 190 (* esempio0: universo ottale *)
 191 ndefinition oct0 ≝ O.
 192 ndefinition oct1 ≝ nat1.
 193 ndefinition oct2 ≝ nat2.
 194 ndefinition oct3 ≝ nat3.
 195 ndefinition oct4 ≝ nat4.
 196 ndefinition oct5 ≝ nat5.
 197 ndefinition oct6 ≝ nat6.
 198 ndefinition oct7 ≝ nat7.
 199
 200 ndefinition oct_UN ≝ « oct0 ; oct1 ; oct2 ; oct3 ; oct4 ; oct5 ; oct6 £ oct7 ».
 201
 202 ndefinition uoct0 ≝ S_EL oct_UN oct0 (refl_eq …).
 203 ndefinition uoct1 ≝ S_EL oct_UN oct1 (refl_eq …).
 204 ndefinition uoct2 ≝ S_EL oct_UN oct2 (refl_eq …).
 205 ndefinition uoct3 ≝ S_EL oct_UN oct3 (refl_eq …).
 206 ndefinition uoct4 ≝ S_EL oct_UN oct4 (refl_eq …).
 207 ndefinition uoct5 ≝ S_EL oct_UN oct5 (refl_eq …).
 208 ndefinition uoct6 ≝ S_EL oct_UN oct6 (refl_eq …).
 209 ndefinition uoct7 ≝ S_EL oct_UN oct7 (refl_eq …).
 210
 211 (* esempio1: NOT ottale *)
 212 ndefinition octNOT ≝
 213  farg1 (S_UN oct_UN) oct_UN
 214   (pair … uoct7 (pair … uoct6 (pair … uoct5 (pair … uoct4 (pair … uoct3 (pair … uoct2 (pair … uoct1 uoct0))))))).
 215
 216 (* esempio2: AND ottale *)
 217 ndefinition octAND0 ≝ pair … uoct0 (pair … uoct0 (pair … uoct0 (pair … uoct0 (pair … uoct0 (pair … uoct0 (pair … uoct0 uoct0)))))).
 218 ndefinition octAND1 ≝ pair … uoct0 (pair … uoct1 (pair … uoct0 (pair … uoct1 (pair … uoct0 (pair … uoct1 (pair … uoct0 uoct1)))))).
 219 ndefinition octAND2 ≝ pair … uoct0 (pair … uoct0 (pair … uoct2 (pair … uoct2 (pair … uoct0 (pair … uoct0 (pair … uoct2 uoct2)))))).
 220 ndefinition octAND3 ≝ pair … uoct0 (pair … uoct1 (pair … uoct2 (pair … uoct3 (pair … uoct0 (pair … uoct1 (pair … uoct2 uoct3)))))).
 221 ndefinition octAND4 ≝ pair … uoct0 (pair … uoct0 (pair … uoct0 (pair … uoct0 (pair … uoct4 (pair … uoct4 (pair … uoct4 uoct4)))))).
 222 ndefinition octAND5 ≝ pair … uoct0 (pair … uoct1 (pair … uoct0 (pair … uoct1 (pair … uoct4 (pair … uoct5 (pair … uoct4 uoct5)))))).
 223 ndefinition octAND6 ≝ pair … uoct0 (pair … uoct0 (pair … uoct2 (pair … uoct2 (pair … uoct4 (pair … uoct4 (pair … uoct6 uoct6)))))).
 224 ndefinition octAND7 ≝ pair … uoct0 (pair … uoct1 (pair … uoct2 (pair … uoct3 (pair … uoct4 (pair … uoct5 (pair … uoct6 uoct7)))))).
 225
 226 ndefinition octAND ≝
 227  farg2 (S_UN oct_UN) oct_UN oct_UN
 228   (pair … octAND0 (pair … octAND1 (pair … octAND2 (pair … octAND3 (pair … octAND4 (pair … octAND5 (pair … octAND6 octAND7))))))).
 229
 230 (* ora e' possibile fare
 231    octNOT uoctX
 232    octAND uoctX uoctY
 233 *)