helm/software/matita/library/formal_topology/basic_pairs.ma

   1 (**************************************************************************)
   2 (*       ___                                                              *)
   3 (*      ||M||                                                             *)
   4 (*      ||A||       A project by Andrea Asperti                           *)
   5 (*      ||T||                                                             *)
   6 (*      ||I||       Developers:                                           *)
   7 (*      ||T||         The HELM team.                                      *)
   8 (*      ||A||         http://helm.cs.unibo.it                             *)
   9 (*      \   /                                                             *)
  10 (*       \ /        This file is distributed under the terms of the       *)
  11 (*        v         GNU General Public License Version 2                  *)
  12 (*                                                                        *)
  13 (**************************************************************************)
  14
  15 include "formal_topology/relations.ma".
  16 include "formal_topology/notation.ma".
  17
  18 record basic_pair: Type1 ≝ {
  19    concr: REL; form: REL; rel: concr ⇒_\r1 form
  20 }.
  21
  22 interpretation "basic pair relation" 'Vdash2 x y c = (fun21 ??? (rel c) x y).
  23 interpretation "basic pair relation (non applied)" 'Vdash c = (rel c).
  24
  25 record relation_pair (BP1,BP2: basic_pair): Type1 ≝ {
  26    concr_rel: (concr BP1) ⇒_\r1 (concr BP2); form_rel: (form BP1) ⇒_\r1 (form BP2);
  27    commute: comp1 REL ??? concr_rel (rel ?) =_1 form_rel ∘ ⊩
  28  }.
  29
  30 interpretation "concrete relation" 'concr_rel r = (concr_rel ?? r).
  31 interpretation "formal relation" 'form_rel r = (form_rel ?? r).
  32
  33 definition relation_pair_equality: ∀o1,o2. equivalence_relation1 (relation_pair o1 o2).
  34  intros; constructor 1; [ apply (λr,r'. ⊩ ∘ r \sub\c = ⊩ ∘ r' \sub\c);
  35   | simplify; intros; apply refl1;
  36   | simplify; intros 2; apply sym1;
  37   | simplify; intros 3; apply trans1; ]
  38 qed.
  39
  40 definition relation_pair_setoid: basic_pair → basic_pair → setoid1.
  41  intros;
  42  constructor 1;
  43   [ apply (relation_pair b b1)
  44   | apply relation_pair_equality
  45   ]
  46 qed.
  47
  48 definition relation_pair_of_relation_pair_setoid :
  49   ∀P,Q. relation_pair_setoid P Q → relation_pair P Q ≝ λP,Q,x.x.
  50 coercion relation_pair_of_relation_pair_setoid.
  51
  52 alias symbol "compose" (instance 1) = "category1 composition".
  53 lemma eq_to_eq':
  54   ∀o1,o2.∀r,r':relation_pair_setoid o1 o2. r =_1 r' → r \sub\f ∘ ⊩ =_1 r'\sub\f ∘ ⊩.
  55  intros 5 (o1 o2 r r' H);
  56  apply (.= (commute ?? r)^-1);
  57  change in H with (⊩ ∘ r \sub\c = ⊩ ∘ r' \sub\c);
  58  apply rule (.= H);
  59  apply (commute ?? r').
  60 qed.
  61
  62 definition id_relation_pair: ∀o:basic_pair. relation_pair o o.
  63  intro;
  64  constructor 1;
  65   [1,2: apply id1;
  66   | lapply (id_neutral_right1 ? (concr o) ? (⊩)) as H;
  67     lapply (id_neutral_left1 ?? (form o) (⊩)) as H1;
  68     apply (.= H);
  69     apply (H1^-1);]
  70 qed.
  71
  72 lemma relation_pair_composition:
  73   ∀o1,o2,o3: basic_pair.
  74   relation_pair_setoid o1 o2 → relation_pair_setoid o2 o3 → relation_pair_setoid o1 o3.
  75 intros 3 (o1 o2 o3);
  76   intros (r r1);
  77     constructor 1;
  78      [ apply (r1 \sub\c ∘ r \sub\c)
  79      | apply (r1 \sub\f ∘ r \sub\f)
  80      | lapply (commute ?? r) as H;
  81        lapply (commute ?? r1) as H1;
  82        alias symbol "trans" = "trans1".
  83        alias symbol "assoc" = "category1 assoc".
  84        apply (.= ASSOC);
  85        apply (.= #‡H1);
  86        alias symbol "invert" = "setoid1 symmetry".
  87        apply (.= ASSOC ^ -1);
  88        apply (.= H‡#);
  89        apply ASSOC]
  90 qed.
  91
  92 lemma relation_pair_composition_is_morphism:
  93   ∀o1,o2,o3: basic_pair.
  94   ∀a,a':relation_pair_setoid o1 o2.
  95   ∀b,b':relation_pair_setoid o2 o3.
  96    a=a' → b=b' →
  97     relation_pair_composition o1 o2 o3 a b
  98     = relation_pair_composition o1 o2 o3 a' b'.
  99 intros 3 (o1 o2 o3);
 100     intros;
 101     change with (⊩ ∘ (b\sub\c ∘ a\sub\c) = ⊩ ∘ (b'\sub\c ∘ a'\sub\c));
 102     change in e with (⊩ ∘ a \sub\c = ⊩ ∘ a' \sub\c);
 103     change in e1 with (⊩ ∘ b \sub\c = ⊩ ∘ b' \sub\c);
 104     apply (.= ASSOC);
 105     apply (.= #‡e1);
 106     apply (.= #‡(commute ?? b'));
 107     apply (.= ASSOC ^ -1);
 108     apply (.= e‡#);
 109     apply (.= ASSOC);
 110     apply (.= #‡(commute ?? b')^-1);
 111     apply (ASSOC ^ -1);
 112 qed.
 113
 114 definition relation_pair_composition_morphism:
 115  ∀o1,o2,o3. binary_morphism1 (relation_pair_setoid o1 o2) (relation_pair_setoid o2 o3) (relation_pair_setoid o1 o3).
 116  intros;
 117  constructor 1;
 118   [ apply relation_pair_composition;
 119   | apply relation_pair_composition_is_morphism;]
 120 qed.
 121
 122 lemma relation_pair_composition_morphism_assoc:
 123 Πo1:basic_pair
 124 .Πo2:basic_pair
 125  .Πo3:basic_pair
 126   .Πo4:basic_pair
 127    .Πa12:relation_pair_setoid o1 o2
 128     .Πa23:relation_pair_setoid o2 o3
 129      .Πa34:relation_pair_setoid o3 o4
 130       .relation_pair_composition_morphism o1 o3 o4
 131        (relation_pair_composition_morphism o1 o2 o3 a12 a23) a34
 132        =relation_pair_composition_morphism o1 o2 o4 a12
 133         (relation_pair_composition_morphism o2 o3 o4 a23 a34).
 134    intros;
 135     change with (⊩ ∘ (a34\sub\c ∘ (a23\sub\c ∘ a12\sub\c)) =
 136                  ⊩ ∘ ((a34\sub\c ∘ a23\sub\c) ∘ a12\sub\c));
 137     alias symbol "refl" = "refl1".
 138     alias symbol "prop2" = "prop21".
 139     apply (ASSOC‡#);
 140 qed.
 141
 142 lemma relation_pair_composition_morphism_respects_id:
 143   ∀o1,o2:basic_pair.∀a:relation_pair_setoid o1 o2.
 144   relation_pair_composition_morphism o1 o1 o2 (id_relation_pair o1) a=a.
 145    intros;
 146     change with (⊩ ∘ (a\sub\c ∘ (id_relation_pair o1)\sub\c) = ⊩ ∘ a\sub\c);
 147     apply ((id_neutral_right1 ????)‡#);
 148 qed.
 149
 150 lemma relation_pair_composition_morphism_respects_id_r:
 151   ∀o1,o2:basic_pair.∀a:relation_pair_setoid o1 o2.
 152   relation_pair_composition_morphism o1 o2 o2 a (id_relation_pair o2)=a.
 153   intros;
 154     change with (⊩ ∘ ((id_relation_pair o2)\sub\c ∘ a\sub\c) = ⊩ ∘ a\sub\c);
 155     apply ((id_neutral_left1 ????)‡#);
 156 qed.
 157
 158 definition BP: category1.
 159  constructor 1;
 160   [ apply basic_pair
 161   | apply relation_pair_setoid
 162   | apply id_relation_pair
 163   | apply relation_pair_composition_morphism
 164   | apply relation_pair_composition_morphism_assoc;
 165   | apply relation_pair_composition_morphism_respects_id;
 166   | apply relation_pair_composition_morphism_respects_id_r;]
 167 qed.
 168
 169 definition basic_pair_of_BP : objs1 BP → basic_pair ≝ λx.x.
 170 coercion basic_pair_of_BP.
 171
 172 definition relation_pair_setoid_of_arrows1_BP :
 173   ∀P,Q. arrows1 BP P Q → relation_pair_setoid P Q ≝ λP,Q,x.x.
 174 coercion relation_pair_setoid_of_arrows1_BP.
 175
 176 (*
 177 definition BPext: ∀o: BP. (form o) ⇒_1 Ω^(concr o).
 178  intros; constructor 1;
 179   [ apply (ext ? ? (rel o));
 180   | intros;
 181     apply (.= #‡e);
 182     apply refl1]
 183 qed.
 184
 185 definition BPextS: ∀o: BP. Ω^(form o) ⇒_1 Ω^(concr o).
 186  intros; constructor 1;
 187   [ apply (minus_image ?? (rel o));
 188   | intros; apply (#‡e); ]
 189 qed.
 190
 191 definition fintersects: ∀o: BP. (form o) × (form o) ⇒_1 Ω^(form o).
 192  intros (o); constructor 1;
 193   [ apply (λa,b: form o.{c | BPext o c ⊆ BPext o a ∩ BPext o b });
 194     intros; simplify; apply (.= (†e)‡#); apply refl1
 195   | intros; split; simplify; intros;
 196      [ apply (. #‡((†e^-1)‡(†e1^-1))); assumption
 197      | apply (. #‡((†e)‡(†e1))); assumption]]
 198 qed.
 199
 200 interpretation "fintersects" 'fintersects U V = (fun21 ??? (fintersects ?) U V).
 201
 202 definition fintersectsS:
 203  ∀o:BP. Ω^(form o) × Ω^(form o) ⇒_1 Ω^(form o).
 204  intros (o); constructor 1;
 205   [ apply (λo: basic_pair.λa,b: Ω^(form o).{c | BPext o c ⊆ BPextS o a ∩ BPextS o b });
 206     intros; simplify; apply (.= (†e)‡#); apply refl1
 207   | intros; split; simplify; intros;
 208      [ apply (. #‡((†e^-1)‡(†e1^-1))); assumption
 209      | apply (. #‡((†e)‡(†e1))); assumption]]
 210 qed.
 211
 212 interpretation "fintersectsS" 'fintersects U V = (fun21 ??? (fintersectsS ?) U V).
 213
 214 definition relS: ∀o: BP. (concr o) × Ω^(form o) ⇒_1 CPROP.
 215  intros (o); constructor 1;
 216   [ apply (λx:concr o.λS: Ω^(form o).∃y:form o.y ∈ S ∧ x ⊩⎽o y);
 217   | intros; split; intros; cases e2; exists [1,3: apply w]
 218      [ apply (. (#‡e1^-1)‡(e^-1‡#)); assumption
 219      | apply (. (#‡e1)‡(e‡#)); assumption]]
 220 qed.
 221
 222 interpretation "basic pair relation for subsets" 'Vdash2 x y c = (fun21 (concr ?) ?? (relS c) x y).
 223 interpretation "basic pair relation for subsets (non applied)" 'Vdash c = (fun21 ??? (relS c)).
 224 *)