matita/components/grafite_engine/grafiteEngine.ml

   1 (* Copyright (C) 2005, HELM Team.
   2  *
   3  * This file is part of HELM, an Hypertextual, Electronic
   4  * Library of Mathematics, developed at the Computer Science
   5  * Department, University of Bologna, Italy.
   6  *
   7  * HELM is free software; you can redistribute it and/or
   8  * modify it under the terms of the GNU General Public License
   9  * as published by the Free Software Foundation; either version 2
  10  * of the License, or (at your option) any later version.
  11  *
  12  * HELM is distributed in the hope that it will be useful,
  13  * but WITHOUT ANY WARRANTY; without even the implied warranty of
  14  * MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the
  15  * GNU General Public License for more details.
  16  *
  17  * You should have received a copy of the GNU General Public License
  18  * along with HELM; if not, write to the Free Software
  19  * Foundation, Inc., 59 Temple Place - Suite 330, Boston,
  20  * MA  02111-1307, USA.
  21  *
  22  * For details, see the HELM World-Wide-Web page,
  23  * http://helm.cs.unibo.it/
  24  *)
  25
  26 (* $Id$ *)
  27
  28 (* mo file name, ma file name *)
  29 exception NMacro of GrafiteAst.loc * GrafiteAst.nmacro
  30
  31 type 'a disambiguator_input = string * int * 'a
  32
  33 type options = {
  34   do_heavy_checks: bool ;
  35 }
  36
  37 let basic_eval_unification_hint (t,n) status =
  38  NCicUnifHint.add_user_provided_hint status t n
  39 ;;
  40
  41 let inject_unification_hint =
  42  let basic_eval_unification_hint (t,n)
  43    ~refresh_uri_in_universe ~refresh_uri_in_term ~refresh_uri_in_reference
  44    ~alias_only status
  45  =
  46   if not alias_only then
  47    let t = refresh_uri_in_term (status :> NCic.status) t in
  48     basic_eval_unification_hint (t,n) status
  49   else
  50    status
  51  in
  52   GrafiteTypes.Serializer.register#run "unification_hints"
  53    basic_eval_unification_hint
  54 ;;
  55
  56 let eval_unification_hint status t n =
  57  let metasenv,subst,status,t =
  58   GrafiteDisambiguate.disambiguate_nterm status None [] [] [] ("",0,t) in
  59  assert (metasenv=[]);
  60  let t = NCicUntrusted.apply_subst status subst [] t in
  61  let status = basic_eval_unification_hint (t,n) status in
  62   NCicLibrary.dump_obj status (inject_unification_hint (t,n))
  63 ;;
  64
  65 let basic_index_obj l status =
  66   status#set_auto_cache
  67     (List.fold_left
  68       (fun t (ks,v) ->
  69          List.fold_left (fun t k ->
  70            NDiscriminationTree.DiscriminationTree.index t k v)
  71           t ks)
  72     status#auto_cache l)
  73 ;;
  74
  75 let basic_eval_interpretation ~alias_only (dsc, (symbol, args), cic_appl_pattern) status =
  76  let status =
  77   if not alias_only then
  78    Interpretations.add_interpretation status dsc (symbol, args) cic_appl_pattern
  79   else
  80    status
  81  in
  82  let mode = GrafiteAst.WithPreferences (*assert false*) in (* MATITA 1.0 VEDI SOTTO *)
  83  let diff =
  84   [DisambiguateTypes.Symbol (symbol, 0), GrafiteAst.Symbol_alias (symbol,0,dsc)]
  85  in
  86   GrafiteDisambiguate.set_proof_aliases status ~implicit_aliases:false mode diff
  87 ;;
  88
  89 let inject_interpretation =
  90  let basic_eval_interpretation (dsc, (symbol, args), cic_appl_pattern)
  91    ~refresh_uri_in_universe ~refresh_uri_in_term ~refresh_uri_in_reference
  92    ~alias_only
  93  =
  94   let rec refresh =
  95    function
  96       NotationPt.NRefPattern (NReference.Ref (uri,spec)) ->
  97        NotationPt.NRefPattern
  98         (NReference.reference_of_spec (NCicLibrary.refresh_uri uri) spec)
  99     | NotationPt.VarPattern _
 100     | NotationPt.ImplicitPattern as x -> x
 101     | NotationPt.ApplPattern l -> NotationPt.ApplPattern (List.map refresh l)
 102   in
 103   let cic_appl_pattern = refresh cic_appl_pattern in
 104    basic_eval_interpretation ~alias_only (dsc, (symbol, args), cic_appl_pattern)
 105  in
 106   GrafiteTypes.Serializer.register#run "interpretation"
 107    basic_eval_interpretation
 108 ;;
 109
 110 let eval_interpretation status data=
 111  let status = basic_eval_interpretation ~alias_only:false data status in
 112   NCicLibrary.dump_obj status (inject_interpretation data)
 113 ;;
 114
 115 let basic_eval_alias (mode,diff) status =
 116   GrafiteDisambiguate.set_proof_aliases status ~implicit_aliases:false mode diff
 117 ;;
 118
 119 let inject_alias =
 120  let basic_eval_alias (mode,diff) ~refresh_uri_in_universe ~refresh_uri_in_term
 121    ~refresh_uri_in_reference ~alias_only =
 122    basic_eval_alias (mode,diff)
 123  in
 124   GrafiteTypes.Serializer.register#run "alias" basic_eval_alias
 125 ;;
 126
 127 let eval_alias status data=
 128  let status = basic_eval_alias data status in
 129   NCicLibrary.dump_obj status (inject_alias data)
 130 ;;
 131
 132 let basic_eval_input_notation (l1,l2) status =
 133   GrafiteParser.extend status l1
 134    (fun env loc ->
 135      NotationPt.AttributedTerm
 136       (`Loc loc,TermContentPres.instantiate_level2 status env l2))
 137 ;;
 138
 139 let inject_input_notation =
 140  let basic_eval_input_notation (l1,l2)
 141   ~refresh_uri_in_universe ~refresh_uri_in_term ~refresh_uri_in_reference
 142   ~alias_only status
 143  =
 144    if not alias_only then
 145     let l1 =
 146      CicNotationParser.refresh_uri_in_checked_l1_pattern
 147       ~refresh_uri_in_term:(refresh_uri_in_term (status:>NCic.status))
 148       ~refresh_uri_in_reference l1 in
 149     let l2 = NotationUtil.refresh_uri_in_term
 150       ~refresh_uri_in_term:(refresh_uri_in_term (status:>NCic.status))
 151       ~refresh_uri_in_reference l2
 152     in
 153      basic_eval_input_notation (l1,l2) status
 154    else
 155     status
 156  in
 157   GrafiteTypes.Serializer.register#run "input_notation"
 158    basic_eval_input_notation
 159 ;;
 160
 161 let eval_input_notation status data=
 162  let status = basic_eval_input_notation data status in
 163   NCicLibrary.dump_obj status (inject_input_notation data)
 164 ;;
 165
 166 let basic_eval_output_notation (l1,l2) status =
 167  TermContentPres.add_pretty_printer status l2 l1
 168 ;;
 169
 170 let inject_output_notation =
 171  let basic_eval_output_notation (l1,l2)
 172   ~refresh_uri_in_universe ~refresh_uri_in_term ~refresh_uri_in_reference
 173   ~alias_only status
 174  =
 175   if not alias_only then
 176    let l1 =
 177     CicNotationParser.refresh_uri_in_checked_l1_pattern
 178      ~refresh_uri_in_term:(refresh_uri_in_term (status:>NCic.status))
 179       ~refresh_uri_in_reference l1 in
 180    let l2 = NotationUtil.refresh_uri_in_term
 181      ~refresh_uri_in_term:(refresh_uri_in_term (status:>NCic.status))
 182       ~refresh_uri_in_reference l2
 183    in
 184     basic_eval_output_notation (l1,l2) status
 185   else
 186    status
 187  in
 188   GrafiteTypes.Serializer.register#run "output_notation"
 189    basic_eval_output_notation
 190 ;;
 191
 192 let eval_output_notation status data=
 193  let status = basic_eval_output_notation data status in
 194   NCicLibrary.dump_obj status (inject_output_notation data)
 195 ;;
 196
 197 let record_index_obj =
 198  let aux l ~refresh_uri_in_universe
 199    ~refresh_uri_in_term ~refresh_uri_in_reference ~alias_only status
 200  =
 201   let refresh_uri_in_term = refresh_uri_in_term (status:>NCic.status) in
 202   if not alias_only then
 203     basic_index_obj
 204       (List.map
 205         (fun ks,v -> List.map refresh_uri_in_term ks, refresh_uri_in_term v)
 206       l) status
 207   else
 208    status
 209  in
 210   GrafiteTypes.Serializer.register#run "index_obj" aux
 211 ;;
 212
 213 let compute_keys status uri height kind =
 214  let mk_item ty spec =
 215    let orig_ty = NTacStatus.mk_cic_term [] ty in
 216    let status,keys = NnAuto.keys_of_type status orig_ty in
 217    let keys =
 218      List.map
 219        (fun t ->
 220           snd (NTacStatus.term_of_cic_term status t (NTacStatus.ctx_of t)))
 221        keys
 222    in
 223    keys,NCic.Const(NReference.reference_of_spec uri spec)
 224  in
 225  let data =
 226   match kind with
 227   | NCic.Fixpoint (ind,ifl,_) ->
 228      HExtlib.list_mapi
 229        (fun (_,_,rno,ty,_) i ->
 230           if ind then mk_item ty (NReference.Fix (i,rno,height))
 231           else mk_item ty (NReference.CoFix height)) ifl
 232   | NCic.Inductive (b,lno,itl,_) ->
 233      HExtlib.list_mapi
 234        (fun (_,_,ty,_) i -> mk_item ty (NReference.Ind (b,i,lno))) itl
 235      @
 236      List.map (fun ((_,_,ty),i,j) -> mk_item ty (NReference.Con (i,j+1,lno)))
 237        (List.flatten (HExtlib.list_mapi
 238          (fun (_,_,_,cl) i -> HExtlib.list_mapi (fun x j-> x,i,j) cl)
 239          itl))
 240   | NCic.Constant (_,_,Some _, ty, _) ->
 241      [ mk_item ty (NReference.Def height) ]
 242   | NCic.Constant (_,_,None, ty, _) ->
 243      [ mk_item ty NReference.Decl ]
 244  in
 245   HExtlib.filter_map
 246    (fun (keys, t) ->
 247      let keys = List.filter
 248        (function
 249          | (NCic.Meta _)
 250          | (NCic.Appl (NCic.Meta _::_)) -> false
 251          | _ -> true)
 252        keys
 253      in
 254      if keys <> [] then
 255       begin
 256         HLog.debug ("Indexing:" ^
 257           status#ppterm ~metasenv:[] ~subst:[] ~context:[] t);
 258         HLog.debug ("With keys:" ^ String.concat "\n" (List.map (fun t ->
 259           status#ppterm ~metasenv:[] ~subst:[] ~context:[] t) keys));
 260         Some (keys,t)
 261       end
 262      else
 263       begin
 264         HLog.debug ("Not indexing:" ^
 265           status#ppterm ~metasenv:[] ~subst:[] ~context:[] t);
 266         None
 267       end)
 268     data
 269 ;;
 270
 271 let index_obj_for_auto status (uri, height, _, _, kind) =
 272  (*prerr_endline (string_of_int height);*)
 273   let data = compute_keys status uri height kind in
 274   let status = basic_index_obj data status in
 275    NCicLibrary.dump_obj status (record_index_obj data)
 276 ;;
 277
 278 let index_eq uri status =
 279   let eq_status = status#eq_cache in
 280   let eq_status = NCicParamod.index_obj status eq_status uri in
 281     status#set_eq_cache eq_status
 282 ;;
 283
 284 let record_index_eq =
 285  let basic_index_eq uri
 286    ~refresh_uri_in_universe ~refresh_uri_in_term ~refresh_uri_in_reference
 287    ~alias_only status
 288    = if not alias_only then index_eq (NCicLibrary.refresh_uri uri) status else
 289      status
 290  in
 291   GrafiteTypes.Serializer.register#run "index_eq" basic_index_eq
 292 ;;
 293
 294 let index_eq_for_auto status uri =
 295  if NnAuto.is_a_fact_obj status uri then
 296    let newstatus = index_eq uri status in
 297      if newstatus#eq_cache == status#eq_cache then status
 298      else
 299        ((*prerr_endline ("recording " ^ (NUri.string_of_uri uri));*)
 300         NCicLibrary.dump_obj newstatus (record_index_eq uri))
 301  else
 302    ((*prerr_endline "Not a fact";*)
 303    status)
 304 ;;
 305
 306 let inject_constraint =
 307  let basic_eval_add_constraint (u1,u2)
 308      ~refresh_uri_in_universe ~refresh_uri_in_term ~refresh_uri_in_reference
 309      ~alias_only status
 310  =
 311   if not alias_only then
 312    let u1 = refresh_uri_in_universe u1 in
 313    let u2 = refresh_uri_in_universe u2 in
 314     (* NCicLibrary.add_constraint adds the constraint to the NCicEnvironment
 315      * and also to the storage (for undo/redo). During inclusion of compiled
 316      * files the storage must not be touched. *)
 317     NCicEnvironment.add_lt_constraint u1 u2;
 318     status
 319   else
 320    status
 321  in
 322   GrafiteTypes.Serializer.register#run "constraints" basic_eval_add_constraint
 323 ;;
 324
 325 let eval_add_constraint status u1 u2 =
 326  let status = NCicLibrary.add_constraint status u1 u2 in
 327   NCicLibrary.dump_obj status (inject_constraint (u1,u2))
 328 ;;
 329
 330 let eval_ng_tac tac =
 331  let rec aux f (text, prefix_len, tac) =
 332   match tac with
 333   | GrafiteAst.NApply (_loc, t) -> NTactics.apply_tac (text,prefix_len,t)
 334   | GrafiteAst.NSmartApply (_loc, t) ->
 335       NnAuto.smart_apply_tac (text,prefix_len,t)
 336   | GrafiteAst.NAssert (_loc, seqs) ->
 337      NTactics.assert_tac
 338       ((List.map
 339         (function (hyps,concl) ->
 340           List.map
 341            (function
 342               (id,`Decl t) -> id,`Decl (text,prefix_len,t)
 343              |(id,`Def (b,t))->id,`Def((text,prefix_len,b),(text,prefix_len,t))
 344            ) hyps,
 345           (text,prefix_len,concl))
 346        ) seqs)
 347   | GrafiteAst.NAuto (_loc, (None,a)) ->
 348       NnAuto.auto_tac ~params:(None,a) ?trace_ref:None
 349   | GrafiteAst.NAuto (_loc, (Some l,a)) ->
 350       NnAuto.auto_tac
 351         ~params:(Some List.map (fun x -> "",0,x) l,a) ?trace_ref:None
 352   | GrafiteAst.NBranch _ -> NTactics.branch_tac ~force:false
 353   | GrafiteAst.NCases (_loc, what, where) ->
 354       NTactics.cases_tac
 355         ~what:(text,prefix_len,what)
 356         ~where:(text,prefix_len,where)
 357   | GrafiteAst.NCase1 (_loc,n) -> NTactics.case1_tac n
 358   | GrafiteAst.NChange (_loc, pat, ww) ->
 359       NTactics.change_tac
 360        ~where:(text,prefix_len,pat) ~with_what:(text,prefix_len,ww)
 361   | GrafiteAst.NConstructor (_loc,num,args) ->
 362      NTactics.constructor_tac
 363        ?num ~args:(List.map (fun x -> text,prefix_len,x) args)
 364   | GrafiteAst.NCut (_loc, t) -> NTactics.cut_tac (text,prefix_len,t)
 365 (*| GrafiteAst.NDiscriminate (_,what) -> NDestructTac.discriminate_tac ~what:(text,prefix_len,what)
 366   | GrafiteAst.NSubst (_,what) -> NDestructTac.subst_tac ~what:(text,prefix_len,what)*)
 367   | GrafiteAst.NClear (_loc, l) -> NTactics.clear_tac l
 368   | GrafiteAst.NDestruct (_,dom,skip) -> NDestructTac.destruct_tac dom skip
 369   | GrafiteAst.NDot _ -> NTactics.dot_tac
 370   | GrafiteAst.NElim (_loc, what, where) ->
 371       NTactics.elim_tac
 372         ~what:(text,prefix_len,what)
 373         ~where:(text,prefix_len,where)
 374   | GrafiteAst.NFocus (_,l) -> NTactics.focus_tac l
 375   | GrafiteAst.NGeneralize (_loc, where) ->
 376       NTactics.generalize_tac ~where:(text,prefix_len,where)
 377   | GrafiteAst.NId _ -> (fun x -> x)
 378   | GrafiteAst.NIntro (_loc,n) -> NTactics.intro_tac n
 379   | GrafiteAst.NIntros (_loc,ns) -> NTactics.intros_tac ns
 380   | GrafiteAst.NInversion (_loc, what, where) ->
 381       NTactics.inversion_tac
 382         ~what:(text,prefix_len,what)
 383         ~where:(text,prefix_len,where)
 384   | GrafiteAst.NLApply (_loc, t) -> NTactics.lapply_tac (text,prefix_len,t)
 385   | GrafiteAst.NLetIn (_loc,where,what,name) ->
 386       NTactics.letin_tac ~where:(text,prefix_len,where)
 387         ~what:(text,prefix_len,what) name
 388   | GrafiteAst.NMerge _ -> NTactics.merge_tac
 389   | GrafiteAst.NPos (_,l) -> NTactics.pos_tac l
 390   | GrafiteAst.NPosbyname (_,s) -> NTactics.case_tac s
 391   | GrafiteAst.NReduce (_loc, reduction, where) ->
 392       NTactics.reduce_tac ~reduction ~where:(text,prefix_len,where)
 393   | GrafiteAst.NRewrite (_loc,dir,what,where) ->
 394      NTactics.rewrite_tac ~dir ~what:(text,prefix_len,what)
 395       ~where:(text,prefix_len,where)
 396   | GrafiteAst.NSemicolon _ -> fun x -> x
 397   | GrafiteAst.NShift _ -> NTactics.shift_tac
 398   | GrafiteAst.NSkip _ -> NTactics.skip_tac
 399   | GrafiteAst.NUnfocus _ -> NTactics.unfocus_tac
 400   | GrafiteAst.NWildcard _ -> NTactics.wildcard_tac
 401   | GrafiteAst.NTry (_,tac) -> NTactics.try_tac
 402       (f f (text, prefix_len, tac))
 403   | GrafiteAst.NAssumption _ -> NTactics.assumption_tac
 404   | GrafiteAst.NBlock (_,l) ->
 405       NTactics.block_tac (List.map (fun x -> aux f (text,prefix_len,x)) l)
 406   |GrafiteAst.NRepeat (_,tac) ->
 407       NTactics.repeat_tac (f f (text, prefix_len, tac))
 408  in
 409   aux aux tac (* trick for non uniform recursion call *)
 410 ;;
 411
 412 let subst_metasenv_and_fix_names status =
 413   let u,h,metasenv, subst,o = status#obj in
 414   let o =
 415     NCicUntrusted.map_obj_kind ~skip_body:true
 416      (NCicUntrusted.apply_subst status subst []) o
 417   in
 418    status#set_obj(u,h,NCicUntrusted.apply_subst_metasenv status subst metasenv,subst,o)
 419 ;;
 420
 421 let is_proof_irrelevant status context ty =
 422   match
 423     NCicReduction.whd status ~subst:[] context
 424      (NCicTypeChecker.typeof status ~subst:[] ~metasenv:[] context ty)
 425   with
 426      NCic.Sort NCic.Prop -> true
 427    | NCic.Sort _ -> false
 428    | _ -> assert false
 429 ;;
 430
 431 let rec relevance_of status ?(context=[]) ty =
 432  match NCicReduction.whd status ~subst:[] context ty with
 433     NCic.Prod (n,s,t) ->
 434      not (is_proof_irrelevant status context s) ::
 435       relevance_of status ~context:((n,NCic.Decl s)::context) t
 436   | _ -> []
 437 ;;
 438
 439 let compute_relevance status uri =
 440  function
 441     NCic.Constant (_,name,bo,ty,attrs) ->
 442      let relevance = relevance_of status ty in
 443       NCic.Constant (relevance,name,bo,ty,attrs)
 444   | NCic.Fixpoint (ind,funs,attrs) ->
 445      let funs =
 446        List.map
 447        (fun (_,name,recno,ty,bo) ->
 448          let relevance = relevance_of status ty in
 449           relevance,name,recno,ty,bo
 450         ) funs
 451      in
 452       NCic.Fixpoint (ind,funs,attrs)
 453   | NCic.Inductive (ind,leftno,tys,attrs) ->
 454      let context =
 455       List.rev_map (fun (_,name,arity,_) -> name,NCic.Decl arity) tys in
 456      let tysno = List.length tys in
 457      let tys =
 458        List.map
 459         (fun (_,name,arity,cons) ->
 460          let relevance = relevance_of status arity in
 461          let cons =
 462           List.map
 463            (fun (_,name,ty) ->
 464              let dety =
 465                NCicTypeChecker.debruijn status uri tysno ~subst:[] [] ty in
 466              let relevance = relevance_of status ~context dety in
 467               relevance,name,ty
 468            ) cons
 469          in
 470           (relevance,name,arity,cons)
 471         ) tys
 472      in
 473       NCic.Inductive (ind,leftno,tys,attrs)
 474 ;;
 475
 476
 477 let rec eval_ncommand ~include_paths opts status (text,prefix_len,cmd) =
 478   match cmd with
 479   | GrafiteAst.Include (loc, mode, fname) ->
 480            let _root, baseuri, fullpath, _rrelpath =
 481        Librarian.baseuri_of_script ~include_paths fname in
 482      let baseuri = NUri.uri_of_string baseuri in
 483      (* MATITA 1.0: keep WithoutPreferences? *)
 484      let alias_only = (mode = GrafiteAst.OnlyPreferences) in
 485       GrafiteTypes.Serializer.require
 486        ~alias_only ~baseuri ~fname:fullpath status
 487   | GrafiteAst.UnificationHint (loc, t, n) -> eval_unification_hint status t n
 488   | GrafiteAst.NCoercion (loc, name, t, ty, source, target) ->
 489      let status, composites =
 490       NCicCoercDeclaration.eval_ncoercion status name t ty source target in
 491      let mode = GrafiteAst.WithPreferences in (* MATITA 1.0: fixme *)
 492      let aliases = GrafiteDisambiguate.aliases_for_objs status composites in
 493       eval_alias status (mode,aliases)
 494   | GrafiteAst.NQed loc ->
 495      if status#ng_mode <> `ProofMode then
 496       raise (GrafiteTypes.Command_error "Not in proof mode")
 497      else
 498       let uri,height,menv,subst,obj_kind = status#obj in
 499        if menv <> [] then
 500         raise
 501          (GrafiteTypes.Command_error"You can't Qed an incomplete theorem")
 502        else
 503         let obj_kind =
 504          NCicUntrusted.map_obj_kind
 505           (NCicUntrusted.apply_subst status subst []) obj_kind in
 506         let height = NCicTypeChecker.height_of_obj_kind status uri [] obj_kind in
 507         (* fix the height inside the object *)
 508         let rec fix () = function
 509           | NCic.Const (NReference.Ref (u,spec)) when NUri.eq u uri ->
 510              NCic.Const (NReference.reference_of_spec u
 511               (match spec with
 512               | NReference.Def _ -> NReference.Def height
 513               | NReference.Fix (i,j,_) -> NReference.Fix(i,j,height)
 514               | NReference.CoFix _ -> NReference.CoFix height
 515               | NReference.Ind _ | NReference.Con _
 516               | NReference.Decl as s -> s))
 517           | t -> NCicUtils.map status (fun _ () -> ()) () fix t
 518         in
 519         let obj_kind =
 520           match obj_kind with
 521           | NCic.Fixpoint _ ->
 522               NCicUntrusted.map_obj_kind (fix ()) obj_kind
 523           | _ -> obj_kind
 524         in
 525         let obj_kind = compute_relevance status uri obj_kind in
 526         let obj = uri,height,[],[],obj_kind in
 527         let old_status = status in
 528         let status = NCicLibrary.add_obj status obj in
 529         let index_obj =
 530          match obj_kind with
 531             NCic.Constant (_,_,_,_,(_,`Example,_))
 532           | NCic.Fixpoint (_,_,(_,`Example,_)) -> false
 533           | _ -> true
 534         in
 535         let status =
 536          if index_obj then
 537           let status = index_obj_for_auto status obj in
 538            (try index_eq_for_auto status uri
 539            with _ -> status)
 540          else
 541           status in
 542 (*
 543           try
 544             index_eq uri status
 545           with _ -> prerr_endline "got an exception"; status
 546         in *)
 547 (*         prerr_endline (status#ppobj obj); *)
 548         HLog.message ("New object: " ^ NUri.string_of_uri uri);
 549          (try
 550        (*prerr_endline (status#ppobj obj);*)
 551            let boxml = NCicElim.mk_elims status obj in
 552            let boxml = boxml @ NCicElim.mk_projections status obj in
 553            let status = status#set_ng_mode `CommandMode in
 554            let xxaliases = GrafiteDisambiguate.aliases_for_objs status [uri] in
 555            let mode = GrafiteAst.WithPreferences in (* MATITA 1.0: fixme *)
 556            let status = eval_alias status (mode,xxaliases) in
 557            let status =
 558             List.fold_left
 559              (fun status boxml ->
 560                try
 561                 let nstatus =
 562                  eval_ncommand ~include_paths opts status
 563                   ("",0,GrafiteAst.NObj (HExtlib.dummy_floc,boxml))
 564                 in
 565                 if nstatus#ng_mode <> `CommandMode then
 566                   begin
 567                     (*HLog.warn "error in generating projection/eliminator";*)
 568                     assert(status#ng_mode = `CommandMode);
 569                     status
 570                   end
 571                 else
 572                   nstatus
 573                with
 574                | MultiPassDisambiguator.DisambiguationError _
 575                | NCicTypeChecker.TypeCheckerFailure _ ->
 576                   (*HLog.warn "error in generating projection/eliminator";*)
 577                   status
 578              ) status boxml in
 579            let _,_,_,_,nobj = obj in
 580            let status = match nobj with
 581                NCic.Inductive (is_ind,leftno,[it],_) ->
 582                  let _,ind_name,ty,cl = it in
 583                  List.fold_left
 584                    (fun status outsort ->
 585                       let status = status#set_ng_mode `ProofMode in
 586                       try
 587                        (let status,invobj =
 588                          NInversion.mk_inverter
 589                           (ind_name ^ "_inv_" ^
 590                             (snd (NCicElim.ast_of_sort outsort)))
 591                           is_ind it leftno outsort status status#baseuri in
 592                        let _,_,menv,_,_ = invobj in
 593                         (match menv with
 594                              [] -> eval_ncommand ~include_paths opts status
 595                                     ("",0,GrafiteAst.NQed Stdpp.dummy_loc)
 596                            | _ -> status))
 597                        (* XXX *)
 598                       with _ -> (*HLog.warn "error in generating inversion principle"; *)
 599                                 let status = status#set_ng_mode `CommandMode in status)
 600                   status
 601                   (NCic.Prop::
 602                     List.map (fun s -> NCic.Type s) (NCicEnvironment.get_universes ()))
 603               | _ -> status
 604            in
 605            let coercions =
 606             match obj with
 607               _,_,_,_,NCic.Inductive
 608                (true,leftno,[_,_,_,[_,_,_]],(_,`Record fields))
 609                ->
 610                 HExtlib.filter_map
 611                  (fun (name,is_coercion,arity) ->
 612                    if is_coercion then Some(name,leftno,arity) else None) fields
 613             | _ -> [] in
 614            let status =
 615             List.fold_left
 616              (fun status (name,cpos,arity) ->
 617                try
 618                  let metasenv,subst,status,t =
 619                   GrafiteDisambiguate.disambiguate_nterm status None [] [] []
 620                    ("",0,NotationPt.Ident (name,None)) in
 621                  assert (metasenv = [] && subst = []);
 622                  let status, nuris =
 623                    NCicCoercDeclaration.
 624                      basic_eval_and_record_ncoercion_from_t_cpos_arity
 625                       status (name,t,cpos,arity) in
 626                  let aliases = GrafiteDisambiguate.aliases_for_objs status nuris in
 627                   eval_alias status (mode,aliases)
 628                with MultiPassDisambiguator.DisambiguationError _->
 629                  HLog.warn ("error in generating coercion: "^name);
 630                  status)
 631              status coercions
 632            in
 633             status
 634           with
 635            exn ->
 636             NCicLibrary.time_travel old_status;
 637             raise exn)
 638   | GrafiteAst.NCopy (log,tgt,src_uri, map) ->
 639      if status#ng_mode <> `CommandMode then
 640       raise (GrafiteTypes.Command_error "Not in command mode")
 641      else
 642        let tgt_uri_ext, old_ok =
 643          match NCicEnvironment.get_checked_obj status src_uri with
 644          | _,_,[],[], (NCic.Inductive _ as ok) -> ".ind", ok
 645          | _,_,[],[], (NCic.Fixpoint _ as ok) -> ".con", ok
 646          | _,_,[],[], (NCic.Constant _ as ok) -> ".con", ok
 647          | _ -> assert false
 648        in
 649        let tgt_uri = NUri.uri_of_string (status#baseuri^"/"^tgt^tgt_uri_ext) in
 650        let map = (src_uri, tgt_uri) :: map in
 651        let ok =
 652          let rec subst () = function
 653            | NCic.Meta _ -> assert false
 654            | NCic.Const (NReference.Ref (u,spec)) as t ->
 655                (try NCic.Const
 656                  (NReference.reference_of_spec (List.assoc u map)spec)
 657                with Not_found -> t)
 658            | t -> NCicUtils.map status (fun _ _ -> ()) () subst t
 659          in
 660          NCicUntrusted.map_obj_kind ~skip_body:false (subst ()) old_ok
 661        in
 662        let ninitial_stack = Continuationals.Stack.of_nmetasenv [] in
 663        let status = status#set_obj (tgt_uri,0,[],[],ok) in
 664        (*prerr_endline (status#ppobj (tgt_uri,0,[],[],ok));*)
 665        let status = status#set_stack ninitial_stack in
 666        let status = subst_metasenv_and_fix_names status in
 667        let status = status#set_ng_mode `ProofMode in
 668        eval_ncommand ~include_paths opts status ("",0,GrafiteAst.NQed Stdpp.dummy_loc)
 669   | GrafiteAst.NObj (loc,obj) ->
 670      if status#ng_mode <> `CommandMode then
 671       raise (GrafiteTypes.Command_error "Not in command mode")
 672      else
 673       let status,obj =
 674        GrafiteDisambiguate.disambiguate_nobj status
 675         ~baseuri:status#baseuri (text,prefix_len,obj) in
 676       let uri,height,nmenv,nsubst,nobj = obj in
 677       let ninitial_stack = Continuationals.Stack.of_nmetasenv nmenv in
 678       let status = status#set_obj obj in
 679       let status = status#set_stack ninitial_stack in
 680       let status = subst_metasenv_and_fix_names status in
 681       let status = status#set_ng_mode `ProofMode in
 682       (match nmenv with
 683           [] ->
 684            eval_ncommand ~include_paths opts status ("",0,GrafiteAst.NQed Stdpp.dummy_loc)
 685         | _ -> status)
 686   | GrafiteAst.NDiscriminator (_,_) -> assert false (*(loc, indty) ->
 687       if status#ng_mode <> `CommandMode then
 688         raise (GrafiteTypes.Command_error "Not in command mode")
 689       else
 690         let status = status#set_ng_mode `ProofMode in
 691         let metasenv,subst,status,indty =
 692           GrafiteDisambiguate.disambiguate_nterm None status [] [] [] (text,prefix_len,indty) in
 693         let indtyno, (_,_,tys,_,_) = match indty with
 694             NCic.Const ((NReference.Ref (_,NReference.Ind (_,indtyno,_))) as r) ->
 695               indtyno, NCicEnvironment.get_checked_indtys r
 696           | _ -> prerr_endline ("engine: indty expected... (fix this error message)"); assert false in
 697         let it = List.nth tys indtyno in
 698         let status,obj =  NDestructTac.mk_discriminator it status in
 699         let _,_,menv,_,_ = obj in
 700           (match menv with
 701                [] -> eval_ncommand ~include_paths opts status ("",0,GrafiteAst.NQed Stdpp.dummy_loc)
 702              | _ -> prerr_endline ("Discriminator: non empty metasenv");
 703                     status, []) *)
 704   | GrafiteAst.NInverter (loc, name, indty, selection, sort) ->
 705      if status#ng_mode <> `CommandMode then
 706       raise (GrafiteTypes.Command_error "Not in command mode")
 707      else
 708       let metasenv,subst,status,sort = match sort with
 709         | None -> [],[],status,NCic.Sort NCic.Prop
 710         | Some s ->
 711            GrafiteDisambiguate.disambiguate_nterm status None [] [] []
 712             (text,prefix_len,s)
 713       in
 714       assert (metasenv = []);
 715       let sort = NCicReduction.whd status ~subst [] sort in
 716       let sort =
 717        match sort with
 718           NCic.Sort s -> s
 719         | _ ->
 720            raise (Invalid_argument (Printf.sprintf
 721             "ninverter: found target %s, which is not a sort"
 722              (status#ppterm ~metasenv ~subst ~context:[] sort))) in
 723       let status = status#set_ng_mode `ProofMode in
 724       let metasenv,subst,status,indty =
 725        GrafiteDisambiguate.disambiguate_nterm status None [] [] subst
 726         (text,prefix_len,indty) in
 727       let indtyno,(_,leftno,tys,_,_) =
 728        match indty with
 729           NCic.Const ((NReference.Ref (_,NReference.Ind (_,indtyno,_))) as r) ->
 730            indtyno, NCicEnvironment.get_checked_indtys status r
 731         | _ ->
 732           prerr_endline ("engine: indty ="  ^ status#ppterm ~metasenv:[]
 733            ~subst:[] ~context:[] indty);
 734           assert false in
 735       let it = List.nth tys indtyno in
 736       let status,obj =
 737        NInversion.mk_inverter name true it leftno ?selection sort
 738         status status#baseuri in
 739       let _,_,menv,_,_ = obj in
 740        (match menv with
 741           [] ->
 742             eval_ncommand ~include_paths opts status
 743              ("",0,GrafiteAst.NQed Stdpp.dummy_loc)
 744         | _ -> assert false)
 745   | GrafiteAst.NUnivConstraint (loc,u1,u2) ->
 746       eval_add_constraint status [`Type,u1] [`Type,u2]
 747   (* ex lexicon commands *)
 748   | GrafiteAst.Interpretation (loc, dsc, (symbol, args), cic_appl_pattern) ->
 749      let cic_appl_pattern =
 750       GrafiteDisambiguate.disambiguate_cic_appl_pattern status args
 751        cic_appl_pattern
 752      in
 753       eval_interpretation status (dsc,(symbol, args),cic_appl_pattern)
 754   | GrafiteAst.Notation (loc, dir, l1, associativity, precedence, l2) ->
 755       let l1 =
 756         CicNotationParser.check_l1_pattern
 757          l1 (dir = Some `RightToLeft) precedence associativity
 758       in
 759       let status =
 760         if dir <> Some `RightToLeft then eval_input_notation status (l1,l2)
 761         else status
 762       in
 763        if dir <> Some `LeftToRight then eval_output_notation status (l1,l2)
 764        else status
 765   | GrafiteAst.Alias (loc, spec) ->
 766      let diff =
 767       (*CSC: Warning: this code should be factorized with the corresponding
 768              code in DisambiguatePp *)
 769       match spec with
 770       | GrafiteAst.Ident_alias (id,uri) ->
 771          [DisambiguateTypes.Id id,spec]
 772       | GrafiteAst.Symbol_alias (symb, instance, desc) ->
 773          [DisambiguateTypes.Symbol (symb,instance),spec]
 774       | GrafiteAst.Number_alias (instance,desc) ->
 775          [DisambiguateTypes.Num instance,spec]
 776      in
 777       let mode = GrafiteAst.WithPreferences in(*assert false in (* VEDI SOPRA *) MATITA 1.0*)
 778        eval_alias status (mode,diff)
 779 ;;
 780
 781 let eval_comment opts status (text,prefix_len,c) = status
 782
 783 let rec eval_executable ~include_paths opts status (text,prefix_len,ex) =
 784   match ex with
 785   | GrafiteAst.NTactic (_(*loc*), tacl) ->
 786       if status#ng_mode <> `ProofMode then
 787        raise (GrafiteTypes.Command_error "Not in proof mode")
 788       else
 789        let status =
 790         List.fold_left
 791           (fun status tac ->
 792             let status = eval_ng_tac (text,prefix_len,tac) status in
 793             subst_metasenv_and_fix_names status)
 794           status tacl
 795        in
 796         status
 797   | GrafiteAst.NCommand (_, cmd) ->
 798       eval_ncommand ~include_paths opts status (text,prefix_len,cmd)
 799   | GrafiteAst.NMacro (loc, macro) ->
 800      raise (NMacro (loc,macro))
 801
 802 and eval_ast ~include_paths ?(do_heavy_checks=false) status (text,prefix_len,st)
 803 =
 804   let opts = { do_heavy_checks = do_heavy_checks ; } in
 805   match st with
 806   | GrafiteAst.Executable (_,ex) ->
 807      eval_executable ~include_paths opts status (text,prefix_len,ex)
 808   | GrafiteAst.Comment (_,c) ->
 809       eval_comment opts status (text,prefix_len,c)
 810 ;;