helm/style/basic.xsl

   1 <?xml version="1.0"?>
   2
   3 <!-- Copyright (C) 2000, HELM Team                                     -->
   4 <!--                                                                   -->
   5 <!-- This file is part of HELM, an Hypertextual, Electronic            -->
   6 <!-- Library of Mathematics, developed at the Computer Science         -->
   7 <!-- Department, University of Bologna, Italy.                         -->
   8 <!--                                                                   -->
   9 <!-- HELM is free software; you can redistribute it and/or             -->
  10 <!-- modify it under the terms of the GNU General Public License       -->
  11 <!-- as published by the Free Software Foundation; either version 2    -->
  12 <!-- of the License, or (at your option) any later version.            -->
  13 <!--                                                                   -->
  14 <!-- HELM is distributed in the hope that it will be useful,           -->
  15 <!-- but WITHOUT ANY WARRANTY; without even the implied warranty of    -->
  16 <!-- MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the     -->
  17 <!-- GNU General Public License for more details.                      -->
  18 <!--                                                                   -->
  19 <!-- You should have received a copy of the GNU General Public License -->
  20 <!-- along with HELM; if not, write to the Free Software               -->
  21 <!-- Foundation, Inc., 59 Temple Place - Suite 330, Boston,            -->
  22 <!-- MA  02111-1307, USA.                                              -->
  23 <!--                                                                   -->
  24 <!-- For details, see the HELM World-Wide-Web page,                    -->
  25 <!-- http://cs.unibo.it/helm/.                                         -->
  26
  27 <!--******************************************************************-->
  28 <!-- Basic Logic                                                      -->
  29 <!-- First draft: April 3 2000                                        -->
  30 <!-- HELM Group: Asperti, Padovani, Sacerdoti, Schena, Guidi          -->
  31 <!--******************************************************************-->
  32
  33 <xsl:stylesheet version="1.0" xmlns:xsl="http://www.w3.org/1999/XSL/Transform"
  34                               xmlns:m="http://www.w3.org/1998/Math/MathML"
  35                               xmlns:helm="http://www.cs.unibo.it/helm">
  36
  37
  38 <!-- ************************* LOGIC *********************************-->
  39
  40 <!-- AND -->
  41
  42 <xsl:template match="APPLY[MUTIND[attribute::uri='cic:/Coq/Init/Logic/Conjunction/and.ind'] and (count(child::*) = 3)]" mode="pure">
  43     <m:apply helm:xref="{@id}">
  44     <m:and definitionURL="{MUTIND/@uri}" helm:xref="{MUTIND/@id}"/>
  45      <xsl:apply-templates select="*[2]" mode="noannot"/>
  46      <xsl:apply-templates select="*[3]" mode="noannot"/>
  47     </m:apply>
  48 </xsl:template>
  49
  50 <!-- OR -->
  51
  52 <xsl:template match="APPLY[MUTIND[attribute::uri='cic:/Coq/Init/Logic/Disjunction/or.ind'] and (count(child::*) = 3)]" mode="pure">
  53     <m:apply helm:xref="{@id}">
  54     <m:or definitionURL="{MUTIND/@uri}" helm:xref="{MUTIND/@id}"/>
  55      <xsl:apply-templates select="*[2]" mode="noannot"/>
  56      <xsl:apply-templates select="*[3]" mode="noannot"/>
  57     </m:apply>
  58 </xsl:template>
  59
  60 <!-- NOT -->
  61
  62 <xsl:template match="APPLY[CONST[attribute::uri='cic:/Coq/Init/Logic/not.con'] and (count(child::*) = 2)]" mode="pure">
  63     <m:apply helm:xref="{@id}">
  64     <m:not definitionURL="{CONST/@uri}" helm:xref="{MUTIND/@id}"/>
  65      <xsl:apply-templates select="*[2]" mode="noannot"/>
  66     </m:apply>
  67 </xsl:template>
  68
  69 <!-- IFF -->
  70 <!--
  71 <xsl:template match="APPLY[CONST[attribute::uri='cic:/Coq/Init/Logic/Equivalence/iff.ind'] and (count(child::*) = 3)]" mode="pure">
  72     <m:apply helm:xref="{@id}">
  73     <m:iff definitionURL="{CONST/@uri}" helm:xref="{CONST/@id}"/>
  74      <xsl:apply-templates select="*[2]" mode="noannot"/>
  75      <xsl:apply-templates select="*[3]" mode="noannot"/>
  76     </m:apply>
  77 </xsl:template>
  78 -->
  79
  80 <!-- EXISTS -->
  81
  82 <xsl:template match="APPLY[MUTIND[attribute::uri='cic:/Coq/Init/Logic/First_order_quantifiers/ex.ind' or attribute::uri='cic:/Coq/Init/Logic_Type/exT.ind'] and (count(child::*) = 3)]" mode="pure">
  83     <m:apply helm:xref="{@id}">
  84      <m:exists definitionURL="{MUTIND/@uri}" helm:xref="{MUTIND/@id}"/>
  85      <xsl:choose>
  86       <xsl:when test="name(*[3]) = 'LAMBDA'">
  87        <m:bvar>
  88         <m:ci><xsl:call-template name="insert_subscript"><xsl:with-param name="node_value"><xsl:value-of select="LAMBDA/target/@binder"/></xsl:with-param></xsl:call-template></m:ci>
  89        </m:bvar>
  90        <xsl:apply-templates select="LAMBDA/target" mode="noannot"/>
  91       </xsl:when>
  92       <xsl:otherwise>
  93        <m:bvar>
  94         <m:ci>$x</m:ci>
  95        </m:bvar>
  96        <m:apply>
  97         <m:csymbol>app</m:csymbol>
  98         <xsl:apply-templates select="*[3]" mode="noannot"/>
  99         <m:ci>$x</m:ci>
 100        </m:apply>
 101       </xsl:otherwise>
 102      </xsl:choose>
 103     </m:apply>
 104 </xsl:template>
 105
 106 <xsl:template match="APPLY[MUTIND[attribute::uri='cic:/Coq/Init/Logic/First_order_quantifiers/ex2.ind' or attribute::uri='cic:/Coq/Init/Logic_Type/exT2.ind'] and (count(child::*) = 4)]" mode="pure">
 107     <m:apply helm:xref="{@id}">
 108     <m:exists definitionURL="{MUTIND/@uri}" helm:xref="{MUTIND/@id}"/>
 109      <xsl:choose>
 110       <xsl:when test="name(*[3]) = 'LAMBDA'">
 111        <xsl:variable name="bvarname" select="*[3]/target/@binder"/>
 112        <m:bvar>
 113         <m:ci><xsl:call-template name="insert_subscript"><xsl:with-param name="node_value"><xsl:value-of select="$bvarname"/></xsl:with-param></xsl:call-template></m:ci>
 114        </m:bvar>
 115        <m:condition>
 116         <xsl:apply-templates select="LAMBDA[1]/target" mode="noannot"/>
 117        </m:condition>
 118        <xsl:choose>
 119         <xsl:when test="(name(*[4]) = 'LAMBDA') and
 120            ($bvarname = *[4]/target/@binder)">
 121          <xsl:apply-templates select="LAMBDA[2]/target" mode="noannot"/>
 122         </xsl:when>
 123         <xsl:otherwise>
 124          <m:apply>
 125           <m:csymbol>app</m:csymbol>
 126           <xsl:apply-templates select="*[4]" mode="noannot"/>
 127           <m:ci><xsl:call-template name="insert_subscript"><xsl:with-param name="node_value"><xsl:value-of select="$bvarname"/></xsl:with-param></xsl:call-template></m:ci>
 128          </m:apply>
 129         </xsl:otherwise>
 130        </xsl:choose>
 131       </xsl:when>
 132       <xsl:otherwise>
 133        <xsl:choose>
 134         <xsl:when test="name(*[4]) = 'LAMBDA'">
 135          <xsl:variable name="bvarname" select="*[4]/target/@binder"/>
 136          <m:bvar>
 137           <m:ci><xsl:call-template name="insert_subscript"><xsl:with-param name="node_value"><xsl:value-of select="$bvarname"/></xsl:with-param></xsl:call-template></m:ci>
 138          </m:bvar>
 139          <m:condition>
 140           <m:apply>
 141            <m:csymbol>app</m:csymbol>
 142            <xsl:apply-templates select="*[3]" mode="noannot"/>
 143            <m:ci><xsl:call-template name="insert_subscript"><xsl:with-param name="node_value"><xsl:value-of select="$bvarname"/></xsl:with-param></xsl:call-template></m:ci>
 144           </m:apply>
 145          </m:condition>
 146          <xsl:apply-templates select="*[4]/target" mode="noannot"/>
 147         </xsl:when>
 148         <xsl:otherwise>
 149          <m:bvar>
 150           <m:ci>x</m:ci>
 151          </m:bvar>
 152          <m:condition>
 153           <m:apply>
 154            <m:csymbol>app</m:csymbol>
 155            <xsl:apply-templates select="*[3]" mode="noannot"/>
 156            <m:ci>x</m:ci>
 157           </m:apply>
 158          </m:condition>
 159          <m:apply>
 160           <m:csymbol>app</m:csymbol>
 161           <xsl:apply-templates select="*[4]" mode="noannot"/>
 162           <m:ci>x</m:ci>
 163          </m:apply>
 164         </xsl:otherwise>
 165        </xsl:choose>
 166       </xsl:otherwise>
 167      </xsl:choose>
 168     </m:apply>
 169 </xsl:template>
 170
 171 <!-- EQUALITY -->
 172
 173 <xsl:template match="APPLY[MUTIND[attribute::uri='cic:/Coq/Init/Logic/Equality/eq.ind'] and (count(child::*) = 4)]" mode="pure">
 174     <m:apply helm:xref="{@id}">
 175     <m:eq definitionURL="{MUTIND/@uri}" helm:xref="{MUTIND/@id}"/>
 176      <xsl:apply-templates select="*[3]" mode="noannot"/>
 177      <xsl:apply-templates select="*[4]" mode="noannot"/>
 178     </m:apply>
 179 </xsl:template>
 180
 181
 182 <!-- TYPE EQUALITY -->
 183
 184 <xsl:template match="APPLY[MUTIND[attribute::uri='cic:/Coq/Init/Logic_Type/eqT.ind'] and (count(child::*) = 4)]" mode="pure">
 185     <m:apply helm:xref="{@id}">
 186     <m:eq definitionURL="{MUTIND/@uri}" helm:xref="{MUTIND/@id}"/>
 187      <xsl:apply-templates select="*[3]" mode="noannot"/>
 188      <xsl:apply-templates select="*[4]" mode="noannot"/>
 189     </m:apply>
 190 </xsl:template>
 191
 192 <!-- NOT-EQ -->
 193 <!-- NOT and EQ have no parameters -->
 194 <xsl:template match="APPLY[CONST[attribute::uri='cic:/Coq/Init/Logic/not.con']
 195 and (count(child::*) = 2) and APPLY[MUTIND[attribute::uri='cic:/Coq/Init/Logic/Equality/eq.ind']]]" mode="pure">
 196     <xsl:choose>
 197      <xsl:when test="count(APPLY/child::*) = 4">
 198       <m:apply helm:xref="{@id}">
 199        <m:neq/>
 200        <xsl:apply-templates select="*[2]/*[3]" mode="noannot"/>
 201        <xsl:apply-templates select="*[2]/*[4]" mode="set"/>
 202       </m:apply>
 203      </xsl:when>
 204      <xsl:otherwise>
 205       <xsl:apply-imports/>
 206      </xsl:otherwise>
 207     </xsl:choose>
 208 </xsl:template>
 209
 210 <!-- NOT-EQT -->
 211 <xsl:template match="APPLY[CONST[attribute::uri='cic:/Coq/Init/Logic/not.con']
 212 and (count(child::*) = 2) and APPLY[MUTIND[attribute::uri='cic:/Coq/Init/Logic_Type/eqT.ind']]]" mode="pure">
 213     <xsl:choose>
 214      <xsl:when test="count(APPLY/child::*) = 4">
 215       <m:apply helm:xref="{@id}">
 216        <m:neq/>
 217        <xsl:apply-templates select="*[2]/*[3]" mode="noannot"/>
 218        <xsl:apply-templates select="*[2]/*[4]" mode="set"/>
 219       </m:apply>
 220      </xsl:when>
 221      <xsl:otherwise>
 222       <xsl:apply-imports/>
 223      </xsl:otherwise>
 224     </xsl:choose>
 225 </xsl:template>
 226
 227 <!-- ************************ DATATYPES ******************************* -->
 228
 229 <!-- no datatypes in MathML content -->
 230
 231 <!-- ************************** PEANO ********************************* -->
 232
 233 <!-- see arith.xsl --> <!-- FG -->
 234
 235 </xsl:stylesheet>
 236
 237
 238
 239
 240