helm/style/link.xsl

   1 <?xml version="1.0"?>
   2
   3 <!-- Copyright (C) 2000, HELM Team                                     -->
   4 <!--                                                                   -->
   5 <!-- This file is part of HELM, an Hypertextual, Electronic            -->
   6 <!-- Library of Mathematics, developed at the Computer Science         -->
   7 <!-- Department, University of Bologna, Italy.                         -->
   8 <!--                                                                   -->
   9 <!-- HELM is free software; you can redistribute it and/or             -->
  10 <!-- modify it under the terms of the GNU General Public License       -->
  11 <!-- as published by the Free Software Foundation; either version 2    -->
  12 <!-- of the License, or (at your option) any later version.            -->
  13 <!--                                                                   -->
  14 <!-- HELM is distributed in the hope that it will be useful,           -->
  15 <!-- but WITHOUT ANY WARRANTY; without even the implied warranty of    -->
  16 <!-- MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the     -->
  17 <!-- GNU General Public License for more details.                      -->
  18 <!--                                                                   -->
  19 <!-- You should have received a copy of the GNU General Public License -->
  20 <!-- along with HELM; if not, write to the Free Software               -->
  21 <!-- Foundation, Inc., 59 Temple Place - Suite 330, Boston,            -->
  22 <!-- MA  02111-1307, USA.                                              -->
  23 <!--                                                                   -->
  24 <!-- For details, see the HELM World-Wide-Web page,                    -->
  25 <!-- http://cs.unibo.it/helm/.                                         -->
  26
  27 <xsl:stylesheet version="1.0" xmlns:xsl="http://www.w3.org/1999/XSL/Transform"
  28                               xmlns:m="http://www.w3.org/1998/Math/MathML"
  29                               xmlns:helm="http://www.cs.unibo.it/helm"
  30                               xmlns:xlink="http://www.w3.org/1999/xlink">
  31
  32 <!--***********************************************************************-->
  33 <!-- From MathML presentation or HTML to themselves with links             -->
  34 <!-- HELM Group: Asperti, Padovani, Sacerdoti, Schena                      -->
  35 <!-- First draft: March 16 2001, Irene Schena                              -->
  36 <!--***********************************************************************-->
  37
  38 <xsl:import href="links_library.xsl"/>
  39
  40 <xsl:key name="id" use="@id" match="m:*"/>
  41
  42 <xsl:template match = "m:semantics">
  43    <xsl:apply-templates select="*[1]" mode="semantics"/>
  44 </xsl:template>
  45
  46 <!-- Discharging content markup mantaining the linking info (helm:xref and
  47 xlink:href) -->
  48 <xsl:template match = "*" mode="semantics">
  49   <xsl:copy>
  50    <xsl:copy-of select="@*"/>
  51    <xsl:if test="@xref">
  52     <xsl:variable name="cnode" select="key('id',@xref)"/>
  53     <xsl:if test="$cnode/@definitionURL">
  54      <xsl:attribute name="xlink:href">
  55       <xsl:call-template name="makeURL"><xsl:with-param name="uri" select="$cnode/@definitionURL"/></xsl:call-template>
  56      </xsl:attribute>
  57     <!-- xlink:show='other' requires the exact modality to be -->
  58     <!-- specified in non-xlink markup. The point is that the -->
  59     <!-- element is already MathML ==> we can't add other     -->
  60     <!-- markup without introducing another new namespace.    -->
  61     <!-- So, for now no markup is used.                       -->
  62      <xsl:attribute name="xlink:show">other</xsl:attribute>
  63     </xsl:if>
  64     <xsl:if test="$cnode/@helm:xref">
  65      <xsl:attribute name="helm:xref">
  66       <xsl:value-of select="$cnode/@helm:xref"/>
  67      </xsl:attribute>
  68     </xsl:if>
  69    </xsl:if>
  70    <xsl:apply-templates mode="semantics"/>
  71   </xsl:copy>
  72 </xsl:template>
  73
  74 <!-- _top to refresh the whole frameset (avoids the matrioska effect ;-) -->
  75 <!-- a[@href] doesn't match with every anchor elements!!!                -->
  76 <xsl:template match="*[@href]">
  77    <xsl:copy>
  78     <xsl:copy-of select="@*"/>
  79     <xsl:choose>
  80     <xsl:when test="starts-with(@href,&quot;cic:&quot;)">
  81      <xsl:attribute name="href">
  82       <xsl:call-template name="makeURL">
  83        <xsl:with-param name="uri" select="@href"/>
  84       </xsl:call-template>
  85      </xsl:attribute>
  86      <xsl:attribute name="target">cic</xsl:attribute>
  87     </xsl:when>
  88     <xsl:when test="starts-with(@href,&quot;theory:&quot;)">
  89      <xsl:attribute name="href">
  90       <xsl:call-template name="makeTheoryURL">
  91        <xsl:with-param name="uri" select="@href"/>
  92       </xsl:call-template>
  93      </xsl:attribute>
  94      <xsl:attribute name="target">theory</xsl:attribute>
  95     </xsl:when>
  96     <xsl:when test="starts-with(@href,&quot;#&quot;)">
  97      <xsl:attribute name="href"><xsl:value-of  select="@href"/></xsl:attribute>
  98      <xsl:if test="@target">
  99       <xsl:attribute name="target"><xsl:value-of select="@target"/></xsl:attribute>
 100      </xsl:if>
 101     </xsl:when>
 102     <xsl:otherwise>
 103      <xsl:attribute name="href"><xsl:value-of  select="@href"/></xsl:attribute>
 104      <xsl:attribute name="target">_blank</xsl:attribute>
 105     </xsl:otherwise>
 106     </xsl:choose>
 107     <xsl:apply-templates/>
 108    </xsl:copy>
 109 </xsl:template>
 110
 111 <xsl:template match = "/|*">
 112   <xsl:copy>
 113    <xsl:copy-of select="@*"/>
 114    <xsl:apply-templates/>
 115   </xsl:copy>
 116 </xsl:template>
 117
 118 </xsl:stylesheet>