matita/components/ng_library/nCicLibrary.ml

   1 (*
   2     ||M||  This file is part of HELM, an Hypertextual, Electronic
   3     ||A||  Library of Mathematics, developed at the Computer Science
   4     ||T||  Department, University of Bologna, Italy.
   5     ||I||
   6     ||T||  HELM is free software; you can redistribute it and/or
   7     ||A||  modify it under the terms of the GNU General Public License
   8     \   /  version 2 or (at your option) any later version.
   9      \ /   This software is distributed as is, NO WARRANTY.
  10       V_______________________________________________________________ *)
  11
  12 (* $Id$ *)
  13
  14 exception LibraryOutOfSync of string Lazy.t
  15 exception IncludedFileNotCompiled of string * string
  16
  17 let magic = 2;;
  18
  19 let refresh_uri uri = NUri.uri_of_string (NUri.string_of_uri uri);;
  20
  21 let refresh_uri_in_universe =
  22  List.map (fun (x,u) -> x, refresh_uri u)
  23 ;;
  24
  25 let rec refresh_uri_in_term =
  26  function
  27   | NCic.Meta (i,(n,NCic.Ctx l)) ->
  28      NCic.Meta (i,(n,NCic.Ctx (List.map refresh_uri_in_term l)))
  29   | NCic.Meta _ as t -> t
  30   | NCic.Const (NReference.Ref (u,spec)) ->
  31      NCic.Const (NReference.reference_of_spec (refresh_uri u) spec)
  32   | NCic.Sort (NCic.Type l) -> NCic.Sort (NCic.Type (refresh_uri_in_universe l))
  33   | NCic.Match (NReference.Ref (uri,spec),outtype,term,pl) ->
  34      let r = NReference.reference_of_spec (refresh_uri uri) spec in
  35      let outtype = refresh_uri_in_term outtype in
  36      let term = refresh_uri_in_term term in
  37      let pl = List.map refresh_uri_in_term pl in
  38       NCic.Match (r,outtype,term,pl)
  39   | t -> NCicUtils.map (fun _ _ -> ()) () (fun _ -> refresh_uri_in_term) t
  40 ;;
  41
  42 let refresh_uri_in_obj (uri,height,metasenv,subst,obj_kind) =
  43  assert (metasenv = []);
  44  assert (subst = []);
  45  refresh_uri uri,height,metasenv,subst,
  46   NCicUntrusted.map_obj_kind refresh_uri_in_term obj_kind
  47 ;;
  48
  49 let path_of_baseuri ?(no_suffix=false) baseuri =
  50  let uri = NUri.string_of_uri baseuri in
  51  let path = String.sub uri 4 (String.length uri - 4) in
  52  let path = Helm_registry.get "matita.basedir" ^ path in
  53  let dirname = Filename.dirname path in
  54   HExtlib.mkdir dirname;
  55   if no_suffix then
  56    path
  57   else
  58    path ^ ".ng"
  59 ;;
  60
  61 let require_path path =
  62  let ch = open_in path in
  63  let mmagic,dump = Marshal.from_channel ch in
  64   close_in ch;
  65   if mmagic <> magic then
  66    raise (LibraryOutOfSync (lazy "The library is out of sync with the implementation. Please recompile the library."))
  67   else
  68    dump
  69 ;;
  70
  71 let require0 ~baseuri =
  72   require_path (path_of_baseuri baseuri)
  73 ;;
  74
  75 let db_path () = Helm_registry.get "matita.basedir" ^ "/ng_db.ng";;
  76
  77
  78 type timestamp =
  79  [ `Obj of NUri.uri * NCic.obj
  80  | `Constr of NCic.universe * NCic.universe] list *
  81  (NUri.uri * string * NReference.reference) list *
  82  NCic.obj NUri.UriMap.t *
  83  NUri.uri list
  84 ;;
  85
  86 let time0 = [],[],NUri.UriMap.empty,[];;
  87 let storage = ref [];;
  88 let local_aliases = ref [];;
  89 let cache = ref NUri.UriMap.empty;;
  90 let includes = ref [];;
  91
  92 let load_db,set_global_aliases,get_global_aliases,add_deps,get_deps,remove_deps=
  93  let global_aliases = ref [] in
  94  let rev_includes_map = ref NUri.UriMap.empty in
  95  let store_db () =
  96   let ch = open_out (db_path ()) in
  97   Marshal.to_channel ch (magic,(!global_aliases,!rev_includes_map)) [];
  98   close_out ch in
  99  let load_db () =
 100   HExtlib.mkdir (Helm_registry.get "matita.basedir");
 101   try
 102    let ga,im = require_path (db_path ()) in
 103    let ga =
 104     List.map
 105      (fun (uri,name,NReference.Ref (uri2,spec)) ->
 106        refresh_uri uri,name,NReference.reference_of_spec (refresh_uri uri2) spec
 107      ) ga in
 108    let im =
 109     NUri.UriMap.fold
 110      (fun u l im -> NUri.UriMap.add (refresh_uri u) (List.map refresh_uri l) im
 111      ) im NUri.UriMap.empty
 112    in
 113     global_aliases := ga;
 114     rev_includes_map := im
 115   with
 116    Sys_error _ -> () in
 117  let get_deps u =
 118   let get_deps_one_step u =
 119     try NUri.UriMap.find u !rev_includes_map with Not_found -> [] in
 120   let rec aux res =
 121    function
 122       [] -> res
 123     | he::tl ->
 124        if List.mem he res then
 125         aux res tl
 126        else
 127         aux (he::res) (get_deps_one_step he @ tl)
 128   in
 129    aux [] [u] in
 130  let remove_deps u =
 131   rev_includes_map := NUri.UriMap.remove u !rev_includes_map;
 132   rev_includes_map :=
 133    NUri.UriMap.map
 134     (fun l -> List.filter (fun uri -> not (NUri.eq u uri)) l) !rev_includes_map;
 135   store_db ()
 136  in
 137   load_db,
 138   (fun ga -> global_aliases := ga; store_db ()),
 139   (fun () -> !global_aliases),
 140   (fun u l ->
 141     rev_includes_map := NUri.UriMap.add u (l @ get_deps u) !rev_includes_map;
 142     store_db ()),
 143   get_deps,
 144   remove_deps
 145 ;;
 146
 147 let init = load_db;;
 148
 149 class type g_status =
 150  object
 151   method timestamp: timestamp
 152  end
 153
 154 class status =
 155  object(self)
 156   val timestamp = (time0 : timestamp)
 157   method timestamp = timestamp
 158   method set_timestamp v = {< timestamp = v >}
 159   method set_library_status
 160    : 'status. #g_status as 'status -> 'self
 161    = fun o -> self#set_timestamp o#timestamp
 162  end
 163
 164 let time_travel status =
 165  let sto,ali,cac,inc = status#timestamp in
 166   let diff_len = List.length !storage - List.length sto in
 167   let to_be_deleted,_ = HExtlib.split_nth diff_len !storage in
 168    if List.length to_be_deleted > 0 then
 169      NCicEnvironment.invalidate_item (HExtlib.list_last to_be_deleted);
 170    storage := sto; local_aliases := ali; cache := cac; includes := inc
 171 ;;
 172
 173 let serialize ~baseuri dump =
 174  let ch = open_out (path_of_baseuri baseuri) in
 175  Marshal.to_channel ch (magic,dump) [];
 176  close_out ch;
 177  List.iter
 178   (function
 179    | `Obj (uri,obj) ->
 180        let ch = open_out (path_of_baseuri uri) in
 181        Marshal.to_channel ch (magic,obj) [];
 182        close_out ch
 183    | `Constr _ -> ()
 184   ) !storage;
 185  set_global_aliases (!local_aliases @ get_global_aliases ());
 186  List.iter (fun u -> add_deps u [baseuri]) !includes;
 187  time_travel (new status)
 188 ;;
 189
 190 type obj = string * Obj.t
 191
 192 class dumpable_status =
 193  object(self)
 194   val dump = ([] : obj list)
 195   method dump = dump
 196   method set_dump v = {< dump = v >}
 197  end
 198
 199 module type SerializerType =
 200  sig
 201   type dumpable_status
 202
 203   type 'a register_type =
 204    'a ->
 205     refresh_uri_in_universe:(NCic.universe -> NCic.universe) ->
 206     refresh_uri_in_term:(NCic.term -> NCic.term) ->
 207      dumpable_status -> dumpable_status
 208
 209   val register: < run: 'a.  string -> 'a register_type -> ('a -> obj) >
 210   val serialize: baseuri:NUri.uri -> obj list -> unit
 211    (* the obj is the "include" command to be added to the dump list *)
 212   val require: baseuri:NUri.uri -> dumpable_status -> dumpable_status * obj
 213  end
 214
 215 module Serializer(D: sig type dumpable_status end) =
 216  struct
 217   type dumpable_status = D.dumpable_status
 218   type 'a register_type =
 219    'a ->
 220     refresh_uri_in_universe:(NCic.universe -> NCic.universe) ->
 221     refresh_uri_in_term:(NCic.term -> NCic.term) ->
 222      dumpable_status -> dumpable_status
 223
 224   let require1 = ref (fun _ -> assert false) (* unknown data*)
 225   let already_registered = ref []
 226
 227   let register =
 228    object
 229     method run : 'a.  string -> 'a register_type -> ('a -> obj)
 230     = fun tag require ->
 231      assert (not (List.mem tag !already_registered));
 232      already_registered := tag :: !already_registered;
 233      let old_require1 = !require1 in
 234      require1 :=
 235       (fun ((tag',data) as x) ->
 236         if tag=tag' then
 237          require (Obj.magic data) ~refresh_uri_in_universe ~refresh_uri_in_term
 238         else
 239          old_require1 x);
 240      (fun x -> tag,Obj.repr x)
 241    end
 242
 243   let serialize = serialize
 244
 245   let require2 ~baseuri status =
 246    try
 247     includes := baseuri::!includes;
 248     let dump = require0 ~baseuri in
 249      List.fold_right !require1 dump status
 250    with
 251     Sys_error _ ->
 252      raise (IncludedFileNotCompiled(path_of_baseuri baseuri,NUri.string_of_uri baseuri))
 253
 254   let record_include =
 255    let aux baseuri ~refresh_uri_in_universe ~refresh_uri_in_term =
 256      (* memorizzo baseuri in una tabella; *)
 257      require2 ~baseuri
 258    in
 259     register#run "include" aux
 260
 261   let require ~baseuri status =
 262    let status = require2 ~baseuri status in
 263     status,record_include baseuri
 264 end
 265
 266
 267 let decompile ~baseuri =
 268  let baseuris = get_deps baseuri in
 269  List.iter (fun baseuri ->
 270   remove_deps baseuri;
 271   HExtlib.safe_remove (path_of_baseuri baseuri);
 272   let basepath = path_of_baseuri ~no_suffix:true baseuri in
 273   try
 274    let od = Unix.opendir basepath in
 275    let rec aux names =
 276     try
 277      let name = Unix.readdir od in
 278       if name <> "." && name <> ".." then aux (name::names) else aux names
 279     with
 280      End_of_file -> names in
 281    let names = List.map (fun name -> basepath ^ "/" ^ name) (aux []) in
 282     Unix.closedir od;
 283     List.iter Unix.unlink names;
 284     HExtlib.rmdir_descend basepath;
 285     set_global_aliases
 286      (List.filter
 287       (fun (_,_,NReference.Ref (nuri,_)) ->
 288         Filename.dirname (NUri.string_of_uri nuri) <> NUri.string_of_uri baseuri
 289       ) (get_global_aliases ()))
 290   with
 291    Unix.Unix_error _ -> () (* raised by Unix.opendir, we hope :-) *)
 292  ) baseuris
 293 ;;
 294
 295 LibraryClean.set_decompile_cb
 296  (fun ~baseuri -> decompile ~baseuri:(NUri.uri_of_string baseuri));;
 297
 298 let fetch_obj uri =
 299  let obj = require0 ~baseuri:uri in
 300   refresh_uri_in_obj obj
 301 ;;
 302
 303 let resolve name =
 304  try
 305   HExtlib.filter_map
 306    (fun (_,name',nref) -> if name'=name then Some nref else None)
 307    (!local_aliases @ get_global_aliases ())
 308  with
 309   Not_found -> raise (NCicEnvironment.ObjectNotFound (lazy name))
 310 ;;
 311
 312 let aliases_of uri =
 313   HExtlib.filter_map
 314    (fun (uri',_,nref) ->
 315      if NUri.eq uri' uri then Some nref else None) !local_aliases
 316 ;;
 317
 318 let add_obj status ((u,_,_,_,_) as obj) =
 319  NCicEnvironment.check_and_add_obj obj;
 320  storage := (`Obj (u,obj))::!storage;
 321   let _,height,_,_,obj = obj in
 322   let references =
 323    match obj with
 324       NCic.Constant (_,name,None,_,_) ->
 325        [u,name,NReference.reference_of_spec u NReference.Decl]
 326     | NCic.Constant (_,name,Some _,_,_) ->
 327        [u,name,NReference.reference_of_spec u (NReference.Def height)]
 328     | NCic.Fixpoint (is_ind,fl,_) ->
 329        HExtlib.list_mapi
 330         (fun (_,name,recno,_,_) i ->
 331           if is_ind then
 332            u,name,NReference.reference_of_spec u(NReference.Fix(i,recno,height))
 333           else
 334            u,name,NReference.reference_of_spec u (NReference.CoFix i)) fl
 335     | NCic.Inductive (inductive,leftno,il,_) ->
 336        List.flatten
 337         (HExtlib.list_mapi
 338          (fun (_,iname,_,cl) i ->
 339            HExtlib.list_mapi
 340             (fun (_,cname,_) j->
 341               u,cname,
 342                NReference.reference_of_spec u (NReference.Con (i,j+1,leftno))
 343             ) cl @
 344            [u,iname,
 345              NReference.reference_of_spec u
 346               (NReference.Ind (inductive,i,leftno))]
 347          ) il)
 348   in
 349   local_aliases := references @ !local_aliases;
 350   status#set_timestamp (!storage,!local_aliases,!cache,!includes)
 351 ;;
 352
 353 let add_constraint status u1 u2 =
 354   NCicEnvironment.add_lt_constraint u1 u2;
 355   storage := (`Constr (u1,u2)) :: !storage;
 356   status#set_timestamp (!storage,!local_aliases,!cache,!includes)
 357 ;;
 358
 359 let get_obj u =
 360  try
 361   List.assq u
 362    (HExtlib.filter_map
 363     (function `Obj (u,o) -> Some (u,o) | _ -> None )
 364     !storage)
 365  with Not_found ->
 366   try fetch_obj u
 367   with Sys_error _ ->
 368    try NUri.UriMap.find u !cache
 369    with Not_found ->
 370     raise (NCicEnvironment.ObjectNotFound
 371              (lazy (NUri.string_of_uri u)))
 372 ;;
 373
 374 let clear_cache () = cache := NUri.UriMap.empty;;
 375
 376 NCicEnvironment.set_get_obj get_obj;;
 377 NCicPp.set_get_obj get_obj;;