matita/components/ng_library/nCicLibrary.ml

   1 (*
   2     ||M||  This file is part of HELM, an Hypertextual, Electronic
   3     ||A||  Library of Mathematics, developed at the Computer Science
   4     ||T||  Department, University of Bologna, Italy.
   5     ||I||
   6     ||T||  HELM is free software; you can redistribute it and/or
   7     ||A||  modify it under the terms of the GNU General Public License
   8     \   /  version 2 or (at your option) any later version.
   9      \ /   This software is distributed as is, NO WARRANTY.
  10       V_______________________________________________________________ *)
  11
  12 (* $Id$ *)
  13
  14 exception LibraryOutOfSync of string Lazy.t
  15 exception IncludedFileNotCompiled of string * string
  16
  17 let magic = 2;;
  18
  19 let refresh_uri uri = NUri.uri_of_string (NUri.string_of_uri uri);;
  20
  21 let refresh_uri_in_universe =
  22  List.map (fun (x,u) -> x, refresh_uri u)
  23 ;;
  24
  25 let rec refresh_uri_in_term =
  26  function
  27   | NCic.Meta (i,(n,NCic.Ctx l)) ->
  28      NCic.Meta (i,(n,NCic.Ctx (List.map refresh_uri_in_term l)))
  29   | NCic.Meta _ as t -> t
  30   | NCic.Const (NReference.Ref (u,spec)) ->
  31      NCic.Const (NReference.reference_of_spec (refresh_uri u) spec)
  32   | NCic.Sort (NCic.Type l) -> NCic.Sort (NCic.Type (refresh_uri_in_universe l))
  33   | NCic.Match (NReference.Ref (uri,spec),outtype,term,pl) ->
  34      let r = NReference.reference_of_spec (refresh_uri uri) spec in
  35      let outtype = refresh_uri_in_term outtype in
  36      let term = refresh_uri_in_term term in
  37      let pl = List.map refresh_uri_in_term pl in
  38       NCic.Match (r,outtype,term,pl)
  39   | t -> NCicUtils.map (fun _ _ -> ()) () (fun _ -> refresh_uri_in_term) t
  40 ;;
  41
  42 let refresh_uri_in_obj (uri,height,metasenv,subst,obj_kind) =
  43  assert (metasenv = []);
  44  assert (subst = []);
  45  refresh_uri uri,height,metasenv,subst,
  46   NCicUntrusted.map_obj_kind refresh_uri_in_term obj_kind
  47 ;;
  48
  49 let path_of_baseuri ?(no_suffix=false) baseuri =
  50  let uri = NUri.string_of_uri baseuri in
  51  let path = String.sub uri 4 (String.length uri - 4) in
  52  let path = Helm_registry.get "matita.basedir" ^ path in
  53  let dirname = Filename.dirname path in
  54   HExtlib.mkdir dirname;
  55   if no_suffix then
  56    path
  57   else
  58    path ^ ".ng"
  59 ;;
  60
  61 let require_path path =
  62  let ch = open_in path in
  63  let mmagic,dump = Marshal.from_channel ch in
  64   close_in ch;
  65   if mmagic <> magic then
  66    raise (LibraryOutOfSync (lazy "The library is out of sync with the implementation. Please recompile the library."))
  67   else
  68    dump
  69 ;;
  70
  71 let require0 ~baseuri =
  72   require_path (path_of_baseuri baseuri)
  73 ;;
  74
  75 let db_path () = Helm_registry.get "matita.basedir" ^ "/ng_db.ng";;
  76
  77
  78 type timestamp =
  79  [ `Obj of NUri.uri * NCic.obj
  80  | `Constr of NCic.universe * NCic.universe] list *
  81  (NUri.uri * string * NReference.reference) list *
  82  NCic.obj NUri.UriMap.t *
  83  NUri.uri list
  84 ;;
  85
  86 let time0 = [],[],NUri.UriMap.empty,[];;
  87 let storage = ref [];;
  88 let local_aliases = ref [];;
  89 let cache = ref NUri.UriMap.empty;;
  90 let includes = ref [];;
  91
  92 let load_db,set_global_aliases,get_global_aliases,add_deps,get_deps,remove_deps=
  93  let global_aliases = ref [] in
  94  let rev_includes_map = ref NUri.UriMap.empty in
  95  let store_db () =
  96   let ch = open_out (db_path ()) in
  97   Marshal.to_channel ch (magic,(!global_aliases,!rev_includes_map)) [];
  98   close_out ch in
  99  let load_db () =
 100   HExtlib.mkdir (Helm_registry.get "matita.basedir");
 101   try
 102    let ga,im = require_path (db_path ()) in
 103    let ga =
 104     List.map
 105      (fun (uri,name,NReference.Ref (uri2,spec)) ->
 106        refresh_uri uri,name,NReference.reference_of_spec (refresh_uri uri2) spec
 107      ) ga in
 108    let im =
 109     NUri.UriMap.fold
 110      (fun u l im -> NUri.UriMap.add (refresh_uri u) (List.map refresh_uri l) im
 111      ) im NUri.UriMap.empty
 112    in
 113     global_aliases := ga;
 114     rev_includes_map := im
 115   with
 116    Sys_error _ -> () in
 117  let get_deps u =
 118   let get_deps_one_step u =
 119     try NUri.UriMap.find u !rev_includes_map with Not_found -> [] in
 120   let rec aux res =
 121    function
 122       [] -> res
 123     | he::tl ->
 124        if List.mem he res then
 125         aux res tl
 126        else
 127         aux (he::res) (get_deps_one_step he @ tl)
 128   in
 129    aux [] [u] in
 130  let remove_deps u =
 131   rev_includes_map := NUri.UriMap.remove u !rev_includes_map;
 132   rev_includes_map :=
 133    NUri.UriMap.map
 134     (fun l -> List.filter (fun uri -> not (NUri.eq u uri)) l) !rev_includes_map;
 135   store_db ()
 136  in
 137   load_db,
 138   (fun ga -> global_aliases := ga; store_db ()),
 139   (fun () -> !global_aliases),
 140   (fun u l ->
 141     rev_includes_map := NUri.UriMap.add u (l @ get_deps u) !rev_includes_map;
 142     store_db ()),
 143   get_deps,
 144   remove_deps
 145 ;;
 146
 147 let init = load_db;;
 148
 149 class status =
 150  object(self)
 151   val timestamp = (time0 : timestamp)
 152   method timestamp = timestamp
 153   method set_timestamp v = {< timestamp = v >}
 154  end
 155
 156 let time_travel status =
 157  let sto,ali,cac,inc = status#timestamp in
 158   let diff_len = List.length !storage - List.length sto in
 159   let to_be_deleted,_ = HExtlib.split_nth diff_len !storage in
 160    if List.length to_be_deleted > 0 then
 161      NCicEnvironment.invalidate_item (HExtlib.list_last to_be_deleted);
 162    storage := sto; local_aliases := ali; cache := cac; includes := inc
 163 ;;
 164
 165 let serialize ~baseuri dump =
 166  let ch = open_out (path_of_baseuri baseuri) in
 167  Marshal.to_channel ch (magic,dump) [];
 168  close_out ch;
 169  List.iter
 170   (function
 171    | `Obj (uri,obj) ->
 172        let ch = open_out (path_of_baseuri uri) in
 173        Marshal.to_channel ch (magic,obj) [];
 174        close_out ch
 175    | `Constr _ -> ()
 176   ) !storage;
 177  set_global_aliases (!local_aliases @ get_global_aliases ());
 178  List.iter (fun u -> add_deps u [baseuri]) !includes;
 179  time_travel (new status)
 180 ;;
 181
 182 type obj = string * Obj.t
 183
 184 class dumpable_status =
 185  object(self)
 186   val dump = ([] : obj list)
 187   method dump = dump
 188   method set_dump v = {< dump = v >}
 189  end
 190
 191 module type SerializerType =
 192  sig
 193   type dumpable_status
 194
 195   type 'a register_type =
 196    'a ->
 197     refresh_uri_in_universe:(NCic.universe -> NCic.universe) ->
 198     refresh_uri_in_term:(NCic.term -> NCic.term) ->
 199      dumpable_status -> dumpable_status
 200
 201   val register: < run: 'a.  string -> 'a register_type -> ('a -> obj) >
 202   val serialize: baseuri:NUri.uri -> obj list -> unit
 203    (* the obj is the "include" command to be added to the dump list *)
 204   val require: baseuri:NUri.uri -> dumpable_status -> dumpable_status * obj
 205  end
 206
 207 module Serializer(D: sig type dumpable_status end) =
 208  struct
 209   type dumpable_status = D.dumpable_status
 210   type 'a register_type =
 211    'a ->
 212     refresh_uri_in_universe:(NCic.universe -> NCic.universe) ->
 213     refresh_uri_in_term:(NCic.term -> NCic.term) ->
 214      dumpable_status -> dumpable_status
 215
 216   let require1 = ref (fun _ -> assert false) (* unknown data*)
 217   let already_registered = ref []
 218
 219   let register =
 220    object
 221     method run : 'a.  string -> 'a register_type -> ('a -> obj)
 222     = fun tag require ->
 223      assert (not (List.mem tag !already_registered));
 224      already_registered := tag :: !already_registered;
 225      let old_require1 = !require1 in
 226      require1 :=
 227       (fun ((tag',data) as x) ->
 228         if tag=tag' then
 229          require (Obj.magic data) ~refresh_uri_in_universe ~refresh_uri_in_term
 230         else
 231          old_require1 x);
 232      (fun x -> tag,Obj.repr x)
 233    end
 234
 235   let serialize = serialize
 236
 237   let require2 ~baseuri status =
 238    try
 239     includes := baseuri::!includes;
 240     let dump = require0 ~baseuri in
 241      List.fold_right !require1 dump status
 242    with
 243     Sys_error _ ->
 244      raise (IncludedFileNotCompiled(path_of_baseuri baseuri,NUri.string_of_uri baseuri))
 245
 246   let record_include =
 247    let aux baseuri ~refresh_uri_in_universe ~refresh_uri_in_term =
 248      (* memorizzo baseuri in una tabella; *)
 249      require2 ~baseuri
 250    in
 251     register#run "include" aux
 252
 253   let require ~baseuri status =
 254    let status = require2 ~baseuri status in
 255     status,record_include baseuri
 256 end
 257
 258
 259 let decompile ~baseuri =
 260  let baseuris = get_deps baseuri in
 261  List.iter (fun baseuri ->
 262   remove_deps baseuri;
 263   HExtlib.safe_remove (path_of_baseuri baseuri);
 264   let basepath = path_of_baseuri ~no_suffix:true baseuri in
 265   try
 266    let od = Unix.opendir basepath in
 267    let rec aux names =
 268     try
 269      let name = Unix.readdir od in
 270       if name <> "." && name <> ".." then aux (name::names) else aux names
 271     with
 272      End_of_file -> names in
 273    let names = List.map (fun name -> basepath ^ "/" ^ name) (aux []) in
 274     Unix.closedir od;
 275     List.iter Unix.unlink names;
 276     HExtlib.rmdir_descend basepath;
 277     set_global_aliases
 278      (List.filter
 279       (fun (_,_,NReference.Ref (nuri,_)) ->
 280         Filename.dirname (NUri.string_of_uri nuri) <> NUri.string_of_uri baseuri
 281       ) (get_global_aliases ()))
 282   with
 283    Unix.Unix_error _ -> () (* raised by Unix.opendir, we hope :-) *)
 284  ) baseuris
 285 ;;
 286
 287 LibraryClean.set_decompile_cb
 288  (fun ~baseuri -> decompile ~baseuri:(NUri.uri_of_string baseuri));;
 289
 290 let fetch_obj uri =
 291  let obj = require0 ~baseuri:uri in
 292   refresh_uri_in_obj obj
 293 ;;
 294
 295 let resolve name =
 296  try
 297   HExtlib.filter_map
 298    (fun (_,name',nref) -> if name'=name then Some nref else None)
 299    (!local_aliases @ get_global_aliases ())
 300  with
 301   Not_found -> raise (NCicEnvironment.ObjectNotFound (lazy name))
 302 ;;
 303
 304 let aliases_of uri =
 305   HExtlib.filter_map
 306    (fun (uri',_,nref) ->
 307      if NUri.eq uri' uri then Some nref else None) !local_aliases
 308 ;;
 309
 310 let add_obj status ((u,_,_,_,_) as obj) =
 311  NCicEnvironment.check_and_add_obj obj;
 312  storage := (`Obj (u,obj))::!storage;
 313   let _,height,_,_,obj = obj in
 314   let references =
 315    match obj with
 316       NCic.Constant (_,name,None,_,_) ->
 317        [u,name,NReference.reference_of_spec u NReference.Decl]
 318     | NCic.Constant (_,name,Some _,_,_) ->
 319        [u,name,NReference.reference_of_spec u (NReference.Def height)]
 320     | NCic.Fixpoint (is_ind,fl,_) ->
 321        HExtlib.list_mapi
 322         (fun (_,name,recno,_,_) i ->
 323           if is_ind then
 324            u,name,NReference.reference_of_spec u(NReference.Fix(i,recno,height))
 325           else
 326            u,name,NReference.reference_of_spec u (NReference.CoFix i)) fl
 327     | NCic.Inductive (inductive,leftno,il,_) ->
 328        List.flatten
 329         (HExtlib.list_mapi
 330          (fun (_,iname,_,cl) i ->
 331            HExtlib.list_mapi
 332             (fun (_,cname,_) j->
 333               u,cname,
 334                NReference.reference_of_spec u (NReference.Con (i,j+1,leftno))
 335             ) cl @
 336            [u,iname,
 337              NReference.reference_of_spec u
 338               (NReference.Ind (inductive,i,leftno))]
 339          ) il)
 340   in
 341   local_aliases := references @ !local_aliases;
 342   status#set_timestamp (!storage,!local_aliases,!cache,!includes)
 343 ;;
 344
 345 let add_constraint status u1 u2 =
 346   NCicEnvironment.add_lt_constraint u1 u2;
 347   storage := (`Constr (u1,u2)) :: !storage;
 348   status#set_timestamp (!storage,!local_aliases,!cache,!includes)
 349 ;;
 350
 351 let get_obj u =
 352  try
 353   List.assq u
 354    (HExtlib.filter_map
 355     (function `Obj (u,o) -> Some (u,o) | _ -> None )
 356     !storage)
 357  with Not_found ->
 358   try fetch_obj u
 359   with Sys_error _ ->
 360    try NUri.UriMap.find u !cache
 361    with Not_found ->
 362     raise (NCicEnvironment.ObjectNotFound
 363              (lazy (NUri.string_of_uri u)))
 364 ;;
 365
 366 let clear_cache () = cache := NUri.UriMap.empty;;
 367
 368 NCicEnvironment.set_get_obj get_obj;;
 369 NCicPp.set_get_obj get_obj;;