helm/software/matita/library/formal_topology/relations.ma

   1 (**************************************************************************)
   2 (*       ___                                                              *)
   3 (*      ||M||                                                             *)
   4 (*      ||A||       A project by Andrea Asperti                           *)
   5 (*      ||T||                                                             *)
   6 (*      ||I||       Developers:                                           *)
   7 (*      ||T||         The HELM team.                                      *)
   8 (*      ||A||         http://helm.cs.unibo.it                             *)
   9 (*      \   /                                                             *)
  10 (*       \ /        This file is distributed under the terms of the       *)
  11 (*        v         GNU General Public License Version 2                  *)
  12 (*                                                                        *)
  13 (**************************************************************************)
  14
  15 include "formal_topology/subsets.ma".
  16
  17 record binary_relation (A,B: SET) : Type1 ≝
  18  { satisfy:> binary_morphism1 A B CPROP }.
  19
  20 notation < "hvbox (x \nbsp \natur term 90 r \nbsp y)"  with precedence 45 for @{'satisfy $r $x $y}.
  21 notation > "hvbox (x \natur term 90 r y)"  with precedence 45 for @{'satisfy $r $x $y}.
  22 interpretation "relation applied" 'satisfy r x y = (fun21 ??? (satisfy ?? r) x y).
  23
  24 definition binary_relation_setoid: SET → SET → setoid1.
  25  intros (A B);
  26  constructor 1;
  27   [ apply (binary_relation A B)
  28   | constructor 1;
  29      [ apply (λA,B.λr,r': binary_relation A B. ∀x,y. r x y ↔ r' x y)
  30      | simplify; intros 3; split; intro; assumption
  31      | simplify; intros 5; split; intro;
  32        [ apply (fi ?? (f ??)) | apply (if ?? (f ??))] assumption
  33      | simplify;  intros 7; split; intro;
  34         [ apply (if ?? (f1 ??)) | apply (fi ?? (f ??)) ]
  35         [ apply (if ?? (f ??)) | apply (fi ?? (f1 ??)) ]
  36        assumption]]
  37 qed.
  38
  39 definition binary_relation_of_binary_relation_setoid :
  40   ∀A,B.binary_relation_setoid A B → binary_relation A B ≝ λA,B,c.c.
  41 coercion binary_relation_of_binary_relation_setoid.
  42
  43 definition composition:
  44  ∀A,B,C.
  45   (binary_relation_setoid A B) × (binary_relation_setoid B C) ⇒_1 (binary_relation_setoid A C).
  46  intros;
  47  constructor 1;
  48   [ intros (R12 R23);
  49     constructor 1;
  50     constructor 1;
  51      [ apply (λs1:A.λs3:C.∃s2:B. s1 ♮R12 s2 ∧ s2 ♮R23 s3);
  52      | intros;
  53        split; intro; cases e2 (w H3); clear e2; exists; [1,3: apply w ]
  54         [ apply (. (e^-1‡#)‡(#‡e1^-1)); assumption
  55         | apply (. (e‡#)‡(#‡e1)); assumption]]
  56   | intros 8; split; intro H2; simplify in H2 ⊢ %;
  57     cases H2 (w H3); clear H2; exists [1,3: apply w] cases H3 (H2 H4); clear H3;
  58     [ lapply (if ?? (e x w) H2) | lapply (fi ?? (e x w) H2) ]
  59     [ lapply (if ?? (e1 w y) H4)| lapply (fi ?? (e1 w y) H4) ]
  60     exists; try assumption;
  61     split; assumption]
  62 qed.
  63
  64 definition REL: category1.
  65  constructor 1;
  66   [ apply setoid
  67   | intros (T T1); apply (binary_relation_setoid T T1)
  68   | intros; constructor 1;
  69     constructor 1; unfold setoid1_of_setoid; simplify;
  70      [ (* changes required to avoid universe inconsistency *)
  71        change with (carr o → carr o → CProp); intros; apply (eq ? c c1)
  72      | intros; split; intro; change in a a' b b' with (carr o);
  73        change in e with (eq ? a a'); change in e1 with (eq ? b b');
  74         [ apply (.= (e ^ -1));
  75           apply (.= e2);
  76           apply e1
  77         | apply (.= e);
  78           apply (.= e2);
  79           apply (e1 ^ -1)]]
  80   | apply composition
  81   | intros 9;
  82     split; intro;
  83     cases f (w H); clear f; cases H; clear H;
  84     [cases f (w1 H); clear f | cases f1 (w1 H); clear f1]
  85     cases H; clear H;
  86     exists; try assumption;
  87     split; try assumption;
  88     exists; try assumption;
  89     split; assumption
  90   |6,7: intros 5; unfold composition; simplify; split; intro;
  91         unfold setoid1_of_setoid in x y; simplify in x y;
  92         [1,3: cases e (w H1); clear e; cases H1; clear H1; unfold;
  93           [ apply (. (e : eq1 ? x w)‡#); assumption
  94           | apply (. #‡(e : eq1 ? w y)^-1); assumption]
  95         |2,4: exists; try assumption; split;
  96           (* change required to avoid universe inconsistency *)
  97           change in x with (carr o1); change in y with (carr o2);
  98           first [apply refl | assumption]]]
  99 qed.
 100
 101 definition setoid_of_REL : objs1 REL → setoid ≝ λx.x.
 102 coercion setoid_of_REL.
 103
 104 definition binary_relation_setoid_of_arrow1_REL :
 105   ∀P,Q. arrows1 REL P Q → binary_relation_setoid P Q ≝ λP,Q,x.x.
 106 coercion binary_relation_setoid_of_arrow1_REL.
 107
 108
 109 notation > "B ⇒_\r1 C" right associative with precedence 72 for @{'arrows1_REL $B $C}.
 110 notation "B ⇒\sub (\r 1) C" right associative with precedence 72 for @{'arrows1_REL $B $C}.
 111 interpretation "'arrows1_REL" 'arrows1_REL A B = (arrows1 REL A B).
 112 notation > "B ⇒_\r2 C" right associative with precedence 72 for @{'arrows2_REL $B $C}.
 113 notation "B ⇒\sub (\r 2) C" right associative with precedence 72 for @{'arrows2_REL $B $C}.
 114 interpretation "'arrows2_REL" 'arrows2_REL A B = (arrows2 (category2_of_category1 REL) A B).
 115
 116
 117 definition full_subset: ∀s:REL. Ω^s.
 118  apply (λs.{x | True});
 119  intros; simplify; split; intro; assumption.
 120 qed.
 121
 122 coercion full_subset.
 123
 124 definition comprehension: ∀b:REL. (b ⇒_1. CPROP) → Ω^b.
 125  apply (λb:REL. λP: b ⇒_1 CPROP. {x | P x});
 126  intros; simplify;
 127  apply (.= †e); apply refl1.
 128 qed.
 129
 130 interpretation "subset comprehension" 'comprehension s p =
 131  (comprehension s (mk_unary_morphism1 ?? p ?)).
 132
 133 definition ext: ∀X,S:REL. (X ⇒_\r1 S) × S ⇒_1 (Ω^X).
 134  intros (X S); constructor 1;
 135   [ apply (λr:X ⇒_\r1 S.λf:S.{x ∈ X | x ♮r f}); intros; simplify; apply (.= (e‡#)); apply refl1
 136   | intros; simplify; split; intros; simplify;
 137      [ change with (∀x. x ♮a b → x ♮a' b'); intros;
 138        apply (. (#‡e1^-1)); whd in e; apply (if ?? (e ??)); assumption
 139      | change with (∀x. x ♮a' b' → x ♮a b); intros;
 140        apply (. (#‡e1)); whd in e; apply (fi ?? (e ??));assumption]]
 141 qed.
 142
 143 definition extS: ∀X,S:REL. ∀r:X ⇒_\r1 S. Ω^S ⇒_1 Ω^X.
 144  (* ∃ is not yet a morphism apply (λX,S,r,F.{x ∈ X | ∃a. a ∈ F ∧ x ♮r a});*)
 145  intros (X S r); constructor 1;
 146   [ intro F; constructor 1; constructor 1;
 147     [ apply (λx. x ∈ X ∧ ∃a:S. a ∈ F ∧ x ♮r a);
 148     | intros; split; intro; cases f (H1 H2); clear f; split;
 149        [ apply (. (e^-1‡#)); assumption
 150        |3: apply (. (e‡#)); assumption
 151        |2,4: cases H2 (w H3); exists; [1,3: apply w]
 152          [ apply (. (#‡(e^-1‡#))); assumption
 153          | apply (. (#‡(e‡#))); assumption]]]
 154   | intros; split; simplify; intros; cases f; cases e1; split;
 155      [1,3: assumption
 156      |2,4: exists; [1,3: apply w]
 157       [ apply (. (#‡e^-1)‡#); assumption
 158       | apply (. (#‡e)‡#); assumption]]]
 159 qed.
 160 (*
 161 lemma equalset_extS_id_X_X: ∀o:REL.∀X.extS ?? (id1 ? o) X = X.
 162  intros;
 163  unfold extS; simplify;
 164  split; simplify;
 165   [ intros 2; change with (a ∈ X);
 166     cases f; clear f;
 167     cases H; clear H;
 168     cases x; clear x;
 169     change in f2 with (eq1 ? a w);
 170     apply (. (f2\sup -1‡#));
 171     assumption
 172   | intros 2; change in f with (a ∈ X);
 173     split;
 174      [ whd; exact I
 175      | exists; [ apply a ]
 176        split;
 177         [ assumption
 178         | change with (a = a); apply refl]]]
 179 qed.
 180
 181 lemma extS_com: ∀o1,o2,o3,c1,c2,S. extS o1 o3 (c2 ∘ c1) S = extS o1 o2 c1 (extS o2 o3 c2 S).
 182  intros; unfold extS; simplify; split; intros; simplify; intros;
 183   [ cases f (H1 H2); cases H2 (w H3); clear f H2; split; [assumption]
 184     cases H3 (H4 H5); cases H5 (w1 H6); clear H3 H5; cases H6 (H7 H8); clear H6;
 185     exists; [apply w1] split [2: assumption] constructor 1; [assumption]
 186     exists; [apply w] split; assumption
 187   | cases f (H1 H2); cases H2 (w H3); clear f H2; split; [assumption]
 188     cases H3 (H4 H5); cases H4 (w1 H6); clear H3 H4; cases H6 (w2 H7); clear H6;
 189     cases H7; clear H7; exists; [apply w2] split; [assumption] exists [apply w] split;
 190     assumption]
 191 qed.
 192 *)
 193
 194 (* the same as ⋄ for a basic pair *)
 195 definition image: ∀U,V:REL. (U ⇒_\r1 V) ⇒_2 (Ω^U ⇒_2 Ω^V).
 196  intros; constructor 1;
 197  [ intro r; constructor 1;
 198    [ apply (λS: Ω^U. {y | ∃x:U. x ♮r y ∧ x ∈ S });
 199      intros; simplify; split; intro; cases e1; exists [1,3: apply w]
 200      [ apply (. (#‡e^-1)‡#); assumption
 201      | apply (. (#‡e)‡#); assumption]
 202    | intros; split;
 203      [ intro y; simplify; intro yA; cases yA; exists; [ apply w ];
 204        apply (. #‡(#‡e^-1)); assumption;
 205      | intro y; simplify; intro yA; cases yA; exists; [ apply w ];
 206        apply (. #‡(#‡e)); assumption;]]
 207  | simplify; intros; intro y; simplify; split; simplify; intros (b H); cases H;
 208    exists; [1,3: apply w]; cases x; split; try assumption;
 209    [ apply (if ?? (e ??)); | apply (fi ?? (e ??)); ] assumption;]
 210 qed.
 211
 212 (* the same as □ for a basic pair *)
 213 definition minus_star_image: ∀U,V:REL. (U ⇒_\r1 V) ⇒_2 (Ω^U ⇒_2 Ω^V).
 214  intros; constructor 1; intros;
 215   [ constructor 1;
 216     [ apply (λS: Ω^U. {y | ∀x:U. x ♮c y → x ∈ S});
 217       intros; simplify; split; intros; apply f;
 218       [ apply (. #‡e); | apply (. #‡e ^ -1)] assumption;
 219     | intros; split; intro; simplify; intros;
 220       [ apply (. #‡e^-1);| apply (. #‡e); ] apply f; assumption;]
 221   | intros; intro; simplify; split; simplify; intros; apply f;
 222     [ apply (. (e x a2)); assumption | apply (. (e^-1 x a2)); assumption]]
 223 qed.
 224
 225 (* the same as Rest for a basic pair *)
 226 definition star_image: ∀U,V:REL. (U ⇒_\r1 V) ⇒_2 (Ω^V ⇒_2 Ω^U).
 227  intros; constructor 1;
 228   [ intro r; constructor 1;
 229     [ apply (λS: Ω \sup V. {x | ∀y:V. x ♮r y → y ∈ S});
 230       intros; simplify; split; intros; apply f;
 231       [ apply (. e ‡#);| apply (. e^ -1‡#);] assumption;
 232     | intros; split; simplify; intros;
 233       [ apply (. #‡e^-1);| apply (. #‡e); ] apply f; assumption;]
 234   | intros; intro; simplify; split; simplify; intros; apply f;
 235     [ apply (. e a2 y); | apply (. e^-1 a2 y)] assumption;]
 236 qed.
 237
 238 (* the same as Ext for a basic pair *)
 239 definition minus_image: ∀U,V:REL. (U ⇒_\r1 V) ⇒_2 (Ω^V ⇒_2 Ω^U).
 240  intros; constructor 1;
 241   [ intro r; constructor 1;
 242     [ apply (λS: Ω^V. {x | ∃y:V. x ♮r y ∧ y ∈ S }).
 243       intros; simplify; split; intros; cases e1; cases x; exists; [1,3: apply w]
 244       split; try assumption; [ apply (. (e^-1‡#)); | apply (. (e‡#));] assumption;
 245     | intros; simplify; split; simplify; intros; cases e1; cases x;
 246       exists [1,3: apply w] split; try assumption;
 247       [ apply (. (#‡e^-1)); | apply (. (#‡e));] assumption]
 248   | intros; intro; simplify; split; simplify; intros; cases e1; exists [1,3: apply w]
 249     cases x; split; try assumption;
 250     [ apply (. e^-1 a2 w); | apply (. e a2 w)] assumption;]
 251 qed.
 252
 253 definition foo : ∀o1,o2:REL.carr1 (o1 ⇒_\r1 o2) → carr2 (setoid2_of_setoid1 (o1 ⇒_\r1 o2)) ≝ λo1,o2,x.x.
 254
 255 interpretation "relation f⎻*" 'OR_f_minus_star r = (fun12 ?? (minus_star_image ? ?) (foo ?? r)).
 256 interpretation "relation f⎻" 'OR_f_minus r = (fun12 ?? (minus_image ? ?) (foo ?? r)).
 257 interpretation "relation f*" 'OR_f_star r = (fun12 ?? (star_image ? ?) (foo ?? r)).
 258
 259 definition image_coercion: ∀U,V:REL. (U ⇒_\r1 V) → Ω^U ⇒_2 Ω^V.
 260 intros (U V r Us); apply (image U V r); qed.
 261 coercion image_coercion.
 262
 263 (* minus_image is the same as ext *)
 264
 265 theorem image_id: ∀o. (id1 REL o : carr2 (Ω^o ⇒_2 Ω^o)) =_1 (id2 SET1 Ω^o).
 266  intros; unfold image_coercion; unfold image; simplify;
 267  whd in match (?:carr2 ?);
 268   intro U; simplify; split; simplify; intros;
 269   [ change with (a ∈ U);
 270     cases e; cases x; change in e1 with (w =_1 a); apply (. e1^-1‡#); assumption
 271   | change in f with (a ∈ U);
 272     exists; [apply a] split; [ change with (a = a); apply refl1 | assumption]]
 273 qed.
 274
 275 theorem minus_star_image_id: ∀o:REL.
 276   ((id1 REL o)⎻* : carr2 (Ω^o ⇒_2 Ω^o)) =_1 (id2 SET1 Ω^o).
 277  intros; unfold minus_star_image; simplify; intro U; simplify;
 278  split; simplify; intros;
 279   [ change with (a ∈ U); apply f; change with (a=a); apply refl1
 280   | change in f1 with (eq1 ? x a); apply (. f1‡#); apply f]
 281 qed.
 282
 283 alias symbol "compose" (instance 5) = "category2 composition".
 284 alias symbol "compose" (instance 4) = "category1 composition".
 285 theorem image_comp: ∀A,B,C.∀r:B ⇒_\r1 C.∀s:A ⇒_\r1 B.
 286   ((r ∘ s) : carr2 (Ω^A ⇒_2 Ω^C)) =_1 r ∘ s.
 287  intros; intro U; split; intro x; (unfold image; unfold SET1; simplify);
 288  intro H; cases H;
 289  cases x1; [cases f|cases f1]; exists; [1,3: apply w1] cases x2; split; try assumption;
 290    exists; try assumption; split; assumption;
 291 qed.
 292
 293 theorem minus_star_image_comp:
 294  ∀A,B,C.∀r:B ⇒_\r1 C.∀s:A ⇒_\r1 B.
 295   minus_star_image A C (r ∘ s) =_1 minus_star_image B C r ∘ (minus_star_image A B s).
 296  intros; unfold minus_star_image; intro X; simplify; split; simplify; intros;
 297  [ whd; intros; simplify; whd; intros; apply f; exists; try assumption; split; assumption;
 298  | cases f1; cases x1; apply f; assumption]
 299 qed.
 300
 301
 302 (*
 303 (*CSC: unused! *)
 304 theorem ext_comp:
 305  ∀o1,o2,o3: REL.
 306   ∀a: arrows1 ? o1 o2.
 307    ∀b: arrows1 ? o2 o3.
 308     ∀x. ext ?? (b∘a) x = extS ?? a (ext ?? b x).
 309  intros;
 310  unfold ext; unfold extS; simplify; split; intro; simplify; intros;
 311  cases f; clear f; split; try assumption;
 312   [ cases f2; clear f2; cases x1; clear x1; exists; [apply w] split;
 313      [1: split] assumption;
 314   | cases H; clear H; cases x1; clear x1; exists [apply w]; split;
 315      [2: cases f] assumption]
 316 qed.
 317 *)
 318
 319 axiom daemon : False.
 320
 321 theorem extS_singleton:
 322  ∀o1,o2.∀a.∀x.extS o1 o2 a {(x)} = ext o1 o2 a x.
 323  intros; unfold extS; unfold ext; unfold singleton; simplify;
 324  split; intros 2; simplify; simplify in f;
 325  [ cases f; cases e; cases x1; change in f2 with (x =_1 w); apply (. #‡f2); assumption;
 326  | split; try apply I; exists [apply x] split; try assumption; change with (x = x); apply rule #;] qed.