matita/components/ng_kernel/nCicTypeChecker.ml

   1 (*
   2     ||M||  This file is part of HELM, an Hypertextual, Electronic
   3     ||A||  Library of Mathematics, developed at the Computer Science
   4     ||T||  Department, University of Bologna, Italy.
   5     ||I||
   6     ||T||  HELM is free software; you can redistribute it and/or
   7     ||A||  modify it under the terms of the GNU General Public License
   8     \   /  version 2 or (at your option) any later version.
   9      \ /   This software is distributed as is, NO WARRANTY.
  10       V_______________________________________________________________ *)
  11
  12 (* $Id$ *)
  13
  14 module C = NCic
  15 module Ref = NReference
  16 module R = NCicReduction
  17 module S = NCicSubstitution
  18 module U = NCicUtils
  19 module E = NCicEnvironment
  20
  21 exception TypeCheckerFailure of string Lazy.t
  22 exception AssertFailure of string Lazy.t
  23
  24 (*
  25 let raise = function
  26   | TypeCheckerFailure s as e -> prerr_endline (Lazy.force s); raise e
  27   | e -> raise e
  28 ;;
  29 *)
  30
  31 type recf_entry =
  32   | Evil of int (* rno *)
  33   | UnfFix of bool list (* fixed arguments *)
  34   | Safe
  35 ;;
  36
  37 let is_dangerous i l =
  38   List.exists (function (j,Evil _) when j=i -> true | _ -> false) l
  39 ;;
  40
  41 let is_unfolded i l =
  42   List.exists (function (j,UnfFix _) when j=i -> true | _ -> false) l
  43 ;;
  44
  45 let is_safe i l =
  46   List.exists (function (j,Safe) when j=i -> true | _ -> false) l
  47 ;;
  48
  49 let get_recno i l =
  50   try match List.assoc i l with Evil rno -> rno | _ -> assert false
  51   with Not_found -> assert false
  52 ;;
  53
  54 let get_fixed_args i l =
  55   try match List.assoc i l with UnfFix fa -> fa | _ -> assert false
  56   with Not_found -> assert false
  57 ;;
  58
  59 let shift_k e (c,rf,x) = e::c,List.map (fun (k,v) -> k+1,v) rf,x+1;;
  60
  61 (* for debugging only
  62 let string_of_recfuns ~subst ~metasenv ~context l =
  63   let pp = status#ppterm ~subst ~metasenv ~context in
  64   let safe, rest = List.partition (function (_,Safe) -> true | _ -> false) l in
  65   let dang,unf = List.partition (function (_,UnfFix _)-> false | _->true)rest in
  66   "\n\tsafes: "^String.concat "," (List.map (fun (i,_)->pp (C.Rel i)) safe) ^
  67   "\n\tfix  : "^String.concat ","
  68    (List.map
  69      (function (i,UnfFix l)-> pp(C.Rel i)^"/"^String.concat "," (List.map
  70        string_of_bool l)
  71      | _ ->assert false) unf) ^
  72   "\n\trec  : "^String.concat ","
  73    (List.map
  74      (function (i,Evil rno)->pp(C.Rel i)^"/"^string_of_int rno
  75      | _ -> assert false) dang)
  76 ;;
  77 *)
  78
  79 let fixed_args bos j n nn =
  80  let rec aux k acc = function
  81   | C.Appl (C.Rel i::args) when i-k > n && i-k <= nn ->
  82      let rec combine l1 l2 =
  83       match l1,l2 with
  84          [],[] -> []
  85        | he1::tl1, he2::tl2 -> (he1,he2)::combine tl1 tl2
  86        | _::tl, [] -> (false,C.Rel ~-1)::combine tl [] (* dummy term *)
  87        | [],_::_ -> assert false
  88      in
  89      let lefts, _ = HExtlib.split_nth (min j (List.length args)) args in
  90       List.map (fun ((b,x),i) -> b && x = C.Rel (k-i))
  91        (HExtlib.list_mapi (fun x i -> x,i) (combine acc lefts))
  92   | t -> U.fold (fun _ k -> k+1) k aux acc t
  93  in
  94   List.fold_left (aux 0)
  95    (let rec f = function 0 -> [] | n -> true :: f (n-1) in f j) bos
  96 ;;
  97
  98 let debruijn status uri number_of_types ~subst context =
  99 (* manca la subst! *)
 100  let rec aux k t =
 101   match t with
 102    | C.Meta (i,(s,l)) ->
 103       (try
 104         let _,_,term,_ = U.lookup_subst i subst in
 105         let ts = S.subst_meta status (0,l) term in
 106         let ts' = aux (k-s) ts in
 107          if ts == ts' then t else ts'
 108        with U.Subst_not_found _ ->
 109         match l with
 110            C.Ctx l ->
 111             let l1 = HExtlib.sharing_map (aux (k-s)) l in
 112             if l1 == l then t else C.Meta (i,(s,C.Ctx l1))
 113          | _ -> t)
 114    | C.Const (Ref.Ref (uri1,(Ref.Fix (no,_,_) | Ref.CoFix no)))
 115    | C.Const (Ref.Ref (uri1,Ref.Ind (_,no,_))) when NUri.eq uri uri1 ->
 116       C.Rel (k + number_of_types - no)
 117    | t -> U.map status (fun _ k -> k+1) k aux t
 118  in
 119   aux (List.length context)
 120 ;;
 121
 122 let sort_of_prod (status:#NCic.status) ~metasenv ~subst context (name,s) t (t1, t2) =
 123    let t1 = R.whd status ~subst context t1 in
 124    let t2 = R.whd status ~subst ((name,C.Decl s)::context) t2 in
 125    match t1, t2 with
 126    | C.Sort _, C.Sort C.Prop -> t2
 127    | C.Sort (C.Type u1), C.Sort (C.Type u2) ->
 128       C.Sort (C.Type (NCicEnvironment.max u1 u2))
 129    | C.Sort C.Prop,C.Sort (C.Type _) -> t2
 130    | C.Meta (_,(_,(C.Irl 0 | C.Ctx []))), C.Sort _ -> t2
 131    | C.Meta (_,(_,(C.Irl 0 | C.Ctx []))), C.Meta (i,(_,(C.Irl 0 | C.Ctx [])))
 132    | C.Sort _, C.Meta  (i,(_,(C.Irl 0 | C.Ctx []))) ->
 133         NCic.Meta (i,(0, C.Irl 0))
 134    | x, (C.Sort _ | C.Meta (_,(_,(C.Irl 0 | C.Ctx []))))
 135    | _, x ->
 136       let y, context =
 137         if x == t1 then s, context else t, ((name,C.Decl s)::context)
 138       in
 139       raise (TypeCheckerFailure (lazy (Printf.sprintf
 140         "%s is expected to be a type, but its type is %s that is not a sort"
 141          (status#ppterm ~subst ~metasenv ~context y)
 142          (status#ppterm ~subst ~metasenv ~context x))))
 143 ;;
 144
 145 (* instantiate_parameters ps (x1:T1)...(xn:Tn)C                             *)
 146 (* returns ((x_|ps|:T_|ps|)...(xn:Tn)C){ps_1 / x1 ; ... ; ps_|ps| / x_|ps|} *)
 147 let rec instantiate_parameters status params c =
 148   match c, params with
 149   | c,[] -> c
 150   | C.Prod (_,_,ta), he::tl -> instantiate_parameters status tl (S.subst status he ta)
 151   | _,_ -> raise (AssertFailure (lazy "1"))
 152 ;;
 153
 154 let specialize_inductive_type_constrs status ~subst context ty_term =
 155   match R.whd status ~subst context ty_term with
 156   | C.Const (Ref.Ref (_,Ref.Ind _) as ref)
 157   | C.Appl (C.Const (Ref.Ref (_,Ref.Ind _) as ref) :: _ ) as ty ->
 158       let args = match ty with C.Appl (_::tl) -> tl | _ -> [] in
 159       let _, leftno, itl, _, i = E.get_checked_indtys status ref in
 160       let left_args,_ = HExtlib.split_nth leftno args in
 161       let _,_,_,cl = List.nth itl i in
 162       List.map
 163         (fun (rel,name,ty) -> rel, name, instantiate_parameters status left_args ty) cl
 164   | _ -> assert false
 165 ;;
 166
 167 let specialize_and_abstract_constrs status ~subst r_uri r_len context ty_term =
 168   let cl = specialize_inductive_type_constrs status ~subst context ty_term in
 169   let len = List.length context in
 170   let context_dcl =
 171     match E.get_checked_obj status r_uri with
 172     | _,_,_,_, C.Inductive (_,_,tys,_) ->
 173         context @ List.map (fun (_,name,arity,_) -> name,C.Decl arity) tys
 174     | _ -> assert false
 175   in
 176   context_dcl,
 177   List.map (fun (_,id,ty) -> id, debruijn status r_uri r_len ~subst context ty) cl,
 178   len, len + r_len
 179 ;;
 180
 181 exception DoesOccur;;
 182
 183 let does_not_occur status ~subst context n nn t =
 184   let rec aux k _ = function
 185     | C.Rel m when m > n+k && m <= nn+k -> raise DoesOccur
 186     | C.Rel m when m <= k || m > nn+k -> ()
 187     | C.Rel m ->
 188         (try match List.nth context (m-1-k) with
 189           | _,C.Def (bo,_) -> aux 0 () (S.lift status (m-k) bo)
 190           | _ -> ()
 191          with Failure _ -> assert false)
 192     | C.Meta (_,(_,(C.Irl 0 | C.Ctx []))) -> (* closed meta *) ()
 193     | C.Meta (mno,(s,l)) ->
 194          (try
 195             (* possible optimization here: try does_not_occur on l and
 196                perform substitution only if DoesOccur is raised *)
 197             let _,_,term,_ = U.lookup_subst mno subst in
 198             aux (k-s) () (S.subst_meta status (0,l) term)
 199           with U.Subst_not_found _ -> () (*match l with
 200           | C.Irl len -> if not (n+k >= s+len || s > nn+k) then raise DoesOccur
 201           | C.Ctx lc -> List.iter (aux (k-s) ()) lc*))
 202     | t -> U.fold (fun _ k -> k + 1) k aux () t
 203   in
 204    try aux 0 () t; true
 205    with DoesOccur -> false
 206 ;;
 207
 208 let rec eat_lambdas (status:#NCic.status) ~subst ~metasenv context n te =
 209   match (n, R.whd status ~subst context te) with
 210   | (0, _) -> (te, context)
 211   | (n, C.Lambda (name,so,ta)) when n > 0 ->
 212       eat_lambdas status ~subst ~metasenv ((name,(C.Decl so))::context) (n - 1) ta
 213    | (n, te) ->
 214       raise (AssertFailure (lazy (Printf.sprintf "eat_lambdas (%d, %s)" n
 215         (status#ppterm ~subst ~metasenv ~context te))))
 216 ;;
 217
 218 let rec eat_or_subst_lambdas status
 219   ~subst ~metasenv n te to_be_subst args (context,_,_ as k)
 220 =
 221   match n, R.whd status ~subst context te, to_be_subst, args with
 222   | (n, C.Lambda (_,_,ta),true::to_be_subst,arg::args) when n > 0 ->
 223       eat_or_subst_lambdas status ~subst ~metasenv (n - 1) (S.subst status arg ta)
 224        to_be_subst args k
 225   | (n, C.Lambda (name,so,ta),false::to_be_subst,_::args) when n > 0 ->
 226       eat_or_subst_lambdas status ~subst ~metasenv (n - 1) ta to_be_subst args
 227        (shift_k (name,(C.Decl so)) k)
 228   | (_, te, _, _) -> te, k
 229 ;;
 230
 231 let check_homogeneous_call (status:#NCic.status) ~subst context indparamsno n uri reduct tl =
 232  let last =
 233   List.fold_left
 234    (fun k x ->
 235      if k = 0 then 0
 236      else
 237       match R.whd status ~subst context x with
 238       | C.Rel m when m = n - (indparamsno - k) -> k - 1
 239       | _ -> raise (TypeCheckerFailure (lazy
 240          ("Argument "^string_of_int (indparamsno - k + 1) ^ " (of " ^
 241          string_of_int indparamsno ^ " fixed) is not homogeneous in "^
 242          "appl:\n"^ status#ppterm ~context ~subst ~metasenv:[] reduct))))
 243    indparamsno tl
 244  in
 245   if last <> 0 then
 246    raise (TypeCheckerFailure
 247     (lazy ("Non-positive occurence in mutual inductive definition(s) [2]"^
 248      NUri.string_of_uri uri)))
 249 ;;
 250
 251 (* Inductive types being checked for positivity have *)
 252 (* indexes x s.t. n < x <= nn.                       *)
 253 let rec weakly_positive status ~subst context n nn uri indparamsno posuri te =
 254   (*CSC: Not very nice. *)
 255   let dummy = C.Sort C.Prop in
 256   (*CSC: to be moved in cicSubstitution? *)
 257   let rec subst_inductive_type_with_dummy _ = function
 258     | C.Meta (_,(_,C.Irl _)) as x -> x
 259     | C.Meta (i,(lift,C.Ctx ls)) ->
 260         C.Meta (i,(lift,C.Ctx
 261           (List.map (subst_inductive_type_with_dummy ()) ls)))
 262     | C.Const (Ref.Ref (uri',Ref.Ind (true,0,_))) when NUri.eq uri' uri -> dummy
 263     | C.Appl ((C.Const (Ref.Ref (uri',Ref.Ind (true,0,lno))))::tl)
 264         when NUri.eq uri' uri ->
 265           let _, rargs = HExtlib.split_nth lno tl in
 266           if rargs = [] then dummy else C.Appl (dummy :: rargs)
 267     | t -> U.map status (fun _ x->x) () subst_inductive_type_with_dummy t
 268   in
 269   (* this function has the same semantics of are_all_occurrences_positive
 270      but the i-th context entry role is played by dummy and some checks
 271      are skipped because we already know that are_all_occurrences_positive
 272      of uri in te. *)
 273   let rec aux context n nn te =
 274     match R.whd status ~subst context te with
 275      | t when t = dummy -> true
 276      | C.Meta (i,lc) ->
 277         (try
 278           let _,_,term,_ = U.lookup_subst i subst in
 279           let t = S.subst_meta status lc term in
 280            weakly_positive status ~subst context n nn uri indparamsno posuri t
 281          with U.Subst_not_found _ -> true)
 282      | C.Appl (te::rargs) when te = dummy ->
 283         List.for_all (does_not_occur status ~subst context n nn) rargs
 284      | C.Prod (name,source,dest) when
 285         does_not_occur status ~subst ((name,C.Decl source)::context) 0 1 dest ->
 286          (* dummy abstraction, so we behave as in the anonimous case *)
 287          strictly_positive status ~subst context n nn indparamsno posuri source &&
 288          aux ((name,C.Decl source)::context) (n + 1) (nn + 1) dest
 289      | C.Prod (name,source,dest) ->
 290          does_not_occur status ~subst context n nn source &&
 291          aux ((name,C.Decl source)::context) (n + 1) (nn + 1) dest
 292      | _ ->
 293        raise (TypeCheckerFailure (lazy "Malformed inductive constructor type"))
 294    in
 295      aux context n nn (subst_inductive_type_with_dummy () te)
 296
 297 and strictly_positive status ~subst context n nn indparamsno posuri te =
 298   match R.whd status ~subst context te with
 299    | t when does_not_occur status ~subst context n nn t -> true
 300    | C.Meta (i,lc) ->
 301       (try
 302         let _,_,term,_ = U.lookup_subst i subst in
 303         let t = S.subst_meta status lc term in
 304          strictly_positive status ~subst context n nn indparamsno posuri t
 305        with U.Subst_not_found _ -> true)
 306    | C.Rel _ when indparamsno = 0 -> true
 307    | C.Appl ((C.Rel m)::tl) as reduct when m > n && m <= nn ->
 308       check_homogeneous_call status ~subst context indparamsno n posuri reduct tl;
 309       List.for_all (does_not_occur status ~subst context n nn) tl
 310    | C.Prod (name,so,ta) ->
 311       does_not_occur status ~subst context n nn so &&
 312        strictly_positive status ~subst ((name,C.Decl so)::context) (n+1) (nn+1)
 313         indparamsno posuri ta
 314    | C.Appl (C.Const (Ref.Ref (uri,Ref.Ind _) as r)::tl) ->
 315       let _,paramsno,tyl,_,i = E.get_checked_indtys status r in
 316       let _,name,ity,cl = List.nth tyl i in
 317       let ok = List.length tyl = 1 in
 318       let params, arguments = HExtlib.split_nth paramsno tl in
 319       let lifted_params = List.map (S.lift status 1) params in
 320       let cl =
 321         List.map (fun (_,_,te) -> instantiate_parameters status lifted_params te) cl
 322       in
 323       ok &&
 324       List.for_all (does_not_occur status ~subst context n nn) arguments &&
 325       List.for_all
 326        (weakly_positive status ~subst ((name,C.Decl ity)::context) (n+1) (nn+1)
 327          uri indparamsno posuri) cl
 328    | _ -> false
 329
 330 (* the inductive type indexes are s.t. n < x <= nn *)
 331 and are_all_occurrences_positive (status:#NCic.status) ~subst context uri indparamsno i n nn te =
 332   match R.whd status ~subst context te with
 333   |  C.Appl ((C.Rel m)::tl) as reduct when m = i ->
 334       check_homogeneous_call status ~subst context indparamsno n uri reduct tl;
 335       List.for_all (does_not_occur status ~subst context n nn) tl
 336   | C.Rel m when m = i ->
 337       if indparamsno = 0 then
 338        true
 339       else
 340         raise (TypeCheckerFailure
 341          (lazy ("Non-positive occurence in mutual inductive definition(s) [3]"^
 342           NUri.string_of_uri uri)))
 343    | C.Prod (name,source,dest) when
 344       does_not_occur status ~subst ((name,C.Decl source)::context) 0 1 dest ->
 345       strictly_positive status ~subst context n nn indparamsno uri source &&
 346        are_all_occurrences_positive status ~subst
 347         ((name,C.Decl source)::context) uri indparamsno
 348         (i+1) (n + 1) (nn + 1) dest
 349    | C.Prod (name,source,dest) ->
 350        if not (does_not_occur status ~subst context n nn source) then
 351          raise (TypeCheckerFailure (lazy ("Non-positive occurrence in "^
 352          status#ppterm ~context ~metasenv:[] ~subst te)));
 353        are_all_occurrences_positive status ~subst ((name,C.Decl source)::context)
 354         uri indparamsno (i+1) (n + 1) (nn + 1) dest
 355    | _ ->
 356      raise
 357       (TypeCheckerFailure (lazy ("Malformed inductive constructor type " ^
 358         (NUri.string_of_uri uri))))
 359 ;;
 360
 361 exception NotGuarded of string Lazy.t;;
 362
 363 let type_of_branch (status:#NCic.status) ~subst context leftno outty cons tycons =
 364  let rec aux liftno context cons tycons =
 365    match R.whd status ~subst context tycons with
 366    | C.Const (Ref.Ref (_,Ref.Ind _)) -> C.Appl [S.lift status liftno outty ; cons]
 367    | C.Appl (C.Const (Ref.Ref (_,Ref.Ind _))::tl) ->
 368        let _,arguments = HExtlib.split_nth leftno tl in
 369        C.Appl (S.lift status liftno outty::arguments@[cons])
 370    | C.Prod (name,so,de) ->
 371        let cons =
 372         match S.lift status 1 cons with
 373         | C.Appl l -> C.Appl (l@[C.Rel 1])
 374         | t -> C.Appl [t ; C.Rel 1]
 375        in
 376         C.Prod (name,so, aux (liftno+1) ((name,(C.Decl so))::context) cons de)
 377    | t -> raise (AssertFailure
 378       (lazy ("type_of_branch, the contructor has type: " ^ status#ppterm
 379        ~metasenv:[] ~context:[] ~subst:[] t)))
 380  in
 381   aux 0 context cons tycons
 382 ;;
 383
 384
 385 let rec typeof (status:#NCic.status) ~subst ~metasenv context term =
 386   let rec typeof_aux context =
 387     fun t -> (*prerr_endline (status#ppterm ~metasenv ~subst ~context t);*)
 388     match t with
 389     | C.Rel n ->
 390        (try
 391          match List.nth context (n - 1) with
 392          | (_,C.Decl ty) -> S.lift status n ty
 393          | (_,C.Def (_,ty)) -> S.lift status n ty
 394         with Failure _ | Invalid_argument _ ->
 395           raise (TypeCheckerFailure (lazy ("unbound variable " ^ string_of_int n
 396             ^" under: " ^ status#ppcontext ~metasenv ~subst context))))
 397     | C.Sort s ->
 398          (try C.Sort (NCicEnvironment.typeof_sort s)
 399          with
 400          | NCicEnvironment.UntypableSort msg -> raise (TypeCheckerFailure msg)
 401          | NCicEnvironment.AssertFailure msg -> raise (AssertFailure msg))
 402     | C.Implicit _ -> raise (AssertFailure (lazy "Implicit found"))
 403     | C.Meta (n,l) as t ->
 404        let canonical_ctx,ty =
 405         try
 406          let _,c,_,ty = U.lookup_subst n subst in c,ty
 407         with U.Subst_not_found _ -> try
 408          let _,c,ty = U.lookup_meta n metasenv in c, ty
 409 (*          match ty with C.Implicit _ -> assert false | _ -> c,ty *)
 410         with U.Meta_not_found _ ->
 411          raise (AssertFailure (lazy (Printf.sprintf
 412           "%s not found in:\n%s" (status#ppterm ~subst ~metasenv ~context t)
 413            (status#ppmetasenv ~subst metasenv)
 414           )))
 415        in
 416         check_metasenv_consistency t ~subst ~metasenv context canonical_ctx l;
 417         S.subst_meta status l ty
 418     | C.Const ref -> type_of_constant status ref
 419     | C.Prod (name,s,t) ->
 420        let sort1 = typeof_aux context s in
 421        let sort2 = typeof_aux ((name,(C.Decl s))::context) t in
 422        sort_of_prod status ~metasenv ~subst context (name,s) t (sort1,sort2)
 423     | C.Lambda (n,s,t) ->
 424        let sort = typeof_aux context s in
 425        (match R.whd status ~subst context sort with
 426        | C.Meta _ | C.Sort _ -> ()
 427        | _ ->
 428          raise
 429            (TypeCheckerFailure (lazy (Printf.sprintf
 430              ("Not well-typed lambda-abstraction: " ^^
 431              "the source %s should be a type; instead it is a term " ^^
 432              "of type %s") (status#ppterm ~subst ~metasenv ~context s)
 433              (status#ppterm ~subst ~metasenv ~context sort)))));
 434        let ty = typeof_aux ((n,(C.Decl s))::context) t in
 435          C.Prod (n,s,ty)
 436     | C.LetIn (n,ty,t,bo) ->
 437        let ty_t = typeof_aux context t in
 438        let _ = typeof_aux context ty in
 439        if not (R.are_convertible status ~metasenv ~subst context ty_t ty) then
 440          raise
 441           (TypeCheckerFailure
 442             (lazy (Printf.sprintf
 443               "The type of %s is %s but it is expected to be %s"
 444                 (status#ppterm ~subst ~metasenv ~context t)
 445                 (status#ppterm ~subst ~metasenv ~context ty_t)
 446                 (status#ppterm ~subst ~metasenv ~context ty))))
 447        else
 448          let ty_bo = typeof_aux  ((n,C.Def (t,ty))::context) bo in
 449          S.subst status ~avoid_beta_redexes:true t ty_bo
 450     | C.Appl (he::(_::_ as args)) ->
 451        let ty_he = typeof_aux context he in
 452        let args_with_ty = List.map (fun t -> t, typeof_aux context t) args in
 453        eat_prods status ~subst ~metasenv context he ty_he args_with_ty
 454    | C.Appl _ -> raise (AssertFailure (lazy "Appl of length < 2"))
 455    | C.Match (Ref.Ref (_,Ref.Ind (_,tyno,_)) as r,outtype,term,pl) ->
 456       let outsort = typeof_aux context outtype in
 457       let _,leftno,itl,_,_ = E.get_checked_indtys status r in
 458       let constructorsno =
 459         let _,_,_,cl = List.nth itl tyno in List.length cl
 460       in
 461       let parameters, arguments =
 462         let ty = R.whd status ~subst context (typeof_aux context term) in
 463         let r',tl =
 464          match ty with
 465             C.Const (Ref.Ref (_,Ref.Ind _) as r') -> r',[]
 466           | C.Appl (C.Const (Ref.Ref (_,Ref.Ind _) as r') :: tl) -> r',tl
 467           | _ ->
 468              raise
 469                (TypeCheckerFailure (lazy (Printf.sprintf
 470                  "Case analysis: analysed term %s is not an inductive one"
 471                  (status#ppterm ~subst ~metasenv ~context term)))) in
 472         if not (Ref.eq r r') then
 473          raise
 474           (TypeCheckerFailure (lazy (Printf.sprintf
 475             ("Case analysys: analysed term type is %s, but is expected " ^^
 476              "to be (an application of) %s")
 477             (status#ppterm ~subst ~metasenv ~context ty)
 478             (status#ppterm ~subst ~metasenv ~context (C.Const r')))))
 479         else
 480          try HExtlib.split_nth leftno tl
 481          with
 482           Failure _ ->
 483            raise (TypeCheckerFailure (lazy (Printf.sprintf
 484            "%s is partially applied"
 485            (status#ppterm  ~subst ~metasenv ~context ty)))) in
 486       (* let's control if the sort elimination is allowed: [(I q1 ... qr)|B] *)
 487       let sort_of_ind_type =
 488         if parameters = [] then C.Const r
 489         else C.Appl ((C.Const r)::parameters) in
 490       let type_of_sort_of_ind_ty = typeof_aux context sort_of_ind_type in
 491       check_allowed_sort_elimination status ~subst ~metasenv r context
 492        sort_of_ind_type type_of_sort_of_ind_ty outsort;
 493       (* let's check if the type of branches are right *)
 494       if List.length pl <> constructorsno then
 495        raise (TypeCheckerFailure (lazy ("Wrong number of cases in a match")));
 496       let j,branches_ok,p_ty, exp_p_ty =
 497         List.fold_left
 498           (fun (j,b,old_p_ty,old_exp_p_ty) p ->
 499             if b then
 500               let cons =
 501                 let cons = Ref.mk_constructor j r in
 502                 if parameters = [] then C.Const cons
 503                 else C.Appl (C.Const cons::parameters)
 504               in
 505               let ty_p = typeof_aux context p in
 506               let ty_cons = typeof_aux context cons in
 507               let ty_branch =
 508                 type_of_branch status ~subst context leftno outtype cons ty_cons
 509               in
 510               j+1, R.are_convertible status ~metasenv ~subst context ty_p ty_branch,
 511               ty_p, ty_branch
 512             else
 513               j,false,old_p_ty,old_exp_p_ty
 514           ) (1,true,C.Sort C.Prop,C.Sort C.Prop) pl
 515       in
 516       if not branches_ok then
 517         raise
 518          (TypeCheckerFailure
 519           (lazy (Printf.sprintf ("Branch for constructor %s :=\n%s\n"^^
 520           "has type %s\nnot convertible with %s")
 521           (status#ppterm  ~subst ~metasenv ~context
 522             (C.Const (Ref.mk_constructor (j-1) r)))
 523           (status#ppterm ~metasenv ~subst ~context (List.nth pl (j-2)))
 524           (status#ppterm ~metasenv ~subst ~context p_ty)
 525           (status#ppterm ~metasenv ~subst ~context exp_p_ty))));
 526       let res = outtype::arguments@[term] in
 527       R.head_beta_reduce status (C.Appl res)
 528     | C.Match _ -> assert false
 529
 530   (* check_metasenv_consistency checks that the "canonical" context of a
 531      metavariable is consitent - up to relocation via the relocation list l -
 532      with the actual context *)
 533   and check_metasenv_consistency
 534     ~subst ~metasenv term context canonical_context l
 535   =
 536    match l with
 537     | shift, C.Irl n ->
 538        let context = snd (HExtlib.split_nth shift context) in
 539         let rec compare = function
 540          | 0,_,[] -> ()
 541          | 0,_,_::_
 542          | _,_,[] ->
 543             raise (AssertFailure (lazy (Printf.sprintf
 544              "(2) Local and canonical context %s have different lengths"
 545              (status#ppterm ~subst ~context ~metasenv term))))
 546          | m,[],_::_ ->
 547             raise (TypeCheckerFailure (lazy (Printf.sprintf
 548              "Unbound variable -%d in %s" m
 549              (status#ppterm ~subst ~metasenv ~context term))))
 550          | m,t::tl,ct::ctl ->
 551             (match t,ct with
 552                 (_,C.Decl t1), (_,C.Decl t2)
 553               | (_,C.Def (t1,_)), (_,C.Def (t2,_))
 554               | (_,C.Def (_,t1)), (_,C.Decl t2) ->
 555                  if not (R.are_convertible status ~metasenv ~subst tl t1 t2) then
 556                   raise
 557                       (TypeCheckerFailure
 558                         (lazy (Printf.sprintf
 559                       ("Not well typed metavariable local context for %s: " ^^
 560                        "%s expected, which is not convertible with %s")
 561                       (status#ppterm ~subst ~metasenv ~context term)
 562                       (status#ppterm ~subst ~metasenv ~context t2)
 563                       (status#ppterm ~subst ~metasenv ~context t1))))
 564               | _,_ ->
 565                raise
 566                    (TypeCheckerFailure (lazy (Printf.sprintf
 567                     ("Not well typed metavariable local context for %s: " ^^
 568                      "a definition expected, but a declaration found")
 569                     (status#ppterm ~subst ~metasenv ~context term)))));
 570             compare (m - 1,tl,ctl)
 571         in
 572          compare (n,context,canonical_context)
 573     | shift, lc_kind ->
 574        (* we avoid useless lifting by shortening the context*)
 575        let l,context = (0,lc_kind), snd (HExtlib.split_nth shift context) in
 576        let lifted_canonical_context =
 577          let rec lift_metas i = function
 578            | [] -> []
 579            | (n,C.Decl t)::tl ->
 580                (n,C.Decl (S.subst_meta status l (S.lift status i t)))::(lift_metas (i+1) tl)
 581            | (n,C.Def (t,ty))::tl ->
 582                (n,C.Def ((S.subst_meta status l (S.lift status i t)),
 583                           S.subst_meta status l (S.lift status i ty)))::(lift_metas (i+1) tl)
 584          in
 585           lift_metas 1 canonical_context in
 586        let l = U.expand_local_context lc_kind in
 587        try
 588         List.iter2
 589         (fun t ct ->
 590           match (t,ct) with
 591           | t, (_,C.Def (ct,_)) ->
 592              (*CSC: the following optimization is to avoid a possibly expensive
 593                     reduction that can be easily avoided and that is quite
 594                     frequent. However, this is better handled using levels to
 595                     control reduction *)
 596              let optimized_t =
 597               match t with
 598               | C.Rel n ->
 599                   (try
 600                     match List.nth context (n - 1) with
 601                     | (_,C.Def (te,_)) -> S.lift status n te
 602                     | _ -> t
 603                     with Failure _ -> t)
 604               | _ -> t
 605              in
 606              if not (R.are_convertible status ~metasenv ~subst context optimized_t ct)
 607              then
 608                raise
 609                  (TypeCheckerFailure
 610                    (lazy (Printf.sprintf
 611                      ("Not well typed metavariable local context: " ^^
 612                       "expected a term convertible with %s, found %s")
 613                      (status#ppterm ~subst ~metasenv ~context ct)
 614                      (status#ppterm ~subst ~metasenv ~context t))))
 615           | t, (_,C.Decl ct) ->
 616               let type_t = typeof_aux context t in
 617               if not (R.are_convertible status ~metasenv ~subst context type_t ct) then
 618                 raise (TypeCheckerFailure
 619                  (lazy (Printf.sprintf
 620                   ("Not well typed metavariable local context: "^^
 621                   "expected a term of type %s, found %s of type %s")
 622                   (status#ppterm ~subst ~metasenv ~context ct)
 623                   (status#ppterm ~subst ~metasenv ~context t)
 624                   (status#ppterm ~subst ~metasenv ~context type_t))))
 625         ) l lifted_canonical_context
 626        with
 627        | Invalid_argument "List.iter2" ->
 628           raise (AssertFailure (lazy (Printf.sprintf
 629            "(1) Local and canonical context %s have different lengths"
 630            (status#ppterm ~subst ~metasenv ~context term))))
 631
 632  in
 633    typeof_aux context term
 634
 635 and check_allowed_sort_elimination status ~subst ~metasenv r =
 636   let mkapp he arg =
 637     match he with
 638     | C.Appl l -> C.Appl (l @ [arg])
 639     | t -> C.Appl [t;arg] in
 640   let rec aux context ind arity1 arity2 =
 641    let arity1 = R.whd status ~subst context arity1 in
 642    let arity2 = R.whd status ~subst context arity2 in
 643      match arity1,arity2 with
 644       | C.Prod (name,so1,de1), C.Prod (_,so2,de2) ->
 645          if not (R.are_convertible status ~metasenv ~subst context so1 so2) then
 646           raise (TypeCheckerFailure (lazy (Printf.sprintf
 647            "In outtype: expected %s, found %s"
 648            (status#ppterm ~subst ~metasenv ~context so1)
 649            (status#ppterm ~subst ~metasenv ~context so2)
 650            )));
 651          aux ((name, C.Decl so1)::context)
 652           (mkapp (S.lift status 1 ind) (C.Rel 1)) de1 de2
 653       | C.Sort _, C.Prod (name,so,ta) ->
 654          if not (R.are_convertible status ~metasenv ~subst context so ind) then
 655           raise (TypeCheckerFailure (lazy (Printf.sprintf
 656            "In outtype: expected %s, found %s"
 657            (status#ppterm ~subst ~metasenv ~context ind)
 658            (status#ppterm ~subst ~metasenv ~context so)
 659            )));
 660          (match arity1, R.whd status ~subst ((name,C.Decl so)::context) ta with
 661            | C.Sort s1, (C.Sort s2 as arity2) ->
 662                (match NCicEnvironment.allowed_sort_elimination s1 s2 with
 663                | `Yes -> ()
 664                | `UnitOnly ->
 665        (* TODO: we should pass all these parameters since we
 666         * have them already *)
 667                let _,leftno,itl,_,i = E.get_checked_indtys status r in
 668                let itl_len = List.length itl in
 669                let _,itname,ittype,cl = List.nth itl i in
 670                let cl_len = List.length cl in
 671                 (* is it a singleton, non recursive and non informative
 672                    definition or an empty one? *)
 673                 if not
 674                  (cl_len = 0 ||
 675                   (itl_len = 1 && cl_len = 1 &&
 676                    let _,_,constrty = List.hd cl in
 677                      is_non_recursive_singleton status
 678                        ~subst r itname ittype constrty &&
 679                      is_non_informative status ~metasenv ~subst leftno constrty))
 680                 then
 681                  raise (TypeCheckerFailure (lazy
 682                   ("Sort elimination not allowed: " ^
 683                    status#ppterm ~metasenv ~subst ~context arity1
 684                    ^ " towards "^
 685                    status#ppterm ~metasenv ~subst ~context arity2
 686                  ))))
 687            | _ -> ())
 688       | _,_ -> ()
 689   in
 690    aux
 691
 692 and eat_prods status ~subst ~metasenv context he ty_he args_with_ty =
 693   let rec aux ty_he = function
 694   | [] -> ty_he
 695   | (arg, ty_arg)::tl ->
 696       match R.whd status ~subst context ty_he with
 697       | C.Prod (_,s,t) ->
 698           if R.are_convertible status ~metasenv ~subst context ty_arg s then
 699             aux (S.subst status ~avoid_beta_redexes:true arg t) tl
 700           else
 701            let indent s = "   " ^ (Str.global_replace (Str.regexp "\n") "\n   " s) in
 702             raise
 703               (TypeCheckerFailure
 704                 (lazy (Printf.sprintf
 705                   ("Appl: wrong application of\n%s\nThe argument\n%s\nhas type"^^
 706                    "\n%s\nbut it should have type \n%s\nContext:\n%s\n")
 707                   (indent (status#ppterm ~subst ~metasenv ~context he))
 708                   (indent (status#ppterm ~subst ~metasenv ~context arg))
 709                   (indent (status#ppterm ~subst ~metasenv ~context ty_arg))
 710                   (indent (status#ppterm ~subst ~metasenv ~context s))
 711                   (status#ppcontext ~subst ~metasenv context))))
 712        | _ ->
 713           raise
 714             (TypeCheckerFailure
 715               (lazy (Printf.sprintf
 716                 "Appl: %s is not a function, it cannot be applied"
 717                 (status#ppterm ~subst ~metasenv ~context
 718                  (let res = List.length tl in
 719                   let eaten = List.length args_with_ty - res in
 720                    (C.Appl
 721                     (he::List.map fst
 722                      (fst (HExtlib.split_nth eaten args_with_ty)))))))))
 723   in
 724     aux ty_he args_with_ty
 725
 726 and is_non_recursive_singleton status ~subst (Ref.Ref (uri,_)) iname ity cty =
 727      let ctx = [iname, C.Decl ity] in
 728      let cty = debruijn status uri 1 [] ~subst cty in
 729      let len = List.length ctx in
 730      let rec aux ctx n nn t =
 731        match R.whd status ~subst ctx t with
 732        | C.Prod (name, src, tgt) ->
 733             does_not_occur status ~subst ctx n nn src &&
 734              aux ((name, C.Decl src) :: ctx) (n+1) (nn+1) tgt
 735        | C.Rel k | C.Appl (C.Rel k :: _) when k = nn -> true
 736        | _ -> assert false
 737      in
 738      aux ctx (len-1) len cty
 739
 740 and is_non_informative status ~metasenv ~subst paramsno c =
 741  let rec aux context c =
 742    match R.whd status ~subst context c with
 743     | C.Prod (n,so,de) ->
 744        let s = typeof status ~metasenv ~subst context so in
 745        (s = C.Sort C.Prop ||
 746         match s with C.Sort (C.Type ((`CProp,_)::_)) -> true | _ -> false) &&
 747        aux ((n,(C.Decl so))::context) de
 748     | _ -> true in
 749  let context',dx = NCicReduction.split_prods status ~subst [] paramsno c in
 750   aux context' dx
 751
 752 and check_mutual_inductive_defs status uri ~metasenv ~subst leftno tyl =
 753   (* let's check if the arity of the inductive types are well formed *)
 754   List.iter (fun (_,_,x,_) -> ignore (typeof status ~subst ~metasenv [] x)) tyl;
 755   (* let's check if the types of the inductive constructors are well formed. *)
 756   let len = List.length tyl in
 757   let tys = List.rev_map (fun (_,n,ty,_) -> (n,(C.Decl ty))) tyl in
 758   ignore
 759    (List.fold_right
 760     (fun (it_relev,_,ty,cl) i ->
 761        let context,ty_sort = NCicReduction.split_prods status ~subst [] ~-1 ty in
 762        let sx_context_ty_rev,_ = HExtlib.split_nth leftno (List.rev context) in
 763        List.iter
 764          (fun (k_relev,_,te) ->
 765            let k_relev =
 766             try snd (HExtlib.split_nth leftno k_relev)
 767             with Failure _ -> k_relev in
 768            let te = debruijn status uri len [] ~subst te in
 769            let context,te = NCicReduction.split_prods status ~subst tys leftno te in
 770            let _,chopped_context_rev =
 771             HExtlib.split_nth (List.length tys) (List.rev context) in
 772            let sx_context_te_rev,_ =
 773             HExtlib.split_nth leftno chopped_context_rev in
 774            (try
 775              ignore (List.fold_left2
 776               (fun context item1 item2 ->
 777                 let convertible =
 778                  match item1,item2 with
 779                    (_,C.Decl ty1),(_,C.Decl ty2) ->
 780                      R.are_convertible status ~metasenv ~subst context ty1 ty2
 781                  | (_,C.Def (bo1,ty1)),(_,C.Def (bo2,ty2)) ->
 782                      R.are_convertible status ~metasenv ~subst context ty1 ty2 &&
 783                       R.are_convertible status ~metasenv ~subst context bo1 bo2
 784                  | _,_ -> false
 785                 in
 786                  if not convertible then
 787                   raise (TypeCheckerFailure (lazy
 788                    ("Mismatch between the left parameters of the constructor " ^
 789                     "and those of its inductive type")))
 790                  else
 791                   item1::context
 792               ) [] sx_context_ty_rev sx_context_te_rev)
 793             with Invalid_argument "List.fold_left2" -> assert false);
 794            let con_sort = typeof status ~subst ~metasenv context te in
 795            (match R.whd status ~subst context con_sort, R.whd status ~subst [] ty_sort with
 796                (C.Sort (C.Type u1) as s1), (C.Sort (C.Type u2) as s2) ->
 797                 if not (E.universe_leq u1 u2) then
 798                  raise
 799                   (TypeCheckerFailure
 800                     (lazy ("The type " ^ status#ppterm ~metasenv ~subst ~context s1^
 801                       " of the constructor is not included in the inductive" ^
 802                       " type sort " ^ status#ppterm ~metasenv ~subst ~context s2)))
 803              | C.Sort _, C.Sort C.Prop
 804              | C.Sort _, C.Sort C.Type _ -> ()
 805              | _, _ ->
 806                 raise
 807                  (TypeCheckerFailure
 808                    (lazy ("Wrong constructor or inductive arity shape"))));
 809            (* let's check also the positivity conditions *)
 810            if
 811              not
 812                (are_all_occurrences_positive status ~subst context uri leftno
 813                  (i+leftno) leftno (len+leftno) te)
 814            then
 815              raise
 816                (TypeCheckerFailure
 817                  (lazy ("Non positive occurence in "^NUri.string_of_uri
 818                  uri)))
 819            else check_relevance status ~subst ~metasenv context k_relev te)
 820          cl;
 821         check_relevance status ~subst ~metasenv [] it_relev ty;
 822         i+1)
 823     tyl 1)
 824
 825 and check_relevance status ~subst ~metasenv context relevance ty =
 826   let error context ty =
 827     raise (TypeCheckerFailure
 828      (lazy ("Wrong relevance declaration: " ^
 829      String.concat "," (List.map string_of_bool relevance)^
 830      "\nfor type: "^status#ppterm ~metasenv ~subst ~context ty)))
 831   in
 832   let rec aux context relevance ty =
 833     match R.whd status ~subst context ty with
 834     | C.Prod (name,so,de) ->
 835         let sort = typeof status ~subst ~metasenv context so in
 836         (match (relevance,R.whd status ~subst context sort) with
 837           | [],_ -> ()
 838           | false::tl,C.Sort C.Prop -> aux ((name,(C.Decl so))::context) tl de
 839           | true::_,C.Sort C.Prop
 840           | false::_,C.Sort _
 841           | false::_,C.Meta _ -> error context ty
 842           | true::tl,C.Sort _
 843           | true::tl,C.Meta _ -> aux ((name,(C.Decl so))::context) tl de
 844           | _ -> raise (AssertFailure (lazy (Printf.sprintf
 845                  "Prod: the type %s of the source of %s is not a sort"
 846                   (status#ppterm ~subst ~metasenv ~context sort)
 847                   (status#ppterm ~subst ~metasenv ~context so)))))
 848     | _ -> (match relevance with
 849       | [] -> ()
 850       | _::_ -> error context ty)
 851   in aux context relevance ty
 852
 853 and guarded_by_destructors (status:#NCic.status) r_uri r_len ~subst ~metasenv context recfuns t =
 854  let recursor f k t = U.fold shift_k k (fun k () -> f k) () t in
 855  let rec aux (context, recfuns, x as k) t =
 856 (*
 857    prerr_endline ("GB:\n" ^
 858      status#ppcontext ~subst ~metasenv context^
 859      status#ppterm ~metasenv ~subst ~context t^
 860        string_of_recfuns ~subst ~metasenv ~context recfuns);
 861 *)
 862   try
 863   match t with
 864   | C.Rel m as t when is_dangerous m recfuns ->
 865       raise (NotGuarded (lazy
 866         (status#ppterm ~subst ~metasenv ~context t ^
 867          " is a partial application of a fix")))
 868   | C.Appl ((C.Rel m)::tl) as t when is_dangerous m recfuns ->
 869      let rec_no = get_recno m recfuns in
 870      if not (List.length tl > rec_no) then
 871        raise (NotGuarded (lazy
 872          (status#ppterm ~context ~subst ~metasenv t ^
 873          " is a partial application of a fix")))
 874      else
 875        let rec_arg = List.nth tl rec_no in
 876        if not (is_really_smaller status r_uri r_len ~subst ~metasenv k rec_arg) then
 877          raise (NotGuarded (lazy (Printf.sprintf ("Recursive call %s, %s is not"
 878           ^^ " smaller.\ncontext:\n%s") (status#ppterm ~context ~subst ~metasenv
 879           t) (status#ppterm ~context ~subst ~metasenv rec_arg)
 880           (status#ppcontext ~subst ~metasenv context))));
 881        List.iter (aux k) tl
 882   | C.Appl ((C.Rel m)::tl) when is_unfolded m recfuns ->
 883        let fixed_args = get_fixed_args m recfuns in
 884        HExtlib.list_iter_default2
 885         (fun x b -> if not b then aux k x) tl false fixed_args
 886   | C.Rel m ->
 887      (match List.nth context (m-1) with
 888      | _,C.Decl _ -> ()
 889      | _,C.Def (bo,_) -> aux k (S.lift status m bo))
 890   | C.Meta _ -> ()
 891   | C.Appl (C.Const ((Ref.Ref (uri,Ref.Fix (i,recno,_))) as r)::args) ->
 892       if List.exists (fun t -> try aux k t;false with NotGuarded _ -> true) args
 893       then
 894       let fl,_,_ = E.get_checked_fixes_or_cofixes status r in
 895       let ctx_tys, bos =
 896         List.split (List.map (fun (_,name,_,ty,bo) -> (name, C.Decl ty), bo) fl)
 897       in
 898       let fl_len = List.length fl in
 899       let bos = List.map (debruijn status uri fl_len context ~subst) bos in
 900       let j = List.fold_left min max_int (List.map (fun (_,_,i,_,_)->i) fl) in
 901       let ctx_len = List.length context in
 902         (* we may look for fixed params not only up to j ... *)
 903       let fa = fixed_args bos j ctx_len (ctx_len + fl_len) in
 904       HExtlib.list_iter_default2
 905        (fun x b -> if not b then aux k x) args false fa;
 906       let context = context@ctx_tys in
 907       let ctx_len = List.length context in
 908       let extra_recfuns =
 909         HExtlib.list_mapi (fun _ i -> ctx_len - i, UnfFix fa) ctx_tys
 910       in
 911       let new_k = context, extra_recfuns@recfuns, x in
 912       let bos_and_ks =
 913         HExtlib.list_mapi
 914          (fun bo fno ->
 915           let bo_and_k =
 916             eat_or_subst_lambdas status ~subst ~metasenv j bo fa args new_k
 917           in
 918            if
 919             fno = i &&
 920             List.length args > recno &&
 921             (*case where the recursive argument is already really_smaller *)
 922             is_really_smaller status r_uri r_len ~subst ~metasenv k
 923              (List.nth args recno)
 924            then
 925             let bo,(context, _, _ as new_k) = bo_and_k in
 926             let bo, context' =
 927              eat_lambdas status ~subst ~metasenv context (recno + 1 - j) bo in
 928             let new_context_part,_ =
 929              HExtlib.split_nth (List.length context' - List.length context)
 930               context' in
 931             let k = List.fold_right shift_k new_context_part new_k in
 932             let context, recfuns, x = k in
 933             let k = context, (1,Safe)::recfuns, x in
 934               bo,k
 935            else
 936             bo_and_k
 937          ) bos
 938       in
 939        List.iter (fun (bo,k) -> aux k bo) bos_and_ks
 940   | C.Match (Ref.Ref (_,Ref.Ind (true,_,_)),outtype,term,pl) as t ->
 941      (match R.whd status ~subst context term with
 942      | C.Rel m | C.Appl (C.Rel m :: _ ) as t when is_safe m recfuns || m = x ->
 943          let ty = typeof status ~subst ~metasenv context term in
 944          let dc_ctx, dcl, start, stop =
 945            specialize_and_abstract_constrs status ~subst r_uri r_len context ty in
 946          let args = match t with C.Appl (_::tl) -> tl | _ -> [] in
 947          aux k outtype;
 948          List.iter (aux k) args;
 949          List.iter2
 950            (fun p (_,dc) ->
 951              let rl = recursive_args status ~subst ~metasenv dc_ctx start stop dc in
 952              let p, k = get_new_safes status ~subst k p rl in
 953              aux k p)
 954            pl dcl
 955      | _ -> recursor aux k t)
 956   | t -> recursor aux k t
 957   with
 958    NotGuarded _ as exc ->
 959     let t' = R.whd status ~delta:0 ~subst context t in
 960     if t = t' then raise exc
 961     else aux k t'
 962  in
 963   try aux (context, recfuns, 1) t
 964   with NotGuarded s -> raise (TypeCheckerFailure s)
 965
 966 and guarded_by_constructors status ~subst ~metasenv context t indURI indlen nn =
 967  let rec aux context n nn h te =
 968   match R.whd status ~subst context te with
 969    | C.Rel m when m > n && m <= nn -> h
 970    | C.Rel _ | C.Meta _ -> true
 971    | C.Sort _
 972    | C.Implicit _
 973    | C.Prod _
 974    | C.Const (Ref.Ref (_,Ref.Ind _))
 975    | C.LetIn _ -> raise (AssertFailure (lazy "17"))
 976    | C.Lambda (name,so,de) ->
 977       does_not_occur status ~subst context n nn so &&
 978       aux ((name,C.Decl so)::context) (n + 1) (nn + 1) h de
 979    | C.Appl ((C.Rel m)::tl) when m > n && m <= nn ->
 980       h && List.for_all (does_not_occur status ~subst context n nn) tl
 981    | C.Const (Ref.Ref (_,Ref.Con _)) -> true
 982    | C.Appl (C.Const (Ref.Ref (_, Ref.Con (_,j,paramsno))) :: tl) as t ->
 983       let ty_t = typeof status ~subst ~metasenv context t in
 984       let dc_ctx, dcl, start, stop =
 985         specialize_and_abstract_constrs status ~subst indURI indlen context ty_t in
 986       let _, dc = List.nth dcl (j-1) in
 987 (*
 988         prerr_endline (status#ppterm ~subst ~metasenv ~context:dc_ctx dc);
 989         prerr_endline (status#ppcontext ~subst ~metasenv dc_ctx);
 990  *)
 991       let rec_params = recursive_args status ~subst ~metasenv dc_ctx start stop dc in
 992       let rec analyse_instantiated_type rec_spec args =
 993        match rec_spec, args with
 994        | h::rec_spec, he::args ->
 995            aux context n nn h he && analyse_instantiated_type rec_spec args
 996        | _,[] -> true
 997        | _ -> raise (AssertFailure (lazy
 998          ("Too many args for constructor: " ^ String.concat " "
 999          (List.map (fun x-> status#ppterm ~subst ~metasenv ~context x) args))))
1000       in
1001       let _, args = HExtlib.split_nth paramsno tl in
1002       analyse_instantiated_type rec_params args
1003    | C.Appl ((C.Match (_,out,te,pl))::_)
1004    | C.Match (_,out,te,pl) as t ->
1005        let tl = match t with C.Appl (_::tl) -> tl | _ -> [] in
1006        List.for_all (does_not_occur status ~subst context n nn) tl &&
1007        does_not_occur status ~subst context n nn out &&
1008        does_not_occur status ~subst context n nn te &&
1009        List.for_all (aux context n nn h) pl
1010 (* IMPOSSIBLE unsless we allow to pass cofix to other fix/cofix as we do for
1011    higher order fix in g_b_destructors.
1012
1013    | C.Const (Ref.Ref (u,(Ref.Fix _| Ref.CoFix _)) as ref)
1014    | C.Appl(C.Const (Ref.Ref(u,(Ref.Fix _| Ref.CoFix _)) as ref) :: _) as t ->
1015       let tl = match t with C.Appl (_::tl) -> tl | _ -> [] in
1016       let fl,_,_ = E.get_checked_fixes_or_cofixes ref in
1017       let len = List.length fl in
1018       let tys = List.map (fun (_,n,_,ty,_) -> n, C.Decl ty) fl in
1019       List.for_all (does_not_occur status ~subst context n nn) tl &&
1020       List.for_all
1021        (fun (_,_,_,_,bo) ->
1022           aux (context@tys) n nn h (debruijn status u len context bo))
1023        fl
1024 *)
1025    | C.Const _
1026    | C.Appl _ as t -> does_not_occur status ~subst context n nn t
1027  in
1028    aux context 0 nn false t
1029
1030 and recursive_args status ~subst ~metasenv context n nn te =
1031   match R.whd status ~subst context te with
1032   | C.Rel _ | C.Appl _ | C.Const _ -> []
1033   | C.Prod (name,so,de) ->
1034      (not (does_not_occur status ~subst context n nn so)) ::
1035       (recursive_args status ~subst ~metasenv
1036         ((name,(C.Decl so))::context) (n+1) (nn + 1) de)
1037   | t ->
1038      raise (AssertFailure (lazy ("recursive_args:" ^ status#ppterm ~subst
1039      ~metasenv ~context:[] t)))
1040
1041 and get_new_safes status ~subst (context, recfuns, x as k) p rl =
1042   match R.whd status ~subst context p, rl with
1043   | C.Lambda (name,so,ta), b::tl ->
1044       let recfuns = (if b then [0,Safe] else []) @ recfuns in
1045       get_new_safes status ~subst
1046         (shift_k (name,(C.Decl so)) (context, recfuns, x)) ta tl
1047   | C.Meta _ as e, _ | e, [] -> e, k
1048   | _ -> raise (AssertFailure (lazy "Ill formed pattern"))
1049
1050 and is_really_smaller status
1051   r_uri r_len ~subst ~metasenv (context, recfuns, x as k) te
1052 =
1053  match R.whd status ~subst context te with
1054  | C.Rel m when is_safe m recfuns -> true
1055  | C.Lambda (name, s, t) ->
1056     is_really_smaller status r_uri r_len ~subst ~metasenv (shift_k (name,C.Decl s) k) t
1057  | C.Appl (he::_) ->
1058     is_really_smaller status r_uri r_len ~subst ~metasenv k he
1059  | C.Appl [] | C.Implicit _ -> assert false
1060  | C.Meta _ -> true
1061  | C.Match (Ref.Ref (_,Ref.Ind (isinductive,_,_)),_,term,pl) ->
1062     (match term with
1063     | C.Rel m | C.Appl (C.Rel m :: _ ) when is_safe m recfuns || m = x ->
1064         if not isinductive then
1065           List.for_all (is_really_smaller status r_uri r_len ~subst ~metasenv k) pl
1066         else
1067           let ty = typeof status ~subst ~metasenv context term in
1068           let dc_ctx, dcl, start, stop =
1069             specialize_and_abstract_constrs status ~subst r_uri r_len context ty in
1070           List.for_all2
1071            (fun p (_,dc) ->
1072              let rl = recursive_args status ~subst ~metasenv dc_ctx start stop dc in
1073              let e, k = get_new_safes status ~subst k p rl in
1074              is_really_smaller status r_uri r_len ~subst ~metasenv k e)
1075            pl dcl
1076     | _ -> List.for_all (is_really_smaller status r_uri r_len ~subst ~metasenv k) pl)
1077  | _ -> false
1078
1079 and returns_a_coinductive status ~subst context ty =
1080   match R.whd status ~subst context ty with
1081   | C.Const (Ref.Ref (uri,Ref.Ind (false,_,_)) as ref)
1082   | C.Appl (C.Const (Ref.Ref (uri,Ref.Ind (false,_,_)) as ref)::_) ->
1083      let _, _, itl, _, _ = E.get_checked_indtys status ref in
1084      Some (uri,List.length itl)
1085   | C.Prod (n,so,de) ->
1086      returns_a_coinductive status ~subst ((n,C.Decl so)::context) de
1087   | _ -> None
1088
1089 and type_of_constant status ((Ref.Ref (uri,_)) as ref) =
1090  let error () =
1091   raise (TypeCheckerFailure (lazy "Inconsistent cached infos in reference"))
1092  in
1093   match E.get_checked_obj status uri, ref with
1094   | (_,_,_,_,C.Inductive(isind1,lno1,tl,_)),Ref.Ref(_,Ref.Ind (isind2,i,lno2))->
1095       if isind1 <> isind2 || lno1 <> lno2 then error ();
1096       let _,_,arity,_ = List.nth tl i in arity
1097   | (_,_,_,_,C.Inductive (_,lno1,tl,_)), Ref.Ref (_,Ref.Con (i,j,lno2))  ->
1098       if lno1 <> lno2 then error ();
1099       let _,_,_,cl = List.nth tl i in
1100       let _,_,arity = List.nth cl (j-1) in
1101       arity
1102   | (_,_,_,_,C.Fixpoint (false,fl,_)), Ref.Ref (_,Ref.CoFix i) ->
1103       let _,_,_,arity,_ = List.nth fl i in
1104       arity
1105   | (_,h1,_,_,C.Fixpoint (true,fl,_)), Ref.Ref (_,Ref.Fix (i,recno2,h2)) ->
1106       let _,_,recno1,arity,_ = List.nth fl i in
1107       if h1 <> h2 || recno1 <> recno2 then error ();
1108       arity
1109   | (_,_,_,_,C.Constant (_,_,None,ty,_)), Ref.Ref (_,Ref.Decl) -> ty
1110   | (_,h1,_,_,C.Constant (_,_,Some _,ty,_)), Ref.Ref (_,Ref.Def h2) ->
1111      if h1 <> h2 then error ();
1112      ty
1113   | _ ->
1114     raise (AssertFailure
1115      (lazy ("type_of_constant: environment/reference: " ^
1116        Ref.string_of_reference ref)))
1117
1118 and get_relevance status ~metasenv ~subst context t args =
1119    let ty = typeof status ~subst ~metasenv context t in
1120    let rec aux context ty = function
1121      | [] -> []
1122      | arg::tl -> match R.whd status ~subst context ty with
1123        | C.Prod (_,so,de) ->
1124            let sort = typeof status ~subst ~metasenv context so in
1125            let new_ty = S.subst status ~avoid_beta_redexes:true arg de in
1126            (*prerr_endline ("so: " ^ status#ppterm ~subst ~metasenv:[]
1127              ~context so);
1128            prerr_endline ("sort: " ^ status#ppterm ~subst ~metasenv:[]
1129              ~context sort);*)
1130            (match R.whd status ~subst context sort with
1131               | C.Sort C.Prop ->
1132                   false::(aux context new_ty tl)
1133               | C.Sort _
1134               | C.Meta _ -> true::(aux context new_ty tl)
1135               | _ -> raise (TypeCheckerFailure (lazy (Printf.sprintf
1136                      "Prod: the type %s of the source of %s is not a sort"
1137                       (status#ppterm ~subst ~metasenv ~context sort)
1138                       (status#ppterm ~subst ~metasenv ~context so)))))
1139        | _ ->
1140           raise
1141             (TypeCheckerFailure
1142               (lazy (Printf.sprintf
1143                 "Appl: %s is not a function, it cannot be applied"
1144                 (status#ppterm ~subst ~metasenv ~context
1145                  (let res = List.length tl in
1146                   let eaten = List.length args - res in
1147                    (C.Appl
1148                     (t::fst
1149                      (HExtlib.split_nth eaten args))))))))
1150    in aux context ty args
1151 ;;
1152
1153 let typecheck_context status ~metasenv ~subst context =
1154  ignore
1155   (List.fold_right
1156    (fun d context  ->
1157      begin
1158       match d with
1159          _,C.Decl t -> ignore (typeof status ~metasenv ~subst:[] context t)
1160        | name,C.Def (te,ty) ->
1161          ignore (typeof status ~metasenv ~subst:[] context ty);
1162          let ty' = typeof status ~metasenv ~subst:[] context te in
1163           if not (R.are_convertible status ~metasenv ~subst context ty' ty) then
1164            raise (AssertFailure (lazy (Printf.sprintf (
1165             "the type of the definiens for %s in the context is not "^^
1166             "convertible with the declared one.\n"^^
1167             "inferred type:\n%s\nexpected type:\n%s")
1168             name (status#ppterm ~subst ~metasenv ~context ty')
1169             (status#ppterm ~subst ~metasenv ~context ty))))
1170      end;
1171      d::context
1172    ) context [])
1173 ;;
1174
1175 let typecheck_metasenv status metasenv =
1176  ignore
1177   (List.fold_left
1178     (fun metasenv (i,(_,context,ty) as conj) ->
1179       if List.mem_assoc i metasenv then
1180        raise (TypeCheckerFailure (lazy ("duplicate meta " ^ string_of_int i ^
1181         " in metasenv")));
1182       typecheck_context status ~metasenv ~subst:[] context;
1183       ignore (typeof status ~metasenv ~subst:[] context ty);
1184       metasenv @ [conj]
1185     ) [] metasenv)
1186 ;;
1187
1188 let typecheck_subst status ~metasenv subst =
1189  ignore
1190   (List.fold_left
1191     (fun subst (i,(_,context,ty,bo) as conj) ->
1192       if List.mem_assoc i subst then
1193        raise (AssertFailure (lazy ("duplicate meta " ^ string_of_int i ^
1194         " in substitution")));
1195       if List.mem_assoc i metasenv then
1196        raise (AssertFailure (lazy ("meta " ^ string_of_int i ^
1197         " is both in the metasenv and in the substitution")));
1198       typecheck_context status ~metasenv ~subst context;
1199       ignore (typeof status ~metasenv ~subst context ty);
1200       let ty' = typeof status ~metasenv ~subst context bo in
1201        if not (R.are_convertible status ~metasenv ~subst context ty' ty) then
1202         raise (AssertFailure (lazy (Printf.sprintf (
1203          "the type of the definiens for %d in the substitution is not "^^
1204          "convertible with the declared one.\n"^^
1205          "inferred type:\n%s\nexpected type:\n%s")
1206          i
1207          (status#ppterm ~subst ~metasenv ~context ty')
1208          (status#ppterm ~subst ~metasenv ~context ty))));
1209       subst @ [conj]
1210     ) [] subst)
1211 ;;
1212
1213 let height_of_term status tl =
1214  let h = ref 0 in
1215  let get_height (NReference.Ref (uri,_)) =
1216   let _,height,_,_,_ = NCicEnvironment.get_checked_obj status uri in
1217    height in
1218  let rec aux =
1219   function
1220      NCic.Meta (_,(_,NCic.Ctx l)) -> List.iter aux l
1221    | NCic.Meta _ -> ()
1222    | NCic.Rel _
1223    | NCic.Sort _ -> ()
1224    | NCic.Implicit _ -> assert false
1225    | NCic.Const nref -> h := max !h (get_height nref)
1226    | NCic.Prod (_,t1,t2)
1227    | NCic.Lambda (_,t1,t2) -> aux t1; aux t2
1228    | NCic.LetIn (_,s,ty,t) -> aux s; aux ty; aux t
1229    | NCic.Appl l -> List.iter aux l
1230    | NCic.Match (_,outty,t,pl) -> aux outty; aux t; List.iter aux pl
1231  in
1232   List.iter aux tl;
1233   1 + !h
1234 ;;
1235
1236 let height_of_obj_kind status uri ~subst =
1237  function
1238     NCic.Inductive _
1239   | NCic.Constant (_,_,None,_,_)
1240   | NCic.Fixpoint (false,_,_) -> 0
1241   | NCic.Fixpoint (true,ifl,_) ->
1242      let iflno = List.length ifl in
1243       height_of_term status
1244        (List.fold_left
1245         (fun l (_,_,_,ty,bo) ->
1246           let bo = debruijn status uri iflno [] ~subst bo in
1247            ty::bo::l
1248        ) [] ifl)
1249   | NCic.Constant (_,_,Some bo,ty,_) -> height_of_term status [bo;ty]
1250 ;;
1251
1252 let typecheck_obj status (uri,height,metasenv,subst,kind) =
1253 (*height must be checked since it is not only an optimization during reduction*)
1254  let iheight = height_of_obj_kind status uri ~subst kind in
1255  if height <> iheight then
1256   raise (TypeCheckerFailure (lazy (Printf.sprintf
1257    "the declared object height (%d) is not the inferred one (%d)"
1258    height iheight)));
1259  typecheck_metasenv status metasenv;
1260  typecheck_subst status ~metasenv subst;
1261  match kind with
1262    | C.Constant (relevance,_,Some te,ty,_) ->
1263       let _ = typeof status ~subst ~metasenv [] ty in
1264       let ty_te = typeof status ~subst ~metasenv [] te in
1265       if not (R.are_convertible status ~metasenv ~subst [] ty_te ty) then
1266        raise (TypeCheckerFailure (lazy (Printf.sprintf (
1267         "the type of the body is not convertible with the declared one.\n"^^
1268         "inferred type:\n%s\nexpected type:\n%s")
1269         (status#ppterm ~subst ~metasenv ~context:[] ty_te)
1270         (status#ppterm ~subst ~metasenv ~context:[] ty))));
1271       check_relevance status ~subst ~metasenv [] relevance ty
1272       (*check_relevance status ~in_type:false ~subst ~metasenv relevance te*)
1273    | C.Constant (relevance,_,None,ty,_) ->
1274       ignore (typeof status ~subst ~metasenv [] ty);
1275       check_relevance status ~subst ~metasenv [] relevance ty
1276    | C.Inductive (_, leftno, tyl, _) ->
1277        check_mutual_inductive_defs status uri ~metasenv ~subst leftno tyl
1278    | C.Fixpoint (inductive,fl,_) ->
1279       let types, kl =
1280         List.fold_left
1281          (fun (types,kl) (relevance,name,k,ty,_) ->
1282            let _ = typeof status ~subst ~metasenv [] ty in
1283             check_relevance status ~subst ~metasenv [] relevance ty;
1284             ((name,C.Decl ty)::types, k::kl)
1285          ) ([],[]) fl
1286       in
1287       let len = List.length types in
1288       let dfl, kl =
1289         List.split (List.map2
1290           (fun (_,_,_,_,bo) rno ->
1291              let dbo = debruijn status uri len [] ~subst bo in
1292              dbo, Evil rno)
1293           fl kl)
1294       in
1295       List.iter2 (fun (_,_,x,ty,_) bo ->
1296        let ty_bo = typeof status ~subst ~metasenv types bo in
1297        if not (R.are_convertible status ~metasenv ~subst types ty_bo ty)
1298        then raise (TypeCheckerFailure (lazy ("(Co)Fix: ill-typed bodies")))
1299        else
1300         if inductive then begin
1301           let m, context = eat_lambdas status ~subst ~metasenv types (x + 1) bo in
1302           let r_uri, r_len =
1303             let he =
1304              match List.hd context with _,C.Decl t -> t | _ -> assert false
1305             in
1306             match R.whd status ~subst (List.tl context) he with
1307             | C.Const (Ref.Ref (uri,Ref.Ind _) as ref)
1308             | C.Appl (C.Const (Ref.Ref (uri,Ref.Ind _) as ref) :: _) ->
1309                 let _,_,itl,_,_ = E.get_checked_indtys status ref in
1310                   uri, List.length itl
1311             | _ ->
1312               raise (TypeCheckerFailure
1313                (lazy "Fix: the recursive argument is not inductive"))
1314           in
1315           (* guarded by destructors conditions D{f,k,x,M} *)
1316           let rec enum_from k =
1317             function [] -> [] | v::tl -> (k,v)::enum_from (k+1) tl
1318           in
1319           guarded_by_destructors status r_uri r_len
1320            ~subst ~metasenv context (enum_from (x+2) kl) m
1321         end else
1322          match returns_a_coinductive status ~subst [] ty with
1323           | None ->
1324              raise (TypeCheckerFailure
1325                (lazy "CoFix: does not return a coinductive type"))
1326           | Some (r_uri, r_len) ->
1327              (* guarded by constructors conditions C{f,M} *)
1328              if not
1329              (guarded_by_constructors status ~subst ~metasenv types bo r_uri r_len len)
1330              then
1331                raise (TypeCheckerFailure
1332                 (lazy ("CoFix: not guarded by constructors: " ^ status#ppobj (uri,height,metasenv,subst,kind))))
1333         ) fl dfl
1334 ;;
1335
1336 (* trust *)
1337
1338 let trust = ref  (fun _ -> false);;
1339 let set_trust f = trust := f
1340 let trust_obj obj = !trust obj
1341
1342
1343 (* web interface stuff *)
1344
1345 let logger =
1346  ref (function (`Start_type_checking _|`Type_checking_completed _|`Type_checking_interrupted _|`Type_checking_failed _|`Trust_obj _) -> ())
1347 ;;
1348
1349 let set_logger f = logger := f;;
1350
1351 let typecheck_obj status obj =
1352  let u,_,_,_,_ = obj in
1353  try
1354   !logger (`Start_type_checking u);
1355   typecheck_obj status obj;
1356   !logger (`Type_checking_completed u)
1357  with
1358     Sys.Break as e ->
1359      !logger (`Type_checking_interrupted u);
1360      raise e
1361   | e ->
1362      !logger (`Type_checking_failed u);
1363      raise e
1364 ;;
1365
1366 E.set_typecheck_obj
1367  (fun status obj ->
1368    if trust_obj obj then
1369     let u,_,_,_,_ = obj in
1370      !logger (`Trust_obj u)
1371    else
1372     typecheck_obj status obj)
1373 ;;
1374
1375 let _ = NCicReduction.set_get_relevance get_relevance;;
1376
1377 let indent = ref 0;;
1378 let debug = true;;
1379 let logger =
1380     let do_indent () = String.make !indent ' ' in
1381     (function
1382       | `Start_type_checking s ->
1383           if debug then
1384            prerr_endline (do_indent () ^ "Start: " ^ NUri.string_of_uri s);
1385           incr indent
1386       | `Type_checking_completed s ->
1387           decr indent;
1388           if debug then
1389            prerr_endline (do_indent () ^ "End: " ^ NUri.string_of_uri s)
1390       | `Type_checking_interrupted s ->
1391           decr indent;
1392           if debug then
1393            prerr_endline (do_indent () ^ "Break: " ^ NUri.string_of_uri s)
1394       | `Type_checking_failed s ->
1395           decr indent;
1396           if debug then
1397            prerr_endline (do_indent () ^ "Fail: " ^ NUri.string_of_uri s)
1398       | `Trust_obj s ->
1399           if debug then
1400            prerr_endline (do_indent () ^ "Trust: " ^ NUri.string_of_uri s))
1401 ;;
1402 (* let _ = set_logger logger ;; *)
1403 (* EOF *)