helm/software/matita/library/nat/plus.ma

   1 (**************************************************************************)
   2 (*       ___                                                                *)
   3 (*      ||M||                                                             *)
   4 (*      ||A||       A project by Andrea Asperti                           *)
   5 (*      ||T||                                                             *)
   6 (*      ||I||       Developers:                                           *)
   7 (*      ||T||       A.Asperti, C.Sacerdoti Coen,                          *)
   8 (*      ||A||       E.Tassi, S.Zacchiroli                                 *)
   9 (*      \   /                                                             *)
  10 (*       \ /        This file is distributed under the terms of the       *)
  11 (*        v         GNU Lesser General Public License Version 2.1         *)
  12 (*                                                                        *)
  13 (**************************************************************************)
  14
  15 include "nat/nat.ma".
  16
  17 let rec plus n m \def
  18  match n with
  19  [ O \Rightarrow m
  20  | (S p) \Rightarrow S (plus p m) ].
  21
  22 interpretation "natural plus" 'plus x y = (plus x y).
  23
  24 theorem plus_n_O: \forall n:nat. n = n+O.
  25 intros.elim n.
  26 simplify.reflexivity.
  27 simplify.apply eq_f.assumption.
  28 qed.
  29
  30 theorem plus_n_Sm : \forall n,m:nat. S (n+m) = n+(S m).
  31 intros.elim n.
  32 simplify.reflexivity.
  33 simplify.apply eq_f.assumption.
  34 qed.
  35
  36 theorem plus_n_SO : \forall n:nat. S n = n+(S O).
  37 intro.rewrite > plus_n_O.
  38 apply plus_n_Sm.
  39 qed.
  40
  41 theorem sym_plus: \forall n,m:nat. n+m = m+n.
  42 intros.elim n.
  43 simplify.apply plus_n_O.
  44 simplify.rewrite > H.apply plus_n_Sm.
  45 qed.
  46
  47 theorem associative_plus : associative nat plus.
  48 unfold associative.intros.elim x.
  49 simplify.reflexivity.
  50 simplify.apply eq_f.assumption.
  51 qed.
  52
  53 theorem assoc_plus : \forall n,m,p:nat. (n+m)+p = n+(m+p)
  54 \def associative_plus.
  55
  56 theorem injective_plus_r: \forall n:nat.injective nat nat (\lambda m.n+m).
  57 intro.simplify.intros 2.elim n.
  58 exact H.
  59 apply H.apply inj_S.apply H1.
  60 qed.
  61
  62 theorem inj_plus_r: \forall p,n,m:nat. p+n = p+m \to n=m
  63 \def injective_plus_r.
  64
  65 theorem injective_plus_l: \forall m:nat.injective nat nat (\lambda n.n+m).
  66 intro.simplify.intros.
  67 apply (injective_plus_r m).
  68 rewrite < sym_plus.
  69 rewrite < (sym_plus y).
  70 assumption.
  71 qed.
  72
  73 theorem inj_plus_l: \forall p,n,m:nat. n+p = m+p \to n=m
  74 \def injective_plus_l.